Add ARM files

[dh-make-perl] / dev / arm / libperl-critic-perl / libperl-critic-perl-1.088 / lib / Perl / Critic / Policy / Subroutines / ProtectPrivateSubs.pm

diff --git a/dev/arm/libperl-critic-perl/libperl-critic-perl-1.088/lib/Perl/Critic/Policy/Subroutines/ProtectPrivateSubs.pm b/dev/arm/libperl-critic-perl/libperl-critic-perl-1.088/lib/Perl/Critic/Policy/Subroutines/ProtectPrivateSubs.pm
new file mode 100644 (file)
index 0000000..aaf4898
--- /dev/null
+++ b/dev/arm/libperl-critic-perl/libperl-critic-perl-1.088/lib/Perl/Critic/Policy/Subroutines/ProtectPrivateSubs.pm
@@ -0,0 +1,129 @@
+##############################################################################
+#      $URL: http://perlcritic.tigris.org/svn/perlcritic/trunk/Perl-Critic/lib/Perl/Critic/Policy/Subroutines/ProtectPrivateSubs.pm $
+#     $Date: 2008-07-03 10:19:10 -0500 (Thu, 03 Jul 2008) $
+#   $Author: clonezone $
+# $Revision: 2489 $
+##############################################################################
+
+package Perl::Critic::Policy::Subroutines::ProtectPrivateSubs;
+
+use 5.006001;
+use strict;
+use warnings;
+use Readonly;
+
+use Perl::Critic::Utils qw{ :severities };
+use base 'Perl::Critic::Policy';
+
+our $VERSION = '1.088';
+
+#-----------------------------------------------------------------------------
+
+Readonly::Scalar my $DESC => q{Private subroutine/method used};
+Readonly::Scalar my $EXPL => q{Use published APIs};
+
+#-----------------------------------------------------------------------------
+
+sub supported_parameters { return ()                     }
+sub default_severity     { return $SEVERITY_MEDIUM       }
+sub default_themes       { return qw( core maintenance ) }
+sub applies_to           { return 'PPI::Token::Word'     }
+
+#-----------------------------------------------------------------------------
+
+sub violates {
+    my ( $self, $elem, undef ) = @_;
+
+    my $psib = $elem->sprevious_sibling;
+    my $psib_name = eval { $psib->content };
+    no warnings 'uninitialized';    ## no critic ProhibitNoWarnings
+    if (   $psib_name ne 'package'
+        && $psib_name ne 'require'
+        && $psib_name ne 'use'
+        && (   $self->_is_other_pkg_private_function($elem)
+            || $self->_is_other_pkg_private_method($elem) )
+        )
+    {
+        return $self->violation( $DESC, $EXPL, $elem );
+    }
+    return;                         #ok!
+}
+
+sub _is_other_pkg_private_function {
+    my ( $self, $elem ) = @_;
+    return $elem =~ m{ (\w+)::_\w+ \z }xms
+        && $elem !~ m{ \A SUPER::_\w+ \z }xms;
+}
+
+sub _is_other_pkg_private_method {
+    my ( $self, $elem ) = @_;
+
+    # look for structures like "Some::Package->_foo()"
+    $elem =~ m{ \A _\w+ \z }xms || return;
+    my $op = $elem->sprevious_sibling() || return;
+    $op eq q{->} || return;
+    my $pkg = $op->sprevious_sibling() || return;
+    $pkg->isa('PPI::Token::Word') || return;
+    return 1;
+}
+
+1;
+
+__END__
+
+#-----------------------------------------------------------------------------
+
+=pod
+
+=head1 NAME
+
+Perl::Critic::Policy::Subroutines::ProtectPrivateSubs - Prevent access to private subs in other packages.
+
+=head1 AFFILIATION
+
+This Policy is part of the core L<Perl::Critic> distribution.
+
+
+=head1 DESCRIPTION
+
+By convention Perl authors (like authors in many other languages)
+indicate private methods and variables by inserting a leading
+underscore before the identifier.  This policy catches attempts to
+access private variables from outside the package itself.
+
+
+=head1 CONFIGURATION
+
+This Policy is not configurable except for the standard options.
+
+
+=head1 HISTORY
+
+This policy is inspired by a similar test in L<B::Lint>
+
+=head1 SEE ALSO
+
+L<Perl::Critic::Policy::Subroutines::ProtectPrivateSubs>
+
+=head1 AUTHOR
+
+Chris Dolan <cdolan@cpan.org>
+
+=head1 COPYRIGHT
+
+Copyright (c) 2006-2008 Chris Dolan.  All rights reserved.
+
+This program is free software; you can redistribute it and/or modify
+it under the same terms as Perl itself.  The full text of this license
+can be found in the LICENSE file included with this module.
+
+=cut
+
+# Local Variables:
+#   mode: cperl
+#   cperl-indent-level: 4
+#   fill-column: 78
+#   indent-tabs-mode: nil
+#   c-indentation-style: bsd
+# End:
+# ex: set ts=8 sts=4 sw=4 tw=78 ft=perl expandtab shiftround :