git.maemo.org Git - quandoparte/blob - application/application.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-11-13T19:51:39
   4 #
   5 #-------------------------------------------------
   6
   7 QT += webkit network xml maemo5
   8
   9 TARGET = quandoparte
  10 TEMPLATE = app
  11
  12 TRANSLATIONS = resources/i18n/quandoparte_it.ts
  13
  14 SOURCES += main.cpp \
  15     settingsdialog.cpp \
  16     stationview.cpp \
  17     app.cpp \
  18     stationlistview.cpp \
  19     keypressforwarder.cpp
  20
  21 HEADERS += \
  22     settingsdialog.h \
  23     stationview.h \
  24     app.h \
  25     stationlistview.h \
  26     keypressforwarder.h
  27
  28 FORMS += \
  29     settingsdialog.ui \
  30     stationlistview.ui
  31
  32 CONFIG += webkit mobility
  33 MOBILITY = location
  34
  35 symbian {
  36     TARGET.UID3 = 0xe30fb688
  37     # TARGET.CAPABILITY +=
  38     TARGET.EPOCSTACKSIZE = 0x14000
  39     TARGET.EPOCHEAPSIZE = 0x020000 0x800000
  40 }
  41
  42 OTHER_FILES += \
  43     debian/changelog \
  44     debian/compat \
  45     debian/control \
  46     debian/copyright \
  47     debian/README \
  48     debian/rules \
  49     quandoparte.desktop \
  50     icons/quandoparte.png \
  51     resources/quandoparte.css \
  52     resources/arrivals.css \
  53     resources/departures.css \
  54     $$replace(TRANSLATIONS, .ts, .qm)
  55
  56 message($${OTHER_FILES})
  57 unix:!symbian {
  58     maemo5 {
  59         target.path = /opt/usr/bin
  60     } else {
  61         target.path = /usr/local/bin
  62     }
  63     INSTALLS += target
  64 }
  65
  66 unix:!symbian {
  67     desktopfile.files = $${TARGET}.desktop
  68     maemo5 {
  69         desktopfile.path = /usr/share/applications/hildon
  70     } else {
  71         desktopfile.path = /usr/share/applications
  72     }
  73     INSTALLS += desktopfile
  74 }
  75
  76 unix:!symbian {
  77     css.files = resources/$${TARGET}.css resources/arrivals.css resources/departures.css
  78     i18n.files = $$replace(TRANSLATIONS, .ts, .qm)
  79     maemo5 {
  80         i18n.path = /opt/usr/share/apps/$${TARGET}/i18n
  81         css.path = /opt/usr/share/apps/$${TARGET}/css
  82     } else {
  83         i18n.path = /usr/share/apps/$${TARGET}/i18n
  84         css.path = /usr/share/apps/$${TARGET}/css
  85     }
  86     icon48.files = icons/48x48/$${TARGET}.png
  87     icon64.files = icons/64x64/$${TARGET}.png
  88     icon48.path = /usr/share/icons/hicolor/48x48/apps
  89     icon64.path = /usr/share/icons/hicolor/64x64/apps
  90     INSTALLS += icon48
  91     INSTALLS += icon64
  92     INSTALLS += css
  93     INSTALLS += i18n
  94 }