git.maemo.org Git - quandoparte/blob - application/application.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-11-13T19:51:39
   4 #
   5 #-------------------------------------------------
   6
   7 QT += webkit network
   8
   9 maemo5 {
  10     QT += maemo5
  11 }
  12
  13 CONFIG += qt webkit mobility
  14 MOBILITY = location
  15
  16 TARGET = quandoparte
  17 TEMPLATE = app
  18 VERSION = 0.4.4
  19 VERSION_STRING = '\\"$${VERSION}\\"'
  20 DEFINES += QP_VERSION=\"$${VERSION_STRING}\"
  21
  22 !debug {
  23     DEFINES += QT_NO_DEBUG_OUTPUT
  24 }
  25
  26 TRANSLATIONS = resources/i18n/quandoparte_it.ts
  27
  28 SOURCES += main.cpp \
  29     settingsdialog.cpp \
  30     stationview.cpp \
  31     app.cpp \
  32     stationlistview.cpp \
  33     keypressforwarder.cpp \
  34     stationlistmodel.cpp \
  35     stationlistproxymodel.cpp
  36
  37 HEADERS += \
  38     settingsdialog.h \
  39     stationview.h \
  40     app.h \
  41     stationlistview.h \
  42     keypressforwarder.h \
  43     stationlistmodel.h \
  44     stationlistproxymodel.h
  45
  46 FORMS += \
  47     settingsdialog.ui \
  48     stationlistview.ui
  49
  50 symbian {
  51     TARGET.UID3 = 0xe30fb688
  52     # TARGET.CAPABILITY +=
  53     TARGET.EPOCSTACKSIZE = 0x14000
  54     TARGET.EPOCHEAPSIZE = 0x020000 0x800000
  55 }
  56
  57 OTHER_FILES += \
  58     quandoparte.desktop \
  59     icons/48x48/quandoparte.png \
  60     icons/64x64/quandoparte.png \
  61     icons/scalable/quandoparte.svg \
  62     icons/quandoparte.png \
  63     resources/quandoparte.css \
  64     resources/arrivals.css \
  65     resources/departures.css \
  66     $$replace(TRANSLATIONS, .ts, .qm) \
  67     resources/stations/stations.qpl \
  68     resources/stations/generatelist.xq \
  69     resources/stations/generateunclassifiedlist.xq
  70
  71 unix {
  72     isEmpty(PREFIX) {
  73         maemo5 {
  74             PREFIX=/opt/usr
  75             DESKTOPDIR=/usr/share/applications/hildon
  76         } else {
  77             PREFIX=/usr/local
  78             DESKTOPDIR=$$PREFIX/share/applications
  79         }
  80     }
  81     BINDIR=$$PREFIX/bin
  82     DESKTOPDIR=$$PREFIX/share/applications
  83     DATADIR=$$PREFIX/share/apps/$${TARGET}
  84     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
  85 }
  86
  87 message(Installing to prefix $$PREFIX)
  88
  89 unix:!symbian {
  90     target.path = $$BINDIR
  91     INSTALLS += target
  92 }
  93
  94 unix:!symbian {
  95     desktopfile.files = $${TARGET}.desktop
  96     desktopfile.path = $$DESKTOPDIR
  97     INSTALLS += desktopfile
  98 }
  99
 100 unix:!symbian {
 101     css.files = resources/$${TARGET}.css resources/arrivals.css resources/departures.css
 102     i18n.files = $$replace(TRANSLATIONS, .ts, .qm)
 103     stations.files = resources/stations/stations.qpl
 104
 105     i18n.path = $$DATADIR/i18n
 106     css.path = $$DATADIR/css
 107     stations.path = $$DATADIR/stations
 108
 109     icon48.files = icons/48x48/$${TARGET}.png
 110     icon64.files = icons/64x64/$${TARGET}.png
 111     iconscalable.files = icons/scalable/$${TARGET}.svg
 112
 113     icon48.path = /usr/share/icons/hicolor/48x48/apps
 114     icon64.path = /usr/share/icons/hicolor/64x64/apps
 115     iconscalable.path = /usr/share/icons/hicolor/scalable/apps
 116
 117     INSTALLS += icon48
 118     INSTALLS += icon64
 119     INSTALLS += iconscalable
 120     INSTALLS += css
 121     INSTALLS += i18n
 122     INSTALLS += stations
 123 }
 124
 125 unix {
 126     desktopfile.files = $${TARGET}.desktop
 127     maemo5 {
 128         desktopfile.path = /usr/share/applications/hildon
 129     } else {
 130         desktopfile.path = $$DATADIR/applications
 131     }
 132     INSTALLS += desktopfile
 133 }