git.maemo.org Git - monky/blob - configure.ac

   1 AC_INIT([Conky],[1.4.3],[brenden1@users.sourceforge.net])
   2
   3 AM_INIT_AUTOMAKE(conky, 1.4.3)
   4 AM_CONFIG_HEADER(src/config.h)
   5 dnl
   6 dnl C Compiler
   7 dnl
   8
   9 AC_PROG_CC
  10 AC_PROG_LIBTOOL
  11 PKG_PROG_PKG_CONFIG([0.17.2])
  12
  13
  14 AC_CONFIG_FILES(
  15         Makefile
  16         doc/Makefile
  17         src/Makefile
  18         src/build.h
  19         )
  20
  21 uname=`uname`
  22
  23 case $uname in
  24   Linux*)
  25     WANT_SYSINFO=yes
  26     ;;
  27   FreeBSD*)
  28     WANT_KVM=yes
  29     WANT_DEVSTAT=yes
  30     ;;
  31 #  NetBSD*)
  32 #    WANT_KVM=yes
  33 #    WANT_OSSLIB=yes
  34 #    ;;
  35
  36 #  OpenBSD*)
  37 #    WANT_KVM=yes
  38 #    WANT_OSSLIB=yes
  39 #    ;;
  40
  41 # Solaris doesn't work at all right now
  42 #  SunOS*)
  43 #    WANT_KSTAT=yes
  44 #    ;;
  45
  46   *)
  47     echo "Your operating system $uname isn't supported"
  48     echo "Feel free to help. :P"
  49     exit 1
  50     ;;
  51 esac
  52
  53 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  54 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  55 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD)
  56 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  57 # AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  58
  59 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  60 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  61 AC_SUBST(BUILD_DATE)
  62 AC_SUBST(BUILD_ARCH)
  63
  64 dnl
  65 dnl XFT option
  66 dnl
  67
  68 want_xft=yes
  69 AC_ARG_ENABLE(xft,
  70 [  --enable-xft            enable if you want to use Xft [[default=yes]]],
  71   [want_xft="$enableval"])
  72
  73 dnl
  74 dnl OWN_WINDOW option
  75 dnl
  76
  77 dah=yes
  78 AC_ARG_ENABLE(own_window,
  79 [  --enable-own-window     enable if you want support for creating own window [[default=yes]]],
  80   [dah="$enableval"])
  81
  82 if test $dah != "no"; then
  83   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
  84 fi
  85
  86 dnl
  87 dnl PROC_UPTIME option
  88 dnl
  89
  90 dah=yes
  91 AC_ARG_ENABLE(proc_uptime,
  92 [  --enable-proc-uptime    enable using /proc/uptime for uptime [[default=yes]]],
  93   [dah="$enableval"])
  94
  95 if test $dah = "yes"; then
  96   AC_DEFINE(PROC_UPTIME, 1, [Define if you want to use /proc/uptime for uptime])
  97 fi
  98
  99 dnl
 100 dnl XMMS (Version 1)
 101 dnl
 102
 103 want_xmms=auto
 104 AC_ARG_ENABLE(xmms,
 105    [  --enable-xmms           enable xmms (ver. 1) media player support [[default=auto]]],
 106    [want_xmms="$enableval"])
 107
 108 case x$want_xmms in
 109     xauto)
 110         want_xmms=yes
 111         ## its ok to favor the glib 2.0 headers over 1.2 for our purposes ##
 112         PKG_CHECK_MODULES([XMMS], [glib-2.0], [], [PKG_CHECK_MODULES([XMMS], [glib-1.2], [], [want_xmms=no])])
 113
 114         if test x$want_xmms = xyes; then
 115             AC_CHECK_HEADERS([dlfcn.h], [], [want_xmms=no])
 116             if test x$want_xmms = xyes; then
 117                 AC_CHECK_LIB(dl, dlopen, [LIBS="$LIBS -ldl"],
 118                                          [AC_CHECK_FUNCS(dlopen,[],
 119                                                                 [want_xmms=no])])
 120                 if test x$want_xmms = xyes; then
 121                      CFLAGS="$CFLAGS $XMMS_CFLAGS"
 122                      ### if we link to glib 1.2, that means 2.0 wasn't found ###
 123                      ### if we link to glib 2.0, that's ok, we will load libglib-1.2.so.0 dynamically ###
 124                      LIBS="$LIBS $XMMS_LIBS"
 125                      AC_DEFINE(XMMS, 1, [Define for XMMS Ver. 1 support])
 126                 fi
 127             fi
 128         fi
 129         ;;
 130     xyes)
 131         ## its ok to favor the glib 2.0 headers over 1.2 for our purposes ##
 132         PKG_CHECK_MODULES([XMMS], [glib-2.0], [], [PKG_CHECK_MODULES([XMMS], [glib-1.2])])
 133         CFLAGS="$CFLAGS $XMMS_CFLAGS"
 134         ### if we link to glib 1.2, that means 2.0 wasn't found ###
 135         ### if we link to glib 2.0, that's ok, we will load libglib-1.2.so.0 dynamically ###
 136         LIBS="$LIBS $XMMS_LIBS"
 137         AC_CHECK_HEADERS([dlfcn.h], [],
 138              [AC_MSG_ERROR(["dlfcn.h not found: dynamic library loading not supported"])])
 139         AC_CHECK_LIB(dl, dlopen, [LIBS="$LIBS -ldl"],
 140                                  [AC_CHECK_FUNCS(dlopen,[],
 141                                                         [AC_MSG_ERROR([dlopen() not available])])])
 142         AC_DEFINE(XMMS, 1, [Define for XMMS Ver. 1 support])
 143         ;;
 144     xno)
 145         ;;
 146     *)
 147         echo "Error: invalid xmms parameter specified: $want_xmms"
 148         exit -1
 149         ;;
 150 esac
 151 AM_CONDITIONAL(BUILD_XMMS, test x$want_xmms = xyes)
 152
 153 dnl
 154 dnl BMP (through 0.9.7.1)
 155 dnl
 156
 157 want_bmp=auto
 158 AC_ARG_ENABLE(bmp,
 159    [  --enable-bmp            enable beep media media player support [[default=auto]]],
 160    [want_bmp="$enableval"])
 161
 162 case x$want_bmp in
 163     xauto)
 164         want_bmp=yes
 165         PKG_CHECK_MODULES([BMP], [glib-2.0], [], [want_bmp=no])
 166         if test x$want_bmp = xyes; then
 167             AC_CHECK_HEADERS([dlfcn.h], [], [want_bmp=no])
 168             if test x$want_bmp = xyes; then
 169                 AC_CHECK_LIB(dl, dlopen, [LIBS="$LIBS -ldl"],
 170                                          [AC_CHECK_FUNCS(dlopen,[],
 171                                                                 [want_bmp=no])])
 172                 if test x$want_bmp = xyes; then
 173                      CFLAGS="$CFLAGS $BMP_CFLAGS"
 174                      LIBS="$LIBS $BMP_LIBS"
 175                      AC_DEFINE(BMP, 1, [Define for Beep Media Player support])
 176                 fi
 177             fi
 178         fi
 179         ;;
 180     xyes)
 181         PKG_CHECK_MODULES([BMP], [glib-2.0 >= 2.0])
 182         CFLAGS="$CFLAGS $BMP_CFLAGS"
 183         LIBS="$LIBS $BMP_LIBS"
 184         AC_CHECK_HEADERS([dlfcn.h], [],
 185              [AC_MSG_ERROR(["dlfcn.h not found: dynamic library loading not supported"])])
 186         AC_CHECK_LIB(dl, dlopen, [LIBS="$LIBS -ldl"],
 187                                  [AC_CHECK_FUNCS(dlopen,[],
 188                                                         [AC_MSG_ERROR([dlopen() not available])])])
 189         AC_DEFINE(BMP, 1, [Define for Beep Media Player support])
 190         ;;
 191     xno)
 192         ;;
 193     *)
 194         echo "Error: invalid bmp parameter specified: $want_bmp"
 195         exit -1
 196         ;;
 197 esac
 198 AM_CONDITIONAL(BUILD_BMP, test x$want_bmp = xyes)
 199
 200 dnl
 201 dnl Audacious Media Player
 202 dnl
 203
 204 want_audacious=auto
 205 AC_ARG_ENABLE(audacious,
 206    [  --enable-audacious      enable audacious player support [[default=auto]]],
 207    [want_audacious="$enableval"])
 208
 209 case x$want_audacious in
 210     xauto)
 211         want_audacious=yes
 212         PKG_CHECK_MODULES([AUDACIOUS], [glib-2.0], [], [want_audacious=no])
 213         if test x$want_audacious = xyes; then
 214             AC_CHECK_HEADERS([dlfcn.h], [], [want_audacious=no])
 215             if test x$want_audacious = xyes; then
 216                 AC_CHECK_LIB(dl, dlopen, [LIBS="$LIBS -ldl"],
 217                                          [AC_CHECK_FUNCS(dlopen,[],
 218                                                                 [want_audacious=no])])
 219                 if test x$want_audacious = xyes; then
 220                      CFLAGS="$CFLAGS $AUDACIOUS_CFLAGS"
 221                      LIBS="$LIBS $AUDACIOUS_LIBS"
 222                      AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 223                 fi
 224             fi
 225         fi
 226         ;;
 227     xyes)
 228         PKG_CHECK_MODULES([AUDACIOUS], [glib-2.0])
 229         CFLAGS="$CFLAGS $AUDACIOUS_CFLAGS"
 230         LIBS="$LIBS $AUDACIOUS_LIBS"
 231         AC_CHECK_HEADERS([dlfcn.h], [],
 232              [AC_MSG_ERROR(["dlfcn.h not found: dynamic library loading not supported"])])
 233         AC_CHECK_LIB(dl, dlopen, [LIBS="$LIBS -ldl"],
 234                                  [AC_CHECK_FUNCS(dlopen,[],
 235                                                         [AC_MSG_ERROR([dlopen() not available])])])
 236         AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 237         ;;
 238     xno)
 239         ;;
 240     *)
 241         echo "Error: invalid audacious parameter specified: $want_audacious"
 242         exit -1
 243         ;;
 244 esac
 245 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes)
 246
 247 dnl
 248 dnl InfoPipe (Version 1.3)
 249 dnl
 250
 251 want_infopipe=yes
 252 AC_ARG_ENABLE(infopipe,
 253    [  --enable-infopipe       enable xmms/bmp infopipe support [[default=yes]]],
 254    [want_infopipe="$enableval"])
 255
 256 case x$want_infopipe in
 257     xyes)
 258         AC_DEFINE(INFOPIPE, 1, [Define for InfoPipe support])
 259         ;;
 260     xno)
 261         ;;
 262     *)
 263         echo "Error: invalid infopipe parameter specified: $want_infopipe"
 264         exit -1
 265         ;;
 266 esac
 267 AM_CONDITIONAL(BUILD_INFOPIPE, test x$want_infopipe = xyes)
 268
 269 dnl
 270 dnl BMPx
 271 dnl
 272
 273 want_bmpx=no
 274 AC_ARG_ENABLE(bmpx,
 275               [  --enable-bmpx           enable if you want BMPx support [[default=no]]],
 276               [want_bmpx="$enableval"])
 277
 278 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 279 if test x$want_bmpx = xyes; then
 280         PKG_CHECK_MODULES([BMPX], [bmp-2.0 >= 0.14.0])
 281         CFLAGS="$CFLAGS $BMPX_CFLAGS"
 282         LIBS="$LIBS $BMPX_LIBS"
 283         AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 284 fi
 285
 286 dnl
 287 dnl Seti@Home
 288 dnl
 289
 290 want_seti=yes
 291 AC_ARG_ENABLE(seti,
 292 [  --enable-seti           enable if you want SETI at Home stats [[default=yes]]],
 293   [want_seti="$enableval"])
 294
 295 AM_CONDITIONAL(BUILD_SETI, test x$want_seti = xyes)
 296 if test x$want_seti = xyes; then
 297   AC_DEFINE(SETI, 1, [Define if you want SETI at Home stats])
 298 fi
 299
 300 dnl
 301 dnl Hddtemp
 302 dnl
 303
 304 want_hddtemp=yes
 305 AC_ARG_ENABLE(hddtemp,
 306 [  --enable-hddtemp        enable if you want hddtemp support [[default=yes]]],
 307   [want_hddtemp="$enableval"])
 308
 309 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 310 if test x$want_hddtemp = xyes; then
 311   AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 312 fi
 313
 314 dnl
 315 dnl MPD
 316 dnl
 317
 318 want_mpd=yes
 319 AC_ARG_ENABLE(mpd,
 320 [  --enable-mpd            enable if you want MPD support [[default=yes]]],
 321   [want_mpd="$enableval"])
 322
 323 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 324 if test x$want_mpd = xyes; then
 325   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 326 fi
 327
 328 dnl
 329 dnl XMMS2
 330 dnl
 331
 332 want_xmms2=no
 333 AC_ARG_ENABLE(xmms2,
 334 [  --enable-xmms2          enable if you want XMMS2 support [[default=no]]],
 335   [want_xmms2="$enableval"])
 336
 337 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 338 if test x$want_xmms2 = xyes; then
 339   CFLAGS="$CFLAGS `pkg-config --cflags xmms2-client`"
 340   LIBS="$LIBS `pkg-config --libs xmms2-client`"
 341   AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 342 fi
 343
 344 dnl
 345 dnl IMLIB2
 346 dnl
 347
 348 want_imlib2=no
 349 AC_ARG_ENABLE(imlib2,
 350 [  --enable-imlib2         enable if you want Imlib2 support [[default=no]]],
 351   [want_imlib2="$enableval"])
 352
 353 AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 354 if test x$want_imlib2 = xyes; then
 355         PKG_CHECK_MODULES([Imlib2], [imlib2])
 356         CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 357         LIBS="$LIBS $Imlib2_LIBS"
 358         AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 359 fi
 360
 361 dnl
 362 dnl PORT_MONITORS
 363 dnl
 364
 365 want_portmon=yes
 366 AC_ARG_ENABLE(portmon,
 367 [  --enable-portmon        enable if you want tcp (ip4) port monitoring [[default=yes]]],
 368   [want_portmon="$enableval"])
 369
 370 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x$want_portmon = xyes)
 371 if test x$want_portmon = xyes; then
 372   AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [], [PORT_MONITORS_MISSING=yes])
 373   if test "x$PORT_MONITORS_MISSING" = xyes; then
 374          AC_MSG_ERROR([missing a needed network header for port monitoring])
 375   fi
 376   AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 377 fi
 378
 379 dnl
 380 dnl Cairo
 381 dnl
 382
 383 dnl
 384 dnl MLDonkey
 385 dnl
 386
 387 want_mldonkey=no
 388 AC_ARG_ENABLE(mldonkey,
 389 [  --enable-mldonkey       enable if you want MLDonkey support [[default=no]]],
 390   [want_mldonkey="$enableval"])
 391
 392 AM_CONDITIONAL(BUILD_MLDONKEY, test x$want_mldonkey = xyes)
 393 if test x$want_mldonkey = xyes; then
 394   AC_DEFINE(MLDONKEY, 1, [Define if you want MLDonkey support])
 395 fi
 396
 397 dnl
 398 dnl ICONV
 399 dnl
 400
 401 AM_ICONV
 402 if test "$am_cv_func_iconv" != yes; then
 403         AC_MSG_WARN([Could not find libiconv])
 404 else
 405         LIBS="$LIBS $LIBICONV"
 406 fi
 407
 408 dnl
 409 dnl debug
 410 dnl
 411
 412 want_debug=no
 413 AC_ARG_ENABLE(debug,
 414         [  --enable-debug       compile with debug symbols [[default=no]]],
 415         [want_debug="$enableval"])
 416
 417 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 418         CFLAGS="$CFLAGS -g3"
 419 fi
 420
 421 dnl
 422 dnl X
 423 dnl
 424
 425 dah=yes
 426 AC_ARG_ENABLE(double_buffer,
 427 [  --enable-double-buffer  enable if you want to support flicker-free operation [[default=yes]]],
 428   [dah="$enableval"])
 429
 430 want_xdamage=yes
 431 AC_ARG_ENABLE(xdamage,
 432 [  --enable-xdamage        enable if you want Xdamage support [[default=yes]]],
 433   [want_xdamage="$enableval"])
 434
 435 want_x11=yes
 436 AC_ARG_ENABLE(x11,
 437 [  --enable-x11            enable if you want X11 support [[default=yes]]],
 438  [want_x11="$enableval"])
 439
 440
 441 if test "x$want_x11" = "xyes"; then
 442         AC_PATH_X
 443         AC_PATH_XTRA
 444         CFLAGS="$CFLAGS $X_CFLAGS"
 445         LIBS="$LIBS $X_LIBS $X11_LIBS"
 446         LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 447         if test "x$X_DISPLAY_MISSING" = xyes; then
 448                 AC_MSG_ERROR([something went wrong when checking for X11, you're probably missing headers or it's not installed, either re-run configure with --disable-x11, or fix this])
 449         fi
 450         AC_DEFINE(X11, 1, [Define if you want to use X11])
 451         AC_DEFINE(HAVE_X11, 1, [Define if you have X11])
 452         AM_CONDITIONAL(BUILD_X11, true)
 453         if test "x$dah" != xno; then
 454                 AC_DEFINE(DOUBLE_BUFFER, 1, [Define if you want support for the DBE extension])
 455                 AC_CHECK_LIB(Xext, XdbeQueryExtension, [AC_DEFINE([HAVE_XDBE], 1, [Xdbe]) LIBS="$LIBS -lXext"],
 456                      [AC_MSG_ERROR([something went wrong when checking for Xdbe (double buffer extension)])])
 457         fi
 458
 459         if test "x$want_xdamage" = "xyes"; then
 460                 AC_DEFINE(XDAMAGE, 1, [Define if you want support for the Xdamage extension])
 461                 AC_CHECK_LIB(Xdamage, XDamageQueryExtension,
 462                              [AC_DEFINE([HAVE_XDAMAGE], 1, [Xdamage]) LIBS="$LIBS -lXdamage"],
 463                               [AC_MSG_ERROR([something went wrong when checking for Xdamage])])
 464         fi
 465 else
 466         AM_CONDITIONAL(BUILD_X11, false)
 467 fi
 468
 469 dnl
 470 dnl Xft
 471 dnl
 472
 473 if test x$want_xft && test x$want_x11; then
 474   PKG_CHECK_MODULES(XFT, [xft],
 475                     [
 476                      AC_DEFINE(XFT, 1, [Define if you are using Xft])
 477                      CFLAGS="$CFLAGS $XFT_CFLAGS"
 478                      AC_SUBST(XFT_LIBS)
 479                     ],
 480                     [want_xft=no])
 481 fi
 482
 483 dnl
 484 dnl KVM
 485 dnl
 486
 487 if test x$WANT_KVM = xyes; then
 488   AC_CHECK_LIB(kvm, kvm_open,
 489         LIBS="$LIBS -lkvm",
 490         AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 491   )
 492 fi
 493
 494 dnl
 495 dnl devstat
 496 dnl
 497
 498 if test x$WANT_DEVSTAT = xyes; then
 499         AC_CHECK_LIB(devstat, devstat_getversion,
 500                      LIBS="$LIBS -ldevstat",
 501                      AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 502         )
 503 fi
 504
 505 dnl
 506 dnl OSSLIB for NetBSD/OpenBSD
 507 dnl
 508
 509 if test x$WANT_OSSLIB = xyes; then
 510     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 511         LIBS="$LIBS -lossaudio",
 512         AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 513     )
 514 fi
 515
 516 dnl
 517 dnl Some random headers
 518 dnl
 519
 520
 521 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h dirent.h mcheck.h])
 522 AC_CHECK_HEADERS([sys/statfs.h sys/param.h])
 523 AC_CHECK_HEADERS([sys/mount.h], [], [],
 524                  [#ifdef HAVE_SYS_PARAM_H
 525                   #include <sys/param.h>
 526                   #endif
 527 ])
 528
 529 dnl
 530 dnl Check doc stuff
 531 dnl
 532
 533 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 534 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 535 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 536 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 537         AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 538 else
 539         AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 540 fi
 541
 542 dnl
 543 dnl Check sysinfo()
 544 dnl
 545
 546 if test x$WANT_SYSINFO = xyes; then
 547   dah=no
 548   AC_MSG_CHECKING(for sysinfo)
 549   AC_TRY_COMPILE(
 550     [#include <sys/types.h>
 551      #include <sys/sysinfo.h>],
 552     [struct sysinfo s; sysinfo(&s); (void) s.uptime; ],
 553     [AC_MSG_RESULT(yes); dah=yes],
 554     [AC_MSG_RESULT(not usable); dah=no])
 555
 556   if test x$dah = xyes; then
 557     AC_DEFINE(HAVE_SYSINFO, 1, [Define if you have sysinfo (Linux)])
 558   fi
 559 fi
 560
 561 dnl
 562 dnl kstat in Solaris
 563 dnl
 564
 565 if test x$WANT_KSTAT = xyes; then
 566   dah=no
 567   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 568
 569   if test x$dah = xyes; then
 570     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 571     LDFLAGS="$LDFLAGS -lkstat"
 572   fi
 573 fi
 574
 575 AC_DEFUN([AM_LANGINFO_CODESET],
 576 [
 577   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 578     [AC_TRY_LINK([#include <langinfo.h>],
 579       [char* cs = nl_langinfo(CODESET);],
 580       am_cv_langinfo_codeset=yes,
 581       am_cv_langinfo_codeset=no)
 582     ])
 583   if test $am_cv_langinfo_codeset = yes; then
 584     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 585       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 586   fi
 587 ])
 588
 589 dnl
 590 dnl Check getloadavg
 591 dnl
 592
 593 AC_MSG_CHECKING(for getloadavg)
 594 AC_TRY_COMPILE(
 595   [#include <stdlib.h>],
 596   [double v[3]; getloadavg(v, 3);],
 597   [AC_MSG_RESULT(yes)
 598    AC_DEFINE(HAVE_GETLOADAVG, 1, [Define if you have getloadavg])],
 599   [AC_MSG_RESULT(no)])
 600
 601 dnl
 602 dnl Check popen
 603 dnl
 604
 605 AC_CHECK_FUNCS(popen)
 606
 607 dnl
 608 dnl Da.
 609 dnl
 610
 611 CFLAGS="$CFLAGS -Wall -W"
 612
 613 AC_SUBST(CFLAGS)
 614 AC_SUBST(X11_LIBS)
 615
 616 AC_OUTPUT
 617
 618 dnl
 619 dnl Print summary
 620 dnl
 621 cat << EOF
 622
 623 $PACKAGE $VERSION configured successfully:
 624
 625  Installing into:       $prefix
 626  C compiler flags:      $CFLAGS
 627  Linker flags:          $LDFLAGS
 628  Libraries:             $LIBS
 629
 630  * x11:
 631   x11 support:          $want_x11
 632   xft support:          $want_xft
 633   xdamage extension:    $want_xdamage
 634
 635  * music detection:
 636   xmms:                 $want_xmms
 637   bmp:                  $want_bmp
 638   audacious:            $want_audacious
 639   infopipe:             $want_infopipe
 640   bmpx:                 $want_bmpx
 641   xmms2:                $want_xmms2
 642   mpd:                  $want_mpd
 643
 644  * general:
 645   portmon:              $want_portmon
 646   mldonkey:             $want_mldonkey
 647   hddtemp:              $want_hddtemp
 648
 649 EOF