git.maemo.org Git - monky/blob - configure.ac.in

   1 # -*- mode: Makefile; c-basic-offset: 4; tab-width: 4; indent-tabs-mode: t -*-
   2 #
   3 dnl major, minor and micro version macros.
   4 m4_define([conky_version_major], [1])
   5 m4_define([conky_version_minor], [7])
   6 m4_define([conky_version_micro], [3])
   7 m4_define([conky_version_tag], [pre]) dnl [] for releases
   8 m4_define([conky_version_revision],[_pre@REVISION@])
   9 m4_define([conky_version],
  10     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
  11       conky_version_tag(), [pre],
  12       [conky_version_revision()],
  13       [ifelse(conky_version_tag(), [], [], [conky_version_tag()])])])
  14
  15 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  16
  17 AM_INIT_AUTOMAKE(conky, conky_version())
  18 AM_CONFIG_HEADER(src/config.h)
  19 AC_CONFIG_MACRO_DIR([m4])
  20
  21 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  22 dnl libtool must be deleted with make distclean to see this fix.
  23 if test x"$CFLAGS" = x""; then
  24   AC_SUBST(CFLAGS, [ ])
  25 fi
  26
  27 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
  28
  29 dnl
  30 dnl Tools
  31 dnl
  32 AC_PROG_CC
  33 AC_PROG_LD
  34 AC_PROG_INSTALL
  35 AC_PROG_LIBTOOL
  36 AM_PROG_LIBTOOL
  37 AM_PROG_CC_C_O
  38
  39 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  40 if test x"$HAVE_PKGCONFIG" = x"no"; then
  41   AC_MSG_ERROR([pkg-config is required!])
  42 fi
  43 PKG_PROG_PKG_CONFIG([0.19])
  44
  45 AC_CONFIG_FILES(
  46   Makefile
  47   data/Makefile
  48   doc/Makefile
  49   src/Makefile
  50   src/build.h
  51   lua/Makefile
  52   )
  53
  54 uname=`uname`
  55
  56 case $uname in
  57   Linux*)
  58     WANT_SYSINFO=yes
  59     ;;
  60   FreeBSD*|GNU/kFreeBSD*)
  61     WANT_KVM=yes
  62     WANT_DEVSTAT=yes
  63     ;;
  64 #  NetBSD*)
  65 #    WANT_KVM=yes
  66 #    WANT_OSSLIB=yes
  67 #    ;;
  68
  69   OpenBSD*)
  70     WANT_KVM=yes
  71     WANT_OSSLIB=yes
  72     ;;
  73
  74 # Solaris doesn't work at all right now
  75 #  SunOS*)
  76 #    WANT_KSTAT=yes
  77 #    ;;
  78
  79   *)
  80     echo "Your operating system $uname isn't supported"
  81     echo "Feel free to help. :P"
  82     exit 1
  83     ;;
  84 esac
  85
  86 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  87 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  88 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD -o x$uname = xGNU/kFreeBSD)
  89 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  90 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  91
  92 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  93 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  94 AC_SUBST(BUILD_DATE)
  95 AC_SUBST(BUILD_ARCH)
  96
  97
  98 dnl
  99 dnl BUILD_CONFIG_OUTPUT option
 100 dnl
 101
 102 AC_ARG_ENABLE([config_output],
 103               AC_HELP_STRING([--disable-config-output], [disable if you do not want conky to output a default config (with -C) @<:@default=yes@:>@]),
 104               [want_config_output="$enableval"], [want_config_output=yes])
 105
 106 AM_CONDITIONAL(BUILD_CONFIG_OUTPUT, test x$want_config_output = xyes)
 107 if test x$want_config_output = xyes; then
 108   AC_DEFINE(CONFIG_OUTPUT, 1, [Define if you want conky to output a default config (with -C)])
 109   AC_CHECK_FUNCS(fopencookie)
 110   AC_CHECK_FUNCS(funopen)
 111 fi
 112
 113 dnl
 114 dnl OWN_WINDOW option
 115 dnl
 116
 117 AC_ARG_ENABLE([own_window],
 118               AC_HELP_STRING([--disable-own-window],
 119                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
 120               [dah="$enableval"], [dah=yes])
 121
 122 if test $dah != "no"; then
 123   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 124 fi
 125
 126 dnl
 127 dnl NCURSES option
 128 dnl
 129
 130 AC_ARG_ENABLE([ncurses],
 131               AC_HELP_STRING([--disable-ncurses], [disable if you do not want ncurses support in conky @<:@default=yes@:>@]),
 132               [want_ncurses="$enableval"], [want_ncurses=yes])
 133
 134 AM_CONDITIONAL(BUILD_NCURSES, test x$want_ncurses = xyes)
 135 if test x$want_ncurses = xyes; then
 136       conky_LIBS="$conky_LIBS -lncurses"
 137       AC_DEFINE(NCURSES, 1, [Define for ncurses support])
 138 fi
 139
 140
 141 dnl
 142 dnl Audacious Media Player
 143 dnl
 144
 145 AC_ARG_ENABLE([audacious],
 146               AC_HELP_STRING([--enable-audacious=[[yes|no|legacy]]],
 147                              [enable audacious player support @<:@default=no@:>@]),
 148               [want_audacious="$enableval"], [want_audacious=no])
 149
 150 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes -o x$want_audacious = xlegacy)
 151 if test x$want_audacious = xyes; then
 152       PKG_CHECK_MODULES([Audacious], [audacious >= 1.4.0 dbus-glib-1 glib-2.0 gobject-2.0])
 153       conky_CFLAGS="$conky_CFLAGS $Audacious_CFLAGS"
 154       conky_LIBS="$conky_LIBS $Audacious_LIBS"
 155       save_CPPFLAGS="$CPPFLAGS"
 156       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 157       AC_CHECK_HEADERS([audacious/audctrl.h audacious/dbus.h glib.h glib-object.h],
 158                        [], AC_MSG_ERROR([required header(s) not found]))
 159       CPPFLAGS="$save_CPPFLAGS"
 160       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 161 else if test x$want_audacious = xlegacy; then
 162       PKG_CHECK_MODULES([Audacious], [audacious < 1.4.0 glib-2.0])
 163       conky_CFLAGS="$conky_CFLAGS $Audacious_CFLAGS"
 164       conky_LIBS="$conky_LIBS $Audacious_LIBS"
 165       save_CPPFLAGS="$CPPFLAGS"
 166       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 167       AC_CHECK_HEADERS([audacious/beepctrl.h glib.h], [], AC_MSG_ERROR([required  header(s) not found]))
 168       CPPFLAGS="$save_CPPFLAGS"
 169       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 170       AC_DEFINE(AUDACIOUS_LEGACY, 1, [Define for Audacious Legacy support])
 171       fi
 172 fi
 173
 174
 175 dnl
 176 dnl BMPx
 177 dnl
 178
 179 AC_ARG_ENABLE([bmpx],
 180               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 181               [want_bmpx="$enableval"], [want_bmpx=no])
 182
 183 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 184 if test x$want_bmpx = xyes; then
 185   PKG_CHECK_MODULES([BMPx], [bmp-2.0 >= 0.14.0])
 186   conky_CFLAGS="$conky_CFLAGS $BMPx_CFLAGS"
 187   conky_LIBS="$conky_LIBS $BMPx_LIBS"
 188   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 189 fi
 190
 191
 192 dnl
 193 dnl Support for IBM/Lenovo notebooks
 194 dnl
 195
 196 AC_ARG_ENABLE([ibm],
 197               AC_HELP_STRING([--enable-ibm], [enable if you want support for IBM/Lenovo notebooks @<:default=no@:>@]),
 198               [want_ibm="$enableval"], [want_ibm=no])
 199
 200 AM_CONDITIONAL(BUILD_IBM, test x$want_ibm = xyes)
 201 if test x$want_ibm = xyes; then
 202         if test x"$uname" != xLinux; then
 203                 AC_MSG_NOTICE([support for IBM/Lenovo notebooks not supported on $uname... disabling])
 204                 want_ibm=no
 205         else
 206                 AC_DEFINE(IBM, 1, [Define if you want support for IBM/Lenovo notebooks (SMAPI)])
 207         fi
 208 fi
 209
 210
 211 dnl
 212 dnl Hddtemp
 213 dnl
 214
 215 AC_ARG_ENABLE([hddtemp],
 216               AC_HELP_STRING([--disable-hddtemp],
 217                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 218               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 219
 220 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 221 if test x$want_hddtemp = xyes; then
 222   if test x"$uname" != xLinux; then
 223       AC_MSG_NOTICE([hddtemp not supported on $uname... disabling])
 224       want_hddtemp=no
 225   else
 226       AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 227   fi
 228 fi
 229
 230
 231 dnl
 232 dnl Apcupsd
 233 dnl
 234
 235 AC_ARG_ENABLE([apcupsd],
 236               AC_HELP_STRING([--disable-apcupsd],
 237                              [disable if you do not want apcupsd support @<:@default=yes@:>@]),
 238               [want_apcupsd="$enableval"], [want_apcupsd=yes])
 239
 240 if test x$want_apcupsd = xyes; then
 241   if test x"$uname" != xLinux; then
 242       AC_MSG_NOTICE([apcupsd not supported on $uname... disabling])
 243       want_apcupsd=no
 244   else
 245       AC_DEFINE(APCUPSD, 1, [Define if you want apcupsd support])
 246   fi
 247 fi
 248 AM_CONDITIONAL(BUILD_APCUPSD, test x$want_apcupsd = xyes)
 249
 250
 251 dnl
 252 dnl I/O stats
 253 dnl
 254
 255 AC_ARG_ENABLE([iostats],
 256               AC_HELP_STRING([--enable-iostats],
 257                              [enable if you want support for per-task I/O statistics @<:@default=yes@:>@]),
 258               [want_iostats="$enableval"], [want_iostats=yes])
 259
 260 if test x$want_iostats = xyes; then
 261   if test x"$uname" != xLinux; then
 262       AC_MSG_NOTICE([iostats not supported on $uname... disabling])
 263       want_iostats=no
 264   else
 265       AC_DEFINE(IOSTATS, 1, [Define if you want support for per-task I/O statistics])
 266   fi
 267 fi
 268
 269
 270 dnl
 271 dnl Math
 272 dnl
 273
 274 AC_ARG_ENABLE([math],
 275               AC_HELP_STRING([--disable-math], [disable if you do not want math support @<:@default=yes@:>@]),
 276               [want_math="$enableval"], [want_math=yes])
 277
 278 AM_CONDITIONAL(BUILD_MATH, test x$want_math = xyes)
 279 if test x$want_math = xyes; then
 280   conky_LIBS="$conky_LIBS -lm"
 281   AC_DEFINE(MATH, 1, [Define if you want math support])
 282 fi
 283
 284 dnl
 285 dnl MPD
 286 dnl
 287
 288 AC_ARG_ENABLE([mpd],
 289               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 290               [want_mpd="$enableval"], [want_mpd=yes])
 291
 292 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 293 if test x$want_mpd = xyes; then
 294   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 295 fi
 296
 297 dnl
 298 dnl MOC
 299 dnl
 300
 301 AC_ARG_ENABLE([moc],
 302               AC_HELP_STRING([--disable-moc], [disable if you do not want MOC support @<:@default=yes@:>@]),
 303               [want_moc="$enableval"], [want_moc=yes])
 304
 305 AM_CONDITIONAL(BUILD_MOC, test x$want_moc = xyes)
 306 if test x$want_moc = xyes; then
 307   AC_DEFINE(MOC, 1, [Define if you want MOC support])
 308 fi
 309
 310 dnl
 311 dnl XMMS2
 312 dnl
 313
 314 AC_ARG_ENABLE([xmms2],
 315               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 316               [want_xmms2="$enableval"], [want_xmms2=no])
 317
 318 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 319 if test x$want_xmms2 = xyes; then
 320   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 321     conky_CFLAGS="$conky_CFLAGS $XMMS2_CFLAGS"
 322     conky_LIBS="$conky_LIBS $XMMS2_LIBS"
 323     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 324 fi
 325
 326 dnl
 327 dnl libcurl, see below for more (this has to be above the other uses of want_curl)
 328 dnl
 329
 330 AC_ARG_ENABLE([curl],
 331                 AC_HELP_STRING([--enable-curl], [enable if you want curl support @<:@default=no@:>@]),
 332                 [want_curl="$enableval"], [want_curl=no])
 333
 334 dnl
 335 dnl EVE Skill Monitor
 336 dnl
 337
 338 AC_ARG_ENABLE([eve],
 339               AC_HELP_STRING([--enable-eve], [Eve-Online skill monitor @<:@default=no@:>@]),
 340               [want_eve="$enableval"], [want_eve=no])
 341
 342 AM_CONDITIONAL(BUILD_EVE, test x$want_eve = xyes)
 343 if test x$want_eve = xyes; then
 344         want_curl=yes
 345         want_libxml2=yes
 346         AC_DEFINE(EVE, 1, [Define if you want Eve-Online Skill monitor support])
 347         AC_DEFINE(EVEURL_TRAINING, "http://api.eve-online.com/char/SkillInTraining.xml.aspx", [Eve training URL])
 348         AC_DEFINE(EVEURL_SKILLTREE, "http://api.eve-online.com/eve/Skilltree.xml.aspx", [Eve skilltree URL])
 349         AC_DEFINE(MY_ENCODING, "ISO-8859-1", [Textencoding to use])
 350         AC_DEFINE(EVE_OUTPUT_FORMAT, "%s %d in %s", [Eve output format])
 351 fi
 352
 353 dnl
 354 dnl RSS
 355 dnl
 356
 357 AC_ARG_ENABLE([rss],
 358               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 359               [want_rss="$enableval"], [want_rss=no])
 360 #
 361 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 362 if test x$want_rss = xyes; then
 363         WANT_GLIB=yes
 364         want_curl=yes
 365         want_libxml2=yes
 366         AC_DEFINE(RSS, 1, [Define if you want Curl support])
 367 fi
 368
 369 dnl
 370 dnl WEATHER
 371 dnl
 372
 373 AC_ARG_ENABLE([weather-metar],
 374               AC_HELP_STRING([--enable-weather-metar], [enable if you want METAR weather support @<:@default=no@:>@]),
 375               [want_metar="$enableval"], [want_metar=no])
 376
 377 AC_ARG_ENABLE([weather-xoap],
 378               AC_HELP_STRING([--enable-weather-xoap], [enable if you want XOAP weather support (also enables METAR) @<:@default=no@:>@]),
 379               [want_xoap="$enableval"], [want_xoap=no])
 380 #
 381 if test x$want_xoap = xyes; then
 382         want_metar=yes
 383 fi
 384 AM_CONDITIONAL(BUILD_WEATHER, test x$want_metar = xyes)
 385 AM_CONDITIONAL(BUILD_XOAP, test x$want_xoap = xyes)
 386 if test x$want_metar = xyes; then
 387         if test x$want_xoap = xyes; then
 388                 want_libxml2=yes
 389                 AC_DEFINE(XOAP, 1, [Define if you want XOAP weather support])
 390                 AC_DEFINE(XOAP_FILE, "$HOME/.xoaprc", [User xoap keys file])
 391         fi
 392         want_curl=yes
 393         AC_DEFINE(WEATHER, 1, [Define if you want METAR weather support])
 394 fi
 395
 396 dnl
 397 dnl X11
 398 dnl
 399
 400 AC_ARG_ENABLE([x11],
 401               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 402               [want_x11="$enableval"], [want_x11=yes])
 403
 404 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 405 if test "x$want_x11" = "xyes"; then
 406     if $PKG_CONFIG --exists x11; then
 407       PKG_CHECK_MODULES([X11], [x11])
 408       conky_CFLAGS="$conky_CFLAGS $X11_CFLAGS"
 409       conky_LIBS="$conky_LIBS $X11_LIBS"
 410     else
 411       dnl non-modular X11 installations
 412       AC_PATH_X
 413       AC_PATH_XTRA
 414       conky_CFLAGS="$conky_CFLAGS $X_CFLAGS"
 415       conky_LIBS="$conky_LIBS $X_LIBS"
 416       conky_LDFLAGS="$conky_LDFLAGS $conky_LIBS $X_PRE_LIBS"
 417       if test "x$no_x" = "xyes"; then
 418         AC_MSG_ERROR([Can't locate your X11 installation])
 419       fi
 420       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 421     fi
 422     AC_DEFINE(X11, 1, [Define if you want to use X11])
 423 fi
 424
 425 dnl
 426 dnl IMLIB2
 427 dnl
 428
 429 AC_ARG_ENABLE([imlib2],
 430                           AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 431                           [want_imlib2="$enableval"], [want_imlib2=no])
 432 AC_ARG_ENABLE([lua-imlib2],
 433               AC_HELP_STRING([--enable-lua-imlib2], [enable if you want Lua Imlib2 bindings for Conky @<:@default=no@:>@]),
 434               [want_lua_imlib2="$enableval"], [want_lua_imlib2=no])
 435
 436 # if lua-imlib2 is enabled, we must force imlib2
 437 if test x$want_lua_imlib2 = xyes; then
 438         want_imlib2=yes
 439 fi
 440
 441 if test x$want_imlib2 = xyes; then
 442         if test "x$want_x11" != "xyes"; then
 443                 dnl silently disable if no x11
 444                 want_imlib2=no
 445         else
 446                 PKG_CHECK_MODULES([Imlib2], [imlib2])
 447                 conky_CFLAGS="$conky_CFLAGS $Imlib2_CFLAGS"
 448                 conky_LIBS="$conky_LIBS $Imlib2_LIBS"
 449                 AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 450         fi
 451 fi
 452 AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 453
 454 dnl
 455 dnl Lua
 456 dnl
 457
 458 AC_ARG_ENABLE([lua],
 459               AC_HELP_STRING([--enable-lua], [enable if you want Lua scripting support @<:@default=yes@:>@]),
 460               [want_lua="$enableval"], [want_lua=yes])
 461 AC_ARG_ENABLE([lua-cairo],
 462               AC_HELP_STRING([--enable-lua-cairo], [enable if you want Lua Cairo bindings for Conky @<:@default=no@:>@]),
 463               [want_lua_cairo="$enableval"], [want_lua_cairo=no])
 464 need_tolua=no
 465 if test x$want_lua_cairo = xyes -o x$want_lua_imlib2 = xyes; then
 466         need_tolua=yes
 467         want_lua=yes
 468 fi
 469
 470 AM_CONDITIONAL(BUILD_LUA, test x$want_lua = xyes)
 471 if test x$want_lua = xyes; then
 472         PKG_CHECK_MODULES(LUA, lua >= 5.1, [ ],[
 473                 PKG_CHECK_MODULES(LUA51, lua-5.1 >= 5.1, [ ],[
 474                         PKG_CHECK_MODULES(LUA51, lua5.1 >= 5.1)
 475                 ])
 476         ])
 477         conky_CFLAGS="$conky_CFLAGS $LUA_CFLAGS $LUA51_CFLAGS"
 478         conky_LIBS="$conky_LIBS $LUA_LIBS $LUA51_LIBS"
 479
 480         if test x$need_tolua = xyes; then
 481                 AC_DEFINE(LUA_EXTRAS, 1, [Define if you want Lua extras])
 482                 if test "x$want_x11" != "xyes"; then
 483                         dnl silently disable if no x11
 484                         want_lua_cairo=no
 485                 else
 486                         if test x$want_lua_cairo = xyes; then
 487                                 PKG_CHECK_MODULES([cairo], cairo)
 488                                 PKG_CHECK_MODULES([cairo_xlib], cairo-xlib)
 489                                 AC_DEFINE(HAVE_LUA_CAIRO, 1, [Define if you want Lua Cairo bindings for Conky])
 490                                 libcairo_CFLAGS="$libcairo_CFLAGS $cairo_CFLAGS $cairo_xlib_CFLAGS"
 491                                 libcairo_LIBS="$libcairo_LIBS $cairo_LIBS $cairo_xlib_LIBS"
 492                         fi
 493                         if test x$want_imlib2 = xyes; then
 494                                 AC_DEFINE(HAVE_LUA_IMLIB2, 1, [Define if you want Lua Imlib2 bindings for Conky])
 495                         fi
 496                 fi
 497                 AC_CHECK_PROGS(toluapp, [tolua++ tolua++5.1], no)
 498                 if test x$toluapp = xno; then
 499                         AC_MSG_ERROR([tolua++ or tolua++5.1 is required for Lua extras.])
 500                 else
 501                         AC_SEARCH_LIBS(tolua_error,
 502                                                    [tolua++ tolua++5.1],
 503                                                    [
 504                                                         AC_SUBST(tolua_LIBS, "${LIBS}")
 505                                                         AC_SUBST(tolua_CFLAGS, "${CFLAGS}")
 506                                                         ],
 507                                                    AC_MSG_ERROR([tolua_error not found]),
 508                                                    [$LUA_LIBS $LUA51_LIBS])
 509                 fi
 510                 conky_LIBS="$conky_LIBS $tolua_LIBS"
 511                 tolua_CFLAGS="$tolua_CFLAGS $LUA_CFLAGS $LUA51_CFLAGS"
 512                 tolua_LIBS="$tolua_LIBS $LUA_LIBS $LUA51_LIBS"
 513         fi
 514         AC_DEFINE(HAVE_LUA, 1, [Define if you want Lua scripting support])
 515 fi
 516 AM_CONDITIONAL(BUILD_LUA_CAIRO, test x$want_lua_cairo = xyes)
 517 AM_CONDITIONAL(BUILD_LUA_IMLIB2, test x$want_lua_imlib2 = xyes)
 518
 519 dnl
 520 dnl Wireless extensions
 521 dnl
 522
 523 AC_ARG_ENABLE([wlan],
 524               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 525               [want_wlan="$enableval"], [want_wlan=no])
 526
 527 AM_CONDITIONAL(BUILD_WLAN, test x$want_wlan = xyes)
 528 if test x$want_wlan = xyes; then
 529   AC_CHECK_HEADERS([iwlib.h], [], AC_MSG_ERROR([iwlib.h header not found]))
 530   AC_CHECK_LIB([iw], [iw_sockets_open], [conky_LIBS="$conky_LIBS -liw"], AC_MSG_ERROR([iw_sockets_open not found]))
 531         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 532 fi
 533
 534 dnl
 535 dnl PORT_MONITORS
 536 dnl
 537
 538 AC_ARG_ENABLE([portmon],
 539               AC_HELP_STRING([--disable-portmon],
 540                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 541               [want_portmon="$enableval"], [want_portmon=yes])
 542
 543 if test x"$want_portmon" = xyes; then
 544   if test x"$uname" != xLinux; then
 545       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 546       want_portmon=no
 547   else
 548         AC_CHECK_FUNCS([getnameinfo], [], AC_MSG_ERROR([getnameinfo function not found]))
 549         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 550            [PORT_MONITORS_MISSING=yes])
 551         if test x"$PORT_MONITORS_MISSING" = xyes; then
 552               AC_MSG_ERROR([missing a needed network header for port monitoring])
 553         fi
 554         WANT_GLIB=yes
 555         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 556   fi
 557 fi
 558 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 559
 560
 561 dnl
 562 dnl ICONV
 563 dnl
 564
 565 m4_pattern_allow([AM_ICONV])
 566 AM_ICONV
 567 if test "$am_cv_func_iconv" != yes; then
 568   AC_MSG_WARN([Could not find libiconv])
 569 else
 570   conky_LIBS="$conky_LIBS $LIBICONV"
 571 fi
 572 AM_CONDITIONAL(BUILD_ICONV, test "$am_cv_func_iconv" = yes)
 573
 574 dnl
 575 dnl Xext Double-buffering Extension
 576 dnl
 577
 578 AC_ARG_ENABLE([double_buffer],
 579               AC_HELP_STRING([--disable-double-buffer],
 580                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 581               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 582
 583 if test "x$want_double_buffer" = "xyes"; then
 584     if test "x$want_x11" != "xyes"; then
 585       dnl silently disable if no x11
 586       want_double_buffer=no
 587     else
 588       if $PKG_CONFIG --exists xext; then
 589         PKG_CHECK_MODULES([Xext],[xext])
 590         conky_CFLAGS="$conky_CFLAGS $Xext_CFLAGS"
 591         conky_LIBS="$conky_LIBS $Xext_LIBS"
 592       else
 593         dnl non-modular X11 installation
 594         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [conky_LIBS="$conky_LIBS -lXext"],
 595                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 596       fi
 597       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 598     fi
 599 fi
 600
 601
 602 dnl
 603 dnl Xdamage Extension
 604 dnl
 605
 606 AC_ARG_ENABLE([xdamage],
 607               AC_HELP_STRING([--disable-xdamage],
 608                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 609               [want_xdamage="$enableval"], [want_xdamage=yes])
 610
 611 if test "x$want_xdamage" = "xyes"; then
 612     if test "x$want_x11" != "xyes"; then
 613       dnl silently disable if no x11
 614       want_xdamage=no
 615     else
 616       if $PKG_CONFIG --exists xdamage; then
 617         PKG_CHECK_MODULES([XDamage],[xdamage])
 618         conky_CFLAGS="$conky_CFLAGS $XDamage_CFLAGS"
 619         conky_LIBS="$conky_LIBS $XDamage_LIBS"
 620       else
 621         dnl non-modular X11 installation
 622                 AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [conky_LIBS="$conky_LIBS -lXdamage"],
 623                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 624       fi
 625       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 626     fi
 627 fi
 628
 629
 630 dnl
 631 dnl Xft
 632 dnl
 633
 634 AC_ARG_ENABLE([xft],
 635               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 636               [want_xft="$enableval"], [want_xft=yes])
 637
 638 if test x$want_xft = "xyes"; then
 639     if test "x$want_x11" != "xyes"; then
 640       dnl silently disable if no x11
 641       want_xft=no
 642     else
 643       PKG_CHECK_MODULES([Xft], [xft])
 644       conky_CFLAGS="$conky_CFLAGS $Xft_CFLAGS"
 645       conky_LIBS="$conky_LIBS $Xft_LIBS"
 646       AC_DEFINE(XFT, 1, [Define for Xft support])
 647     fi
 648 fi
 649
 650 dnl
 651 dnl NVIDIA libXNVCtrl support
 652 dnl
 653
 654 AC_ARG_ENABLE([nvidia],
 655                 AC_HELP_STRING([--enable-nvidia], [enable if you want nvidia support @<:@default=no@:>@]),
 656                 [want_nvidia="$enableval"], [want_nvidia=no])
 657 if test x$want_nvidia = xyes; then
 658     if test "x$want_x11" != "xyes"; then
 659                 # do nada
 660                 want_nvidia=no
 661         else
 662                 AC_CHECK_HEADERS([NVCtrl/NVCtrl.h], [], AC_MSG_ERROR([NVCtrl/NVCtrl.h header not found]))
 663 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLQueryVersion], [] ,[AC_MSG_ERROR([grrr])] )
 664 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLCheckTargetData], [], [AC_MSG_ERROR([grr])])
 665 dnl ## am I Stupid ??
 666 dnl ## it won't find the lib for some reason!?
 667                 conky_LIBS="$conky_LIBS -lXNVCtrl"
 668                         AC_DEFINE(NVIDIA, 1, [Define if you want nvidia support])
 669         fi
 670 fi
 671 AM_CONDITIONAL(BUILD_NVIDIA, test x$want_nvidia = xyes)
 672
 673 dnl
 674 dnl GLIB
 675 dnl
 676
 677 if test x$WANT_GLIB = xyes; then
 678         PKG_CHECK_MODULES([GLib2], [glib-2.0])
 679         conky_CFLAGS="$conky_CFLAGS $GLib2_CFLAGS"
 680         conky_LIBS="$conky_LIBS $GLib2_LIBS"
 681 fi
 682
 683 dnl
 684 dnl libcurl
 685 dnl
 686
 687 if test x$want_curl = xyes; then
 688         PKG_CHECK_MODULES([libcurl], libcurl)
 689         conky_CFLAGS="$conky_CFLAGS $libcurl_CFLAGS"
 690         conky_LIBS="$conky_LIBS $libcurl_LIBS"
 691         AC_DEFINE(HAVE_CURL, 1, [Define if you want Curl support])
 692 fi
 693 AM_CONDITIONAL(BUILD_CURL, test x$want_curl = xyes)
 694
 695 dnl
 696 dnl libx
 697 dnl
 698
 699 if test x$want_libxml2 = xyes; then
 700         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 701         conky_CFLAGS="$conky_CFLAGS $libxml2_CFLAGS"
 702         conky_LIBS="$conky_LIBS $libxml2_LIBS"
 703 fi
 704
 705 dnl
 706 dnl KVM
 707 dnl
 708
 709 if test x$WANT_KVM = xyes; then
 710   AC_CHECK_LIB(kvm, kvm_open,
 711     conky_LIBS="$conky_LIBS -lkvm",
 712   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 713   )
 714 fi
 715
 716 dnl
 717 dnl devstat
 718 dnl
 719
 720 if test x$WANT_DEVSTAT = xyes; then
 721   AC_CHECK_LIB(devstat, devstat_getversion,
 722          conky_LIBS="$conky_LIBS -ldevstat",
 723          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 724   )
 725 fi
 726
 727 dnl
 728 dnl OSSLIB for NetBSD/OpenBSD
 729 dnl
 730
 731 if test x$WANT_OSSLIB = xyes; then
 732     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 733   conky_LIBS="$conky_LIBS -lossaudio",
 734   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 735     )
 736 fi
 737
 738 dnl
 739 dnl ALSA for Linux
 740 dnl
 741 AC_ARG_ENABLE([alsa],
 742               AC_HELP_STRING([--disable-alsa], [disable if you do not
 743   want ALSA support @<:@default=yes@:>@]),
 744               [want_alsa="$enableval"], [want_alsa=yes])
 745
 746 if test x$want_alsa = xyes; then
 747     AC_CHECK_HEADER(alsa/asoundlib.h,, want_alsa=no)
 748 fi
 749 if test x$want_alsa = xyes; then
 750     AC_CHECK_LIB(asound, snd_pcm_open,conky_LIBS="$conky_LIBS -lasound", want_alsa=no)
 751 fi
 752 if test x$want_alsa = xyes; then
 753 AC_DEFINE(MIXER_IS_ALSA, 1, [Define if the mixers use ALSA])
 754 fi
 755 dnl
 756 dnl Some headers
 757 dnl
 758
 759 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h alsa/asoundlib.h dirent.h mcheck.h \
 760       sys/statfs.h sys/param.h pthread.h semaphore.h assert.h errno.h time.h])
 761 AC_CHECK_HEADERS([sys/mount.h], [], [],
 762      [#ifdef HAVE_SYS_PARAM_H
 763       #include <sys/param.h>
 764       #endif
 765       ])
 766 # check if we have inotify support
 767 AC_CHECK_HEADERS([sys/inotify.h])
 768
 769 dnl
 770 dnl Some defines
 771 dnl
 772
 773 AC_DEFINE(DEFAULTNETDEV, "eth0", [Default networkdevice])
 774 AC_DEFINE(CONFIG_FILE, "$HOME/.conkyrc", [Configfile of the user])
 775 AC_DEFINE(MAX_SPECIALS_DEFAULT, 512, [Default maximum number of special things, e.g. fonts, offsets, aligns, etc.])
 776 AC_DEFINE(MAX_USER_TEXT_DEFAULT, 16384, [Default maximum size of config TEXT buffer, i.e. below TEXT line.])
 777 AC_DEFINE(DEFAULT_TEXT_BUFFER_SIZE, 256, [Default size used for temporary, static text buffers])
 778
 779 dnl
 780 dnl Some functions
 781 dnl
 782
 783 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr strndup gethostbyname_r])
 784 AC_SEARCH_LIBS(clock_gettime, [rt], conky_LIBS="$conky_LIBS -lrt"
 785                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 786                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 787
 788 dnl
 789 dnl Structure checks
 790 dnl
 791
 792 AC_CHECK_MEMBER([struct statfs.f_fstypename],
 793                  [AC_DEFINE(HAVE_STRUCT_STATFS_F_FSTYPENAME, 1, [Define if struct statfs has the f_fstypename member])],
 794                  [],
 795                  [#include <sys/statfs.h>])
 796
 797 dnl
 798 dnl Check for zlib
 799 dnl
 800
 801 AC_CHECK_HEADER(zlib.h,
 802                 [],
 803                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 804
 805
 806 dnl
 807 dnl Check for OpenMP support
 808 dnl
 809 dnl removed for now due to problems with GCC's OpenMP implementation
 810
 811 dnl AC_ARG_ENABLE([openmp],
 812 dnl           AC_HELP_STRING([--enable-openmp], [enable if you want OpenMP support @<:@default=no@:>@]),
 813 dnl           [want_openmp="$enableval"], [want_openmp=no])
 814
 815 dnl if test x$want_openmp = xyes; then
 816 dnl     AX_OPENMP([
 817 dnl       gcc_version=`$CC -dumpversion`
 818 dnl       gcc_major=`echo $gcc_version | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
 819 dnl       gcc_minor=`echo $gcc_version | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
 820 dnl       dnl check that the gcc version is >=4.3, if we're using gcc
 821 dnl       if test ! "x$GCC" = "xyes" -o $gcc_major -ge 4 -a $gcc_minor -ge 3; then
 822 dnl         AC_DEFINE(HAVE_OPENMP,1,[Define if OpenMP is enabled])
 823 dnl         conky_CFLAGS="$conky_CFLAGS $OPENMP_CFLAGS"
 824 dnl       else
 825 dnl         want_openmp=no
 826 dnl       fi
 827 dnl     ])
 828 dnl fi
 829
 830 dnl
 831 dnl Check doc stuff
 832 dnl
 833
 834 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 835 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 836 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 837 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 838   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 839 else
 840   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 841 fi
 842
 843 dnl
 844 dnl kstat in Solaris
 845 dnl
 846
 847 if test x$WANT_KSTAT = xyes; then
 848   dah=no
 849   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 850
 851   if test x$dah = xyes; then
 852     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 853     conky_LDFLAGS="$conky_LDFLAGS -lkstat"
 854   fi
 855 fi
 856
 857 AC_DEFUN([AM_LANGINFO_CODESET],
 858 [
 859   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 860     [AC_TRY_LINK([#include <langinfo.h>],
 861       [char* cs = nl_langinfo(CODESET);],
 862       am_cv_langinfo_codeset=yes,
 863       am_cv_langinfo_codeset=no)
 864     ])
 865   if test $am_cv_langinfo_codeset = yes; then
 866     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 867       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 868   fi
 869 ])
 870
 871
 872 dnl ************************
 873 dnl * Linker optimizations *
 874 dnl ************************
 875 AC_MSG_CHECKING([if $LD accepts -O1])
 876 case `$LD -O1 -v 2>&1 </dev/null` in
 877 *GNU* | *BSD*)
 878   conky_LDFLAGS="$conky_LDFLAGS -Wl,-O1"
 879   AC_MSG_RESULT([yes])
 880   ;;
 881 *)
 882   AC_MSG_RESULT([no])
 883   ;;
 884 esac
 885
 886 dnl Solve multiple definitions (only necessary when gnulib is used)
 887 dnl conky_LDFLAGS="$conky_LDFLAGS -Xlinker -zmuldefs"
 888
 889 dnl
 890 dnl Da.
 891 dnl
 892
 893 conky_CFLAGS="$conky_CFLAGS -Wall -W"
 894
 895 dnl
 896 dnl debug
 897 dnl
 898
 899 AC_ARG_ENABLE([debug],
 900               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 901               [want_debug="$enableval"], [want_debug=no])
 902
 903 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 904   conky_CFLAGS="$conky_CFLAGS -g3"
 905   AC_DEFINE([DEBUG], 1, [Define for debugging])
 906 fi
 907
 908 dnl
 909 dnl testing
 910 dnl
 911
 912 AC_ARG_ENABLE([testing],
 913               AC_HELP_STRING([--enable-testing], [use strict compiler flags for testing @<:@default=no@:>@]),
 914               [want_testing="$enableval"], [want_testing=no])
 915
 916 if test "x$want_testing" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 917   if test "x$want_debug" = "xyes"; then
 918     conky_CFLAGS="$conky_CFLAGS -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 919     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 920   else
 921     conky_CFLAGS="$conky_CFLAGS -g3 -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 922     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 923   fi
 924 fi
 925
 926 dnl
 927 dnl profiling
 928 dnl
 929
 930 AC_ARG_ENABLE([profiling],
 931               AC_HELP_STRING([--enable-profiling], [specify compiler flags for use with gprof and gcov @<:@default=no@:>@]),
 932               [want_profiling="$enableval"], [want_profiling=no])
 933
 934 if test "x$want_profiling" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 935   if test "x$want_debug" = "xyes"; then
 936     conky_CFLAGS="$conky_CFLAGS -pg -fprofile-arcs -ftest-coverage"
 937   else
 938     conky_CFLAGS="$conky_CFLAGS -g3 -pg -fprofile-arcs -ftest-coverage"
 939   fi
 940   AC_DEFINE([PROFILING], [], [Define for profiling (gprof and gcov) support])
 941 fi
 942
 943 AC_SUBST(conky_CFLAGS)
 944 AC_SUBST(conky_LIBS)
 945 AC_SUBST(X11_LIBS)
 946
 947 AC_OUTPUT
 948
 949 dnl
 950 dnl Print summary
 951 dnl
 952 cat << EOF
 953
 954 $PACKAGE $VERSION configured successfully:
 955
 956  Installing into:   $prefix
 957  System config dir: $sysconfdir
 958  C compiler flags:  $conky_CFLAGS
 959  Libraries:         $conky_LIBS
 960  Linker flags:      $conky_LDFLAGS
 961
 962  * X11:
 963   X11 support:      $want_x11
 964   XDamage support:  $want_xdamage
 965   XDBE support:     $want_double_buffer
 966   Xft support:      $want_xft
 967
 968  * Music detection:
 969   Audacious:        $want_audacious
 970   BMPx:             $want_bmpx
 971   MPD:              $want_mpd
 972   MOC:              $want_moc
 973   XMMS2:            $want_xmms2
 974
 975  * General:
 976 dnl  OpenMP:           $want_openmp
 977   math:             $want_math
 978   hddtemp:          $want_hddtemp
 979   portmon:          $want_portmon
 980   RSS:              $want_rss
 981   Curl:             $want_curl
 982   Weather
 983     METAR:          $want_metar
 984     XOAP:           $want_xoap
 985   wireless:         $want_wlan
 986   IBM:              $want_ibm
 987   nvidia:           $want_nvidia
 988   eve-online:       $want_eve
 989   config-output:    $want_config_output
 990   Imlib2:           $want_imlib2
 991   ALSA mixer:       $want_alsa
 992   apcupsd:          $want_apcupsd
 993   I/O stats:        $want_iostats
 994
 995  * Lua ($want_lua) bindings:
 996   Cairo:            $want_lua_cairo
 997   Imlib2:           $want_lua_imlib2
 998
 999 EOF