git.maemo.org Git - monky/blob - configure.ac.in

   1 dnl $Id$
   2
   3 dnl major, minor and micro version macros.
   4 m4_define([conky_version_major], [1])
   5 m4_define([conky_version_minor], [6])
   6 m4_define([conky_version_micro], [0])
   7 m4_define([conky_version_tag], [pre]) dnl [] for releases
   8 m4_define([conky_version_revision],[_pre@REVISION@])
   9 m4_define([conky_version],
  10     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
  11       conky_version_tag(), [pre],
  12       [conky_version_revision()],
  13       [ifelse(conky_version_tag(), [], [], [conky_version_tag()])])])
  14
  15 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  16
  17 AM_INIT_AUTOMAKE(conky, conky_version())
  18 AM_CONFIG_HEADER(src/config.h)
  19
  20 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  21 dnl libtool must be deleted with make distclean to see this fix.
  22 if test x"$CFLAGS" = x""; then
  23   AC_SUBST(CFLAGS, [ ])
  24 fi
  25
  26 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
  27
  28 dnl
  29 dnl Tools
  30 dnl
  31 AC_PROG_CC
  32 gl_EARLY
  33 AC_PROG_LD
  34 AC_PROG_INSTALL
  35 AC_PROG_LIBTOOL
  36
  37 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  38 if test x"$HAVE_PKGCONFIG" = x"no"; then
  39   AC_MSG_ERROR([pkg-config is required!])
  40 fi
  41 PKG_PROG_PKG_CONFIG([0.19])
  42
  43
  44 dnl **************************************
  45 dnl * Initialize GnuLib modules (libgnu) *
  46 dnl **************************************
  47 gl_INIT
  48
  49 AC_CONFIG_FILES(
  50   Makefile
  51   data/Makefile
  52   doc/Makefile
  53   libgnu/Makefile
  54   src/Makefile
  55   src/build.h
  56   )
  57
  58 uname=`uname`
  59
  60 case $uname in
  61   Linux*)
  62     WANT_SYSINFO=yes
  63     ;;
  64   FreeBSD*|GNU/kFreeBSD*)
  65     WANT_KVM=yes
  66     WANT_DEVSTAT=yes
  67     ;;
  68 #  NetBSD*)
  69 #    WANT_KVM=yes
  70 #    WANT_OSSLIB=yes
  71 #    ;;
  72
  73   OpenBSD*)
  74     WANT_KVM=yes
  75     WANT_OSSLIB=yes
  76     ;;
  77
  78 # Solaris doesn't work at all right now
  79 #  SunOS*)
  80 #    WANT_KSTAT=yes
  81 #    ;;
  82
  83   *)
  84     echo "Your operating system $uname isn't supported"
  85     echo "Feel free to help. :P"
  86     exit 1
  87     ;;
  88 esac
  89
  90 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  91 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  92 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD -o x$uname = xGNU/kFreeBSD)
  93 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  94 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  95
  96 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  97 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  98 AC_SUBST(BUILD_DATE)
  99 AC_SUBST(BUILD_ARCH)
 100
 101
 102 dnl
 103 dnl OWN_WINDOW option
 104 dnl
 105
 106 AC_ARG_ENABLE([own_window],
 107               AC_HELP_STRING([--disable-own-window],
 108                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
 109               [dah="$enableval"], [dah=yes])
 110
 111 if test $dah != "no"; then
 112   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 113 fi
 114
 115
 116 dnl
 117 dnl Audacious Media Player
 118 dnl
 119
 120 AC_ARG_ENABLE([audacious],
 121               AC_HELP_STRING([--enable-audacious=[[yes|no|legacy]]],
 122                              [enable audacious player support @<:@default=no@:>@]),
 123               [want_audacious="$enableval"], [want_audacious=no])
 124
 125 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes -o x$want_audacious = xlegacy)
 126 if test x$want_audacious = xyes; then
 127       PKG_CHECK_MODULES([Audacious], [audacious >= 1.4.0 dbus-glib-1 glib-2.0 gobject-2.0])
 128       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 129       LIBS="$LIBS $Audacious_LIBS"
 130       save_CPPFLAGS="$CPPFLAGS"
 131       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 132       AC_CHECK_HEADERS([audacious/audctrl.h audacious/dbus.h glib.h glib-object.h],
 133                        [], AC_MSG_ERROR([required header(s) not found]))
 134       CPPFLAGS="$save_CPPFLAGS"
 135       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 136 else if test x$want_audacious = xlegacy; then
 137       PKG_CHECK_MODULES([Audacious], [audacious < 1.4.0 glib-2.0])
 138       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 139       LIBS="$LIBS $Audacious_LIBS"
 140       save_CPPFLAGS="$CPPFLAGS"
 141       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 142       AC_CHECK_HEADERS([audacious/beepctrl.h glib.h], [], AC_MSG_ERROR([required  header(s) not found]))
 143       CPPFLAGS="$save_CPPFLAGS"
 144       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 145       AC_DEFINE(AUDACIOUS_LEGACY, 1, [Define for Audacious Legacy support])
 146       fi
 147 fi
 148
 149
 150 dnl
 151 dnl BMPx
 152 dnl
 153
 154 AC_ARG_ENABLE([bmpx],
 155               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 156               [want_bmpx="$enableval"], [want_bmpx=no])
 157
 158 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 159 if test x$want_bmpx = xyes; then
 160   PKG_CHECK_MODULES([BMPx], [bmp-2.0 >= 0.14.0])
 161   CFLAGS="$CFLAGS $BMPx_CFLAGS"
 162   LIBS="$LIBS $BMPx_LIBS"
 163   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 164 fi
 165
 166
 167 dnl
 168 dnl Hddtemp
 169 dnl
 170
 171 AC_ARG_ENABLE([hddtemp],
 172               AC_HELP_STRING([--disable-hddtemp],
 173                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 174               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 175
 176 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 177 if test x$want_hddtemp = xyes; then
 178   if test x"$uname" != xLinux; then
 179       AC_MSG_NOTICE([hddtemp not supported on $uname... disabling])
 180       want_hddtemp=no
 181   else
 182       AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 183   fi
 184 fi
 185
 186 dnl
 187 dnl MPD
 188 dnl
 189
 190 AC_ARG_ENABLE([mpd],
 191               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 192               [want_mpd="$enableval"], [want_mpd=yes])
 193
 194 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 195 if test x$want_mpd = xyes; then
 196   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 197 fi
 198
 199 dnl
 200 dnl XMMS2
 201 dnl
 202
 203 AC_ARG_ENABLE([xmms2],
 204               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 205               [want_xmms2="$enableval"], [want_xmms2=no])
 206
 207 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 208 if test x$want_xmms2 = xyes; then
 209   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 210     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 211     LIBS="$LIBS $XMMS2_LIBS"
 212     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 213 fi
 214
 215 dnl
 216 dnl EVE Skill Monitor
 217 dnl
 218
 219 AC_ARG_ENABLE([eve],
 220               EC_HELP_STRING([--enable-eve], [Eve-Online skill monitor @<:@default=no@:>@]),
 221               [want_eve="$enableval"], [want_eve=no])
 222
 223 AM_CONDITIONAL(BUILD_EVE, test x$want_eve = xyes)
 224 if test x$want_eve = xyes; then
 225         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 226         PKG_CHECK_MODULES([libcurl], libcurl)
 227         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 228         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 229    AC_DEFINE(EVE, 1, [Define if you want Eve-Online Skill monitor support])
 230 fi
 231
 232 dnl
 233 dnl RSS
 234 dnl
 235
 236 AC_ARG_ENABLE([rss],
 237               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 238               [want_rss="$enableval"], [want_rss=no])
 239 #
 240 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 241 if test x$want_rss = xyes; then
 242         WANT_GLIB=yes
 243         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 244         PKG_CHECK_MODULES([libcurl], libcurl)
 245         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 246         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 247         AC_DEFINE(RSS, 1, [Define if you want rss support])
 248 fi
 249
 250 dnl
 251 dnl SMAPI
 252 dnl
 253
 254 AC_ARG_ENABLE([smapi],
 255               AC_HELP_STRING([--enable-smapi], [enable if you want smapi support @<:@default=no@:>@]),
 256               [want_smapi="$enableval"], [want_smapi=no])
 257
 258 AM_CONDITIONAL(BUILD_SMAPI, test x$want_smapi = xyes)
 259 if test x$want_smapi = xyes; then
 260         AC_DEFINE(SMAPI, 1, [Define if you want smapi support])
 261 fi
 262
 263 dnl
 264 dnl Wireless extensions
 265 dnl
 266
 267 AC_ARG_ENABLE([wlan],
 268               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 269               [want_wlan="$enableval"], [want_wlan=no])
 270
 271 AM_CONDITIONAL(BUILD_WLAN, test x$want_wlan = xyes)
 272 if test x$want_wlan = xyes; then
 273   AC_CHECK_HEADERS([iwlib.h], [], AC_MSG_ERROR([iwlib.h header not found]))
 274   AC_CHECK_LIB([iw], [iw_sockets_open], [LIBS="$LIBS -liw"], AC_MSG_ERROR([iw_sockets_open not found]))
 275         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 276 fi
 277
 278 dnl
 279 dnl NVIDIA libXNVCtrl support
 280 dnl
 281
 282 AC_ARG_ENABLE([nvidia],
 283                 AC_HELP_STRING([--enable-nvidia], [enable if you want nvidia support @<:@default=no@:>@]),
 284                 [want_nvidia="$enableval"], [want_nvidia=no])
 285 AM_CONDITIONAL(BUILD_NVIDIA, test x$want_nvidia = xyes)
 286 if test x$want_nvidia = xyes; then
 287         AC_CHECK_HEADERS([NVCtrl/NVCtrl.h], [], AC_MSG_ERROR([NVCtrl/NVCtrl.h header not found]))
 288 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLQueryVersion], [] ,[AC_MSG_ERROR([grrr])] )
 289 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLCheckTargetData], [], [AC_MSG_ERROR([grr])])
 290 dnl ## am I Stupid ??
 291 dnl ## it won't find the lib for some reason!?
 292         LIBS="$LIBS -lXNVCtrl"
 293                 AC_DEFINE(NVIDIA, 1, [Define if you want nvidia support])
 294 fi
 295
 296 dnl
 297 dnl IMLIB2
 298 dnl
 299
 300 dnl --commented out until brenden finishes it --
 301 dnl AC_ARG_ENABLE([imlib2],
 302 dnl    AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 303 dnl    [want_imlib2="$enableval"], [want_imlib2=no])
 304 dnl
 305 dnl AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 306 dnl if test x$want_imlib2 = xyes; then
 307 dnl PKG_CHECK_MODULES([Imlib2], [imlib2])
 308 dnl CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 309 dnl LIBS="$LIBS $Imlib2_LIBS"
 310 dnl AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 311 dnl fi
 312
 313
 314 dnl
 315 dnl PORT_MONITORS
 316 dnl
 317
 318 AC_ARG_ENABLE([portmon],
 319               AC_HELP_STRING([--disable-portmon],
 320                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 321               [want_portmon="$enableval"], [want_portmon=yes])
 322
 323 if test x"$want_portmon" = xyes; then
 324   if test x"$uname" != xLinux; then
 325       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 326       want_portmon=no
 327   else
 328         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 329            [PORT_MONITORS_MISSING=yes])
 330         if test x"$PORT_MONITORS_MISSING" = xyes; then
 331               AC_MSG_ERROR([missing a needed network header for port monitoring])
 332         fi
 333         WANT_GLIB=yes
 334         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 335   fi
 336 fi
 337 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 338
 339
 340 dnl
 341 dnl ICONV
 342 dnl
 343
 344 AM_ICONV
 345 if test "$am_cv_func_iconv" != yes; then
 346   AC_MSG_WARN([Could not find libiconv])
 347 else
 348   LIBS="$LIBS $LIBICONV"
 349 fi
 350
 351 dnl
 352 dnl X11
 353 dnl
 354
 355 AC_ARG_ENABLE([x11],
 356               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 357               [want_x11="$enableval"], [want_x11=yes])
 358
 359 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 360 if test "x$want_x11" = "xyes"; then
 361     if $PKG_CONFIG --exists x11; then
 362       PKG_CHECK_MODULES([X11], [x11])
 363       CFLAGS="$CFLAGS $X11_CFLAGS"
 364       LIBS="$LIBS $X11_LIBS"
 365     else
 366       dnl non-modular X11 installations
 367       AC_PATH_X
 368       AC_PATH_XTRA
 369       CFLAGS="$CFLAGS $X_CFLAGS"
 370       LIBS="$LIBS $X_LIBS"
 371       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 372       if test "x$no_x" = "xyes"; then
 373         AC_MSG_ERROR([Can't locate your X11 installation])
 374       fi
 375       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 376     fi
 377     AC_DEFINE(X11, 1, [Define if you want to use X11])
 378 fi
 379
 380
 381 dnl
 382 dnl Xext Double-buffering Extension
 383 dnl
 384
 385 AC_ARG_ENABLE([double_buffer],
 386               AC_HELP_STRING([--disable-double-buffer],
 387                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 388               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 389
 390 if test "x$want_double_buffer" = "xyes"; then
 391     if test "x$want_x11" != "xyes"; then
 392       dnl silently disable if no x11
 393       want_double_buffer=no
 394     else
 395       if $PKG_CONFIG --exists xext; then
 396         PKG_CHECK_MODULES([Xext],[xext])
 397         CFLAGS="$CFLAGS $Xext_CFLAGS"
 398         LIBS="$LIBS $Xext_LIBS"
 399       else
 400         dnl non-modular X11 installation
 401         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 402                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 403       fi
 404       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 405     fi
 406 fi
 407
 408
 409 dnl
 410 dnl Xdamage Extension
 411 dnl
 412
 413 AC_ARG_ENABLE([xdamage],
 414               AC_HELP_STRING([--disable-xdamage],
 415                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 416               [want_xdamage="$enableval"], [want_xdamage=yes])
 417
 418 if test "x$want_xdamage" = "xyes"; then
 419     if test "x$want_x11" != "xyes"; then
 420       dnl silently disable if no x11
 421       want_xdamage=no
 422     else
 423       if $PKG_CONFIG --exists xdamage; then
 424         PKG_CHECK_MODULES([XDamage],[xdamage])
 425         CFLAGS="$CFLAGS $XDamage_CFLAGS"
 426         LIBS="$LIBS $XDamage_LIBS"
 427       else
 428         dnl non-modular X11 installation
 429         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 430                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 431       fi
 432       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 433     fi
 434 fi
 435
 436
 437 dnl
 438 dnl Xft
 439 dnl
 440
 441 AC_ARG_ENABLE([xft],
 442               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 443               [want_xft="$enableval"], [want_xft=yes])
 444
 445 if test x$want_xft = "xyes"; then
 446     if test "x$want_x11" != "xyes"; then
 447       dnl silently disable if no x11
 448       want_xft=no
 449     else
 450       PKG_CHECK_MODULES([Xft], [xft])
 451       CFLAGS="$CFLAGS $Xft_CFLAGS"
 452       LIBS="$LIBS $Xft_LIBS"
 453       AC_DEFINE(XFT, 1, [Define for Xft support])
 454     fi
 455 fi
 456
 457 dnl
 458 dnl GLIB
 459 dnl
 460
 461 if test x$WANT_GLIB = xyes; then
 462         PKG_CHECK_MODULES([GLib2], [glib-2.0])
 463         CFLAGS="$CFLAGS $GLib2_CFLAGS"
 464         LIBS="$LIBS $GLib2_LIBS"
 465 fi
 466
 467 dnl
 468 dnl KVM
 469 dnl
 470
 471 if test x$WANT_KVM = xyes; then
 472   AC_CHECK_LIB(kvm, kvm_open,
 473     LIBS="$LIBS -lkvm",
 474   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 475   )
 476 fi
 477
 478 dnl
 479 dnl devstat
 480 dnl
 481
 482 if test x$WANT_DEVSTAT = xyes; then
 483   AC_CHECK_LIB(devstat, devstat_getversion,
 484          LIBS="$LIBS -ldevstat",
 485          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 486   )
 487 fi
 488
 489 dnl
 490 dnl OSSLIB for NetBSD/OpenBSD
 491 dnl
 492
 493 if test x$WANT_OSSLIB = xyes; then
 494     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 495   LIBS="$LIBS -lossaudio",
 496   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 497     )
 498 fi
 499
 500 dnl
 501 dnl Some headers
 502 dnl
 503
 504 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h dirent.h mcheck.h \
 505       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 506 AC_CHECK_HEADERS([sys/mount.h], [], [],
 507      [#ifdef HAVE_SYS_PARAM_H
 508       #include <sys/param.h>
 509       #endif
 510       ])
 511
 512 dnl
 513 dnl Some functions
 514 dnl
 515
 516 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr strndup gethostbyname_r])
 517 AC_SEARCH_LIBS(clock_gettime, [rt],
 518                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 519                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 520
 521 dnl
 522 dnl Structure checks
 523 dnl
 524
 525 AC_CHECK_MEMBER([struct statfs.f_fstypename],
 526                  [AC_DEFINE(HAVE_STRUCT_STATFS_F_FSTYPENAME, 1, [Define if struct statfs has the f_fstypename member])],
 527                  [],
 528                  [#include <sys/statfs.h>])
 529
 530 dnl
 531 dnl Check for zlib
 532 dnl
 533
 534 AC_CHECK_HEADER(zlib.h,
 535                 [],
 536                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 537
 538
 539 dnl
 540 dnl Check doc stuff
 541 dnl
 542
 543 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 544 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 545 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 546 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 547   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 548 else
 549   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 550 fi
 551
 552
 553 dnl
 554 dnl kstat in Solaris
 555 dnl
 556
 557 if test x$WANT_KSTAT = xyes; then
 558   dah=no
 559   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 560
 561   if test x$dah = xyes; then
 562     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 563     LDFLAGS="$LDFLAGS -lkstat"
 564   fi
 565 fi
 566
 567 AC_DEFUN([AM_LANGINFO_CODESET],
 568 [
 569   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 570     [AC_TRY_LINK([#include <langinfo.h>],
 571       [char* cs = nl_langinfo(CODESET);],
 572       am_cv_langinfo_codeset=yes,
 573       am_cv_langinfo_codeset=no)
 574     ])
 575   if test $am_cv_langinfo_codeset = yes; then
 576     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 577       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 578   fi
 579 ])
 580
 581
 582 dnl ************************
 583 dnl * Linker optimizations *
 584 dnl ************************
 585 AC_MSG_CHECKING([if $LD accepts -O1])
 586 case `$LD -O1 -v 2>&1 </dev/null` in
 587 *GNU* | *BSD*)
 588   LDFLAGS="$LDFLAGS -Wl,-O1"
 589   AC_MSG_RESULT([yes])
 590   ;;
 591 *)
 592   AC_MSG_RESULT([no])
 593   ;;
 594 esac
 595
 596
 597 dnl
 598 dnl Da.
 599 dnl
 600
 601 CFLAGS="$CFLAGS -Wall -W"
 602
 603 dnl
 604 dnl debug
 605 dnl
 606
 607 AC_ARG_ENABLE([debug],
 608               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 609               [want_debug="$enableval"], [want_debug=no])
 610
 611 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 612   CFLAGS="$CFLAGS -g3 -Werror"
 613   AC_DEFINE([DEBUG], [], [Define for debugging])
 614 fi
 615
 616 dnl
 617 dnl testing
 618 dnl
 619
 620 AC_ARG_ENABLE([testing],
 621               AC_HELP_STRING([--enable-testing], [use strict compiler flags for testing @<:@default=no@:>@]),
 622               [want_testing="$enableval"], [want_testing=no])
 623
 624 if test "x$want_testing" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 625   if test "x$want_debug" = "xyes"; then
 626     CFLAGS="$CFLAGS -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic"
 627     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 628   else
 629     CFLAGS="$CFLAGS -g3 -Werror -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic"
 630     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 631   fi
 632 fi
 633
 634 AC_SUBST(CFLAGS)
 635 AC_SUBST(X11_LIBS)
 636
 637 AC_OUTPUT
 638
 639 dnl
 640 dnl Print summary
 641 dnl
 642 cat << EOF
 643
 644 $PACKAGE $VERSION configured successfully:
 645
 646  Installing into:   $prefix
 647  System config dir: $sysconfdir
 648  C compiler flags:  $CFLAGS
 649  Linker flags:      $LDFLAGS
 650  Libraries:         $LIBS
 651
 652  * X11:
 653   X11 support:      $want_x11
 654   XDamage support:  $want_xdamage
 655   XDBE support:     $want_double_buffer
 656   Xft support:      $want_xft
 657
 658  * Music detection:
 659   Audacious:        $want_audacious
 660   BMPx:             $want_bmpx
 661   MPD:              $want_mpd
 662   XMMS2:            $want_xmms2
 663
 664  * General:
 665   hddtemp:          $want_hddtemp
 666   portmon:          $want_portmon
 667   RSS:              $want_rss
 668   wireless:         $want_wlan
 669   SMAPI:            $want_smapi
 670   nvidia:           $want_nvidia
 671   eve-online:       $want_eve
 672 EOF