git.maemo.org Git - monky/blob - configure.ac.in

   1 dnl major, minor and micro version macros.
   2 m4_define([conky_version_major], [1])
   3 m4_define([conky_version_minor], [7])
   4 m4_define([conky_version_micro], [2])
   5 m4_define([conky_version_tag], [pre]) dnl [] for releases
   6 m4_define([conky_version_revision],[_pre@REVISION@])
   7 m4_define([conky_version],
   8     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
   9       conky_version_tag(), [pre],
  10       [conky_version_revision()],
  11       [ifelse(conky_version_tag(), [], [], [conky_version_tag()])])])
  12
  13 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  14
  15 AM_INIT_AUTOMAKE(conky, conky_version())
  16 AM_CONFIG_HEADER(src/config.h)
  17 AC_CONFIG_MACRO_DIR([m4])
  18
  19 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  20 dnl libtool must be deleted with make distclean to see this fix.
  21 if test x"$CFLAGS" = x""; then
  22   AC_SUBST(CFLAGS, [ ])
  23 fi
  24
  25 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
  26
  27 dnl
  28 dnl Tools
  29 dnl
  30 AC_PROG_CC
  31 AC_PROG_LD
  32 AC_PROG_INSTALL
  33 AC_PROG_LIBTOOL
  34
  35 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  36 if test x"$HAVE_PKGCONFIG" = x"no"; then
  37   AC_MSG_ERROR([pkg-config is required!])
  38 fi
  39 PKG_PROG_PKG_CONFIG([0.19])
  40
  41 AC_CONFIG_FILES(
  42   Makefile
  43   data/Makefile
  44   doc/Makefile
  45   src/Makefile
  46   src/build.h
  47   )
  48
  49 uname=`uname`
  50
  51 case $uname in
  52   Linux*)
  53     WANT_SYSINFO=yes
  54     ;;
  55   FreeBSD*|GNU/kFreeBSD*)
  56     WANT_KVM=yes
  57     WANT_DEVSTAT=yes
  58     ;;
  59 #  NetBSD*)
  60 #    WANT_KVM=yes
  61 #    WANT_OSSLIB=yes
  62 #    ;;
  63
  64   OpenBSD*)
  65     WANT_KVM=yes
  66     WANT_OSSLIB=yes
  67     ;;
  68
  69 # Solaris doesn't work at all right now
  70 #  SunOS*)
  71 #    WANT_KSTAT=yes
  72 #    ;;
  73
  74   *)
  75     echo "Your operating system $uname isn't supported"
  76     echo "Feel free to help. :P"
  77     exit 1
  78     ;;
  79 esac
  80
  81 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  82 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  83 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD -o x$uname = xGNU/kFreeBSD)
  84 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  85 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  86
  87 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  88 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  89 AC_SUBST(BUILD_DATE)
  90 AC_SUBST(BUILD_ARCH)
  91
  92
  93 dnl
  94 dnl BUILD_CONFIG_OUTPUT option
  95 dnl
  96
  97 AC_ARG_ENABLE([config_output],
  98               AC_HELP_STRING([--disable-config-output], [disable if you do not want conky to output a default config (with -C) @<:@default=yes@:>@]),
  99               [want_config_output="$enableval"], [want_config_output=yes])
 100
 101 AM_CONDITIONAL(BUILD_CONFIG_OUTPUT, test x$want_config_output = xyes)
 102 AM_CONDITIONAL(BUILD_FOR_FOPENCOOKIE, test x$want_config_output = xyes)
 103 if test x$want_config_output = xyes; then
 104   AC_DEFINE(CONFIG_OUTPUT, 1, [Define if you want conky to output a default config (with -C)])
 105   AC_CHECK_FUNCS(fopencookie)
 106 fi
 107
 108 dnl
 109 dnl OWN_WINDOW option
 110 dnl
 111
 112 AC_ARG_ENABLE([own_window],
 113               AC_HELP_STRING([--disable-own-window],
 114                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
 115               [dah="$enableval"], [dah=yes])
 116
 117 if test $dah != "no"; then
 118   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 119 fi
 120
 121
 122 dnl
 123 dnl Audacious Media Player
 124 dnl
 125
 126 AC_ARG_ENABLE([audacious],
 127               AC_HELP_STRING([--enable-audacious=[[yes|no|legacy]]],
 128                              [enable audacious player support @<:@default=no@:>@]),
 129               [want_audacious="$enableval"], [want_audacious=no])
 130
 131 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes -o x$want_audacious = xlegacy)
 132 if test x$want_audacious = xyes; then
 133       PKG_CHECK_MODULES([Audacious], [audacious >= 1.4.0 dbus-glib-1 glib-2.0 gobject-2.0])
 134       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 135       LIBS="$LIBS $Audacious_LIBS"
 136       save_CPPFLAGS="$CPPFLAGS"
 137       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 138       AC_CHECK_HEADERS([audacious/audctrl.h audacious/dbus.h glib.h glib-object.h],
 139                        [], AC_MSG_ERROR([required header(s) not found]))
 140       CPPFLAGS="$save_CPPFLAGS"
 141       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 142 else if test x$want_audacious = xlegacy; then
 143       PKG_CHECK_MODULES([Audacious], [audacious < 1.4.0 glib-2.0])
 144       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 145       LIBS="$LIBS $Audacious_LIBS"
 146       save_CPPFLAGS="$CPPFLAGS"
 147       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 148       AC_CHECK_HEADERS([audacious/beepctrl.h glib.h], [], AC_MSG_ERROR([required  header(s) not found]))
 149       CPPFLAGS="$save_CPPFLAGS"
 150       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 151       AC_DEFINE(AUDACIOUS_LEGACY, 1, [Define for Audacious Legacy support])
 152       fi
 153 fi
 154
 155
 156 dnl
 157 dnl BMPx
 158 dnl
 159
 160 AC_ARG_ENABLE([bmpx],
 161               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 162               [want_bmpx="$enableval"], [want_bmpx=no])
 163
 164 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 165 if test x$want_bmpx = xyes; then
 166   PKG_CHECK_MODULES([BMPx], [bmp-2.0 >= 0.14.0])
 167   CFLAGS="$CFLAGS $BMPx_CFLAGS"
 168   LIBS="$LIBS $BMPx_LIBS"
 169   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 170 fi
 171
 172
 173 dnl
 174 dnl Support for IBM/Lenovo notebooks
 175 dnl
 176
 177 AC_ARG_ENABLE([ibm],
 178               AC_HELP_STRING([--enable-ibm], [enable if you want support for IBM/Lenovo notebooks @<:default=no@:>@]),
 179               [want_ibm="$enableval"], [want_ibm=no])
 180
 181 AM_CONDITIONAL(BUILD_IBM, test x$want_ibm = xyes)
 182 if test x$want_ibm = xyes; then
 183         if test x"$uname" != xLinux; then
 184                 AC_MSG_NOTICE([support for IBM/Lenovo notebooks not supported on $uname... disabling])
 185                 want_ibm=no
 186         else
 187                 AC_DEFINE(IBM, 1, [Define if you want support for IBM/Lenovo notebooks (SMAPI)])
 188         fi
 189 fi
 190
 191
 192 dnl
 193 dnl Hddtemp
 194 dnl
 195
 196 AC_ARG_ENABLE([hddtemp],
 197               AC_HELP_STRING([--disable-hddtemp],
 198                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 199               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 200
 201 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 202 if test x$want_hddtemp = xyes; then
 203   if test x"$uname" != xLinux; then
 204       AC_MSG_NOTICE([hddtemp not supported on $uname... disabling])
 205       want_hddtemp=no
 206   else
 207       AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 208   fi
 209 fi
 210
 211 dnl
 212 dnl Math
 213 dnl
 214
 215
 216 dnl
 217 dnl Apcupsd
 218 dnl
 219
 220 AC_ARG_ENABLE([apcupsd],
 221               AC_HELP_STRING([--disable-apcupsd],
 222                              [disable if you do not want apcupsd support @<:@default=yes@:>@]),
 223               [want_apcupsd="$enableval"], [want_apcupsd=yes])
 224
 225 if test x$want_apcupsd = xyes; then
 226   if test x"$uname" != xLinux; then
 227       AC_MSG_NOTICE([apcupsd not supported on $uname... disabling])
 228       want_apcupsd=no
 229   else
 230       AC_DEFINE(APCUPSD, 1, [Define if you want apcupsd support])
 231   fi
 232 fi
 233 AM_CONDITIONAL(BUILD_APCUPSD, test x$want_apcupsd = xyes)
 234
 235 AC_ARG_ENABLE([math],
 236               AC_HELP_STRING([--disable-math], [disable if you do not want math support @<:@default=yes@:>@]),
 237               [want_math="$enableval"], [want_math=yes])
 238
 239 AM_CONDITIONAL(BUILD_MATH, test x$want_math = xyes)
 240 if test x$want_math = xyes; then
 241   LIBS="$LIBS -lm"
 242   AC_DEFINE(MATH, 1, [Define if you want math support])
 243 fi
 244
 245 dnl
 246 dnl MPD
 247 dnl
 248
 249 AC_ARG_ENABLE([mpd],
 250               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 251               [want_mpd="$enableval"], [want_mpd=yes])
 252
 253 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 254 if test x$want_mpd = xyes; then
 255   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 256 fi
 257
 258 dnl
 259 dnl MOC
 260 dnl
 261
 262 AC_ARG_ENABLE([moc],
 263               AC_HELP_STRING([--disable-moc], [disable if you do not want MOC support @<:@default=yes@:>@]),
 264               [want_moc="$enableval"], [want_moc=yes])
 265
 266 AM_CONDITIONAL(BUILD_MOC, test x$want_moc = xyes)
 267 if test x$want_moc = xyes; then
 268   AC_DEFINE(MOC, 1, [Define if you want MOC support])
 269 fi
 270
 271 dnl
 272 dnl XMMS2
 273 dnl
 274
 275 AC_ARG_ENABLE([xmms2],
 276               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 277               [want_xmms2="$enableval"], [want_xmms2=no])
 278
 279 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 280 if test x$want_xmms2 = xyes; then
 281   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 282     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 283     LIBS="$LIBS $XMMS2_LIBS"
 284     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 285 fi
 286
 287 dnl
 288 dnl EVE Skill Monitor
 289 dnl
 290
 291 AC_ARG_ENABLE([eve],
 292               AC_HELP_STRING([--enable-eve], [Eve-Online skill monitor @<:@default=no@:>@]),
 293               [want_eve="$enableval"], [want_eve=no])
 294
 295 AM_CONDITIONAL(BUILD_EVE, test x$want_eve = xyes)
 296 if test x$want_eve = xyes; then
 297         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 298         PKG_CHECK_MODULES([libcurl], libcurl)
 299         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 300         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 301         AC_DEFINE(EVE, 1, [Define if you want Eve-Online Skill monitor support])
 302         AC_DEFINE(EVEURL_TRAINING, "http://api.eve-online.com/char/SkillInTraining.xml.aspx", [Eve training URL])
 303         AC_DEFINE(EVEURL_SKILLTREE, "http://api.eve-online.com/eve/Skilltree.xml.aspx", [Eve skilltree URL])
 304         AC_DEFINE(MY_ENCODING, "ISO-8859-1", [Textencoding to use])
 305         AC_DEFINE(EVE_OUTPUT_FORMAT, "%s %d in %s", [Eve output format])
 306 fi
 307
 308 dnl
 309 dnl RSS
 310 dnl
 311
 312 AC_ARG_ENABLE([rss],
 313               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 314               [want_rss="$enableval"], [want_rss=no])
 315 #
 316 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 317 if test x$want_rss = xyes; then
 318         WANT_GLIB=yes
 319         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 320         PKG_CHECK_MODULES([libcurl], libcurl)
 321         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 322         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 323         AC_DEFINE(RSS, 1, [Define if you want rss support])
 324 fi
 325
 326 dnl
 327 dnl Lua
 328 dnl
 329
 330 AC_ARG_ENABLE([lua],
 331               AC_HELP_STRING([--enable-lua], [enable if you want Lua scripting support @<:@default=yes@:>@]),
 332               [want_lua="$enableval"], [want_lua=yes])
 333 #
 334 AM_CONDITIONAL(BUILD_LUA, test x$want_lua = xyes)
 335 if test x$want_lua = xyes; then
 336         PKG_CHECK_MODULES(LUA, lua >= 5.1, [ ],[
 337                 PKG_CHECK_MODULES(LUA51, lua-5.1 >= 5.1, [ ],[
 338                         PKG_CHECK_MODULES(LUA51, lua5.1 >= 5.1)
 339                 ])
 340         ])
 341         CFLAGS="$CFLAGS $LUA_CFLAGS $LUA51_CFLAGS"
 342         LIBS="$LIBS $LUA_LIBS $LUA51_LIBS"
 343         AC_DEFINE(HAVE_LUA, 1, [Define if you want Lua scripting support])
 344 fi
 345
 346 dnl
 347 dnl Wireless extensions
 348 dnl
 349
 350 AC_ARG_ENABLE([wlan],
 351               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 352               [want_wlan="$enableval"], [want_wlan=no])
 353
 354 AM_CONDITIONAL(BUILD_WLAN, test x$want_wlan = xyes)
 355 if test x$want_wlan = xyes; then
 356   AC_CHECK_HEADERS([iwlib.h], [], AC_MSG_ERROR([iwlib.h header not found]))
 357   AC_CHECK_LIB([iw], [iw_sockets_open], [LIBS="$LIBS -liw"], AC_MSG_ERROR([iw_sockets_open not found]))
 358         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 359 fi
 360
 361 dnl
 362 dnl PORT_MONITORS
 363 dnl
 364
 365 AC_ARG_ENABLE([portmon],
 366               AC_HELP_STRING([--disable-portmon],
 367                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 368               [want_portmon="$enableval"], [want_portmon=yes])
 369
 370 if test x"$want_portmon" = xyes; then
 371   if test x"$uname" != xLinux; then
 372       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 373       want_portmon=no
 374   else
 375         AC_CHECK_FUNCS([getnameinfo], [], AC_MSG_ERROR([getnameinfo function not found]))
 376         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 377            [PORT_MONITORS_MISSING=yes])
 378         if test x"$PORT_MONITORS_MISSING" = xyes; then
 379               AC_MSG_ERROR([missing a needed network header for port monitoring])
 380         fi
 381         WANT_GLIB=yes
 382         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 383   fi
 384 fi
 385 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 386
 387
 388 dnl
 389 dnl ICONV
 390 dnl
 391
 392 AM_ICONV
 393 if test "$am_cv_func_iconv" != yes; then
 394   AC_MSG_WARN([Could not find libiconv])
 395 else
 396   LIBS="$LIBS $LIBICONV"
 397 fi
 398
 399 dnl
 400 dnl X11
 401 dnl
 402
 403 AC_ARG_ENABLE([x11],
 404               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 405               [want_x11="$enableval"], [want_x11=yes])
 406
 407 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 408 if test "x$want_x11" = "xyes"; then
 409     if $PKG_CONFIG --exists x11; then
 410       PKG_CHECK_MODULES([X11], [x11])
 411       CFLAGS="$CFLAGS $X11_CFLAGS"
 412       LIBS="$LIBS $X11_LIBS"
 413     else
 414       dnl non-modular X11 installations
 415       AC_PATH_X
 416       AC_PATH_XTRA
 417       CFLAGS="$CFLAGS $X_CFLAGS"
 418       LIBS="$LIBS $X_LIBS"
 419       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 420       if test "x$no_x" = "xyes"; then
 421         AC_MSG_ERROR([Can't locate your X11 installation])
 422       fi
 423       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 424     fi
 425     AC_DEFINE(X11, 1, [Define if you want to use X11])
 426 fi
 427
 428
 429 dnl
 430 dnl Xext Double-buffering Extension
 431 dnl
 432
 433 AC_ARG_ENABLE([double_buffer],
 434               AC_HELP_STRING([--disable-double-buffer],
 435                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 436               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 437
 438 if test "x$want_double_buffer" = "xyes"; then
 439     if test "x$want_x11" != "xyes"; then
 440       dnl silently disable if no x11
 441       want_double_buffer=no
 442     else
 443       if $PKG_CONFIG --exists xext; then
 444         PKG_CHECK_MODULES([Xext],[xext])
 445         CFLAGS="$CFLAGS $Xext_CFLAGS"
 446         LIBS="$LIBS $Xext_LIBS"
 447       else
 448         dnl non-modular X11 installation
 449         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 450                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 451       fi
 452       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 453     fi
 454 fi
 455
 456
 457 dnl
 458 dnl Xdamage Extension
 459 dnl
 460
 461 AC_ARG_ENABLE([xdamage],
 462               AC_HELP_STRING([--disable-xdamage],
 463                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 464               [want_xdamage="$enableval"], [want_xdamage=yes])
 465
 466 if test "x$want_xdamage" = "xyes"; then
 467     if test "x$want_x11" != "xyes"; then
 468       dnl silently disable if no x11
 469       want_xdamage=no
 470     else
 471       if $PKG_CONFIG --exists xdamage; then
 472         PKG_CHECK_MODULES([XDamage],[xdamage])
 473         CFLAGS="$CFLAGS $XDamage_CFLAGS"
 474         LIBS="$LIBS $XDamage_LIBS"
 475       else
 476         dnl non-modular X11 installation
 477         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 478                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 479       fi
 480       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 481     fi
 482 fi
 483
 484
 485 dnl
 486 dnl Xft
 487 dnl
 488
 489 AC_ARG_ENABLE([xft],
 490               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 491               [want_xft="$enableval"], [want_xft=yes])
 492
 493 if test x$want_xft = "xyes"; then
 494     if test "x$want_x11" != "xyes"; then
 495       dnl silently disable if no x11
 496       want_xft=no
 497     else
 498       PKG_CHECK_MODULES([Xft], [xft])
 499       CFLAGS="$CFLAGS $Xft_CFLAGS"
 500       LIBS="$LIBS $Xft_LIBS"
 501       AC_DEFINE(XFT, 1, [Define for Xft support])
 502     fi
 503 fi
 504
 505 dnl
 506 dnl IMLIB2
 507 dnl
 508
 509 AC_ARG_ENABLE([imlib2],
 510                           AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 511                           [want_imlib2="$enableval"], [want_imlib2=no])
 512 if test x$want_imlib2 = xyes; then
 513         if test "x$want_x11" != "xyes"; then
 514                 dnl silently disable if no x11
 515                 want_imlib2=no
 516         else
 517                 PKG_CHECK_MODULES([Imlib2], [imlib2])
 518                 CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 519                 LIBS="$LIBS $Imlib2_LIBS"
 520                 AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 521         fi
 522 fi
 523 AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 524
 525 dnl
 526 dnl NVIDIA libXNVCtrl support
 527 dnl
 528
 529 AC_ARG_ENABLE([nvidia],
 530                 AC_HELP_STRING([--enable-nvidia], [enable if you want nvidia support @<:@default=no@:>@]),
 531                 [want_nvidia="$enableval"], [want_nvidia=no])
 532 if test x$want_nvidia = xyes; then
 533     if test "x$want_x11" != "xyes"; then
 534                 # do nada
 535                 want_nvidia=no
 536         else
 537                 AC_CHECK_HEADERS([NVCtrl/NVCtrl.h], [], AC_MSG_ERROR([NVCtrl/NVCtrl.h header not found]))
 538 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLQueryVersion], [] ,[AC_MSG_ERROR([grrr])] )
 539 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLCheckTargetData], [], [AC_MSG_ERROR([grr])])
 540 dnl ## am I Stupid ??
 541 dnl ## it won't find the lib for some reason!?
 542                 LIBS="$LIBS -lXNVCtrl"
 543                         AC_DEFINE(NVIDIA, 1, [Define if you want nvidia support])
 544         fi
 545 fi
 546 AM_CONDITIONAL(BUILD_NVIDIA, test x$want_nvidia = xyes)
 547
 548 dnl
 549 dnl GLIB
 550 dnl
 551
 552 if test x$WANT_GLIB = xyes; then
 553         PKG_CHECK_MODULES([GLib2], [glib-2.0])
 554         CFLAGS="$CFLAGS $GLib2_CFLAGS"
 555         LIBS="$LIBS $GLib2_LIBS"
 556 fi
 557
 558 dnl
 559 dnl KVM
 560 dnl
 561
 562 if test x$WANT_KVM = xyes; then
 563   AC_CHECK_LIB(kvm, kvm_open,
 564     LIBS="$LIBS -lkvm",
 565   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 566   )
 567 fi
 568
 569 dnl
 570 dnl devstat
 571 dnl
 572
 573 if test x$WANT_DEVSTAT = xyes; then
 574   AC_CHECK_LIB(devstat, devstat_getversion,
 575          LIBS="$LIBS -ldevstat",
 576          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 577   )
 578 fi
 579
 580 dnl
 581 dnl OSSLIB for NetBSD/OpenBSD
 582 dnl
 583
 584 if test x$WANT_OSSLIB = xyes; then
 585     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 586   LIBS="$LIBS -lossaudio",
 587   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 588     )
 589 fi
 590
 591 dnl
 592 dnl ALSA for Linux
 593 dnl
 594 AC_ARG_ENABLE([alsa],
 595               AC_HELP_STRING([--disable-alsa], [disable if you do not
 596   want ALSA support @<:@default=yes@:>@]),
 597               [want_alsa="$enableval"], [want_alsa=yes])
 598
 599 if test x$want_alsa = xyes; then
 600     AC_CHECK_HEADER(alsa/asoundlib.h,, want_alsa=no)
 601 fi
 602 if test x$want_alsa = xyes; then
 603     AC_CHECK_LIB(asound, snd_pcm_open,LIBS="$LIBS -lasound", want_alsa=no)
 604 fi
 605 if test x$want_alsa = xyes; then
 606 AC_DEFINE(MIXER_IS_ALSA, 1, [Define if the mixers use ALSA])
 607 fi
 608 dnl
 609 dnl Some headers
 610 dnl
 611
 612 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h alsa/asoundlib.h dirent.h mcheck.h \
 613       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 614 AC_CHECK_HEADERS([sys/mount.h], [], [],
 615      [#ifdef HAVE_SYS_PARAM_H
 616       #include <sys/param.h>
 617       #endif
 618       ])
 619 # check if we have inotify support
 620 AC_CHECK_HEADERS([sys/inotify.h])
 621
 622 dnl
 623 dnl Some defines
 624 dnl
 625
 626 AC_DEFINE(DEFAULTNETDEV, "eth0", [Default networkdevice])
 627 AC_DEFINE(CONFIG_FILE, "$HOME/.conkyrc", [Configfile of the user])
 628 AC_DEFINE(MAX_SPECIALS_DEFAULT, 512, [Default maximum number of special things, e.g. fonts, offsets, aligns, etc.])
 629 AC_DEFINE(MAX_USER_TEXT_DEFAULT, 16384, [Default maximum size of config TEXT buffer, i.e. below TEXT line.])
 630 AC_DEFINE(DEFAULT_TEXT_BUFFER_SIZE, 256, [Default size used for temporary, static text buffers])
 631
 632 dnl
 633 dnl Some functions
 634 dnl
 635
 636 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr strndup gethostbyname_r])
 637 AC_SEARCH_LIBS(clock_gettime, [rt],
 638                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 639                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 640
 641 dnl
 642 dnl Structure checks
 643 dnl
 644
 645 AC_CHECK_MEMBER([struct statfs.f_fstypename],
 646                  [AC_DEFINE(HAVE_STRUCT_STATFS_F_FSTYPENAME, 1, [Define if struct statfs has the f_fstypename member])],
 647                  [],
 648                  [#include <sys/statfs.h>])
 649
 650 dnl
 651 dnl Check for zlib
 652 dnl
 653
 654 AC_CHECK_HEADER(zlib.h,
 655                 [],
 656                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 657
 658
 659 dnl
 660 dnl Check for OpenMP support
 661 dnl
 662
 663 AC_ARG_ENABLE([openmp],
 664               AC_HELP_STRING([--enable-openmp], [enable if you want OpenMP support @<:@default=no@:>@]),
 665               [want_openmp="$enableval"], [want_openmp=no])
 666
 667 if test x$want_openmp = xyes; then
 668         AX_OPENMP([
 669           gcc_version=`$CC -dumpversion`
 670           gcc_major=`echo $gcc_version | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\1/'`
 671           gcc_minor=`echo $gcc_version | sed 's/\([[0-9]]*\).\([[0-9]]*\).\([[0-9]]*\)/\2/'`
 672           dnl check that the gcc version is >=4.3, if we're using gcc
 673           if test ! "x$GCC" = "xyes" -o $gcc_major -ge 4 -a $gcc_minor -ge 3; then
 674             AC_DEFINE(HAVE_OPENMP,1,[Define if OpenMP is enabled])
 675             CFLAGS="$CFLAGS $OPENMP_CFLAGS"
 676           else
 677             want_openmp=no
 678           fi
 679
 680         ])
 681 fi
 682
 683 dnl
 684 dnl Check doc stuff
 685 dnl
 686
 687 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 688 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 689 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 690 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 691   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 692 else
 693   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 694 fi
 695
 696 dnl
 697 dnl kstat in Solaris
 698 dnl
 699
 700 if test x$WANT_KSTAT = xyes; then
 701   dah=no
 702   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 703
 704   if test x$dah = xyes; then
 705     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 706     LDFLAGS="$LDFLAGS -lkstat"
 707   fi
 708 fi
 709
 710 AC_DEFUN([AM_LANGINFO_CODESET],
 711 [
 712   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 713     [AC_TRY_LINK([#include <langinfo.h>],
 714       [char* cs = nl_langinfo(CODESET);],
 715       am_cv_langinfo_codeset=yes,
 716       am_cv_langinfo_codeset=no)
 717     ])
 718   if test $am_cv_langinfo_codeset = yes; then
 719     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 720       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 721   fi
 722 ])
 723
 724
 725 dnl ************************
 726 dnl * Linker optimizations *
 727 dnl ************************
 728 AC_MSG_CHECKING([if $LD accepts -O1])
 729 case `$LD -O1 -v 2>&1 </dev/null` in
 730 *GNU* | *BSD*)
 731   LDFLAGS="$LDFLAGS -Wl,-O1"
 732   AC_MSG_RESULT([yes])
 733   ;;
 734 *)
 735   AC_MSG_RESULT([no])
 736   ;;
 737 esac
 738
 739 dnl Solve multiple definitions (only necessary when gnulib is used)
 740 dnl LDFLAGS="$LDFLAGS -Xlinker -zmuldefs"
 741
 742 dnl
 743 dnl Da.
 744 dnl
 745
 746 CFLAGS="$CFLAGS -Wall -W"
 747
 748 dnl
 749 dnl debug
 750 dnl
 751
 752 AC_ARG_ENABLE([debug],
 753               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 754               [want_debug="$enableval"], [want_debug=no])
 755
 756 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 757   CFLAGS="$CFLAGS -g3"
 758   AC_DEFINE([DEBUG], 1, [Define for debugging])
 759 fi
 760
 761 dnl
 762 dnl testing
 763 dnl
 764
 765 AC_ARG_ENABLE([testing],
 766               AC_HELP_STRING([--enable-testing], [use strict compiler flags for testing @<:@default=no@:>@]),
 767               [want_testing="$enableval"], [want_testing=no])
 768
 769 if test "x$want_testing" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 770   if test "x$want_debug" = "xyes"; then
 771     CFLAGS="$CFLAGS -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 772     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 773   else
 774     CFLAGS="$CFLAGS -g3 -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic -Werror"
 775     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 776   fi
 777 fi
 778
 779 AC_SUBST(CFLAGS)
 780 AC_SUBST(X11_LIBS)
 781
 782 AC_OUTPUT
 783
 784 dnl
 785 dnl Print summary
 786 dnl
 787 cat << EOF
 788
 789 $PACKAGE $VERSION configured successfully:
 790
 791  Installing into:   $prefix
 792  System config dir: $sysconfdir
 793  C compiler flags:  $CFLAGS
 794  Linker flags:      $LDFLAGS
 795  Libraries:         $LIBS
 796
 797  * X11:
 798   X11 support:      $want_x11
 799   XDamage support:  $want_xdamage
 800   XDBE support:     $want_double_buffer
 801   Xft support:      $want_xft
 802
 803  * Music detection:
 804   Audacious:        $want_audacious
 805   BMPx:             $want_bmpx
 806   MPD:              $want_mpd
 807   MOC:              $want_moc
 808   XMMS2:            $want_xmms2
 809
 810  * General:
 811   OpenMP:           $want_openmp
 812   math:             $want_math
 813   hddtemp:          $want_hddtemp
 814   portmon:          $want_portmon
 815   RSS:              $want_rss
 816   Lua:              $want_lua
 817   wireless:         $want_wlan
 818   IBM:              $want_ibm
 819   nvidia:           $want_nvidia
 820   eve-online:       $want_eve
 821   config-output:    $want_config_output
 822   Imlib2:           $want_imlib2
 823   ALSA mixer:       $want_alsa
 824   apcupsd:          $want_apcupsd
 825 EOF