git.maemo.org Git - monky/blob - configure.ac.in

   1 dnl $Id$
   2
   3 dnl major, minor and micro version macros.
   4 m4_define([conky_version_major], [1])
   5 m4_define([conky_version_minor], [6])
   6 m4_define([conky_version_micro], [0])
   7 m4_define([conky_version_tag], [pre]) dnl [] for releases
   8 m4_define([conky_version_revision],[_pre@REVISION@])
   9 m4_define([conky_version],
  10     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
  11       conky_version_tag(), [pre],
  12       [conky_version_revision()],
  13       [ifelse(conky_version_tag(), [], [], [conky_version_tag()])])])
  14
  15 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  16
  17 AM_INIT_AUTOMAKE(conky, conky_version())
  18 AM_CONFIG_HEADER(src/config.h)
  19
  20 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  21 dnl libtool must be deleted with make distclean to see this fix.
  22 if test x"$CFLAGS" = x""; then
  23   AC_SUBST(CFLAGS, [ ])
  24 fi
  25
  26 dnl
  27 dnl Tools
  28 dnl
  29 AC_PROG_CC
  30 AC_PROG_LD
  31 AC_PROG_INSTALL
  32 AC_PROG_LIBTOOL
  33
  34 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  35 if test x"$HAVE_PKGCONFIG" = x"no"; then
  36   AC_MSG_ERROR([pkg-config is required!])
  37 fi
  38 PKG_PROG_PKG_CONFIG([0.19])
  39
  40 AC_CONFIG_FILES(
  41   Makefile
  42   data/Makefile
  43   doc/Makefile
  44   src/Makefile
  45   src/build.h
  46   )
  47
  48 uname=`uname`
  49
  50 case $uname in
  51   Linux*)
  52     WANT_SYSINFO=yes
  53     ;;
  54   FreeBSD*|GNU/kFreeBSD*)
  55     WANT_KVM=yes
  56     WANT_DEVSTAT=yes
  57     ;;
  58 #  NetBSD*)
  59 #    WANT_KVM=yes
  60 #    WANT_OSSLIB=yes
  61 #    ;;
  62
  63   OpenBSD*)
  64     WANT_KVM=yes
  65     WANT_OSSLIB=yes
  66     ;;
  67
  68 # Solaris doesn't work at all right now
  69 #  SunOS*)
  70 #    WANT_KSTAT=yes
  71 #    ;;
  72
  73   *)
  74     echo "Your operating system $uname isn't supported"
  75     echo "Feel free to help. :P"
  76     exit 1
  77     ;;
  78 esac
  79
  80 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  81 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  82 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD -o x$uname = xGNU/kFreeBSD)
  83 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  84 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  85
  86 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  87 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  88 AC_SUBST(BUILD_DATE)
  89 AC_SUBST(BUILD_ARCH)
  90
  91
  92 dnl
  93 dnl OWN_WINDOW option
  94 dnl
  95
  96 AC_ARG_ENABLE([own_window],
  97               AC_HELP_STRING([--disable-own-window],
  98                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
  99               [dah="$enableval"], [dah=yes])
 100
 101 if test $dah != "no"; then
 102   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 103 fi
 104
 105
 106 dnl
 107 dnl Audacious Media Player
 108 dnl
 109
 110 AC_ARG_ENABLE([audacious],
 111               AC_HELP_STRING([--enable-audacious=[[yes|no|legacy]]],
 112                              [enable audacious player support @<:@default=no@:>@]),
 113               [want_audacious="$enableval"], [want_audacious=no])
 114
 115 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes -o x$want_audacious = xlegacy)
 116 if test x$want_audacious = xyes; then
 117       PKG_CHECK_MODULES([Audacious], [audacious >= 1.4.0 dbus-glib-1 glib-2.0 gobject-2.0])
 118       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 119       LIBS="$LIBS $Audacious_LIBS"
 120       save_CPPFLAGS="$CPPFLAGS"
 121       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 122       AC_CHECK_HEADERS([audacious/audctrl.h audacious/dbus.h glib.h glib-object.h],
 123                        [], AC_MSG_ERROR([required header(s) not found]))
 124       CPPFLAGS="$save_CPPFLAGS"
 125       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 126 else if test x$want_audacious = xlegacy; then
 127       PKG_CHECK_MODULES([Audacious], [audacious < 1.4.0 glib-2.0])
 128       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 129       LIBS="$LIBS $Audacious_LIBS"
 130       save_CPPFLAGS="$CPPFLAGS"
 131       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 132       AC_CHECK_HEADERS([audacious/beepctrl.h glib.h], [], AC_MSG_ERROR([required  header(s) not found]))
 133       CPPFLAGS="$save_CPPFLAGS"
 134       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 135       AC_DEFINE(AUDACIOUS_LEGACY, 1, [Define for Audacious Legacy support])
 136       fi
 137 fi
 138
 139
 140 dnl
 141 dnl BMPx
 142 dnl
 143
 144 AC_ARG_ENABLE([bmpx],
 145               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 146               [want_bmpx="$enableval"], [want_bmpx=no])
 147
 148 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 149 if test x$want_bmpx = xyes; then
 150   PKG_CHECK_MODULES([BMPx], [bmp-2.0 >= 0.14.0])
 151   CFLAGS="$CFLAGS $BMPx_CFLAGS"
 152   LIBS="$LIBS $BMPx_LIBS"
 153   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 154 fi
 155
 156
 157 dnl
 158 dnl Hddtemp
 159 dnl
 160
 161 AC_ARG_ENABLE([hddtemp],
 162               AC_HELP_STRING([--disable-hddtemp],
 163                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 164               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 165
 166 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 167 if test x$want_hddtemp = xyes; then
 168   if test x"$uname" != xLinux; then
 169       AC_MSG_NOTICE([hddtemp not supported on $uname... disabling])
 170       want_hddtemp=no
 171   else
 172       AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 173   fi
 174 fi
 175
 176 dnl
 177 dnl MPD
 178 dnl
 179
 180 AC_ARG_ENABLE([mpd],
 181               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 182               [want_mpd="$enableval"], [want_mpd=yes])
 183
 184 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 185 if test x$want_mpd = xyes; then
 186   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 187 fi
 188
 189 dnl
 190 dnl XMMS2
 191 dnl
 192
 193 AC_ARG_ENABLE([xmms2],
 194               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 195               [want_xmms2="$enableval"], [want_xmms2=no])
 196
 197 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 198 if test x$want_xmms2 = xyes; then
 199   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 200     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 201     LIBS="$LIBS $XMMS2_LIBS"
 202     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 203 fi
 204
 205 dnl
 206 dnl EVE Skill Monitor
 207 dnl
 208
 209 AC_ARG_ENABLE([eve],
 210               EC_HELP_STRING([--enable-eve], [Eve-Online skill monitor @<:@default=no@:>@]),
 211               [want_eve="$enableval"], [want_eve=no])
 212
 213 AM_CONDITIONAL(BUILD_EVE, test x$want_eve = xyes)
 214 if test x$want_eve = xyes; then
 215         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 216         PKG_CHECK_MODULES([libcurl], libcurl)
 217         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 218         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 219    AC_DEFINE(EVE, 1, [Define if you want Eve-Online Skill monitor support])
 220 fi
 221
 222 dnl
 223 dnl RSS
 224 dnl
 225
 226 AC_ARG_ENABLE([rss],
 227               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 228               [want_rss="$enableval"], [want_rss=no])
 229 #
 230 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 231 if test x$want_rss = xyes; then
 232         WANT_GLIB=yes
 233         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 234         PKG_CHECK_MODULES([libcurl], libcurl)
 235         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 236         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 237         AC_DEFINE(RSS, 1, [Define if you want rss support])
 238 fi
 239
 240 dnl
 241 dnl SMAPI
 242 dnl
 243
 244 AC_ARG_ENABLE([smapi],
 245               AC_HELP_STRING([--enable-smapi], [enable if you want smapi support @<:@default=no@:>@]),
 246               [want_smapi="$enableval"], [want_smapi=no])
 247
 248 AM_CONDITIONAL(BUILD_SMAPI, test x$want_smapi = xyes)
 249 if test x$want_smapi = xyes; then
 250         AC_DEFINE(SMAPI, 1, [Define if you want smapi support])
 251 fi
 252
 253 dnl
 254 dnl Wireless extensions
 255 dnl
 256
 257 AC_ARG_ENABLE([wlan],
 258               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 259               [want_wlan="$enableval"], [want_wlan=no])
 260
 261 AM_CONDITIONAL(BUILD_WLAN, test x$want_wlan = xyes)
 262 if test x$want_wlan = xyes; then
 263   AC_CHECK_HEADERS([iwlib.h], [], AC_MSG_ERROR([iwlib.h header not found]))
 264   AC_CHECK_LIB([iw], [iw_sockets_open], [LIBS="$LIBS -liw"], AC_MSG_ERROR([iw_sockets_open not found]))
 265         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 266 fi
 267
 268 dnl
 269 dnl NVIDIA libXNVCtrl support
 270 dnl
 271
 272 AC_ARG_ENABLE([nvidia],
 273                 AC_HELP_STRING([--enable-nvidia], [enable if you want nvidia support @<:@default=no@:>@]),
 274                 [want_nvidia="$enableval"], [want_nvidia=no])
 275 AM_CONDITIONAL(BUILD_NVIDIA, test x$want_nvidia = xyes)
 276 if test x$want_nvidia = xyes; then
 277         AC_CHECK_HEADERS([NVCtrl/NVCtrl.h], [], AC_MSG_ERROR([NVCtrl/NVCtrl.h header not found]))
 278 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLQueryVersion], [] ,[AC_MSG_ERROR([grrr])] )
 279 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLCheckTargetData], [], [AC_MSG_ERROR([grr])])
 280 dnl ## am I Stupid ??
 281 dnl ## it won't find the lib for some reason!?
 282         LIBS="$LIBS -lXNVCtrl"
 283                 AC_DEFINE(NVIDIA, 1, [Define if you want nvidia support])
 284 fi
 285
 286 dnl
 287 dnl IMLIB2
 288 dnl
 289
 290 dnl --commented out until brenden finishes it --
 291 dnl AC_ARG_ENABLE([imlib2],
 292 dnl    AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 293 dnl    [want_imlib2="$enableval"], [want_imlib2=no])
 294 dnl
 295 dnl AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 296 dnl if test x$want_imlib2 = xyes; then
 297 dnl PKG_CHECK_MODULES([Imlib2], [imlib2])
 298 dnl CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 299 dnl LIBS="$LIBS $Imlib2_LIBS"
 300 dnl AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 301 dnl fi
 302
 303
 304 dnl
 305 dnl PORT_MONITORS
 306 dnl
 307
 308 AC_ARG_ENABLE([portmon],
 309               AC_HELP_STRING([--disable-portmon],
 310                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 311               [want_portmon="$enableval"], [want_portmon=yes])
 312
 313 if test x"$want_portmon" = xyes; then
 314   if test x"$uname" != xLinux; then
 315       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 316       want_portmon=no
 317   else
 318         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 319            [PORT_MONITORS_MISSING=yes])
 320         if test x"$PORT_MONITORS_MISSING" = xyes; then
 321               AC_MSG_ERROR([missing a needed network header for port monitoring])
 322         fi
 323         WANT_GLIB=yes
 324         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 325   fi
 326 fi
 327 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 328
 329
 330 dnl
 331 dnl ICONV
 332 dnl
 333
 334 AM_ICONV
 335 if test "$am_cv_func_iconv" != yes; then
 336   AC_MSG_WARN([Could not find libiconv])
 337 else
 338   LIBS="$LIBS $LIBICONV"
 339 fi
 340
 341 dnl
 342 dnl X11
 343 dnl
 344
 345 AC_ARG_ENABLE([x11],
 346               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 347               [want_x11="$enableval"], [want_x11=yes])
 348
 349 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 350 if test "x$want_x11" = "xyes"; then
 351     if $PKG_CONFIG --exists x11; then
 352       PKG_CHECK_MODULES([X11], [x11])
 353       CFLAGS="$CFLAGS $X11_CFLAGS"
 354       LIBS="$LIBS $X11_LIBS"
 355     else
 356       dnl non-modular X11 installations
 357       AC_PATH_X
 358       AC_PATH_XTRA
 359       CFLAGS="$CFLAGS $X_CFLAGS"
 360       LIBS="$LIBS $X_LIBS"
 361       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 362       if test "x$no_x" = "xyes"; then
 363         AC_MSG_ERROR([Can't locate your X11 installation])
 364       fi
 365       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 366     fi
 367     AC_DEFINE(X11, 1, [Define if you want to use X11])
 368 fi
 369
 370
 371 dnl
 372 dnl Xext Double-buffering Extension
 373 dnl
 374
 375 AC_ARG_ENABLE([double_buffer],
 376               AC_HELP_STRING([--disable-double-buffer],
 377                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 378               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 379
 380 if test "x$want_double_buffer" = "xyes"; then
 381     if test "x$want_x11" != "xyes"; then
 382       dnl silently disable if no x11
 383       want_double_buffer=no
 384     else
 385       if $PKG_CONFIG --exists xext; then
 386         PKG_CHECK_MODULES([Xext],[xext])
 387         CFLAGS="$CFLAGS $Xext_CFLAGS"
 388         LIBS="$LIBS $Xext_LIBS"
 389       else
 390         dnl non-modular X11 installation
 391         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 392                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 393       fi
 394       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 395     fi
 396 fi
 397
 398
 399 dnl
 400 dnl Xdamage Extension
 401 dnl
 402
 403 AC_ARG_ENABLE([xdamage],
 404               AC_HELP_STRING([--disable-xdamage],
 405                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 406               [want_xdamage="$enableval"], [want_xdamage=yes])
 407
 408 if test "x$want_xdamage" = "xyes"; then
 409     if test "x$want_x11" != "xyes"; then
 410       dnl silently disable if no x11
 411       want_xdamage=no
 412     else
 413       if $PKG_CONFIG --exists xdamage; then
 414         PKG_CHECK_MODULES([XDamage],[xdamage])
 415         CFLAGS="$CFLAGS $XDamage_CFLAGS"
 416         LIBS="$LIBS $XDamage_LIBS"
 417       else
 418         dnl non-modular X11 installation
 419         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 420                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 421       fi
 422       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 423     fi
 424 fi
 425
 426
 427 dnl
 428 dnl Xft
 429 dnl
 430
 431 AC_ARG_ENABLE([xft],
 432               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 433               [want_xft="$enableval"], [want_xft=yes])
 434
 435 if test x$want_xft = "xyes"; then
 436     if test "x$want_x11" != "xyes"; then
 437       dnl silently disable if no x11
 438       want_xft=no
 439     else
 440       PKG_CHECK_MODULES([Xft], [xft])
 441       CFLAGS="$CFLAGS $Xft_CFLAGS"
 442       LIBS="$LIBS $Xft_LIBS"
 443       AC_DEFINE(XFT, 1, [Define for Xft support])
 444     fi
 445 fi
 446
 447 dnl
 448 dnl GLIB
 449 dnl
 450
 451 if test x$WANT_GLIB = xyes; then
 452         PKG_CHECK_MODULES([GLib2], [glib-2.0])
 453         CFLAGS="$CFLAGS $GLib2_CFLAGS"
 454         LIBS="$LIBS $GLib2_LIBS"
 455 fi
 456
 457 dnl
 458 dnl KVM
 459 dnl
 460
 461 if test x$WANT_KVM = xyes; then
 462   AC_CHECK_LIB(kvm, kvm_open,
 463     LIBS="$LIBS -lkvm",
 464   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 465   )
 466 fi
 467
 468 dnl
 469 dnl devstat
 470 dnl
 471
 472 if test x$WANT_DEVSTAT = xyes; then
 473   AC_CHECK_LIB(devstat, devstat_getversion,
 474          LIBS="$LIBS -ldevstat",
 475          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 476   )
 477 fi
 478
 479 dnl
 480 dnl OSSLIB for NetBSD/OpenBSD
 481 dnl
 482
 483 if test x$WANT_OSSLIB = xyes; then
 484     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 485   LIBS="$LIBS -lossaudio",
 486   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 487     )
 488 fi
 489
 490 dnl
 491 dnl Some headers
 492 dnl
 493
 494 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h dirent.h mcheck.h \
 495       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 496 AC_CHECK_HEADERS([sys/mount.h], [], [],
 497      [#ifdef HAVE_SYS_PARAM_H
 498       #include <sys/param.h>
 499       #endif
 500       ])
 501
 502 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
 503
 504 dnl
 505 dnl Some functions
 506 dnl
 507
 508 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr strndup gethostbyname_r])
 509 AC_SEARCH_LIBS(clock_gettime, [rt],
 510                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 511                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 512
 513 dnl
 514 dnl Structure checks
 515 dnl
 516
 517 AC_CHECK_MEMBER([struct statfs.f_fstypename],
 518                  [AC_DEFINE(HAVE_STRUCT_STATFS_F_FSTYPENAME, 1, [Define if struct statfs has the f_fstypename member])],
 519                  [],
 520                  [#include <sys/statfs.h>])
 521
 522 dnl
 523 dnl Check for zlib
 524 dnl
 525
 526 AC_CHECK_HEADER(zlib.h,
 527                 [],
 528                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 529
 530
 531 dnl
 532 dnl Check doc stuff
 533 dnl
 534
 535 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 536 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 537 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 538 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 539   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 540 else
 541   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 542 fi
 543
 544
 545 dnl
 546 dnl kstat in Solaris
 547 dnl
 548
 549 if test x$WANT_KSTAT = xyes; then
 550   dah=no
 551   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 552
 553   if test x$dah = xyes; then
 554     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 555     LDFLAGS="$LDFLAGS -lkstat"
 556   fi
 557 fi
 558
 559 AC_DEFUN([AM_LANGINFO_CODESET],
 560 [
 561   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 562     [AC_TRY_LINK([#include <langinfo.h>],
 563       [char* cs = nl_langinfo(CODESET);],
 564       am_cv_langinfo_codeset=yes,
 565       am_cv_langinfo_codeset=no)
 566     ])
 567   if test $am_cv_langinfo_codeset = yes; then
 568     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 569       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 570   fi
 571 ])
 572
 573
 574 dnl ************************
 575 dnl * Linker optimizations *
 576 dnl ************************
 577 AC_MSG_CHECKING([if $LD accepts -O1])
 578 case `$LD -O1 -v 2>&1 </dev/null` in
 579 *GNU* | *BSD*)
 580   LDFLAGS="$LDFLAGS -Wl,-O1"
 581   AC_MSG_RESULT([yes])
 582   ;;
 583 *)
 584   AC_MSG_RESULT([no])
 585   ;;
 586 esac
 587
 588
 589 dnl
 590 dnl Da.
 591 dnl
 592
 593 CFLAGS="$CFLAGS -Wall -W"
 594
 595 dnl
 596 dnl debug
 597 dnl
 598
 599 AC_ARG_ENABLE([debug],
 600               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 601               [want_debug="$enableval"], [want_debug=no])
 602
 603 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 604   CFLAGS="$CFLAGS -g3 -Werror"
 605   AC_DEFINE([DEBUG], [], [Define for debugging])
 606 fi
 607
 608 dnl
 609 dnl testing
 610 dnl
 611
 612 AC_ARG_ENABLE([testing],
 613               AC_HELP_STRING([--enable-testing], [use strict compiler flags for testing @<:@default=no@:>@]),
 614               [want_testing="$enableval"], [want_testing=no])
 615
 616 if test "x$want_testing" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 617   if test "x$want_debug" = "xyes"; then
 618     CFLAGS="$CFLAGS -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic"
 619     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 620   else
 621     CFLAGS="$CFLAGS -g3 -Werror -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic"
 622     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 623   fi
 624 fi
 625
 626 AC_SUBST(CFLAGS)
 627 AC_SUBST(X11_LIBS)
 628
 629 AC_OUTPUT
 630
 631 dnl
 632 dnl Print summary
 633 dnl
 634 cat << EOF
 635
 636 $PACKAGE $VERSION configured successfully:
 637
 638  Installing into:   $prefix
 639  System config dir: $sysconfdir
 640  C compiler flags:  $CFLAGS
 641  Linker flags:      $LDFLAGS
 642  Libraries:         $LIBS
 643
 644  * X11:
 645   X11 support:      $want_x11
 646   XDamage support:  $want_xdamage
 647   XDBE support:     $want_double_buffer
 648   Xft support:      $want_xft
 649
 650  * Music detection:
 651   Audacious:        $want_audacious
 652   BMPx:             $want_bmpx
 653   MPD:              $want_mpd
 654   XMMS2:            $want_xmms2
 655
 656  * General:
 657   hddtemp:          $want_hddtemp
 658   portmon:          $want_portmon
 659   RSS:              $want_rss
 660   wireless:         $want_wlan
 661   SMAPI:            $want_smapi
 662   nvidia:           $want_nvidia
 663   eve-online:       $want_eve
 664 EOF