git.maemo.org Git - monky/blob - configure.ac.in

   1 dnl $Id$
   2
   3 dnl major, minor and micro version macros.
   4 m4_define([conky_version_major], [1])
   5 m4_define([conky_version_minor], [6])
   6 m4_define([conky_version_micro], [0])
   7 m4_define([conky_version_tag], [pre]) dnl [] for releases
   8 m4_define([conky_version_revision],[_pre@REVISION@])
   9 m4_define([conky_version],
  10     [conky_version_major().conky_version_minor().conky_version_micro()ifelse(
  11       conky_version_tag(), [pre],
  12       [conky_version_revision()],
  13       [ifelse(conky_version_tag(), [], [], [conky_version_tag()])])])
  14
  15 AC_INIT([Conky], [conky_version()], [brenden1@users.sourceforge.net])
  16
  17 AM_INIT_AUTOMAKE(conky, conky_version())
  18 AM_CONFIG_HEADER(src/config.h)
  19
  20 dnl prevent libtool setting LTCFLAGS to default of -g -O2 when CFLAGS unset.
  21 dnl libtool must be deleted with make distclean to see this fix.
  22 if test x"$CFLAGS" = x""; then
  23   AC_SUBST(CFLAGS, [ ])
  24 fi
  25
  26 dnl
  27 dnl Tools
  28 dnl
  29 AC_PROG_CC
  30 AC_PROG_LD
  31 AC_PROG_INSTALL
  32 AC_PROG_LIBTOOL
  33
  34 AC_CHECK_PROG(HAVE_PKGCONFIG, pkg-config, yes, no)
  35 if test x"$HAVE_PKGCONFIG" = x"no"; then
  36   AC_MSG_ERROR([pkg-config is required!])
  37 fi
  38 PKG_PROG_PKG_CONFIG([0.19])
  39
  40 AC_CONFIG_FILES(
  41   Makefile
  42   data/Makefile
  43   doc/Makefile
  44   src/Makefile
  45   src/build.h
  46   )
  47
  48 uname=`uname`
  49
  50 case $uname in
  51   Linux*)
  52     WANT_SYSINFO=yes
  53     ;;
  54   FreeBSD*|GNU/kFreeBSD*)
  55     WANT_KVM=yes
  56     WANT_DEVSTAT=yes
  57     ;;
  58 #  NetBSD*)
  59 #    WANT_KVM=yes
  60 #    WANT_OSSLIB=yes
  61 #    ;;
  62
  63   OpenBSD*)
  64     WANT_KVM=yes
  65     WANT_OSSLIB=yes
  66     ;;
  67
  68 # Solaris doesn't work at all right now
  69 #  SunOS*)
  70 #    WANT_KSTAT=yes
  71 #    ;;
  72
  73   *)
  74     echo "Your operating system $uname isn't supported"
  75     echo "Feel free to help. :P"
  76     exit 1
  77     ;;
  78 esac
  79
  80 AM_CONDITIONAL(BUILD_LINUX, test x$uname = xLinux)
  81 #AM_CONDITIONAL(BUILD_SOLARIS, test x$uname = xSunOS)
  82 AM_CONDITIONAL(BUILD_FREEBSD, test x$uname = xFreeBSD -o x$uname = xGNU/kFreeBSD)
  83 #AM_CONDITIONAL(BUILD_NETBSD, test x$uname = xNetBSD)
  84 AM_CONDITIONAL(BUILD_OPENBSD, test x$uname = xOpenBSD)
  85
  86 BUILD_DATE=$(LANG=en_US LC_ALL=en_US LOCALE=en_US date)
  87 BUILD_ARCH="$(uname -sr) ($(uname -m))"
  88 AC_SUBST(BUILD_DATE)
  89 AC_SUBST(BUILD_ARCH)
  90
  91
  92 dnl
  93 dnl OWN_WINDOW option
  94 dnl
  95
  96 AC_ARG_ENABLE([own_window],
  97               AC_HELP_STRING([--disable-own-window],
  98                              [disable if you do not want support for creating own window @<:@default=yes@:>@]),
  99               [dah="$enableval"], [dah=yes])
 100
 101 if test $dah != "no"; then
 102   AC_DEFINE(OWN_WINDOW, 1, [Define if you want support for window creating])
 103 fi
 104
 105
 106 dnl
 107 dnl Audacious Media Player
 108 dnl
 109
 110 AC_ARG_ENABLE([audacious],
 111               AC_HELP_STRING([--enable-audacious=[[yes|no|legacy]]],
 112                              [enable audacious player support @<:@default=no@:>@]),
 113               [want_audacious="$enableval"], [want_audacious=no])
 114
 115 AM_CONDITIONAL(BUILD_AUDACIOUS, test x$want_audacious = xyes -o x$want_audacious = xlegacy)
 116 if test x$want_audacious = xyes; then
 117       PKG_CHECK_MODULES([Audacious], [audacious >= 1.4.0 dbus-glib-1 glib-2.0 gobject-2.0])
 118       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 119       LIBS="$LIBS $Audacious_LIBS"
 120       save_CPPFLAGS="$CPPFLAGS"
 121       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 122       AC_CHECK_HEADERS([audacious/audctrl.h audacious/dbus.h glib.h glib-object.h],
 123                        [], AC_MSG_ERROR([required header(s) not found]))
 124       CPPFLAGS="$save_CPPFLAGS"
 125       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 126 else if test x$want_audacious = xlegacy; then
 127       PKG_CHECK_MODULES([Audacious], [audacious < 1.4.0 glib-2.0])
 128       CFLAGS="$CFLAGS $Audacious_CFLAGS"
 129       LIBS="$LIBS $Audacious_LIBS"
 130       save_CPPFLAGS="$CPPFLAGS"
 131       CPPFLAGS="$Audacious_CFLAGS -I`pkg-config --variable=audacious_include_dir audacious`/audacious"
 132       AC_CHECK_HEADERS([audacious/beepctrl.h glib.h], [], AC_MSG_ERROR([required  header(s) not found]))
 133       CPPFLAGS="$save_CPPFLAGS"
 134       AC_DEFINE(AUDACIOUS, 1, [Define for Audacious support])
 135       AC_DEFINE(AUDACIOUS_LEGACY, 1, [Define for Audacious Legacy support])
 136       fi
 137 fi
 138
 139
 140 dnl
 141 dnl BMPx
 142 dnl
 143
 144 AC_ARG_ENABLE([bmpx],
 145               AC_HELP_STRING([--enable-bmpx], [enable if you want BMPx support @<:@default=no@:>@]),
 146               [want_bmpx="$enableval"], [want_bmpx=no])
 147
 148 AM_CONDITIONAL(BUILD_BMPX, test x$want_bmpx = xyes)
 149 if test x$want_bmpx = xyes; then
 150   PKG_CHECK_MODULES([BMPx], [bmp-2.0 >= 0.14.0])
 151   CFLAGS="$CFLAGS $BMPx_CFLAGS"
 152   LIBS="$LIBS $BMPx_LIBS"
 153   AC_DEFINE(BMPX, 1, [Define if you want BMPx support])
 154 fi
 155
 156
 157 dnl
 158 dnl Hddtemp
 159 dnl
 160
 161 AC_ARG_ENABLE([hddtemp],
 162               AC_HELP_STRING([--disable-hddtemp],
 163                              [disable if you do not want hddtemp support @<:@default=yes@:>@]),
 164               [want_hddtemp="$enableval"], [want_hddtemp=yes])
 165
 166 AM_CONDITIONAL(BUILD_HDDTEMP, test x$want_hddtemp = xyes)
 167 if test x$want_hddtemp = xyes; then
 168   if test x"$uname" != xLinux; then
 169       AC_MSG_NOTICE([hddtemp not supported on $uname... disabling])
 170       want_hddtemp=no
 171   else
 172       AC_DEFINE(HDDTEMP, 1, [Define if you want hddtemp support])
 173   fi
 174 fi
 175
 176 dnl
 177 dnl MPD
 178 dnl
 179
 180 AC_ARG_ENABLE([mpd],
 181               AC_HELP_STRING([--disable-mpd], [disable if you do not want MPD support @<:@default=yes@:>@]),
 182               [want_mpd="$enableval"], [want_mpd=yes])
 183
 184 AM_CONDITIONAL(BUILD_MPD, test x$want_mpd = xyes)
 185 if test x$want_mpd = xyes; then
 186   AC_DEFINE(MPD, 1, [Define if you want MPD support])
 187 fi
 188
 189 dnl
 190 dnl XMMS2
 191 dnl
 192
 193 AC_ARG_ENABLE([xmms2],
 194               AC_HELP_STRING([--enable-xmms2], [enable if you want XMMS2 support @<:@default=no@:>@]),
 195               [want_xmms2="$enableval"], [want_xmms2=no])
 196
 197 AM_CONDITIONAL(BUILD_XMMS2, test x$want_xmms2 = xyes)
 198 if test x$want_xmms2 = xyes; then
 199   PKG_CHECK_MODULES([XMMS2], [xmms2-client])
 200     CFLAGS="$CFLAGS $XMMS2_CFLAGS"
 201     LIBS="$LIBS $XMMS2_LIBS"
 202     AC_DEFINE(XMMS2, 1, [Define if you want XMMS2 support])
 203 fi
 204
 205 dnl
 206 dnl EVE Skill Monitor
 207 dnl
 208
 209 AC_ARG_ENABLE([eve],
 210               EC_HELP_STRING([--enable-eve], [Eve-Online skill monitor @<:@default=no@:>@]),
 211               [want_eve="$enableval"], [want_eve=no])
 212
 213 AM_CONDITIONAL(BUILD_EVE, test x$want_eve = xyes)
 214 if test x$want_eve = xyes; then
 215         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 216         PKG_CHECK_MODULES([libcurl], libcurl)
 217         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 218         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 219    AC_DEFINE(EVE, 1, [Define if you want Eve-Online Skill monitor support])
 220 fi
 221
 222 dnl
 223 dnl RSS
 224 dnl
 225
 226 AC_ARG_ENABLE([rss],
 227               AC_HELP_STRING([--enable-rss], [enable if you want rss support @<:@default=no@:>@]),
 228               [want_rss="$enableval"], [want_rss=no])
 229 #
 230 AM_CONDITIONAL(BUILD_RSS, test x$want_rss = xyes)
 231 if test x$want_rss = xyes; then
 232         WANT_GLIB=yes
 233         PKG_CHECK_MODULES([libxml2], libxml-2.0)
 234         PKG_CHECK_MODULES([libcurl], libcurl)
 235         CFLAGS="$CFLAGS $libxml2_CFLAGS $libcurl_CFLAGS"
 236         LIBS="$LIBS $libxml2_LIBS $libcurl_LIBS"
 237         AC_DEFINE(RSS, 1, [Define if you want rss support])
 238 fi
 239
 240 dnl
 241 dnl SMAPI
 242 dnl
 243
 244 AC_ARG_ENABLE([smapi],
 245               AC_HELP_STRING([--enable-smapi], [enable if you want smapi support @<:@default=no@:>@]),
 246               [want_smapi="$enableval"], [want_smapi=no])
 247
 248 AM_CONDITIONAL(BUILD_SMAPI, test x$want_smapi = xyes)
 249 if test x$want_smapi = xyes; then
 250         AC_DEFINE(SMAPI, 1, [Define if you want smapi support])
 251 fi
 252
 253 dnl
 254 dnl Wireless extensions
 255 dnl
 256
 257 AC_ARG_ENABLE([wlan],
 258               AC_HELP_STRING([--enable-wlan], [enable if you want wireless support @<:@default=no@:>@]),
 259               [want_wlan="$enableval"], [want_wlan=no])
 260
 261 AM_CONDITIONAL(BUILD_WLAN, test x$want_wlan = xyes)
 262 if test x$want_wlan = xyes; then
 263   AC_CHECK_HEADERS([iwlib.h], [], AC_MSG_ERROR([iwlib.h header not found]))
 264   AC_CHECK_LIB([iw], [iw_sockets_open], [LIBS="$LIBS -liw"], AC_MSG_ERROR([iw_sockets_open not found]))
 265         AC_DEFINE(HAVE_IWLIB, 1, [Define if you want wireless support])
 266 fi
 267
 268 dnl
 269 dnl NVIDIA libXNVCtrl support
 270 dnl
 271
 272 AC_ARG_ENABLE([nvidia],
 273                 AC_HELP_STRING([--enable-nvidia], [enable if you want nvidia support @<:@default=no@:>@]),
 274                 [want_nvidia="$enableval"], [want_nvidia=no])
 275 AM_CONDITIONAL(BUILD_NVIDIA, test x$want_nvidia = xyes)
 276 if test x$want_nvidia = xyes; then
 277         AC_CHECK_HEADERS([NVCtrl/NVCtrl.h], [], AC_MSG_ERROR([NVCtrl/NVCtrl.h header not found]))
 278 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLQueryVersion], [] ,[AC_MSG_ERROR([grrr])] )
 279 dnl AC_CHECK_LIB([XNVCtrl], [XNVCTRLCheckTargetData], [], [AC_MSG_ERROR([grr])])
 280 dnl ## am I Stupid ??
 281 dnl ## it won't find the lib for some reason!?
 282         LIBS="$LIBS -lXNVCtrl"
 283                 AC_DEFINE(NVIDIA, 1, [Define if you want nvidia support])
 284 fi
 285
 286 dnl
 287 dnl IMLIB2
 288 dnl
 289
 290 dnl --commented out until brenden finishes it --
 291 dnl AC_ARG_ENABLE([imlib2],
 292 dnl    AC_HELP_STRING([--enable-imlib2], [enable if you want Imlib2 support [[default=no]]]),
 293 dnl    [want_imlib2="$enableval"], [want_imlib2=no])
 294 dnl
 295 dnl AM_CONDITIONAL(BUILD_IMLIB2, test x$want_imlib2 = xyes)
 296 dnl if test x$want_imlib2 = xyes; then
 297 dnl PKG_CHECK_MODULES([Imlib2], [imlib2])
 298 dnl CFLAGS="$CFLAGS $Imlib2_CFLAGS"
 299 dnl LIBS="$LIBS $Imlib2_LIBS"
 300 dnl AC_DEFINE(IMLIB2, 1, [Define if you want Imlib2 support])
 301 dnl fi
 302
 303
 304 dnl
 305 dnl PORT_MONITORS
 306 dnl
 307
 308 AC_ARG_ENABLE([portmon],
 309               AC_HELP_STRING([--disable-portmon],
 310                              [disable if you do not want tcp (ip4) port monitoring @<:@default=yes@:>@]),
 311               [want_portmon="$enableval"], [want_portmon=yes])
 312
 313 if test x"$want_portmon" = xyes; then
 314   if test x"$uname" != xLinux; then
 315       AC_MSG_NOTICE([port monitors not supported on $uname... disabling])
 316       want_portmon=no
 317   else
 318         AC_CHECK_HEADERS([netdb.h netinet/in.h netinet/tcp.h sys/socket.h arpa/inet.h], [],
 319            [PORT_MONITORS_MISSING=yes])
 320         if test x"$PORT_MONITORS_MISSING" = xyes; then
 321               AC_MSG_ERROR([missing a needed network header for port monitoring])
 322         fi
 323         WANT_GLIB=yes
 324         WANT_POSIX_SOURCE=yes
 325         AC_DEFINE(TCP_PORT_MONITOR, 1, [Define if you want tcp port monitoring support])
 326   fi
 327 fi
 328 AM_CONDITIONAL(BUILD_PORT_MONITORS, test x"$want_portmon" = xyes)
 329
 330
 331 dnl
 332 dnl ICONV
 333 dnl
 334
 335 AM_ICONV
 336 if test "$am_cv_func_iconv" != yes; then
 337   AC_MSG_WARN([Could not find libiconv])
 338 else
 339   LIBS="$LIBS $LIBICONV"
 340 fi
 341
 342 dnl
 343 dnl X11
 344 dnl
 345
 346 AC_ARG_ENABLE([x11],
 347               AC_HELP_STRING([--disable-x11], [disable if you do not want X11 support @<:@default=yes@:>@]),
 348               [want_x11="$enableval"], [want_x11=yes])
 349
 350 AM_CONDITIONAL(BUILD_X11, test x$want_x11 = xyes)
 351 if test "x$want_x11" = "xyes"; then
 352     if $PKG_CONFIG --exists x11; then
 353       PKG_CHECK_MODULES([X11], [x11])
 354       CFLAGS="$CFLAGS $X11_CFLAGS"
 355       LIBS="$LIBS $X11_LIBS"
 356     else
 357       dnl non-modular X11 installations
 358       AC_PATH_X
 359       AC_PATH_XTRA
 360       CFLAGS="$CFLAGS $X_CFLAGS"
 361       LIBS="$LIBS $X_LIBS"
 362       LDFLAGS="$LDFLAGS $LIBS $X_PRE_LIBS"
 363       if test "x$no_x" = "xyes"; then
 364         AC_MSG_ERROR([Can't locate your X11 installation])
 365       fi
 366       AC_CHECK_LIB([X11], [XOpenDisplay], [], AC_MSG_ERROR([Could not find XOpenDisplay in -lX11]))
 367     fi
 368     AC_DEFINE(X11, 1, [Define if you want to use X11])
 369 fi
 370
 371
 372 dnl
 373 dnl Xext Double-buffering Extension
 374 dnl
 375
 376 AC_ARG_ENABLE([double_buffer],
 377               AC_HELP_STRING([--disable-double-buffer],
 378                              [disable for no Xdbe double-buffering support @<:@default=yes@:>@]),
 379               [want_double_buffer="$enableval"], [want_double_buffer=yes])
 380
 381 if test "x$want_double_buffer" = "xyes"; then
 382     if test "x$want_x11" != "xyes"; then
 383       dnl silently disable if no x11
 384       want_double_buffer=no
 385     else
 386       if $PKG_CONFIG --exists xext; then
 387         PKG_CHECK_MODULES([Xext],[xext])
 388         CFLAGS="$CFLAGS $Xext_CFLAGS"
 389         LIBS="$LIBS $Xext_LIBS"
 390       else
 391         dnl non-modular X11 installation
 392         AC_CHECK_LIB([Xext], [XdbeQueryExtension], [LIBS="$LIBS -lXext"],
 393                     AC_MSG_ERROR([Could not find XdbeQueryExtension in -lXext]))
 394       fi
 395       AC_DEFINE(HAVE_XDBE, 1, [Define for X11 double-buffering])
 396     fi
 397 fi
 398
 399
 400 dnl
 401 dnl Xdamage Extension
 402 dnl
 403
 404 AC_ARG_ENABLE([xdamage],
 405               AC_HELP_STRING([--disable-xdamage],
 406                              [disable if you do not want Xdamage support @<:@default=yes@:>@]),
 407               [want_xdamage="$enableval"], [want_xdamage=yes])
 408
 409 if test "x$want_xdamage" = "xyes"; then
 410     if test "x$want_x11" != "xyes"; then
 411       dnl silently disable if no x11
 412       want_xdamage=no
 413     else
 414       if $PKG_CONFIG --exists xdamage; then
 415         PKG_CHECK_MODULES([XDamage],[xdamage])
 416         CFLAGS="$CFLAGS $XDamage_CFLAGS"
 417         LIBS="$LIBS $XDamage_LIBS"
 418       else
 419         dnl non-modular X11 installation
 420         AC_CHECK_LIB([Xdamage], [XDamageQueryExtension], [LIBS="$LIBS -lXdamage"],
 421                      AC_MSG_ERROR([Could not find XDamageQueryExtension in -lXdamage]))
 422       fi
 423       AC_DEFINE(HAVE_XDAMAGE, 1, [Define for X11 Xdamage extension])
 424     fi
 425 fi
 426
 427
 428 dnl
 429 dnl Xft
 430 dnl
 431
 432 AC_ARG_ENABLE([xft],
 433               AC_HELP_STRING([--disable-xft], [disable if you do not want to use Xft @<:@default=yes@:>@]),
 434               [want_xft="$enableval"], [want_xft=yes])
 435
 436 if test x$want_xft = "xyes"; then
 437     if test "x$want_x11" != "xyes"; then
 438       dnl silently disable if no x11
 439       want_xft=no
 440     else
 441       PKG_CHECK_MODULES([Xft], [xft])
 442       CFLAGS="$CFLAGS $Xft_CFLAGS"
 443       LIBS="$LIBS $Xft_LIBS"
 444       AC_DEFINE(XFT, 1, [Define for Xft support])
 445     fi
 446 fi
 447
 448 dnl
 449 dnl GLIB
 450 dnl
 451
 452 if test x$WANT_GLIB = xyes; then
 453         PKG_CHECK_MODULES([GLib2], [glib-2.0])
 454         CFLAGS="$CFLAGS $GLib2_CFLAGS"
 455         LIBS="$LIBS $GLib2_LIBS"
 456 fi
 457
 458 dnl
 459 dnl _POSIX_SOURCE
 460 dnl
 461
 462 if test x$WANT_POSIX_SOURCE = xyes; then
 463         CFLAGS="$CFLAGS -D _POSIX_SOURCE"
 464 fi
 465
 466 dnl
 467 dnl KVM
 468 dnl
 469
 470 if test x$WANT_KVM = xyes; then
 471   AC_CHECK_LIB(kvm, kvm_open,
 472     LIBS="$LIBS -lkvm",
 473   AC_MSG_ERROR([Could not find kvm_open in -lkvm.])
 474   )
 475 fi
 476
 477 dnl
 478 dnl devstat
 479 dnl
 480
 481 if test x$WANT_DEVSTAT = xyes; then
 482   AC_CHECK_LIB(devstat, devstat_getversion,
 483          LIBS="$LIBS -ldevstat",
 484          AC_MSG_ERROR([Cound not find devstat_getversion in -ldevstat.])
 485   )
 486 fi
 487
 488 dnl
 489 dnl OSSLIB for NetBSD/OpenBSD
 490 dnl
 491
 492 if test x$WANT_OSSLIB = xyes; then
 493     AC_CHECK_LIB(ossaudio, _oss_ioctl,
 494   LIBS="$LIBS -lossaudio",
 495   AC_MSG_ERROR([Could not find oss_ioctl in -lossaudio.])
 496     )
 497 fi
 498
 499 dnl
 500 dnl Some headers
 501 dnl
 502
 503 AC_CHECK_HEADERS([signal.h unistd.h sys/utsname.h sys/stat.h linux/soundcard.h dirent.h mcheck.h \
 504       sys/statfs.h sys/param.h pthread.h assert.h errno.h time.h])
 505 AC_CHECK_HEADERS([sys/mount.h], [], [],
 506      [#ifdef HAVE_SYS_PARAM_H
 507       #include <sys/param.h>
 508       #endif
 509       ])
 510
 511 AC_DEFINE([_GNU_SOURCE], [], [Define for GNU source and extensions])
 512
 513 dnl
 514 dnl Some functions
 515 dnl
 516
 517 AC_CHECK_FUNCS([calloc malloc free popen sysinfo getloadavg memrchr strndup gethostbyname_r])
 518 AC_SEARCH_LIBS(clock_gettime, [rt],
 519                [AC_DEFINE(HAVE_CLOCK_GETTIME, 1, [Define if you have clock_gettime()])],
 520                [AC_CHECK_FUNCS([gettimeofday], [], [AC_MSG_ERROR([gettimeofday() not available!])])], [])
 521
 522 dnl
 523 dnl Structure checks
 524 dnl
 525
 526 AC_CHECK_MEMBER([struct statfs.f_fstypename],
 527                  [AC_DEFINE(HAVE_STRUCT_STATFS_F_FSTYPENAME, 1, [Define if struct statfs has the f_fstypename member])],
 528                  [],
 529                  [#include <sys/statfs.h>])
 530
 531 dnl
 532 dnl Check for zlib
 533 dnl
 534
 535 AC_CHECK_HEADER(zlib.h,
 536                 [],
 537                 [AC_MSG_ERROR([zlib is missing; please install the headers first])])
 538
 539
 540 dnl
 541 dnl Check doc stuff
 542 dnl
 543
 544 AC_CHECK_PROGS(db2x_xsltproc_cmd, db2x_xsltproc)
 545 AC_CHECK_PROGS(db2x_manxml_cmd, db2x_manxml)
 546 AC_CHECK_PROGS(xsltproc_cmd, xsltproc)
 547 if test x$db2x_xsltproc_cmd = "x" -o x$xsltproc_cmd = "x"; then
 548   AM_CONDITIONAL(HAVE_DOCSTUFF, false)
 549 else
 550   AM_CONDITIONAL(HAVE_DOCSTUFF, true)
 551 fi
 552
 553
 554 dnl
 555 dnl kstat in Solaris
 556 dnl
 557
 558 if test x$WANT_KSTAT = xyes; then
 559   dah=no
 560   AC_CHECK_LIB([kstat], [kstat_open], [dah=yes], [])
 561
 562   if test x$dah = xyes; then
 563     AC_DEFINE(HAVE_KSTAT, 1, [Define if you have kstat (Solaris)])
 564     LDFLAGS="$LDFLAGS -lkstat"
 565   fi
 566 fi
 567
 568 AC_DEFUN([AM_LANGINFO_CODESET],
 569 [
 570   AC_CACHE_CHECK([for nl_langinfo and CODESET], am_cv_langinfo_codeset,
 571     [AC_TRY_LINK([#include <langinfo.h>],
 572       [char* cs = nl_langinfo(CODESET);],
 573       am_cv_langinfo_codeset=yes,
 574       am_cv_langinfo_codeset=no)
 575     ])
 576   if test $am_cv_langinfo_codeset = yes; then
 577     AC_DEFINE(HAVE_LANGINFO_CODESET, 1,
 578       [Define if you have <langinfo.h> and nl_langinfo(CODESET).])
 579   fi
 580 ])
 581
 582
 583 dnl ************************
 584 dnl * Linker optimizations *
 585 dnl ************************
 586 AC_MSG_CHECKING([if $LD accepts -O1])
 587 case `$LD -O1 -v 2>&1 </dev/null` in
 588 *GNU* | *BSD*)
 589   LDFLAGS="$LDFLAGS -Wl,-O1"
 590   AC_MSG_RESULT([yes])
 591   ;;
 592 *)
 593   AC_MSG_RESULT([no])
 594   ;;
 595 esac
 596
 597
 598 dnl
 599 dnl Da.
 600 dnl
 601
 602 CFLAGS="$CFLAGS -Wall -W"
 603
 604 dnl
 605 dnl debug
 606 dnl
 607
 608 AC_ARG_ENABLE([debug],
 609               AC_HELP_STRING([--enable-debug], [compile with debug symbols @<:@default=no@:>@]),
 610               [want_debug="$enableval"], [want_debug=no])
 611
 612 if test "x$want_debug" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 613   CFLAGS="$CFLAGS -g3 -Werror"
 614   AC_DEFINE([DEBUG], [], [Define for debugging])
 615 fi
 616
 617 dnl
 618 dnl testing
 619 dnl
 620
 621 AC_ARG_ENABLE([testing],
 622               AC_HELP_STRING([--enable-testing], [use strict compiler flags for testing @<:@default=no@:>@]),
 623               [want_testing="$enableval"], [want_testing=no])
 624
 625 if test "x$want_testing" = "xyes" -a $ac_cv_c_compiler_gnu != no; then
 626   if test "x$want_debug" = "xyes"; then
 627     CFLAGS="$CFLAGS -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic"
 628     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 629   else
 630     CFLAGS="$CFLAGS -g3 -Werror -Wextra -Wunused -Wdeclaration-after-statement -Wundef -Wendif-labels -Wshadow -Wpointer-arith -Wbad-function-cast -Wcast-qual -Wcast-align -Wwrite-strings -Wstrict-prototypes -Wold-style-definition -Winline -Wmissing-noreturn -Wmissing-format-attribute -Wredundant-decls -std=c99 -pedantic"
 631     AC_DEFINE([TESTING], [], [Define for testing (enables strict compiler flags)])
 632   fi
 633 fi
 634
 635 AC_SUBST(CFLAGS)
 636 AC_SUBST(X11_LIBS)
 637
 638 AC_OUTPUT
 639
 640 dnl
 641 dnl Print summary
 642 dnl
 643 cat << EOF
 644
 645 $PACKAGE $VERSION configured successfully:
 646
 647  Installing into:   $prefix
 648  System config dir: $sysconfdir
 649  C compiler flags:  $CFLAGS
 650  Linker flags:      $LDFLAGS
 651  Libraries:         $LIBS
 652
 653  * X11:
 654   X11 support:      $want_x11
 655   XDamage support:  $want_xdamage
 656   XDBE support:     $want_double_buffer
 657   Xft support:      $want_xft
 658
 659  * Music detection:
 660   Audacious:        $want_audacious
 661   BMPx:             $want_bmpx
 662   MPD:              $want_mpd
 663   XMMS2:            $want_xmms2
 664
 665  * General:
 666   hddtemp:          $want_hddtemp
 667   portmon:          $want_portmon
 668   RSS:              $want_rss
 669   wireless:         $want_wlan
 670   SMAPI:            $want_smapi
 671   nvidia:           $want_nvidia
 672   eve-online:       $want_eve
 673 EOF