git.maemo.org Git - navit-package/blob - configure.in

   1 AC_INIT(navit, 0.2.0)
   2 AC_CONFIG_MACRO_DIR([m4])
   3 SOURCE_MODE=svn
   4
   5 AM_INIT_AUTOMAKE
   6 AM_CONFIG_HEADER(config.h)
   7
   8 AC_SUBST(SOURCE_MODE)
   9 AM_CONDITIONAL(SOURCE_MODE_SVN, [test "x${SOURCE_MODE}" = "xsvn"])
  10
  11 if test "x${SOURCE_MODE}" = "xsvn" ; then
  12         USE_MAINTAINER_MODE=yes
  13 else
  14         USE_MAINTAINER_MODE=no
  15 fi
  16
  17 AC_DEFUN([AM_MAINTAINER_MODE],
  18 [AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  19   dnl maintainer-mode is enabled by default (reason of inclusion of this function)
  20   AC_ARG_ENABLE(maintainer-mode,
  21 [  --enable-maintainer-mode  enable make rules and dependencies not useful
  22                           (and sometimes confusing) to the casual installer],
  23       USE_MAINTAINER_MODE=$enableval)
  24   AC_MSG_RESULT([$USE_MAINTAINER_MODE])
  25   AM_CONDITIONAL(MAINTAINER_MODE, [test $USE_MAINTAINER_MODE = yes])
  26   MAINT=$MAINTAINER_MODE_TRUE
  27   AC_SUBST(MAINT)dnl
  28 ]
  29 )
  30
  31 AU_DEFUN([jm_MAINTAINER_MODE], [AM_MAINTAINER_MODE])
  32
  33 AM_MAINTAINER_MODE
  34
  35
  36 plugins=yes; plugins_reason=default
  37 postgresql=yes; postgresql_reason=default
  38 samplemap=yes; samplemap_reason=default
  39 binding_dbus=yes; binding_dbus_reason=default
  40 binding_python=yes; binding_python_reason=default
  41 font_freetype=yes; font_freetype_reason=default
  42 fontconfig=yes; fontconfig_reason=default
  43 gui_gtk=no; gui_gtk_reason=default
  44 gui_win32=no; gui_win32_reason=default
  45 gui_internal=yes; gui_internal_reason=default
  46 graphics_gd=no; graphics_gd_reason=default
  47 graphics_gtk_drawing_area=no; graphics_gtk_drawing_area_reason=default
  48 graphics_qt_qpainter=yes; graphics_qt_qpainter_reason=default
  49 graphics_opengl=yes; graphics_opengl_reason=default
  50 graphics_sdl=yes; graphics_sdl_reason=default
  51 graphics_win32=no; graphics_win32_reason=default
  52 speech_android=no; speech_android_reason=default
  53 speech_cmdline=yes; speech_cmdline_reason=default
  54 speech_espeak=no; speech_espeak_reason=default
  55 speech_speech_dispatcher=yes; speech_speech_dispatcher_reason=default
  56 vehicle_demo=yes; vehicle_demo_reason=default
  57 vehicle_file=yes; vehicle_file_reason=default
  58 vehicle_gpsd=yes; vehicle_gpsd_reason=default
  59 vehicle_gypsy=yes; vehicle_gypsy_reason=default
  60 vehicle_null=no; vehicle_null_reason=default
  61 vehicle_wince=no; vehicle_wince_reason=default
  62 vehicle_iphone=no; vehicle_iphone_reason=default
  63 vehicle_android=no; vehicle_android_reason=default
  64 graphics_android=no; graphics_android_reason=default
  65
  66 AC_CANONICAL_HOST
  67 win32=no
  68 win32ce=no
  69 case $host_os in
  70 wince|mingw32ce|cegcc)
  71         win32=yes
  72         win32ce=yes
  73         AC_DEFINE(HAVE_API_WIN32_BASE, 1, [Have Windows Base API])
  74         AC_DEFINE(HAVE_API_WIN32_CE, 1, [Have Windows CE API])
  75         gui_win32=yes; gui_win32_reason="host_os is wince"
  76         graphics_win32=yes; graphics_win32_reason="host_os is wince"
  77         vehicle_wince=yes; vehcile_wince_reason="host_os is wince"
  78         speech_espeak=yes; speech_espeak_reason="host_os is wince"
  79         support_libpng=yes
  80         ;;
  81 mingw32)
  82         win32=yes
  83         AC_DEFINE(HAVE_API_WIN32_BASE, 1, [Have Windows Base API])
  84         AC_DEFINE(HAVE_API_WIN32, 1, [Have Windows API])
  85         gui_win32=yes; gui_win32_reason="host_os is mingw32"
  86         graphics_win32=yes; graphics_win32_reason="host_os is mingw32"
  87         speech_espeak=yes; speech_espeak_reason="host_os is mingw32"
  88         support_libpng=yes
  89         LIBS="$LIBS -lwinmm"
  90         ;;
  91 linux*_android)
  92         android=yes
  93         AC_DEFINE(HAVE_API_ANDROID, 1, [Have Android API])
  94         echo "void dl_unwind_find_exidx(void) {}" >crt0.c
  95         $CC -c crt0.c
  96         $AR r libg.a crt0.o
  97         vehicle_android=yes; vehicle_android_reason="host_os is android"
  98         graphics_android=yes; graphics_android_reason="host_os is android"
  99         speech_android=yes; speech_android_reason="host_os is android"
 100         MODULE_LDFLAGS="-Xcompiler -nostdlib"
 101         ;;
 102 esac
 103 if test "x$win32" = "xyes"
 104 then
 105         NAVIT_CFLAGS="$NAVIT_CFLAGS -I\$(top_srcdir)/navit/support/win32"
 106         NAVIT_LIBS="$NAVIT_LIBS -L\$(top_builddir)/navit/support/win32 -lsupport_win32"
 107 fi
 108
 109
 110 AM_CONDITIONAL(SUPPORT_WIN32, [test "x$win32" = "xyes"])
 111 AM_CONDITIONAL(SUPPORT_WIN32CE, [test "x$win32ce" = "xyes"])
 112 AM_CONDITIONAL(SUPPORT_ANDROID, [test "x$android" = "xyes"])
 113
 114 if test "x$support_libpng" = "xyes"
 115 then
 116         NAVIT_CFLAGS="$NAVIT_CFLAGS -I\$(top_srcdir)/navit/support/libpng"
 117         NAVIT_LIBS="$NAVIT_LIBS -L\$(top_builddir)/navit/support/libpng -lsupport_libpng"
 118 fi
 119 AM_CONDITIONAL(SUPPORT_LIBPNG, [test "x$support_libpng" = "xyes"])
 120
 121 AC_SUBST(MODULE_LDFLAGS)
 122
 123 LIBS="$LIBS -lm"
 124 if test "$win32" == "no"; then
 125         LIBS="$LIBS -rdynamic"
 126 fi
 127
 128 m4_ifndef([AC_USE_SYSTEM_EXTENSIONS],
 129         [AC_DEFUN([AC_USE_SYSTEM_EXTENSIONS], [AC_GNU_SOURCE])])
 130
 131 AC_USE_SYSTEM_EXTENSIONS
 132
 133 AC_PROG_OBJC
 134 AC_PROG_CC
 135 AC_PROG_OBJC
 136 if eval "test x`uname` = xDarwin"; then
 137         CFLAGS="$CFLAGS -I/opt/local/include -L/opt/local/lib"
 138 fi
 139 if eval "test x$GCC = xyes"; then
 140         CFLAGS="$CFLAGS -Wall -Wcast-align -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wpointer-arith -Wreturn-type -D_GNU_SOURCE"
 141 fi
 142 AM_PROG_CC_C_O
 143
 144 AC_PROG_CXX
 145 if eval "test x$GXX = xyes"; then
 146         CXXFLAGS="$CXXFLAGS -Wall -Wcast-align -Wpointer-arith -Wreturn-type -D_GNU_SOURCE"
 147 fi
 148
 149 PKG_CHECK_EXISTS
 150 if test "x${cross_compiling}" = "xyes"; then
 151         samplemap="no";samplemap_reason="not supported for cross compiling"
 152         binding_python="no";binding_python_reason="not supported for cross compiling"
 153         postgresql="no";postgresql_reason="not supported for cross compiling"
 154         AC_MSG_CHECKING([for a C compiler for build tools])
 155         AC_CHECK_PROGS(CC_FOR_BUILD, gcc cc)
 156 else
 157         CC_FOR_BUILD=$CC
 158 fi
 159 CCLD_FOR_BUILD="$CC_FOR_BUILD"
 160 AC_SUBST(cross_compiling)
 161 AC_SUBST(CC_FOR_BUILD)
 162 AC_SUBST(CCLD_FOR_BUILD)
 163
 164 # Endianness
 165 # defines WORDS_BIGENDIAN for big-endian systems
 166 AC_C_BIGENDIAN
 167
 168 AC_ARG_ENABLE(variant, [  --enable-variant=something          set variant], NAVIT_VARIANT=$enableval)
 169 AC_SUBST(NAVIT_VARIANT)
 170
 171 AC_ARG_ENABLE(cache-size, [  --enable-cache-size=size in bytes        set cache size], AC_DEFINE_UNQUOTED(CACHE_SIZE,[${enableval}], [Size of Cache in Bytes]))
 172
 173 AC_ARG_ENABLE(avoid-unaligned, [  --enable-avoid-unaligned          avoid unaligned accesses], AVOID_UNALIGNED=$enableval, AVOID_UNALIGNED=no)
 174 test x"${AVOID_UNALIGNED}" = xyes && AC_DEFINE(AVOID_UNALIGNED,[],Define to avoid unaligned access)
 175
 176 AC_ARG_ENABLE(avoid-float, [  --enable-avoid-float              avoid floating point calculations], AVOID_FLOAT=$enableval, AVOID_FLOAT=no)
 177 test x"${AVOID_FLOAT}" = xyes && AC_DEFINE(AVOID_FLOAT,[],Define to avoid floating point)
 178
 179 AC_ARG_ENABLE(transformation-roll, [  --enable-transformation-roll      add support for specifying roll angle in transformation], ENABLE_ROLL=$enableval, ENABLE_ROLL=no)
 180 test x"${ENABLE_ROLL}" = xyes && AC_DEFINE(ENABLE_ROLL,[],Define to add support for specifying roll angle in transformation)
 181
 182 AC_ARG_ENABLE(hildon, [  --disable-hildon              build without maemo/hildon support], enable_hildon=$enableval, enable_hildon=yes)
 183 if test "x${enable_hildon}" = "xyes" ; then
 184         PKG_CHECK_MODULES(HILDON, hildon-1 >= 0.9.9, , [
 185                 AC_MSG_RESULT(no)
 186                 enable_hildon=no
 187         ])
 188         PKG_CHECK_MODULES(GPSBT, gpsbt, [
 189                 AC_DEFINE(HAVE_GPSBT, 1, [Have the gpsbt library])
 190                 AC_SUBST(GPSBT_CFLAGS)
 191                 AC_SUBST(GPSBT_LIBS)
 192                 ], [
 193                 AC_MSG_RESULT(no)
 194         ])
 195         if test x"${enable_hildon}" = xyes ; then
 196                 AC_DEFINE(USE_HILDON, 1, [Build with maemo/hildon support])
 197                 AC_SUBST(HILDON_CFLAGS)
 198                 AC_SUBST(HILDON_LIBS)
 199         fi
 200 fi
 201 AM_CONDITIONAL(USE_HILDON, test "${enable_hildon}" = "xyes")
 202
 203 AC_ARG_ENABLE(garmin, [  --disable-garmin             disable garmin support], USE_GARMIN=$enableval, USE_GARMIN=yes)
 204
 205 # samplemap
 206 AC_PATH_PROG(_PATH_BZCAT,[bzcat])
 207 if test "x${_PATH_BZCAT}" = "x" ; then
 208         samplemap=no; samplemap_reason="bzcat missing"
 209 fi
 210 AC_ARG_ENABLE(samplemap, [  --disable-samplemap             don't build the samplemap], samplemap=$enableval;samplemap_reason="configure parameter")
 211 AM_CONDITIONAL(BUILD_SAMPLEMAP, [test "x$samplemap" = "xyes"])
 212
 213 AC_ARG_ENABLE(fastmath, [  --disable-fastmath             don't build with fastmath], fastmath=$enableval, fastmath=yes)
 214 AM_CONDITIONAL(FASTMATH, [test "x$fastmath" = "xyes"])
 215
 216 if test x"$fastmath" = xyes; then
 217         if eval "test x$GCC = xyes"; then
 218                 CFLAGS="$CFLAGS -ffast-math"
 219         fi
 220 fi
 221
 222 X_CFLAGS="-I$x_includes"
 223 AS_IF([test -n "$ac_x_libraries"], [X_LIBS="-L$ac_x_libraries"])
 224
 225 # glib
 226 AC_ARG_ENABLE(glib, [  --disable-glib             don't build with external glib], glib=$enableval, glib=yes)
 227 if test x"${glib}" = "xyes"; then
 228         PKG_CHECK_MODULES(GLIB, [glib-2.0 gthread-2.0], [glib=yes],[glib=no])
 229 fi
 230 if test "x${glib}" = "xyes"; then
 231         AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if you have (external) glib library])
 232 else
 233         GLIB_CFLAGS="-I\$(top_srcdir)/navit/support -I\$(top_srcdir)/navit/support/glib -I\$(top_srcdir)/navit/support/ezxml"
 234         GLIB_LIBS="-L\$(top_builddir)/navit/support/glib -lsupport_glib -L\$(top_builddir)/navit/support/ezxml -lsupport_ezxml"
 235 fi
 236
 237 # gmodule
 238 AC_ARG_ENABLE(gmodule, [  --disable-gmodule             don't build with gmodule], gmodule=$enableval, gmodule=yes)
 239 if test x"${gmodule}" = "xyes"; then
 240         PKG_CHECK_MODULES(GMODULE, [gmodule-2.0], [gmodule=yes], [gmodule=no])
 241 fi
 242 if test "x${gmodule}" = "xyes"; then
 243         AC_DEFINE(HAVE_GMODULE, 1, [Define to 1 if you have gmodule])
 244 else
 245         AC_CHECK_LIB(dl, dlopen,
 246                 [plugins_reason="default, via dlopen";GMODULE_LIBS="-ldl";AC_DEFINE(HAVE_DLOPEN, 1, [Define to 1 if you have dlopen])],
 247                 [plugins="no"; plugins_reason="package gmodule and dlopen missing"]
 248         )
 249 fi
 250 # plugins
 251 AC_ARG_ENABLE(plugins,  [  --disable-plugins          disable plugins], [ plugins=$enableval;plugin_reason="configure parameter" ])
 252 if test "x${plugins}" = "xyes"; then
 253         AC_ENABLE_SHARED
 254         AC_DISABLE_STATIC
 255         AC_DEFINE(
 256                 [USE_PLUGINS],
 257                 [],
 258                 Define to 1 if you have plugins.
 259         )
 260 else
 261         AC_DISABLE_SHARED
 262         AC_ENABLE_STATIC
 263 fi
 264 AM_CONDITIONAL(PLUGINS, [test "x$plugins" = "xyes"])
 265 AC_PROG_LIBTOOL
 266
 267 AM_CONDITIONAL(EVENT_GLIB, [test "x$glib" = "xyes"])
 268 AM_CONDITIONAL(SUPPORT_GLIB, [test "x$glib" = "xno"])
 269 AM_CONDITIONAL(SUPPORT_EZXML, [test "x$glib" = "xno"])
 270 AM_CONDITIONAL(MAP_POI_GEODOWNLOAD, [test "x$glib" = "xyes"])
 271
 272 AC_CHECK_HEADER(
 273         zlib.h,
 274         AC_DEFINE(
 275                 [HAVE_ZLIB],
 276                 [],
 277                 Define to 1 if you have the <zlib.h> header file.
 278         )
 279         ZLIB_LIBS="-lz"
 280         zlib=yes,
 281         ZLIB_CFLAGS="-I\$(top_srcdir)/navit/support/zlib"
 282         ZLIB_LIBS="-L\$(top_builddir)/navit/support/zlib -lsupport_zlib"
 283         zlib=no
 284 )
 285 AM_CONDITIONAL(SUPPORT_ZLIB, [test "x$zlib" = "xno"])
 286 AC_SUBST(ZLIB_CFLAGS)
 287 AC_SUBST(ZLIB_LIBS)
 288
 289 # gtk
 290 PKG_CHECK_MODULES(GTK2, [gtk+-2.0], [gtk2_pkgconfig=yes], [gtk2_pkgconfig=no])
 291 if test "x$gtk2_pkgconfig" = "xyes"; then
 292         AC_DEFINE(HAVE_GTK2, 1, [Define to 1 if you have gtk2])
 293         graphics_gtk_drawing_area=yes; graphics_gtk_drawing_area_reason="gtk+-2.0 present"
 294         gui_gtk=yes; gui_gtk_reason="gtk+-2.0 present"
 295 fi
 296
 297 # fsync
 298 AC_MSG_CHECKING(for fsync)
 299 AC_TRY_LINK([#include <unistd.h>], [fsync(0);],AC_MSG_RESULT(yes);AC_DEFINE(HAVE_FSYNC, 1, [Define to 1 if you have the `fsync' function.]),AC_MSG_RESULT(no))
 300
 301 # system
 302 AC_MSG_CHECKING(for system)
 303 AC_TRY_LINK([#include <stdlib.h>], [system("/bin/true");],AC_MSG_RESULT(yes);AC_DEFINE(HAVE_SYSTEM, 1, [Define to 1 if you have the `system' function.]),speech_cmdline=no; speech_cmdline_reason="not supported without system()"; AC_MSG_RESULT(no))
 304
 305 AC_MSG_CHECKING(for CreateProcess)
 306 AC_TRY_LINK([#include <windows.h>], [CreateProcess(NULL,NULL,NULL,NULL,0,0,NULL,NULL,NULL,NULL);],AC_MSG_RESULT(yes);AC_DEFINE(HAVE_CREATEPROCESS, 1, [Define to 1 if you have the `CreateProcess' function.]) speech_cmdline=yes; speech_cmdline_reason="CreateProcess exists", AC_MSG_RESULT(no))
 307
 308 AC_ARG_ENABLE(graphics-sdl, [  --disable-graphics-sdl             don't create graphics sdl], graphics_sdl=$enableval;graphics_sdl_reason="configure parameter")
 309
 310 if test "x${graphics_sdl}" = "xyes" ; then
 311         PKG_CHECK_MODULES(SDL,
 312                           [sdl],
 313                           [graphics_sdl="yes"
 314                            graphics_sdl_reason="sdl present"] ,
 315                           [graphics_sdl="no"
 316                            graphics_sdl_reason="sdl not available"]
 317                          )
 318         AC_SUBST(SDL_CFLAGS)
 319         AC_SUBST(SDL_LIBS)
 320 fi
 321 if test "x${graphics_sdl}" = "xyes" ; then
 322         save_CPPFLAGS=$CPPFLAGS
 323         CPPFLAGS="$SDL_CFLAGS $CPPFLAGS"
 324         AC_CHECK_HEADER(SDL_image.h,SDL_IMAGE_LIBS=-lSDL_image,graphics_sdl="no";graphics_sdl_reason="SDL_image.h missing")
 325         AC_SUBST(SDL_IMAGE_LIBS)
 326         CPPFLAGS=$save_CPPFLAGS
 327 fi
 328 if test "x${graphics_sdl}" = "xyes" ; then
 329         AC_DEFINE(USE_GRAPHICS_SDL, 1, [Build with graphics sdl])
 330 fi
 331 AM_CONDITIONAL(USE_GRAPHICS_SDL, test "x${graphics_sdl}" = "xyes")
 332
 333 AC_ARG_ENABLE(postgresql, [  --disable-postgresql             don't add postgresql support to osm2navit], postgresql=$enableval;postgresql_reason="configure parameter")
 334 if test "x${postgresql}" = "xyes" ; then
 335         if test -z "$PG_CONFIG"; then
 336             AC_PATH_PROG([PG_CONFIG], [pg_config], [])
 337         fi
 338         AC_MSG_CHECKING([for PostgreSQL libraries with $PG_CONFIG])
 339         if test ! -x "$PG_CONFIG"; then
 340             if test "x${PG_CONFIG}" = "x" ; then
 341                  postgresql_reason="$PG_CONFIG not executable"
 342             else
 343                  postgresql_reason="pg_config missing"
 344             fi
 345             postgresql=no
 346             AC_MSG_RESULT([no])
 347         else
 348             POSTGRESQL_CFLAGS="-I`$PG_CONFIG --includedir`"
 349             POSTGRESQL_LIBS="-L`$PG_CONFIG --libdir` -lpq"
 350             AC_DEFINE(HAVE_POSTGRESQL, 1, [Postgresql libraries available])
 351             AC_SUBST(POSTGRESQL_CFLAGS)
 352             AC_SUBST(POSTGRESQL_LIBS)
 353             AC_MSG_RESULT([yes])
 354         fi
 355 fi
 356 AM_CONDITIONAL(HAVE_POSTGRESQL, test "x${postgresql}" = "xyes")
 357 # font
 358 # freetype
 359 AC_ARG_ENABLE(font-freetype, [  --disable-font-freetype             don't add freetype support], font_freetype=$enableval;font_freetype_reason="configure parameter")
 360 if test "x${font_freetype}" = "xyes" -a "x${FREETYPE2_CFLAGS}" = "x" -a "x${FREETYPE2_LIBS}" = "x"; then
 361         PKG_CHECK_MODULES(FREETYPE2, [freetype2], , [font_freetype=no;font_freetype_reason="Package freetype2 missing"])
 362 fi
 363 AC_SUBST(FREETYPE2_CFLAGS)
 364 AC_SUBST(FREETYPE2_LIBS)
 365 AM_CONDITIONAL(FONT_FREETYPE, test "x${font_freetype}" = "xyes")
 366
 367 AC_ARG_ENABLE(fontconfig, [  --disable-fontconfig             don't add fontconfig support], fontconfig=$enableval;fontconfig_reason="configure parameter")
 368 if test "x${fontconfig}" = "xyes"; then
 369         PKG_CHECK_MODULES(FONTCONFIG, [fontconfig], [fontconfig=yes], [fontconfig=no])
 370 fi
 371 if test "x$fontconfig" = "xyes"; then
 372    AC_DEFINE(HAVE_FONTCONFIG, 1, [Define to 1 if you have fontconfig])
 373 fi
 374 AC_SUBST(FONTCONFIG_CFLAGS)
 375 AC_SUBST(FONTCONFIG_LIBS)
 376
 377 AM_CONDITIONAL(FONTS, test "x${font_freetype}" = "xyes" -a "x$fontconfig" != "xyes")
 378
 379 PKG_CHECK_MODULES(IMLIB2, [imlib2], [imlib2_pkgconfig=yes], [imlib2_pkgconfig=no])
 380 if test "x$imlib2_pkgconfig" = "xyes"; then
 381    AC_DEFINE(HAVE_IMLIB2, 1, [Define to 1 if you have imlib2])
 382 fi
 383 AC_SUBST(IMLIB2_CFLAGS)
 384 AC_SUBST(IMLIB2_LIBS)
 385
 386
 387
 388 AC_ARG_ENABLE(gui-sdl, [  --disable-gui-sdl             don't create gui sdl ], MODULE_GUI_SDL=$enableval, MODULE_GUI_SDL=yes)
 389 if test "x$MODULE_GUI_SDL" = "xyes"; then
 390         AC_CHECK_HEADER(
 391                 SDL/SDL.h,
 392                 AC_DEFINE(
 393                         [HAVE_LIBSDL],
 394                         [],
 395                         Define to 1 if you have the <SDL/SDL.h> header file.
 396                         )
 397                         SDL_LIBS="-lSDL"
 398                         sdl=yes,
 399                 AC_MSG_WARN([*** no SDL/SDL.h -- SDL support disabled])
 400         )
 401 fi
 402
 403 AC_CHECK_HEADER(
 404         X11/Xmu/Xmu.h,
 405         AC_DEFINE(
 406                 [HAVE_XMU],
 407                 [],
 408                 Define to 1 if you have the <X11/Xmu/Xmu.h> header file.
 409                 )
 410                 xmu=yes,
 411         AC_MSG_WARN([*** no X11/Xmu/Xmu.h -- opengl and SDL support disabled])
 412 )
 413
 414 AC_ARG_ENABLE(graphics-opengl, [  --disable-graphics-opengl      disable graphics type OpenGL], graphics_opengl=$enableval;graphics_opengl_reason="configure parameter")
 415 if test "x${graphics_opengl}" = "xyes" ; then
 416
 417 AC_CHECK_HEADER(
 418         GL/gl.h,
 419         AC_DEFINE(
 420                 [HAVE_OPENGL],
 421                 [],
 422                 Define to 1 if you have the <GL/gl.h> header file.
 423                 )
 424                 OPENGL_LIBS="$X_LIBS -lGL -lGLU"
 425                 opengl=yes,
 426         AC_MSG_WARN([*** no GL/gl.h -- opengl and SDL support disabled];graphics_opengl=no;graphics_opengl_reason="Headers missing")
 427 )
 428
 429 AC_CHECK_HEADER(
 430         GL/glut.h,
 431         AC_DEFINE(
 432                 [HAVE_GLUT],
 433                 [],
 434                 Define to 1 if you have the <GL/glut.h> header file.
 435                 )
 436                 glut=yes,
 437         AC_MSG_WARN([*** no GL/glut.h -- opengl and SDL support disabled]);graphics_opengl=no;graphics_opengl_reason="Headers missing"
 438 )
 439
 440 AC_SUBST(OPENGL_CFLAGS)
 441 AC_SUBST(OPENGL_LIBS)
 442
 443 AC_CHECK_HEADER(
 444         GL/glc.h,
 445         AC_DEFINE(
 446                 [HAVE_GLC],
 447                 [],
 448                 Define to 1 if you have the <GL/glc.h> header file.
 449                 )
 450                 GLC_LIBS="-lGLC"
 451                 glc=yes,
 452         AC_MSG_WARN([*** no GL/glc.h -- opengl and SDL support disabled])
 453 )
 454 AC_SUBST(GLC_CFLAGS)
 455 AC_SUBST(GLC_LIBS)
 456 fi
 457
 458 AM_CONDITIONAL(GUI_SDL, [test "x$sdl" = "xyes" -a "x$opengl" = "xyes" -a "x$glc" = "xyes" -a "x$xmu" = "xyes" ])
 459 AM_CONDITIONAL(GRAPHICS_OPENGL, [test "x$glut" = "xyes" -a "x$opengl" = "xyes" -a "x$glc" = "xyes" ])
 460
 461
 462 if test x"${USE_GARMIN}" = xyes
 463 then
 464         # check for libgarmin
 465         PKG_CHECK_MODULES(LIBGARMIN, libgarmin, use_libgarmin=yes, use_libgarmin=no)
 466         AC_SUBST(LIBGARMIN_CFLAGS)
 467         AC_SUBST(LIBGARMIN_LIBS)
 468 fi
 469         AM_CONDITIONAL(HAVELIBGARMIN, [test "x$use_libgarmin" = "xyes"])
 470
 471 ## binding
 472 # python
 473 AC_ARG_ENABLE(binding-python, [  --disable-binding-python             don't create binding python], binding_python=$enableval;binding_python_reason="configure parameter")
 474 if test "x${binding_python}" = "xyes"; then
 475         AC_PATH_PROG(_PATH_PYTHON,[python])
 476         dnl Libraries and flags for embedded Python.
 477         dnl FIXME: I wish there was a less icky way to get this.
 478         if test "x${_PATH_PYTHON}" != "x" ; then
 479                 AC_MSG_CHECKING(for Python linkage)
 480                 AC_PATH_PROG([PYTHONCONFIG], [python-config], [])
 481                 if test "x${PYTHONCONFIG}" = "x" ; then
 482                         py_prefix=`$_PATH_PYTHON -c 'import sys; print sys.prefix'`
 483                         py_ver=`$_PATH_PYTHON -c 'import sys; print sys.version[[:3]]'`
 484                         py_lib=`$_PATH_PYTHON -c 'import sys; print sys.lib'`
 485                         py_libdir="${py_prefix}/${py_lib}/python${py_ver}"
 486                         PYTHON_CFLAGS="-I${py_prefix}/include/python${py_ver}"
 487                         if test -f $py_libdir/config/Makefile -a -f $py_prefix/include/python${py_ver}/Python.h; then
 488                                 py_libs=`grep '^LIBS=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 489                                 py_libc=`grep '^LIBC=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 490                                 py_libm=`grep '^LIBM=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 491                                 py_liblocalmod=`grep '^LOCALMODLIBS=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 492                                 py_libbasemod=`grep '^BASEMODLIBS=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 493                                 PYTHON_LIBS="-L$py_libdir/config $py_libs $py_libc $py_libm -lpython$py_ver $py_liblocalmod $py_libbasemod"
 494                                 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/[ \\t]*/ /g'`
 495                                 AC_MSG_RESULT($py_libdir)
 496                         else
 497                                 binding_python="no"
 498                                 binding_python_reason="$py_libdir/config/Makefile or $py_prefix/include/python${py_ver}/Python.h missing"
 499                         fi
 500
 501                 else
 502                         PYTHON_CFLAGS="`${PYTHONCONFIG} --cflags`"
 503                         PYTHON_LIBS="`${PYTHONCONFIG} --ldflags`"
 504                 fi
 505         else
 506                 binding_python="no"
 507                 binding_python_reason="python executable missing"
 508         fi
 509 fi
 510 if test "x${binding_python}" = xyes ; then
 511         AC_DEFINE(USE_BINDING_PYTHON, 1, [Build with binding python])
 512 fi
 513 AC_SUBST(PYTHON_CFLAGS)
 514 AC_SUBST(PYTHON_LIBS)
 515 AM_CONDITIONAL(BINDING_PYTHON, test "x${binding_python}" = "xyes")
 516
 517 # dbus
 518 AC_ARG_ENABLE(binding-dbus,   [  --disable-binding-dbus               don't create binding dbus], binding_dbus=$enableval;binding_dbus_reason="configure parameter")
 519 if test "x${binding_dbus}" = "xyes" ; then
 520         PKG_CHECK_MODULES(DBUS, [dbus-glib-1], ,binding_dbus=no)
 521 fi
 522 if test "x${binding_dbus}" = "xyes" ; then
 523         AC_DEFINE(USE_BINDING_DBUS, 1, [Build with binding dbus])
 524 fi
 525 AC_SUBST(DBUS_CFLAGS)
 526 AC_SUBST(DBUS_LIBS)
 527 AM_CONDITIONAL(BINDING_DBUS, test "x${binding_dbus}" = "xyes")
 528 AC_ARG_WITH(dbus-service-dir, [ --with-dbus-service-dir   specify where the dbus service dir resides], DBUS_SERVICE_DIR=$withval, DBUS_SERVICE_DIR="$datarootdir/dbus-1/services")
 529 AC_SUBST(DBUS_SERVICE_DIR)
 530
 531 # svg
 532 AC_ARG_ENABLE(svg, [  --disable-svg        disable Scalable Vector Graphics], enable_svg=$enableval, enable_svg=yes)
 533 AC_ARG_ENABLE(svg2png, [  --disable-svg2png        disable conversion of svgs to pngs], enable_svg2png=$enableval, enable_svg2png=yes)
 534 AC_ARG_ENABLE(svg2png-scaling, [  --enable-svg2png-scaling   enable conversion of svgs to pngs with specified sizes], SVG2PNG_SCALES=$enableval, SVG2PNG_SCALES="8 16 32 48 96")
 535 AC_ARG_ENABLE(svg2png-scaling-flag, [  --enable-svg2png-scaling-flag   enable conversion of flag svgs to pngs with specified sizes], SVG2PNG_SCALES_FLAG=$enableval, SVG2PNG_SCALES_FLAG="8 16 32 48 96")
 536 AC_ARG_ENABLE(svg2png-scaling-nav, [  --enable-svg2png-scaling-nav   enable conversion of nav svgs to pngs with specified sizes], SVG2PNG_SCALES_NAV=$enableval, SVG2PNG_SCALES_NAV="8 16 32 48 96")
 537 AC_ARG_WITH(svg2png-use-convert, [  --with-svg2png-use-convert   use imagemagick's convert for png creation], SVG2PNG_CONVERTER="convert")
 538 AC_ARG_WITH(svg2png-use-rsvg-convert, [  --with-svg2png-use-rsvg-convert   use librsvg's rsvg-convert for png creation], SVG2PNG_CONVERTER="rsvg-convert")
 539 AC_ARG_WITH(svg2png-use-inkscape, [  --with-svg2png-use-inkscape   use inkscapes internal convert routines for png creation], SVG2PNG_CONVERTER="inkscape")
 540 AC_ARG_WITH(svg2png-use-ksvgtopng4, [  --with-svg2png-use-ksvgtopng4   use kde4's ksvgtopng4 for png creation], SVG2PNG_CONVERTER="ksvgtopng4")
 541 AC_ARG_WITH(svg2png-use-ksvgtopng, [  --with-svg2png-use-ksvgtopng   use kde3's convert for png creation], SVG2PNG_CONVERTER="ksvgtopng")
 542 if test "x${enable_svg2png}" = "xyes" ; then
 543     if test "x${SVG2PNG_CONVERTER}" = "x"; then
 544         SVG2PNG_CONVERTER="rsvg-convert ksvgtopng ksvgtopng4 inkscape convert"
 545     fi
 546     AC_PATH_PROGS([SVG2PNG], ${SVG2PNG_CONVERTER}, [none])
 547     if test "x${SVG2PNG}" = "xnone"; then
 548         enable_svg2png="no"
 549     fi
 550 fi
 551 AC_SUBST(SVG2PNG)
 552 AC_SUBST(SVG2PNG_SCALES)
 553 AC_SUBST(SVG2PNG_SCALES_FLAG)
 554 AC_SUBST(SVG2PNG_SCALES_NAV)
 555 AM_CONDITIONAL(USE_SVG2PNG_SCALES, test "x${SVG2PNG_SCALES}" != "xyes" -a "x${SVG2PNG_SCALES}" != "x")
 556 AM_CONDITIONAL(USE_SVG2PNG_SCALES_FLAG, test "x${SVG2PNG_SCALES_FLAG}" != "xyes" -a "x${SVG2PNG_SCALES_FLAG}" != "x")
 557 AM_CONDITIONAL(USE_SVG2PNG_SCALES_NAV, test "x${SVG2PNG_SCALES_NAV}" != "xyes" -a "x${SVG2PNG_SCALES_NAV}" != "x")
 558 AM_CONDITIONAL(USE_SVG2PNG, test "x${enable_svg2png}" = "xyes")
 559 AM_CONDITIONAL(USE_SVG, test "x${enable_svg}" = "xyes")
 560
 561 # XSLTS
 562 AC_ARG_WITH(xslts, [  --with-xslts   enable processing of navit.xml with given xslt scripts], XSLTS=$withval, XSLTS="")
 563 AC_SUBST(XSLTS)
 564 AC_ARG_WITH(saxon, [ --with-saxon   specify the saxon xslt processor], SAXON=$withval, SAXON="saxon")
 565 AC_SUBST(SAXON)
 566
 567 # Android Permissions
 568 AC_ARG_WITH(android-permissions, [  --with-android-permissions   Set additional android permissions], ANDROID_PERMISSIONS=$withval, ANDROID_PERMISSIONS="")
 569 AC_SUBST(ANDROID_PERMISSIONS)
 570
 571 # NLS
 572
 573 AC_ARG_ENABLE(nls,
 574   [  --disable-nls        disable Native Language Support ( gettext/libintl )],
 575    enable_nls=$enableval, enable_nls=yes)
 576
 577
 578 INTLIBS=""
 579 MOFILES=""
 580 POFILES=""
 581 POIFILES=""
 582 LINGUAS=""
 583
 584 if test "x$enable_nls" = "xyes"; then
 585
 586   AC_CHECK_FUNC(gettext, [HAVEGETTEXT="yes"],[INTLIBS="-lintl" HAVEGETTEXT="yes"])
 587   AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
 588   AC_CHECK_PROG(MSGMERGE, msgmerge, msgmerge)
 589   AC_CHECK_PROG(MSGFMT, msgfmt, msgfmt)
 590
 591   if test "$XGETTEXT" != ""; then
 592     if $XGETTEXT --help 2>&1 | grep illegal >/dev/null ; then
 593         echo "xgettext isn't GNU version"
 594         XGETTEXT=""
 595     fi
 596   fi
 597
 598   if test "$XGETTEXT" != "" ; then
 599      PO=""
 600      if test "$LINGUAS" = ""; then
 601            ling=` (cd $srcdir/po; /bin/ls *.po.in) `
 602            for l in $ling; do
 603                 lcode=`basename $l .po.in`
 604                 LINGUAS="$LINGUAS$lcode "
 605            done
 606     fi
 607     AC_DEFINE(ENABLE_NLS, [1], [NLS Please])
 608     echo "xgettext and gettext() exist; will build i18n support for $LINGUAS"
 609   else
 610    LINGUAS=""
 611    PO=""
 612    echo "xgettext doesn't exist; will not build i18n support"
 613    enable_nls=no
 614  fi
 615  for lang in $LINGUAS; do
 616     MOFILES="$MOFILES $lang.mo"
 617  done
 618  for lang in $LINGUAS; do
 619     POFILES="$POFILES $lang.po"
 620  done
 621  for lang in $LINGUAS; do
 622     POIFILES="$POIFILES $lang.po.in"
 623  done
 624
 625 AC_SUBST(INTLIBS)
 626 AC_SUBST(MOFILES)
 627 AC_SUBST(POFILES)
 628 AC_SUBST(POIFILES)
 629 AM_GNU_GETTEXT_VERSION
 630 AM_GNU_GETTEXT(no-libtool, need-ngettext, \$(top_builddir)/intl/)
 631 AC_SUBST(LIBINTL)
 632 AC_SUBST(LTLIBINTL)
 633 if test x"$LIBINTL" != "x" ;then
 634         CFLAGS="$CFLAGS -I\$(top_builddir)/intl/"
 635 fi
 636
 637 fi
 638 AM_CONDITIONAL(ENABLE_NLS, [test "x$enable_nls" = "xyes"])
 639 AC_CHECK_HEADER(
 640         byteswap.h,
 641         AC_DEFINE(
 642                 [HAVE_BYTESWAP_H],
 643                 [1],
 644                 [Define to 1 if you have byteswap.h],
 645                 )
 646                 ,
 647 )
 648
 649 PACKAGE=navit
 650 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
 651 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
 652 AC_SUBST(PACKAGE)
 653 AC_SUBST(VERSION)
 654
 655 AC_CHECK_HEADER(wordexp.h,wordexp_h=yes,wordexp_h=no;NAVIT_CFLAGS="$NAVIT_CFLAGS -I\$(top_srcdir)/navit/support/wordexp";WORDEXP_LIBS="-L\$(top_builddir)/navit/support/wordexp -lsupport_wordexp")
 656 AM_CONDITIONAL(SUPPORT_WORDEXP, [test "x$wordexp_h" = "xno"])
 657
 658 support_libc=no
 659 AC_ARG_ENABLE(support_libc, [  --enable-support-libc enable builtin mini libc ], support_libc=$enableval)
 660 AM_CONDITIONAL(SUPPORT_LIBC, [test "x$support_libc" = "xyes"])
 661 if test "x$support_libc" = "xyes"; then
 662         CFLAGS="$CFLAGS -I\$(top_srcdir)/navit/support/libc"
 663         LIBC_LIBS="-L\$(top_builddir)/navit/support/libc -lsupport_libc"
 664 fi
 665
 666 ## graphics
 667 # android
 668 AC_ARG_ENABLE(graphics-android, [  --disable-graphics-android            disable graphics type android], graphics_android=$enableval;graphics_android_reason="configure parameter")
 669 AM_CONDITIONAL(GRAPHICS_ANDROID, test "x${graphics_android}" = "xyes")
 670 # gd
 671 AC_ARG_ENABLE(graphics-gd, [  --enable-graphics-gd                enable graphics type gd], graphics_gd=$enableval;graphics_gd_reason="configure parameter")
 672 if test "x${graphics_gd}" = "xyes" ; then
 673         if test -z "$GDLIB_CONFIG"; then
 674             AC_PATH_PROG([GDLIB_CONFIG], [gdlib-config], [])
 675         fi
 676         AC_MSG_CHECKING([for gdlib with $GDLIB_CONFIG])
 677         if test ! -x "$GDLIB_CONFIG"; then
 678             if test "x${GDLIB_CONFIG}" = "x" ; then
 679                  graphics_gd_reason="$GDLIB_CONFIG not executable"
 680             else
 681                  graphics_gd_reason="gdlib-config missing"
 682             fi
 683             graphics_gd=no
 684             AC_MSG_RESULT([no])
 685         else
 686             GD_CFLAGS="-I`$GDLIB_CONFIG --includedir`"
 687             GD_LIBS="-L`$GDLIB_CONFIG --libdir` -lgd `$GDLIB_CONFIG --libs`"
 688             AC_SUBST(GD_CFLAGS)
 689             AC_SUBST(GD_LIBS)
 690             AC_MSG_RESULT([yes])
 691         fi
 692 fi
 693 AM_CONDITIONAL(GRAPHICS_GD, test "x${graphics_gd}" = "xyes")
 694 # gtk_drawing_area
 695 AC_ARG_ENABLE(graphics-gtk-drawing-area, [  --disable-graphics-gtk-drawing-area disable graphics type gtk_drawing_area], graphics_gtk_drawing_area=$enableval;graphics_gtk_drawing_area_reason="configure parameter")
 696 AM_CONDITIONAL(GRAPHICS_GTK_DRAWING_AREA, [test "x${graphics_gtk_drawing_area}" = "xyes"])
 697 # win32
 698 AC_ARG_ENABLE(graphics-win32, [  --disable-graphics-win32            disable graphics type win32], graphics_win32=$enableval;graphics_win32_reason="configure parameter")
 699 AM_CONDITIONAL(GRAPHICS_WIN32, test "x${graphics_win32}" = "xyes")
 700 # qt_qpainter
 701 AC_ARG_ENABLE(graphics-qt-qpainter, [  --disable-graphics-qt-qpainter      disable graphics type qt-qpainter], graphics_qt_qpainter=$enableval;graphics_qt_qpainter_reason="configure parameter")
 702 if test "x${graphics_qt_qpainter}" = "xyes" -a "x${QT_GUI_CFLAGS}" = "x" -a "x${QT_GUI_LIBS}" = "x"; then
 703         PKG_CHECK_MODULES(QT_GUI, [QtGui QtCore], ,graphics_qt_qpainter=no,graphics_qt_qpainter_reason="Packages QtGui and/or QtCore missing")
 704         if test "x${graphics_qt_qpainter}" = "xno"; then
 705                 PKG_CHECK_MODULES(QT_GUI, [qt-mt],graphics_qt_qpainter=yes,graphics_qt_qpainter_reason="Package qt-mt present")
 706         fi
 707 fi
 708 if test "x${graphics_qt_qpainter}" = "xyes" ; then
 709         AC_DEFINE(USE_GRAPICS_QT_QPAINTER, 1, [Build with graphics qt_qpainter])
 710         MOC=`$PKG_CONFIG QtGui --variable=moc_location`
 711         if test "x${MOC}" = "x"; then
 712                 AC_CHECK_PROG(MOC, moc, moc)
 713         fi
 714         AC_SUBST(MOC)
 715 fi
 716 AC_SUBST(QT_GUI_CFLAGS)
 717 AC_SUBST(QT_GUI_LIBS)
 718 AM_CONDITIONAL(GRAPHICS_QT_QPAINTER, test "x${graphics_qt_qpainter}" = "xyes")
 719
 720 ## gui
 721 # gtk
 722 AC_ARG_ENABLE(gui-gtk, [  --disable-gui-gtk                   disable gui type gtk ], gui_gtk=$enableval)
 723 AM_CONDITIONAL(GUI_GTK, [test "x${gui_gtk}" = "xyes"])
 724 # internal
 725 AC_ARG_ENABLE(gui-internal, [  --disable-gui-internal              disable gui type internal], gui_internal=$enableval;gui_internal_reason="configure parameter")
 726 AM_CONDITIONAL(GUI_INTERNAL, test "x${gui_internal}" = "xyes")
 727 # win32
 728 AC_ARG_ENABLE(gui-win32, [  --disable-gui-win32                 disable gui type win32], gui_win32=$enableval;gui_win32_reason="configure parameter")
 729 AM_CONDITIONAL(GUI_WIN32, test "x${gui_win32}" = "xyes")
 730
 731 ## speech
 732 # android
 733 AC_ARG_ENABLE(speech-android, [  --disable-speech-android            disable speech type android], speech_android=$enableval;speech_android_reason="configure parameter")
 734 AM_CONDITIONAL(SPEECH_ANDROID, test "x${speech_android}" = "xyes")
 735 # cmdline
 736 AC_ARG_ENABLE(speech-cmdline, [  --disable-speech-cmdline            disable speech type cmdline], speech_cmdline=$enableval;speech_cmdline_reason="configure parameter")
 737 AM_CONDITIONAL(SPEECH_CMDLINE, test "x${speech_cmdline}" = "xyes")
 738 # espeak
 739 AC_ARG_ENABLE(speech-espeak, [  --disable-speech-espeak            disable speech type espeak], speech_espeak=$enableval;speech_espeak_reason="configure parameter")
 740 AM_CONDITIONAL(SPEECH_ESPEAK, test "x${speech_espeak}" = "xyes")
 741 # speech-dispatcher
 742 AC_ARG_ENABLE(speech-speech-dispatcher, [  --disable-speech-speech-dispatcher  disable speech type speech-dispatcher], speech_speech_dispatcher=$enableval;speech_speech_dispatcher_reason="configure parameter")
 743 if test "x$speech_speech_dispatcher" = "xyes"; then
 744         AC_CHECK_HEADER(libspeechd.h, AC_DEFINE([HAVE_LIBSPEECHD],[],Define to 1 if you have the <libspeechd.h> header file.) SPEECHD_LIBS="-lspeechd",  speech_speech_dispatcher=no; speech_speech_dispatcher_reason="libspeechd.h missing")
 745 fi
 746 AC_SUBST(SPEECHD_CFLAGS)
 747 AC_SUBST(SPEECHD_LIBS)
 748 AM_CONDITIONAL(SPEECH_SPEECH_DISPATCHER, test "x${speech_speech_dispatcher}" = "xyes")
 749 AM_CONDITIONAL(SUPPORT_ESPEAK, test "x${support_espeak}" = "xyes")
 750
 751 ## vehicle
 752 # android
 753 AC_ARG_ENABLE(vehicle-android, [  --disable-vehicle-android             disable vehicle type android], vehicle_android=$enableval;vehicle_android_reason="configure parameter")
 754 AM_CONDITIONAL(VEHICLE_ANDROID, test "x${vehicle_android}" = "xyes")
 755 # demo
 756 AC_ARG_ENABLE(vehicle-demo, [  --disable-vehicle-demo              disable vehicle type demo], vehicle_demo=$enableval;vehicle_demo_reason="configure parameter")
 757 AM_CONDITIONAL(VEHICLE_DEMO, test "x${vehicle_demo}" = "xyes")
 758 # file
 759 AC_ARG_ENABLE(vehicle-file, [  --disable-vehicle-file              disable vehicle type file], vehicle_file=$enableval;vehicle_file_reason="configure parameter")
 760 AM_CONDITIONAL(VEHICLE_FILE, test "x${vehicle_file}" = "xyes")
 761 # gpsd
 762 AC_ARG_ENABLE(vehicle-gpsd, [  --disable-vehicle-gpsd              disable vehicle type gpsd], vehicle_gpsd=$enableval;vehicle_gpsd_reason="configure parameter")
 763 if test "x${vehicle_gpsd}" = xyes
 764 then
 765         AC_CHECK_HEADER(gps.h, AC_DEFINE([HAVE_LIBGPS],[],Define to 1 if you have the <gps.h> header file.) GPSD_LIBS="-lgps", vehicle_gpsd=no; vehicle_gpsd_reason="no gps.h" )
 766 fi
 767 AC_SUBST(GPSD_CFLAGS)
 768 AC_SUBST(GPSD_LIBS)
 769 AM_CONDITIONAL(VEHICLE_GPSD, [test "x${vehicle_gpsd}" = "xyes"])
 770 # gypsy
 771 AC_ARG_ENABLE(vehicle-gypsy,[  --disable-vehicle-gypsy             disable vehicle type gypsy], vehicle_gypsy=$enableval;vehicle_gypsy_reason="configure parameter")
 772 if test "x${vehicle_gypsy}" = "xyes"
 773 then
 774         PKG_CHECK_MODULES(GYPSY, gypsy, ,vehicle_gypsy=no;vehicle_gypsy_reason="package gypsy missing")
 775 fi
 776 AC_SUBST(GYPSY_CFLAGS)
 777 AC_SUBST(GYPSY_LIBS)
 778 AM_CONDITIONAL(VEHICLE_GYPSY, test "x${vehicle_gypsy}" = "xyes")
 779 # null
 780 AC_ARG_ENABLE(vehicle-null, [  --enable-vehicle-null             enable vehicle type null], vehicle_null=$enableval;vehicle_null_reason="configure parameter")
 781 AM_CONDITIONAL(VEHICLE_NULL, test "x${vehicle_null}" = "xyes")
 782 # wince
 783 AC_ARG_ENABLE(vehicle-wince, [  --disable-vehicle-wince             disable vehicle type wince], vehicle_wince=$enableval;vehicle_wince_reason="configure parameter")
 784 AM_CONDITIONAL(VEHICLE_WINCE, test "x${vehicle_wince}" = "xyes")
 785 # iphone
 786 AC_ARG_ENABLE(vehicle-iphone, [  --disable-vehicle-iphone              disable vehicle type iphone], vehicle_iphone=$enableval;vehicle_iphone_reason="configure parameter")
 787 AM_CONDITIONAL(VEHICLE_IPHONE, test "x${vehicle_iphone}" = "xyes")
 788 if test "x${vehicle_iphone}" = "xyes"
 789 then
 790         IPHONE_LIBS=-Wl,-framework,CoreLocation
 791 fi
 792 AC_SUBST(IPHONE_CFLAGS)
 793 AC_SUBST(IPHONE_LIBS)
 794 NAVIT_CFLAGS="$NAVIT_CFLAGS $GLIB_CFLAGS $GMODULE_CFLAGS"
 795 NAVIT_LIBS="$NAVIT_LIBS $GLIB_LIBS $GMODULE_LIBS $LIBINTL"
 796 AC_SUBST(NAVIT_CFLAGS)
 797 AC_SUBST(NAVIT_LIBS)
 798 AC_SUBST(WORDEXP_LIBS)
 799 AC_SUBST(LIBC_LIBS)
 800 AC_SUBST(WINDRES)
 801
 802 AC_CONFIG_FILES([
 803 Makefile
 804 navit/Makefile
 805 navit/binding/Makefile
 806 navit/binding/python/Makefile
 807 navit/binding/dbus/Makefile
 808 navit/map/Makefile
 809 navit/map/mg/Makefile
 810 navit/map/textfile/Makefile
 811 navit/map/shapefile/Makefile
 812 navit/map/filter/Makefile
 813 navit/map/binfile/Makefile
 814 navit/map/garmin/Makefile
 815 navit/map/poi_geodownload/Makefile
 816 navit/map/poi_geodownload/libmdb/Makefile
 817 navit/map/poi_geodownload/libmdb/include/Makefile
 818 navit/maptool/Makefile
 819 navit/fib-1.1/Makefile
 820 navit/font/Makefile
 821 navit/font/freetype/Makefile
 822 navit/fonts/Makefile
 823 navit/graphics/Makefile
 824 navit/graphics/android/Makefile
 825 navit/graphics/gd/Makefile
 826 navit/graphics/gtk_drawing_area/Makefile
 827 navit/graphics/opengl/Makefile
 828 navit/graphics/null/Makefile
 829 navit/graphics/sdl/Makefile
 830 navit/graphics/qt_qpainter/Makefile
 831 navit/graphics/win32/Makefile
 832 navit/gui/Makefile
 833 navit/gui/gtk/Makefile
 834 navit/gui/internal/Makefile
 835 navit/gui/win32/Makefile
 836 navit/osd/Makefile
 837 navit/osd/core/Makefile
 838 navit/speech/Makefile
 839 navit/speech/android/Makefile
 840 navit/speech/cmdline/Makefile
 841 navit/speech/espeak/Makefile
 842 navit/speech/speech_dispatcher/Makefile
 843 navit/support/Makefile
 844 navit/support/espeak/Makefile
 845 navit/support/ezxml/Makefile
 846 navit/support/glib/Makefile
 847 navit/support/libc/Makefile
 848 navit/support/libpng/Makefile
 849 navit/support/win32/Makefile
 850 navit/support/wordexp/Makefile
 851 navit/support/zlib/Makefile
 852 navit/vehicle/Makefile
 853 navit/vehicle/android/Makefile
 854 navit/vehicle/file/Makefile
 855 navit/vehicle/gpsd/Makefile
 856 navit/vehicle/gypsy/Makefile
 857 navit/vehicle/null/Makefile
 858 navit/vehicle/demo/Makefile
 859 navit/vehicle/wince/Makefile
 860 navit/vehicle/iphone/Makefile
 861 navit/xpm/Makefile
 862 navit/maps/Makefile
 863 intl/Makefile
 864 po/Makefile
 865 ])
 866 #src/data/garmin_img/Makefile
 867
 868 AC_OUTPUT
 869
 870
 871 echo ""
 872 echo ""
 873 echo "Summary of your installation :"
 874 # FIXME : maybe elaborate missing dependencies
 875 if test x"$sdl" != xyes
 876         then
 877         sdl_failures="(libsdl maybe?) "
 878 fi
 879 if test x"$xmu" != xyes
 880         then
 881         sdl_failures=$sdl_failures"libxmu "
 882 fi
 883 if test x"$glut" != xyes
 884        then
 885         sdl_failures=$sdl_failures"glut "
 886 fi
 887 if test x"$glc" != xyes
 888         then
 889         sdl_failures=$sdl_failures"quesoglc "
 890 fi
 891 if test -z "$sdl_failures"
 892         then
 893         echo "OpenGL gui  : ENABLED, with $CEGUI_LIBS"
 894         else
 895                  echo "OpenGL gui  : DISABLED : you are missing $sdl_failures"
 896 fi
 897 if test x"$enable_hildon" = xyes
 898         then
 899         echo "Maemo/Hildon: ENABLED"
 900         else
 901         echo "Maemo/Hildon: DISABLED"
 902 fi
 903 if test x"${USE_GARMIN}" = xyes
 904         then
 905         if test "x$use_libgarmin" = "xyes"
 906                 then
 907                 echo "Garmin IMG  : ENABLED"
 908                 else
 909                 echo "Garmin IMG  : DISABLED (you don't have libgarmin)"
 910         fi
 911         else
 912                 echo "Garmin IMG  : DISABLED (you requested it)"
 913 fi
 914
 915 if test x"$LIBINTL" = "x" ;then
 916         nls_libs="system gettext support"
 917 else
 918         nls_libs="$LIBINTL"
 919 fi
 920 echo "Plugins:             $plugins ($plugins_reason)"
 921 echo "Postgresql:          $postgresql ($postgresql_reason)"
 922 echo "Samplemap:           $samplemap ($samplemap_reason)"
 923 echo "NLS Support:         $enable_nls ($nls_libs)"
 924 echo "Font renderers:"
 925 echo "  freetype:          $font_freetype ($font_freetype_reason)"
 926 echo "Graphics types:"
 927 echo "  android:  $graphics_android ($graphics_android_reason)"
 928 echo "  gtk_drawing_area:  $graphics_gtk_drawing_area ($graphics_gtk_drawing_area_reason)"
 929 echo "  qt_qpainter:       $graphics_qt_qpainter ($graphics_qt_qpainter_reason)"
 930 echo "  win32:             $graphics_win32 ($graphics_win32_reason)"
 931 echo "  OpenGL:            $graphics_opengl ($graphics_opengl_reason)"
 932 echo "  gd:                $graphics_gd ($graphics_gd_reason)"
 933 echo "  sdl:               $graphics_sdl ($graphics_sdl_reason)"
 934
 935 echo "GUI types:"
 936 echo "  gtk:               $gui_gtk ($gui_gtk_reason)"
 937 echo "  internal:          $gui_internal ($gui_internal_reason)"
 938 echo "  win32:             $gui_win32 ($gui_win32_reason)"
 939
 940 echo "Bindings:"
 941 echo "  dbus:              $binding_dbus ($binding_dbus_reason)"
 942 echo "  python:            $binding_python ($binding_python_reason)"
 943
 944 echo "Speech types:"
 945 echo "  android:           $speech_android ($speech_android_reason)"
 946 echo "  cmdline:           $speech_cmdline ($speech_cmdline_reason)"
 947 echo "  espeak:            $speech_espeak ($speech_espeak_reason)"
 948 echo "  speech_dispatcher: $speech_speech_dispatcher ($speech_speech_dispatcher_reason)"
 949
 950 echo "Vehicle types:"
 951 echo "  android:           $vehicle_android ($vehicle_android_reason)"
 952 echo "  demo:              $vehicle_demo ($vehicle_demo_reason)"
 953 echo "  file:              $vehicle_file ($vehicle_file_reason)"
 954 echo "  gpsd:              $vehicle_gpsd ($vehicle_gpsd_reason)"
 955 echo "  gypsy:             $vehicle_gypsy ($vehicle_gypsy_reason)"
 956 echo "  null:              $vehicle_null ($vehicle_null_reason)"
 957 echo "  wince:             $vehicle_wince ($vehicle_wince_reason)"
 958 echo "  iphone:            $vehicle_iphone ($vehicle_iphone_reason)"
 959
 960 if  test "x${gtk2_pkgconfig}" != "xyes" -a "x${gui_win32}" != "xyes" -a "x${gui_internal}" != "xyes"
 961 then
 962         echo ""
 963         echo ""
 964         echo "*** WARNING! you have no gui that can be built! ***"
 965         echo "Please install the dependency for at least gtk or sdl gui"
 966         echo "For more details, see the wiki at http://wiki.navit-project.org/"
 967         echo ""
 968         exit 1
 969 fi
 970