git.maemo.org Git - navit-package/blob - configure.in

   1 AC_INIT(navit, 0.1.0)
   2 AM_INIT_AUTOMAKE
   3 AM_CONFIG_HEADER(config.h)
   4 AM_MAINTAINER_MODE
   5
   6
   7 m4_ifndef([AC_USE_SYSTEM_EXTENSIONS],
   8         [AC_DEFUN([AC_USE_SYSTEM_EXTENSIONS], [AC_GNU_SOURCE])])
   9
  10 AC_USE_SYSTEM_EXTENSIONS
  11
  12 AC_PROG_CC
  13 if eval "test x$GCC = xyes"; then
  14         CFLAGS="$CFLAGS -Wall -Wcast-align -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wpointer-arith -Wreturn-type -D_GNU_SOURCE"
  15 fi
  16 AC_PROG_CXX
  17 if eval "test x$GXX = xyes"; then
  18         CXXFLAGS="$CXXFLAGS -Wall -Wcast-align -Wmissing-prototypes -Wstrict-prototypes -Wpointer-arith -Wreturn-type -D_GNU_SOURCE"
  19 fi
  20
  21 PKG_CHECK_EXISTS
  22
  23 AC_ARG_ENABLE(plugins,  [  --disable-plugins          disable plugins],
  24                         [
  25                                 AC_DISABLE_SHARED
  26                                 AC_ENABLE_STATIC
  27                                 plugins=$enableval
  28                         ],
  29                         [
  30                                 AC_ENABLE_SHARED
  31                                 AC_DISABLE_STATIC
  32                                 AC_DEFINE(
  33                                         [USE_PLUGINS],
  34                                         [],
  35                                         Define to 1 if you have plugins.
  36                                 )
  37                                 plugins=yes
  38                         ]
  39 )
  40 AC_PROG_LIBTOOL
  41
  42 AC_ARG_ENABLE(avoid-unaligned, [  --enable-avoid-unaligned          avoid unaligned accesses], AVOID_UNALIGNED=$enableval, AVOID_UNALIGNED=no)
  43 test x"${AVOID_UNALIGNED}" = xyes && AC_DEFINE(AVOID_UNALIGNED,[],Define to avoid unaligned access)
  44
  45 AC_ARG_ENABLE(avoid-float, [  --enable-avoid-float              avoid floating point calculations], AVOID_FLOAT=$enableval, AVOID_FLOAT=no)
  46 test x"${AVOID_FLOAT}" = xyes && AC_DEFINE(AVOID_FLOAT,[],Define to avoid floating point)
  47
  48 AC_ARG_ENABLE(hildon, [  --enable-hildon              build with maemo/hildon support], enable_hildon=$enableval, enable_hildon=no)
  49 if test "x${enable_hildon}" = "xyes" ; then
  50         PKG_CHECK_MODULES(enable_hildon, hildon-libs >= 0.12.24, , [
  51                 AC_MSG_RESULT(no)
  52                 enable_hildon=no
  53         ])
  54         if test x"${enable_hildon}" = xyes ; then
  55                 AC_DEFINE(USE_HILDON, 1, [Build with maemo/hildon support])
  56                 AC_SUBST(HILDON_CFLAGS)
  57                 AC_SUBST(HILDON_LIBS)
  58         fi
  59 fi
  60 AM_CONDITIONAL(USE_HILDON, test "${enable_hildon}" = "xyes")
  61
  62 AC_ARG_ENABLE(libgps, [  --disable-libgps             don't use libgps], USE_LIBGPS=$enableval, USE_LIBGPS=yes)
  63 AC_ARG_ENABLE(garmin, [  --disable-garmin             disable garmin support], USE_GARMIN=$enableval, USE_GARMIN=yes)
  64
  65 AC_ARG_ENABLE(samplemap, [  --disable-samplemap             don't build the samplemap], samplemap=$enableval, samplemap=yes)
  66 AM_CONDITIONAL(BUILD_SAMPLEMAP, [test "x$samplemap" = "xyes"])
  67
  68 AC_ARG_ENABLE(fastmath, [  --disable-fastmath             don't build with fastmath], fastmath=$enableval, fastmath=yes)
  69 AM_CONDITIONAL(FASTMATH, [test "x$fastmath" = "xyes"])
  70
  71 if test x"$fastmath" = xyes; then
  72         if eval "test x$GCC = xyes"; then
  73                 CFLAGS="$CFLAGS -ffast-math"
  74         fi
  75 fi
  76
  77 X_CFLAGS="-I$x_includes"
  78 X_LIBS="-L$ac_x_libraries"
  79
  80 PKG_CHECK_MODULES(NAVIT, [glib-2.0 gmodule-2.0 gthread-2.0], [], AC_MSG_ERROR([glib-2.0 or gmodule-2.0 not found. Usually you need to install a package named glib2-devel or libglib2.0-dev]))
  81 AC_SUBST(NAVIT_CFLAGS)
  82 AC_SUBST(NAVIT_LIBS)
  83
  84 AC_CHECK_HEADER(
  85         zlib.h,
  86         AC_DEFINE(
  87                 [HAVE_ZLIB],
  88                 [],
  89                 Define to 1 if you have the <zlib.h> header file.
  90                 )
  91                 ZLIB_LIBS="-lz",
  92         AC_MSG_WARN([*** no zlib.h\ -- reduced functionality of osm2navit])
  93         )
  94 AC_SUBST(ZLIB_LIBS)
  95
  96 AC_ARG_ENABLE(gui-gtk, [  --disable-gui-gtk             don't create gui gtk ], MODULE_GUI_GTK=$enableval, MODULE_GUI_GTK=yes)
  97 if test "x$MODULE_GUI_GTK" = "xyes"; then
  98         PKG_CHECK_MODULES(GTK2, [gtk+-2.0], [gtk2_pkgconfig=yes], [gtk2_pkgconfig=no])
  99         if test "x$gtk2_pkgconfig" = "xyes"; then
 100                 AC_DEFINE(HAVE_GTK2, 1, [Define to 1 if you have gtk2])
 101         fi
 102 fi
 103
 104 GTK2_CFLAGS="$GTK2_CFLAGS -DG_DISABLE_DEPRECATED -DGDK_DISABLE_DEPRECATED -DGDK_PIXBUF_DISABLE_DEPRECATED -DGTK_DISABLE_DEPRECATED"
 105
 106 AC_SUBST(GTK2_CFLAGS)
 107 AC_SUBST(GTK2_LIBS)
 108 AM_CONDITIONAL(GUI_GTK, [test "x$gtk2_pkgconfig" = "xyes"])
 109 AM_CONDITIONAL(GRAPHICS_GTK_DRAWING_AREA, [test "x$gtk2_pkgconfig" = "xyes"])
 110 AM_CONDITIONAL(PLUGINS, [test "x$plugins" = "xyes"])
 111
 112 AC_ARG_ENABLE(graphics-qt-qpainter, [  --disable-graphics-qt-qpainter             don't create graphics qt-qpainter], enable_graphics_qt_qpainter=$enableval, enable_graphics_qt_qpainter=yes)
 113 if test "x${enable_graphics_qt_qpainter}" = "xyes" ; then
 114         PKG_CHECK_MODULES(QT_GUI, [QtGui QtCore], ,enable_graphics_qt_qpainter=no);
 115 fi
 116 if test "x${enable_graphics_qt_qpainter}" = "xyes" ; then
 117         AC_DEFINE(USE_GRAPICS_QT_QPAINTER, 1, [Build with graphics qt_qpainter])
 118         AC_SUBST(QT_GUI_CFLAGS)
 119         AC_SUBST(QT_GUI_LIBS)
 120 fi
 121 AM_CONDITIONAL(USE_GRAPHICS_QT_QPAINTER, test "x${enable_graphics_qt_qpainter}" = "xyes")
 122
 123 PKG_CHECK_MODULES(FREETYPE2, [freetype2], [freetype2_pkgconfig=yes], [freetype2_pkgconfig=no])
 124 if test "x$freetype2_pkgconfig" = "xyes"; then
 125    AC_DEFINE(HAVE_FREETYPE2, 1, [Define to 1 if you have freetype2])
 126 fi
 127 AC_SUBST(FREETYPE2_CFLAGS)
 128 AC_SUBST(FREETYPE2_LIBS)
 129
 130 PKG_CHECK_MODULES(FONTCONFIG, [fontconfig], [fontconfig_pkgconfig=yes], [fontconfig_pkgconfig=no])
 131 if test "x$fontconfig_pkgconfig" = "xyes"; then
 132    AC_DEFINE(HAVE_FONTCONFIG, 1, [Define to 1 if you have fontconfig])
 133 fi
 134 AC_SUBST(FONTCONFIG_CFLAGS)
 135 AC_SUBST(FONTCONFIG_LIBS)
 136
 137 PKG_CHECK_MODULES(IMLIB2, [imlib2], [imlib2_pkgconfig=yes], [imlib2_pkgconfig=no])
 138 if test "x$imlib2_pkgconfig" = "xyes"; then
 139    AC_DEFINE(HAVE_IMLIB2, 1, [Define to 1 if you have imlib2])
 140 fi
 141 AC_SUBST(IMLIB2_CFLAGS)
 142 AC_SUBST(IMLIB2_LIBS)
 143
 144
 145 AC_ARG_ENABLE(speech-speechd, [  --disable-speech-speechd             don't create speech speechd ], MODULE_SPEECH_SPEECHD=$enableval, MODULE_SPEECH_SPEECHD=yes)
 146 if test "x$MODULE_SPEECH_SPEECHD" = "xyes"; then
 147         AC_CHECK_HEADER(libspeechd.h, AC_DEFINE([HAVE_LIBSPEECHD],[],Define to 1 if you have the <libspeechd.h> header file.) SPEECHD_LIBS="-lspeechd" speechd=yes,  AC_MSG_WARN([*** no libspeechd.h -- Speech output disabled]))
 148 fi
 149 AC_SUBST(SPEECHD_CFLAGS)
 150 AC_SUBST(SPEECHD_LIBS)
 151 AM_CONDITIONAL(SPEECH_SPEECH_DISPATCHER, [test "x$speechd" = "xyes"])
 152
 153
 154 AC_ARG_ENABLE(gui-sdl, [  --disable-gui-sdl             don't create gui sdl ], MODULE_GUI_SDL=$enableval, MODULE_GUI_SDL=yes)
 155 if test "x$MODULE_GUI_SDL" = "xyes"; then
 156         AC_CHECK_HEADER(
 157                 SDL/SDL.h,
 158                 AC_DEFINE(
 159                         [HAVE_LIBSDL],
 160                         [],
 161                         Define to 1 if you have the <SDL/SDL.h> header file.
 162                         )
 163                         SDL_LIBS="-lSDL"
 164                         sdl=yes,
 165                 AC_MSG_WARN([*** no SDL/SDL.h -- SDL support disabled])
 166         )
 167 fi
 168 AC_SUBST(SDL_CFLAGS)
 169 AC_SUBST(SDL_LIBS)
 170
 171 PKG_CHECK_MODULES(
 172         [CEGUI],
 173         [CEGUI-OPENGL >= 0.5.0],
 174         [
 175                 AC_DEFINE(
 176                         [HAVE_CEGUI],
 177                         [],
 178                         [Define to 1 if you have the @<:@CEGUI/CEGUI.h@:>@ header file.])
 179                 cegui=yes
 180         ],
 181         [AC_MSG_WARN([*** CEGUI not found -- SDL support disabled])]
 182 )
 183
 184 AC_CHECK_HEADER(
 185         X11/Xmu/Xmu.h,
 186         AC_DEFINE(
 187                 [HAVE_XMU],
 188                 [],
 189                 Define to 1 if you have the <X11/Xmu/Xmu.h> header file.
 190                 )
 191                 xmu=yes,
 192         AC_MSG_WARN([*** no X11/Xmu/Xmu.h -- opengl and SDL support disabled])
 193 )
 194
 195 AC_CHECK_HEADER(
 196         GL/gl.h,
 197         AC_DEFINE(
 198                 [HAVE_OPENGL],
 199                 [],
 200                 Define to 1 if you have the <GL/gl.h> header file.
 201                 )
 202                 OPENGL_LIBS="$X_LIBS -lGL -lGLU"
 203                 opengl=yes,
 204         AC_MSG_WARN([*** no GL/gl.h -- opengl and SDL support disabled])
 205 )
 206
 207 AC_CHECK_HEADER(
 208         GL/glut.h,
 209         AC_DEFINE(
 210                 [HAVE_GLUT],
 211                 [],
 212                 Define to 1 if you have the <GL/glut.h> header file.
 213                 )
 214                 glut=yes,
 215         AC_MSG_WARN([*** no GL/glut.h -- opengl and SDL support disabled])
 216 )
 217
 218 AC_SUBST(OPENGL_CFLAGS)
 219 AC_SUBST(OPENGL_LIBS)
 220
 221 AC_CHECK_HEADER(
 222         GL/glc.h,
 223         AC_DEFINE(
 224                 [HAVE_GLC],
 225                 [],
 226                 Define to 1 if you have the <GL/glc.h> header file.
 227                 )
 228                 GLC_LIBS="-lGLC"
 229                 glc=yes,
 230         AC_MSG_WARN([*** no GL/glc.h -- opengl and SDL support disabled])
 231 )
 232 AC_SUBST(GLC_CFLAGS)
 233 AC_SUBST(GLC_LIBS)
 234
 235 if test x"$cegui" = xyes
 236                 then
 237          # Save the LIBS into a temp var since AC_CHECK_LIB adds the lib into LIBS
 238          # and we want just to check and use CEGUI_LIBS
 239          libstemp="$LIBS"
 240          # For CEGUI, we have to check the presence of some libraries.
 241          # The following are mandatory (used by navit)
 242          # If the user installed NavIt without, issue a warning and disable CEGUI
 243          AC_CHECK_LIB(CEGUIBase, main,
 244                   [],
 245                   [
 246                  echo "Error! Something is wrong with CEGUIBase. Do you have at least cegui-0.5?"
 247                  ])
 248          AC_CHECK_LIB(CEGUIOpenGLRenderer, main,
 249                   [],
 250                   [
 251                  echo "Error! Something is wrong with CEGUIOpenGLRenderer. Do you have at least cegui-0.5? "
 252                  ], $OPENGL_LIBS )
 253          AC_CHECK_LIB(CEGUIFalagardWRBase, main,
 254                   [],
 255                   [
 256                  echo "Error! Something is wrong with CEGUIFalagardWRBase. Do you have at least cegui-0.5?"
 257                  ], $OPENGL_LIBS)
 258          CEGUI_LIBS="-lCEGUIBase -lCEGUIOpenGLRenderer -lCEGUIFalagardWRBase"
 259
 260          # The following are optional, but we need to link against them if cegui was built with them
 261          AC_CHECK_LIB(CEGUIXercesParser, main,
 262                   [CEGUI_LIBS="$CEGUI_LIBS -lCEGUIXercesParser"],
 263                   [echo "CEGUIXercesParser not found/not working, disabled."],
 264                   $OPENGL_LIBS
 265          )
 266
 267          AC_CHECK_LIB(CEGUIExpatParser, main,
 268                   [CEGUI_LIBS="$CEGUI_LIBS -lCEGUIExpatParser"],
 269                   [echo "CEGUIExpatParser not found/not working, disabled."],
 270                   $OPENGL_LIBS
 271          )
 272
 273          AC_CHECK_LIB(CEGUILibxmlParser, main,
 274                   [CEGUI_LIBS="$CEGUI_LIBS -lCEGUILibxmlParser"],
 275                   [echo "CEGUILibxmlParser not found/not working, disabled."],
 276                   $OPENGL_LIBS
 277          )
 278
 279          AC_CHECK_LIB(CEGUITinyXMLParser, main,
 280                   [CEGUI_LIBS="$CEGUI_LIBS -lCEGUITinyXMLParser"],
 281                   [echo "CEGUITinyXMLParser not found/not working, disabled."],
 282                   $OPENGL_LIBS
 283          )
 284
 285          AC_CHECK_LIB(CEGUIDevILImageCodec, main,
 286                   [
 287                         CEGUI_LIBS="$CEGUI_LIBS -lCEGUIDevILImageCodec"
 288                          AC_DEFINE([HAVE_LIBCEGUIDEVILIMAGECODEC],[1],Define to 1 to use DevIL codec)
 289                   ],
 290                   [echo "CEGUIDevILImageCodec not found/not working, disabled."],
 291                   $OPENGL_LIBS
 292          )
 293
 294          AC_CHECK_LIB(CEGUITGAImageCodec, createImageCodec,
 295                   [
 296                           CEGUI_LIBS="$CEGUI_LIBS -lCEGUITGAImageCodec"
 297                           AC_DEFINE(HAVE_LIBCEGUITGAIMAGECODEC,[1],Define to 1 to use the TGA codec)
 298                   ],
 299                   [echo "GUITGAImageCodec not found/not working, disabled."],
 300                   $OPENGL_LIBS
 301          )
 302
 303          libssilly="$OPENGL_LIBS -lpng"
 304          AC_CHECK_LIB(CEGUISILLYImageCodec, createImageCodec,
 305                   [
 306                          CEGUI_LIBS="$CEGUI_LIBS -lCEGUISILLYImageCodec"
 307                          AC_DEFINE([HAVE_LIBCEGUISILLYIMAGECODEC],[1],Define to 1 to use SILLY codec)
 308                   ],
 309                   [echo "CEGUISILLYImageCodec not found/not working, disabled."],
 310                   $libssilly
 311          )
 312          # Restore the libs
 313          LIBS="$libstemp"
 314          echo "CEGUI_LIBS : $CEGUI_LIBS"
 315          fi
 316
 317 AC_SUBST(CEGUI_CFLAGS)
 318 AC_SUBST(CEGUI_LIBS)
 319
 320 AM_CONDITIONAL(GUI_SDL, [test "x$sdl" = "xyes" -a "x$cegui" = "xyes" -a "x$opengl" = "xyes" -a "x$glc" = "xyes" -a "x$xmu" = "xyes" ])
 321 AM_CONDITIONAL(GRAPHICS_OPENGL, [test "x$opengl" = "xyes" -a "x$glc" = "xyes" ])
 322
 323
 324 if test x"${USE_LIBGPS}" = xyes
 325 then
 326         AC_CHECK_HEADER(gps.h, AC_DEFINE([HAVE_LIBGPS],[],Define to 1 if you have the <gps.h> header file.) GPSD_LIBS="-lgps" gpsd=yes,  AC_MSG_WARN([*** no gps.h -- gpsd support disabled]))
 327 fi
 328 AC_SUBST(GPSD_CFLAGS)
 329 AC_SUBST(GPSD_LIBS)
 330 AM_CONDITIONAL(VEHICLE_GPSD, [test "x$gpsd" = "xyes"])
 331
 332 if test x"${USE_GARMIN}" = xyes
 333 then
 334         # check for libgarmin
 335         PKG_CHECK_MODULES(LIBGARMIN, libgarmin, use_libgarmin=yes, use_libgarmin=no)
 336         AC_SUBST(LIBGARMIN_CFLAGS)
 337         AC_SUBST(LIBGARMIN_LIBS)
 338 fi
 339         AM_CONDITIONAL(HAVELIBGARMIN, [test "x$use_libgarmin" = "xyes"])
 340
 341
 342 # binding python
 343 AC_ARG_ENABLE(binding-python, [  --disable-binding-python             don't create binding python], enable_binding_python=$enableval, enable_binding_python=yes)
 344 if test "x${enable_binding_python}" = "xyes" ; then
 345         if test "x${cross_compiling}" = "xyes" ; then
 346                 AC_MSG_WARN([*** cross compiling, support for python disabled])
 347                 enable_binding_python="no"
 348         fi
 349 fi
 350 if test "x${enable_binding_python}" = "xyes"; then
 351         AC_PATH_PROG(_PATH_PYTHON,[python])
 352         dnl Libraries and flags for embedded Python.
 353         dnl FIXME: I wish there was a less icky way to get this.
 354         if test "x${_PATH_PYTHON}" != "x" ; then
 355                 AC_MSG_CHECKING(for Python linkage)
 356                 py_prefix=`$_PATH_PYTHON -c 'import sys; print sys.prefix'`
 357                 py_ver=`$_PATH_PYTHON -c 'import sys; print sys.version[[:3]]'`
 358                 py_libdir="${py_prefix}/lib/python${py_ver}"
 359                 PYTHON_CFLAGS="-I${py_prefix}/include/python${py_ver}"
 360                 if test -f $py_libdir/config/Makefile -a -f $py_prefix/include/python${py_ver}/Python.h; then
 361                         py_libs=`grep '^LIBS=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 362                         py_libc=`grep '^LIBC=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 363                         py_libm=`grep '^LIBM=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 364                         py_liblocalmod=`grep '^LOCALMODLIBS=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 365                         py_libbasemod=`grep '^BASEMODLIBS=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 366                         PYTHON_LIBS="-L$py_libdir/config $py_libs $py_libc $py_libm -lpython$py_ver $py_liblocalmod $py_libbasemod"
 367                         PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/[ \\t]*/ /g'`
 368                         AC_MSG_RESULT($py_libdir)
 369                 else
 370                         AC_MSG_WARN([$py_libdir/config/Makefile or $py_prefix/include/python${py_ver}/Python.h missing, support for python disabled])
 371                         enable_binding_python="no"
 372                 fi
 373         else
 374                 AC_MSG_WARN([no python found, support for python disabled])
 375                 enable_binding_python="no"
 376         fi
 377 fi
 378 if test "x${enable_binding_python}" = xyes ; then
 379         AC_DEFINE(USE_BINDING_PYTHON, 1, [Build with binding python])
 380         AC_SUBST(PYTHON_CFLAGS)
 381         AC_SUBST(PYTHON_LIBS)
 382 fi
 383 AM_CONDITIONAL(USE_BINDING_PYTHON, test "x${enable_binding_python}" = "xyes")
 384
 385 # binding dbus
 386 AC_ARG_ENABLE(binding-dbus,   [  --disable-binding-dbus               don't create binding dbus], enable_binding_dbus=$enableval, enable_binding_dbus=yes)
 387 if test "x${enable_binding_dbus}" = "xyes" ; then
 388         PKG_CHECK_MODULES(DBUS, [dbus-glib-1], ,enable_binding_dbus=no);
 389 fi
 390 if test "x${enable_binding_dbus}" = "xyes" ; then
 391         AC_DEFINE(USE_BINDING_DBUS, 1, [Build with binding dbus])
 392         AC_SUBST(DBUS_CFLAGS)
 393         AC_SUBST(DBUS_LIBS)
 394 fi
 395 AM_CONDITIONAL(USE_BINDING_DBUS, test "x${enable_binding_dbus}" = "xyes")
 396
 397 # NLS
 398
 399 AC_ARG_ENABLE(nls,
 400   [  --disable-nls        disable Native Language Support ( gettext/libintl )],
 401    enable_nls=$enableval, enable_nls=yes)
 402
 403
 404 INTLIBS=""
 405 MOFILES=""
 406 POFILES=""
 407 LINGUAS=""
 408
 409 if test x$enable_nls = xyes; then
 410
 411   AC_CHECK_FUNC(gettext, [HAVEGETTEXT="yes"],
 412              AC_CHECK_LIB(intl, gettext, [INTLIBS="-lintl" HAVEGETTEXT="yes"],
 413                          INTLIBS="" ))
 414
 415   AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
 416   AC_CHECK_PROG(MSGMERGE, msgmerge, msgmerge)
 417   AC_CHECK_PROG(MSGFMT, msgfmt, msgfmt)
 418
 419   if test "$XGETTEXT" != ""; then
 420     if $XGETTEXT --help 2>&1 | grep illegal >/dev/null ; then
 421         echo "xgettext isn't GNU version"
 422         XGETTEXT=""
 423     fi
 424   fi
 425
 426   if test "$XGETTEXT" != "" -a "$HAVEGETTEXT" != ""; then
 427      PO=""
 428      if test "$LINGUAS" = ""; then
 429            ling=` (cd $srcdir/po; /bin/ls *.po) `
 430            for l in $ling; do
 431                 lcode=`basename $l .po`
 432                 LINGUAS="$LINGUAS$lcode "
 433            done
 434     fi
 435     AC_DEFINE(ENABLE_NLS, [1], [NLS Please])
 436     echo "xgettext and gettext() exist; will build i18n support for $LINGUAS"
 437   else
 438    LINGUAS=""
 439    PO=""
 440    echo "xgettext and libintl.a don't both exist; will not build i18n support"
 441  fi
 442  for lang in $LINGUAS; do
 443     MOFILES="$MOFILES $lang.mo"
 444  done
 445  for lang in $LINGUAS; do
 446     POFILES="$POFILES $lang.po"
 447  done
 448 fi
 449
 450
 451 AC_SUBST(INTLIBS)
 452 AC_SUBST(MOFILES)
 453 AC_SUBST(POFILES)
 454 AM_GNU_GETTEXT_VERSION
 455 AM_GNU_GETTEXT
 456
 457 LIBS="$LIBS -lm -rdynamic"
 458
 459 PACKAGE=navit
 460 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
 461 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
 462 AC_SUBST(PACKAGE)
 463 AC_SUBST(VERSION)
 464
 465 AC_CONFIG_FILES([
 466 Makefile
 467 navit/Makefile
 468 navit/binding/Makefile
 469 navit/binding/python/Makefile
 470 navit/binding/dbus/Makefile
 471 navit/data/Makefile
 472 navit/data/mg/Makefile
 473 navit/data/textfile/Makefile
 474 navit/data/binfile/Makefile
 475 navit/data/garmin/Makefile
 476 navit/data/poi_geodownload/Makefile
 477 navit/data/poi_geodownload/libmdb/Makefile
 478 navit/data/poi_geodownload/libmdb/include/Makefile
 479 navit/fib-1.1/Makefile
 480 navit/graphics/Makefile
 481 navit/graphics/gtk_drawing_area/Makefile
 482 navit/graphics/opengl/Makefile
 483 navit/graphics/null/Makefile
 484 navit/graphics/qt_qpainter/Makefile
 485 navit/gui/Makefile
 486 navit/gui/gtk/Makefile
 487 navit/gui/internal/Makefile
 488 navit/gui/sdl/Makefile
 489 navit/gui/sdl/datafiles/Makefile
 490 navit/osd/Makefile
 491 navit/osd/core/Makefile
 492 navit/speech/Makefile
 493 navit/speech/cmdline/Makefile
 494 navit/speech/speech_dispatcher/Makefile
 495 navit/vehicle/Makefile
 496 navit/vehicle/file/Makefile
 497 navit/vehicle/gpsd/Makefile
 498 navit/vehicle/demo/Makefile
 499 navit/xpm/Makefile
 500 navit/maps/Makefile
 501 intl/Makefile
 502 po/Makefile
 503 ])
 504 #src/data/garmin_img/Makefile
 505
 506 AC_OUTPUT
 507
 508
 509 echo ""
 510 echo ""
 511 echo "Summary of your installation :"
 512 if test x"$gtk2_pkgconfig" = xyes
 513         then
 514         echo "GTK gui     : ENABLED"
 515         else
 516         echo "GTK gui     : DISABLED : you are missing a dependency. To fix this install a package named gtk2-devel or libgtk2.0-dev"
 517 fi
 518 # FIXME : maybe elaborate missing dependencies
 519 if test x"$sdl" != xyes
 520         then
 521         sdl_failures="(libsdl maybe?) "
 522 fi
 523 if test x"$xmu" != xyes
 524         then
 525         sdl_failures=$sdl_failures"libxmu "
 526 fi
 527 if test x"$glut" != xyes
 528        then
 529         sdl_failures=$sdl_failures"glut "
 530 fi
 531 if test x"$glc" != xyes
 532         then
 533         sdl_failures=$sdl_failures"quesoglc "
 534 fi
 535 if test x"$cegui" != xyes
 536         then
 537         sdl_failures=$sdl_failures"cegui-devel >= 0.5 "
 538 fi
 539 if test -z "$sdl_failures"
 540         then
 541         echo "OpenGL gui  : ENABLED, with $CEGUI_LIBS"
 542         else
 543                  echo "OpenGL gui  : DISABLED : you are missing $sdl_failures"
 544 fi
 545 if test x"$enable_hildon" = xyes
 546         then
 547         echo "Maemo/Hildon: ENABLED"
 548         else
 549         echo "Maemo/Hildon: DISABLED"
 550 fi
 551
 552 if test x"$gpsd" = xyes
 553         then
 554         echo "GPSD support: ENABLED"
 555         else
 556         echo "GPSD support: DISABLED"
 557 fi
 558 if test x"$speechd" = xyes
 559         then
 560         echo "SPEECHD     : ENABLED"
 561         else
 562         echo "SPEECHD     : DISABLED"
 563 fi
 564 if test x"${USE_GARMIN}" = xyes
 565         then
 566         if test "x$use_libgarmin" = "xyes"
 567                 then
 568                 echo "Garmin IMG  : ENABLED"
 569                 else
 570                 echo "Garmin IMG  : DISABLED (you don't have libgarmin)"
 571         fi
 572         else
 573                 echo "Garmin IMG  : DISABLED (you requested it)"
 574 fi
 575 if test "x$samplemap" = "xyes"
 576         then
 577         echo "Samplemap   : ENABLED"
 578         else
 579         echo "Samplemap   : DISABLED"
 580 fi
 581 if  [ test x"$gtk2_pkgconfig" != xyes ] && [ test x"$sdl" != xyes ]
 582         then
 583         echo ""
 584         echo ""
 585         echo "*** WARNING! you have no gui that can be built! ***"
 586         echo "Please install the dependency for at least gtk or sdl gui"
 587         echo "For more details, see the wiki at http://wiki.navit-project.org/"
 588         echo ""
 589         exit 1
 590 fi