git.maemo.org Git - navit-package/blob - configure.in

   1 AC_INIT(navit, 0.1.0)
   2 AM_INIT_AUTOMAKE
   3 AM_CONFIG_HEADER(config.h)
   4 AM_MAINTAINER_MODE
   5
   6
   7 plugins=yes; plugins_reason=default
   8 postgresql=yes; postgresql_reason=default
   9 samplemap=yes; samplemap_reason=default
  10 binding_dbus=yes; binding_dbus_reason=default
  11 binding_python=yes; binding_python_reason=default
  12 gui_gtk=no; gui_gtk_reason=default
  13 gui_win32=no; gui_win32_reason=default
  14 gui_internal=yes; gui_internal_reason=default
  15 graphics_gd=no; graphics_gd_reason=default
  16 graphics_gtk_drawing_area=no; graphics_gtk_drawing_area_reason=default
  17 graphics_qt_qpainter=yes; graphics_qt_qpainter_reason=default
  18 graphics_opengl=yes; graphics_opengl_reason=default
  19 graphics_win32=no; graphics_win32_reason=default
  20 speech_cmdline=yes; speech_cmdline_reason=default
  21 speech_speech_dispatcher=yes; speech_speech_dispatcher_reason=default
  22 vehicle_demo=yes; vehicle_demo_reason=default
  23 vehicle_file=yes; vehicle_file_reason=default
  24 vehicle_gpsd=yes; vehicle_gpsd_reason=default
  25 vehicle_gypsy=yes; vehicle_gypsy_reason=default
  26 vehicle_wince=no; vehicle_wince_reason=default
  27
  28 m4_ifndef([AC_USE_SYSTEM_EXTENSIONS],
  29         [AC_DEFUN([AC_USE_SYSTEM_EXTENSIONS], [AC_GNU_SOURCE])])
  30
  31 AC_USE_SYSTEM_EXTENSIONS
  32
  33 AC_PROG_CC
  34 if eval "test x$GCC = xyes"; then
  35         CFLAGS="$CFLAGS -Wall -Wcast-align -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wpointer-arith -Wreturn-type -D_GNU_SOURCE"
  36 fi
  37 AM_PROG_CC_C_O
  38
  39 AC_PROG_CXX
  40 if eval "test x$GXX = xyes"; then
  41         CXXFLAGS="$CXXFLAGS -Wall -Wcast-align -Wmissing-prototypes -Wstrict-prototypes -Wpointer-arith -Wreturn-type -D_GNU_SOURCE"
  42 fi
  43
  44 PKG_CHECK_EXISTS
  45 if test "x${cross_compiling}" = "xyes"; then
  46         samplemap="no";samplemap_reason="not supported for cross compiling"
  47         binding_python="no";binding_python_reason="not supported for cross compiling"
  48         postgresql="no";postgresql_reason="not supported for cross compiling"
  49         AC_MSG_CHECKING([for a C compiler for build tools])
  50         AC_CHECK_PROGS(CC_FOR_BUILD, gcc cc)
  51 else
  52         CC_FOR_BUILD=$CC
  53 fi
  54 CCLD_FOR_BUILD="$CC_FOR_BUILD"
  55 AC_SUBST(cross_compiling)
  56 AC_SUBST(CC_FOR_BUILD)
  57 AC_SUBST(CCLD_FOR_BUILD)
  58
  59 AC_ARG_ENABLE(avoid-unaligned, [  --enable-avoid-unaligned          avoid unaligned accesses], AVOID_UNALIGNED=$enableval, AVOID_UNALIGNED=no)
  60 test x"${AVOID_UNALIGNED}" = xyes && AC_DEFINE(AVOID_UNALIGNED,[],Define to avoid unaligned access)
  61
  62 AC_ARG_ENABLE(avoid-float, [  --enable-avoid-float              avoid floating point calculations], AVOID_FLOAT=$enableval, AVOID_FLOAT=no)
  63 test x"${AVOID_FLOAT}" = xyes && AC_DEFINE(AVOID_FLOAT,[],Define to avoid floating point)
  64
  65 AC_ARG_ENABLE(hildon, [  --enable-hildon              build with maemo/hildon support], enable_hildon=$enableval, enable_hildon=no)
  66 if test "x${enable_hildon}" = "xyes" ; then
  67         PKG_CHECK_MODULES(enable_hildon, hildon-libs >= 0.12.24, , [
  68                 AC_MSG_RESULT(no)
  69                 enable_hildon=no
  70         ])
  71         if test x"${enable_hildon}" = xyes ; then
  72                 AC_DEFINE(USE_HILDON, 1, [Build with maemo/hildon support])
  73                 AC_SUBST(HILDON_CFLAGS)
  74                 AC_SUBST(HILDON_LIBS)
  75         fi
  76 fi
  77 AM_CONDITIONAL(USE_HILDON, test "${enable_hildon}" = "xyes")
  78
  79 AC_ARG_ENABLE(garmin, [  --disable-garmin             disable garmin support], USE_GARMIN=$enableval, USE_GARMIN=yes)
  80
  81 # samplemap
  82 AC_PATH_PROG(_PATH_BZCAT,[bzcat])
  83 if test "x${_PATH_BZCAT}" = "x" ; then
  84         samplemap=no; samplemap_reason="bzcat missing"
  85 fi
  86 AC_ARG_ENABLE(samplemap, [  --disable-samplemap             don't build the samplemap], samplemap=$enableval;samplemap_reason="configure parameter")
  87 AM_CONDITIONAL(BUILD_SAMPLEMAP, [test "x$samplemap" = "xyes"])
  88
  89 AC_ARG_ENABLE(fastmath, [  --disable-fastmath             don't build with fastmath], fastmath=$enableval, fastmath=yes)
  90 AM_CONDITIONAL(FASTMATH, [test "x$fastmath" = "xyes"])
  91
  92 if test x"$fastmath" = xyes; then
  93         if eval "test x$GCC = xyes"; then
  94                 CFLAGS="$CFLAGS -ffast-math"
  95         fi
  96 fi
  97
  98 X_CFLAGS="-I$x_includes"
  99 AS_IF([test -n "$ac_x_libraries"], [X_LIBS="-L$ac_x_libraries"])
 100
 101 PKG_CHECK_MODULES(GLIB, [glib-2.0 gthread-2.0], [glib=yes],[glib=no])
 102 if test "x${glib}" = "xyes"; then
 103         AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if you have (external) glib library])
 104 else
 105         GLIB_CFLAGS="-I\$(top_srcdir)/navit/support -I\$(top_srcdir)/navit/support/glib -I\$(top_srcdir)/navit/support/ezxml"
 106         GLIB_LIBS="-L\$(top_builddir)/navit/support/glib -lsupport_glib -L\$(top_builddir)/navit/support/ezxml -lsupport_ezxml"
 107 fi
 108
 109 # gmodule
 110 PKG_CHECK_MODULES(GMODULE, [gmodule-2.0], [gmodule=yes], [gmodule=no])
 111 if test "x${gmodule}" = "xyes"; then
 112         AC_DEFINE(HAVE_GMODULE, 1, [Define to 1 if you have gmodule])
 113 else
 114         AC_CHECK_LIB(dl, dlopen,
 115                 [plugins_reason="default, via dlopen";GMODULE_LIBS="-ldl";AC_DEFINE(HAVE_DLOPEN, 1, [Define to 1 if you have dlopen])],
 116                 [plugins="no"; plugins_reason="package gmodule and dlopen missing"]
 117         )
 118 fi
 119 # plugins
 120 AC_ARG_ENABLE(plugins,  [  --disable-plugins          disable plugins], [ plugins=$enableval;plugin_reason="configure parameter" ])
 121 if test "x${plugins}" = "xyes"; then
 122         AC_ENABLE_SHARED
 123         AC_DISABLE_STATIC
 124         AC_DEFINE(
 125                 [USE_PLUGINS],
 126                 [],
 127                 Define to 1 if you have plugins.
 128         )
 129 else
 130         AC_DISABLE_SHARED
 131         AC_ENABLE_STATIC
 132 fi
 133 AM_CONDITIONAL(PLUGINS, [test "x$plugins" = "xyes"])
 134 AC_PROG_LIBTOOL
 135
 136 AM_CONDITIONAL(EVENT_GLIB, [test "x$glib" = "xyes"])
 137 AM_CONDITIONAL(SUPPORT_GLIB, [test "x$glib" = "xno"])
 138 AM_CONDITIONAL(SUPPORT_EZXML, [test "x$glib" = "xno"])
 139 AM_CONDITIONAL(DATA_POI_GEODOWNLOAD, [test "x$glib" = "xyes"])
 140
 141 AC_CHECK_HEADER(
 142         zlib.h,
 143         AC_DEFINE(
 144                 [HAVE_ZLIB],
 145                 [],
 146                 Define to 1 if you have the <zlib.h> header file.
 147         )
 148         ZLIB_LIBS="-lz"
 149         zlib=yes,
 150         ZLIB_CFLAGS="-I\$(top_srcdir)/navit/support/zlib"
 151         ZLIB_LIBS="-L\$(top_builddir)/navit/support/zlib -lsupport_zlib"
 152         zlib=no
 153 )
 154 AM_CONDITIONAL(SUPPORT_ZLIB, [test "x$zlib" = "xno"])
 155 AC_SUBST(ZLIB_CFLAGS)
 156 AC_SUBST(ZLIB_LIBS)
 157
 158 # gtk
 159 PKG_CHECK_MODULES(GTK2, [gtk+-2.0], [gtk2_pkgconfig=yes], [gtk2_pkgconfig=no])
 160 if test "x$gtk2_pkgconfig" = "xyes"; then
 161         AC_DEFINE(HAVE_GTK2, 1, [Define to 1 if you have gtk2])
 162         graphics_gtk_drawing_area=yes; graphics_gtk_drawing_area_reason="gtk+-2.0 present"
 163         gui_gtk=yes; gui_gtk_reason="gtk+-2.0 present"
 164 fi
 165
 166 # fsync
 167 AC_MSG_CHECKING(for fsync)
 168 AC_TRY_LINK([#include <unistd.h>], [fsync(0);],AC_MSG_RESULT(yes);AC_DEFINE(HAVE_FSYNC, 1, [Define to 1 if you have the `fsync' function.]),AC_MSG_RESULT(no))
 169
 170 # system
 171 AC_MSG_CHECKING(for system)
 172 AC_TRY_LINK([#include <stdlib.h>], [system("/bin/true");],AC_MSG_RESULT(yes);AC_DEFINE(HAVE_SYSTEM, 1, [Define to 1 if you have the `system' function.]),speech_cmdline=no; speech_cmdline_reason="not supported without system()"; AC_MSG_RESULT(no))
 173
 174 AC_ARG_ENABLE(directfb, [  --enable-directfb             enable directfb gui and graphics], MODULE_DIRECTFB=$enableval, MODULE_DIRECTFB=no)
 175
 176 if test "x$MODULE_DIRECTFB" = "xyes"; then
 177         PKG_CHECK_MODULES(DIRECTFB, [directfb], [directfb_pkgconfig=yes], [directfb_pkgconfig=no])
 178         if test "x$directfb_pkgconfig" = "xyes"; then
 179                 AC_DEFINE(HAVE_DIRECTFB, 1, [Define to 1 if you have directfb])
 180         fi
 181 fi
 182
 183 DIRECTFB_CFLAGS="$DIRECTFB_CFLAGS"
 184
 185 #DIRECTFB_CFLAGS="-D_REENTRANT -I/data/oe/tmp/staging/arm-angstrom-linux-gnueabi/usr/include/directfb/"
 186 #DIRECTFB_LIBS="-L/data/oe/tmp/staging/arm-angstrom-linux-gnueabi/usr/lib/ -ldirectfb -lfusion -ldirect -lpthread"
 187
 188 AC_SUBST(DIRECTFB_CFLAGS)
 189 AC_SUBST(DIRECTFB_LIBS)
 190 AM_CONDITIONAL(DIRECTFB, [test "x$directfb_pkgconfig" = "xyes"])
 191
 192
 193 AC_ARG_ENABLE(graphics-sdl, [  --disable-graphics-sdl             don't create graphics sdl], enable_graphics_sdl=$enableval, enable_graphics_sdl=yes)
 194 if test "x${enable_graphics_sdl}" = "xyes" ; then
 195         if test -z "$SDL_CONFIG"; then
 196             AC_PATH_PROG([SDL_CONFIG], [sdl-config], [])
 197         fi
 198 fi
 199 if test "x${enable_graphics_sdl}" = "xyes" ; then
 200         AC_MSG_CHECKING([for SDL libraries with $SDL_CONFIG])
 201         if test ! -x "$SDL_CONFIG"; then
 202             enable_graphics_sdl = "no"
 203             AC_MSG_RESULT([no])
 204         else
 205             SDL_CFLAGS="`$SDL_CONFIG --cflags`"
 206             SDL_LIBS="`$SDL_CONFIG --libs`"
 207             AC_SUBST(SDL_CFLAGS)
 208             AC_SUBST(SDL_LIBS)
 209             AC_MSG_RESULT([yes])
 210         fi
 211 fi
 212 if test "x${enable_graphics_sdl}" = "xyes" ; then
 213         save_CPPFLAGS=$CPPFLAGS
 214         CPPFLAGS="$($SDL_CONFIG --cflags) $CPPFLAGS"
 215         AC_CHECK_HEADER(SDL_image.h,SDL_IMAGE_LIBS=-lSDL_image,enable_graphics_sdl=no)
 216         AC_SUBST(SDL_IMAGE_LIBS)
 217         CPPFLAGS=$save_CPPFLAGS
 218 fi
 219 if test "x${enable_graphics_sdl}" = "xyes" ; then
 220         AC_DEFINE(USE_GRAPICS_SDL, 1, [Build with graphics sdl])
 221 fi
 222 AM_CONDITIONAL(USE_GRAPHICS_SDL, test "x${enable_graphics_sdl}" = "xyes")
 223
 224 AC_ARG_ENABLE(postgresql, [  --disable-postgresql             don't add postgresql support to osm2navit], postgresql=$enableval;postgresql_reason="configure parameter")
 225 if test "x${postgresql}" = "xyes" ; then
 226         if test -z "$PG_CONFIG"; then
 227             AC_PATH_PROG([PG_CONFIG], [pg_config], [])
 228         fi
 229         AC_MSG_CHECKING([for PostgreSQL libraries with $PG_CONFIG])
 230         if test ! -x "$PG_CONFIG"; then
 231             if test "x${PG_CONFIG}" = "x" ; then
 232                  postgresql_reason="$PG_CONFIG not executable"
 233             else
 234                  postgresql_reason="pg_config missing"
 235             fi
 236             postgresql=no
 237             AC_MSG_RESULT([no])
 238         else
 239             POSTGRESQL_CFLAGS="-I`$PG_CONFIG --includedir`"
 240             POSTGRESQL_LIBS="-L`$PG_CONFIG --libdir` -lpq"
 241             AC_DEFINE(HAVE_POSTGRESQL, 1, [Postgresql libraries available])
 242             AC_SUBST(POSTGRESQL_CFLAGS)
 243             AC_SUBST(POSTGRESQL_LIBS)
 244             AC_MSG_RESULT([yes])
 245         fi
 246 fi
 247 AM_CONDITIONAL(HAVE_POSTGRESQL, test "x${postgresql}" = "xyes")
 248
 249 PKG_CHECK_MODULES(FREETYPE2, [freetype2], [freetype2_pkgconfig=yes], [freetype2_pkgconfig=no])
 250 if test "x$freetype2_pkgconfig" = "xyes"; then
 251    AC_DEFINE(HAVE_FREETYPE2, 1, [Define to 1 if you have freetype2])
 252 fi
 253 AC_SUBST(FREETYPE2_CFLAGS)
 254 AC_SUBST(FREETYPE2_LIBS)
 255 AM_CONDITIONAL(FONT_FREETYPE, test "x${freetype2_pkgconfig}" = "xyes")
 256
 257 PKG_CHECK_MODULES(FONTCONFIG, [fontconfig], [fontconfig_pkgconfig=yes], [fontconfig_pkgconfig=no])
 258 if test "x$fontconfig_pkgconfig" = "xyes"; then
 259    AC_DEFINE(HAVE_FONTCONFIG, 1, [Define to 1 if you have fontconfig])
 260 fi
 261 AC_SUBST(FONTCONFIG_CFLAGS)
 262 AC_SUBST(FONTCONFIG_LIBS)
 263
 264 PKG_CHECK_MODULES(IMLIB2, [imlib2], [imlib2_pkgconfig=yes], [imlib2_pkgconfig=no])
 265 if test "x$imlib2_pkgconfig" = "xyes"; then
 266    AC_DEFINE(HAVE_IMLIB2, 1, [Define to 1 if you have imlib2])
 267 fi
 268 AC_SUBST(IMLIB2_CFLAGS)
 269 AC_SUBST(IMLIB2_LIBS)
 270
 271
 272
 273 AC_ARG_ENABLE(gui-sdl, [  --disable-gui-sdl             don't create gui sdl ], MODULE_GUI_SDL=$enableval, MODULE_GUI_SDL=yes)
 274 if test "x$MODULE_GUI_SDL" = "xyes"; then
 275         AC_CHECK_HEADER(
 276                 SDL/SDL.h,
 277                 AC_DEFINE(
 278                         [HAVE_LIBSDL],
 279                         [],
 280                         Define to 1 if you have the <SDL/SDL.h> header file.
 281                         )
 282                         SDL_LIBS="-lSDL"
 283                         sdl=yes,
 284                 AC_MSG_WARN([*** no SDL/SDL.h -- SDL support disabled])
 285         )
 286 fi
 287
 288 PKG_CHECK_MODULES(
 289         [CEGUI],
 290         [CEGUI-OPENGL >= 0.5.0],
 291         [
 292                 AC_DEFINE(
 293                         [HAVE_CEGUI],
 294                         [],
 295                         [Define to 1 if you have the @<:@CEGUI/CEGUI.h@:>@ header file.])
 296                 cegui=yes
 297         ],
 298         [AC_MSG_WARN([*** CEGUI not found -- SDL support disabled])]
 299 )
 300
 301 AC_CHECK_HEADER(
 302         X11/Xmu/Xmu.h,
 303         AC_DEFINE(
 304                 [HAVE_XMU],
 305                 [],
 306                 Define to 1 if you have the <X11/Xmu/Xmu.h> header file.
 307                 )
 308                 xmu=yes,
 309         AC_MSG_WARN([*** no X11/Xmu/Xmu.h -- opengl and SDL support disabled])
 310 )
 311
 312 AC_ARG_ENABLE(graphics-opengl, [  --disable-graphics-opengl      disable graphics type OpenGL], graphics_opengl=$enableval;graphics_opengl_reason="configure parameter")
 313 if test "x${graphics_opengl}" = "xyes" ; then
 314
 315 AC_CHECK_HEADER(
 316         GL/gl.h,
 317         AC_DEFINE(
 318                 [HAVE_OPENGL],
 319                 [],
 320                 Define to 1 if you have the <GL/gl.h> header file.
 321                 )
 322                 OPENGL_LIBS="$X_LIBS -lGL -lGLU"
 323                 opengl=yes,
 324         AC_MSG_WARN([*** no GL/gl.h -- opengl and SDL support disabled];graphics_opengl=no;graphics_opengl_reason="Headers missing")
 325 )
 326
 327 AC_CHECK_HEADER(
 328         GL/glut.h,
 329         AC_DEFINE(
 330                 [HAVE_GLUT],
 331                 [],
 332                 Define to 1 if you have the <GL/glut.h> header file.
 333                 )
 334                 glut=yes,
 335         AC_MSG_WARN([*** no GL/glut.h -- opengl and SDL support disabled]);graphics_opengl=no;graphics_opengl_reason="Headers missing"
 336 )
 337
 338 AC_SUBST(OPENGL_CFLAGS)
 339 AC_SUBST(OPENGL_LIBS)
 340
 341 AC_CHECK_HEADER(
 342         GL/glc.h,
 343         AC_DEFINE(
 344                 [HAVE_GLC],
 345                 [],
 346                 Define to 1 if you have the <GL/glc.h> header file.
 347                 )
 348                 GLC_LIBS="-lGLC"
 349                 glc=yes,
 350         AC_MSG_WARN([*** no GL/glc.h -- opengl and SDL support disabled])
 351 )
 352 AC_SUBST(GLC_CFLAGS)
 353 AC_SUBST(GLC_LIBS)
 354 fi
 355
 356 if test x"$cegui" = xyes
 357                 then
 358          # Save the LIBS into a temp var since AC_CHECK_LIB adds the lib into LIBS
 359          # and we want just to check and use CEGUI_LIBS
 360          libstemp="$LIBS"
 361          # For CEGUI, we have to check the presence of some libraries.
 362          # The following are mandatory (used by navit)
 363          # If the user installed NavIt without, issue a warning and disable CEGUI
 364          AC_CHECK_LIB(CEGUIBase, main,
 365                   [],
 366                   [
 367                  echo "Error! Something is wrong with CEGUIBase. Do you have at least cegui-0.5?"
 368                  ])
 369          AC_CHECK_LIB(CEGUIOpenGLRenderer, main,
 370                   [],
 371                   [
 372                  echo "Error! Something is wrong with CEGUIOpenGLRenderer. Do you have at least cegui-0.5? "
 373                  ], $OPENGL_LIBS )
 374          AC_CHECK_LIB(CEGUIFalagardWRBase, main,
 375                   [],
 376                   [
 377                  echo "Error! Something is wrong with CEGUIFalagardWRBase. Do you have at least cegui-0.5?"
 378                  ], $OPENGL_LIBS)
 379          CEGUI_LIBS="-lCEGUIBase -lCEGUIOpenGLRenderer -lCEGUIFalagardWRBase"
 380
 381          # The following are optional, but we need to link against them if cegui was built with them
 382          AC_CHECK_LIB(CEGUIXercesParser, main,
 383                   [CEGUI_LIBS="$CEGUI_LIBS -lCEGUIXercesParser"],
 384                   [echo "CEGUIXercesParser not found/not working, disabled."],
 385                   $OPENGL_LIBS
 386          )
 387
 388          AC_CHECK_LIB(CEGUIExpatParser, main,
 389                   [CEGUI_LIBS="$CEGUI_LIBS -lCEGUIExpatParser"],
 390                   [echo "CEGUIExpatParser not found/not working, disabled."],
 391                   $OPENGL_LIBS
 392          )
 393
 394          AC_CHECK_LIB(CEGUILibxmlParser, main,
 395                   [CEGUI_LIBS="$CEGUI_LIBS -lCEGUILibxmlParser"],
 396                   [echo "CEGUILibxmlParser not found/not working, disabled."],
 397                   $OPENGL_LIBS
 398          )
 399
 400          AC_CHECK_LIB(CEGUITinyXMLParser, main,
 401                   [CEGUI_LIBS="$CEGUI_LIBS -lCEGUITinyXMLParser"],
 402                   [echo "CEGUITinyXMLParser not found/not working, disabled."],
 403                   $OPENGL_LIBS
 404          )
 405
 406          AC_CHECK_LIB(CEGUIDevILImageCodec, main,
 407                   [
 408                         CEGUI_LIBS="$CEGUI_LIBS -lCEGUIDevILImageCodec"
 409                          AC_DEFINE([HAVE_LIBCEGUIDEVILIMAGECODEC],[1],Define to 1 to use DevIL codec)
 410                   ],
 411                   [echo "CEGUIDevILImageCodec not found/not working, disabled."],
 412                   $OPENGL_LIBS
 413          )
 414
 415          AC_CHECK_LIB(CEGUITGAImageCodec, createImageCodec,
 416                   [
 417                           CEGUI_LIBS="$CEGUI_LIBS -lCEGUITGAImageCodec"
 418                           AC_DEFINE(HAVE_LIBCEGUITGAIMAGECODEC,[1],Define to 1 to use the TGA codec)
 419                   ],
 420                   [echo "GUITGAImageCodec not found/not working, disabled."],
 421                   $OPENGL_LIBS
 422          )
 423
 424          libssilly="$OPENGL_LIBS -lpng"
 425          AC_CHECK_LIB(CEGUISILLYImageCodec, createImageCodec,
 426                   [
 427                          CEGUI_LIBS="$CEGUI_LIBS -lCEGUISILLYImageCodec"
 428                          AC_DEFINE([HAVE_LIBCEGUISILLYIMAGECODEC],[1],Define to 1 to use SILLY codec)
 429                   ],
 430                   [echo "CEGUISILLYImageCodec not found/not working, disabled."],
 431                   $libssilly
 432          )
 433          # Restore the libs
 434          LIBS="$libstemp"
 435          echo "CEGUI_LIBS : $CEGUI_LIBS"
 436          fi
 437
 438 AC_SUBST(CEGUI_CFLAGS)
 439 AC_SUBST(CEGUI_LIBS)
 440
 441 AM_CONDITIONAL(GUI_SDL, [test "x$sdl" = "xyes" -a "x$cegui" = "xyes" -a "x$opengl" = "xyes" -a "x$glc" = "xyes" -a "x$xmu" = "xyes" ])
 442 AM_CONDITIONAL(GRAPHICS_OPENGL, [test "x$glut" = "xyes" - "x$opengl" = "xyes" -a "x$glc" = "xyes" ])
 443
 444 AC_ARG_ENABLE(gui-clutter, [  --disable-gui-clutter             don't create gui clutter ], MODULE_GUI_CLUTTER=$enableval, MODULE_GUI_CLUTTER=yes)
 445 if test "x$MODULE_GUI_CLUTTER" = "xyes"; then
 446         PKG_CHECK_MODULES(CLUTTER, [clutter-0.8], [clutter_pkgconfig=yes], [clutter_pkgconfig=no])
 447         if test "x$clutter_pkgconfig" = "xyes"; then
 448                 AC_DEFINE(HAVE_CLUTTER, 1, [Define to 1 if you have clutter])
 449         fi
 450 fi
 451
 452 AC_SUBST(CLUTTER_CFLAGS)
 453 AC_SUBST(CLUTTER_LIBS)
 454 AM_CONDITIONAL(GUI_CLUTTER, [test "x$clutter_pkgconfig" = "xyes" -a "x$glc" = "xyes" ])
 455
 456
 457
 458
 459 if test x"${USE_GARMIN}" = xyes
 460 then
 461         # check for libgarmin
 462         PKG_CHECK_MODULES(LIBGARMIN, libgarmin, use_libgarmin=yes, use_libgarmin=no)
 463         AC_SUBST(LIBGARMIN_CFLAGS)
 464         AC_SUBST(LIBGARMIN_LIBS)
 465 fi
 466         AM_CONDITIONAL(HAVELIBGARMIN, [test "x$use_libgarmin" = "xyes"])
 467
 468 ## binding
 469 # python
 470 AC_ARG_ENABLE(binding-python, [  --disable-binding-python             don't create binding python], binding_python=$enableval;binding_python_reason="configure parameter")
 471 if test "x${binding_python}" = "xyes"; then
 472         AC_PATH_PROG(_PATH_PYTHON,[python])
 473         dnl Libraries and flags for embedded Python.
 474         dnl FIXME: I wish there was a less icky way to get this.
 475         if test "x${_PATH_PYTHON}" != "x" ; then
 476                 AC_MSG_CHECKING(for Python linkage)
 477                 py_prefix=`$_PATH_PYTHON -c 'import sys; print sys.prefix'`
 478                 py_ver=`$_PATH_PYTHON -c 'import sys; print sys.version[[:3]]'`
 479                 py_libdir="${py_prefix}/lib/python${py_ver}"
 480                 PYTHON_CFLAGS="-I${py_prefix}/include/python${py_ver}"
 481                 if test -f $py_libdir/config/Makefile -a -f $py_prefix/include/python${py_ver}/Python.h; then
 482                         py_libs=`grep '^LIBS=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 483                         py_libc=`grep '^LIBC=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 484                         py_libm=`grep '^LIBM=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 485                         py_liblocalmod=`grep '^LOCALMODLIBS=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 486                         py_libbasemod=`grep '^BASEMODLIBS=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 487                         PYTHON_LIBS="-L$py_libdir/config $py_libs $py_libc $py_libm -lpython$py_ver $py_liblocalmod $py_libbasemod"
 488                         PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/[ \\t]*/ /g'`
 489                         AC_MSG_RESULT($py_libdir)
 490                 else
 491                         binding_python="no"
 492                         binding_python_reason="$py_libdir/config/Makefile or $py_prefix/include/python${py_ver}/Python.h missing"
 493                 fi
 494         else
 495                 binding_python="no"
 496                 binding_python_reason="python executable missing"
 497         fi
 498 fi
 499 if test "x${binding_python}" = xyes ; then
 500         AC_DEFINE(USE_BINDING_PYTHON, 1, [Build with binding python])
 501 fi
 502 AC_SUBST(PYTHON_CFLAGS)
 503 AC_SUBST(PYTHON_LIBS)
 504 AM_CONDITIONAL(BINDING_PYTHON, test "x${binding_python}" = "xyes")
 505
 506 # dbus
 507 AC_ARG_ENABLE(binding-dbus,   [  --disable-binding-dbus               don't create binding dbus], binding_dbus=$enableval;binding_dbus_reason="configure parameter")
 508 if test "x${binding_dbus}" = "xyes" ; then
 509         PKG_CHECK_MODULES(DBUS, [dbus-glib-1], ,binding_dbus=no)
 510 fi
 511 if test "x${binding_dbus}" = "xyes" ; then
 512         AC_DEFINE(USE_BINDING_DBUS, 1, [Build with binding dbus])
 513 fi
 514 AC_SUBST(DBUS_CFLAGS)
 515 AC_SUBST(DBUS_LIBS)
 516 AM_CONDITIONAL(BINDING_DBUS, test "x${binding_dbus}" = "xyes")
 517
 518 # svg
 519 AC_ARG_ENABLE(svg, [  --disable-svg        disable Scalable Vector Graphics], enable_svg=$enableval, enable_svg=yes)
 520 AC_ARG_ENABLE(svg2png, [  --disable-svg2png        disable conversion of svgs to pngs], enable_svg2png=$enableval, enable_svg2png=yes)
 521 AC_ARG_ENABLE(svg2png-scaling, [  --enable-svg2png-scaling   enable conversion of svgs to pngs with specified sizes], SVG2PNG_SCALES=$enableval, SVG2PNG_SCALES="8 16 32 48 96")
 522 AC_ARG_ENABLE(svg2png-scaling-flag, [  --enable-svg2png-scaling-flag   enable conversion of flag svgs to pngs with specified sizes], SVG2PNG_SCALES_FLAG=$enableval, SVG2PNG_SCALES_FLAG="")
 523 AC_ARG_ENABLE(svg2png-scaling-nav, [  --enable-svg2png-scaling-nav   enable conversion of nav svgs to pngs with specified sizes], SVG2PNG_SCALES_NAV=$enableval, SVG2PNG_SCALES_NAV="")
 524 if test "x${enable_svg2png}" = "xyes" ; then
 525         AC_PATH_PROG([KSVGTOPNG], [ksvgtopng], [])
 526         if test ! -x "$KSVGTOPNG"; then
 527             enable_svg2png="no"
 528         fi
 529 fi
 530 AC_SUBST(SVG2PNG_SCALES)
 531 AC_SUBST(SVG2PNG_SCALES_FLAG)
 532 AC_SUBST(SVG2PNG_SCALES_NAV)
 533 AM_CONDITIONAL(USE_SVG2PNG_SCALES, test "x${SVG2PNG_SCALES}" != "xyes" -a "x${SVG2PNG_SCALES}" != "x")
 534 AM_CONDITIONAL(USE_SVG2PNG_SCALES_FLAG, test "x${SVG2PNG_SCALES_FLAG}" != "xyes" -a "x${SVG2PNG_SCALES_FLAG}" != "x")
 535 AM_CONDITIONAL(USE_SVG2PNG_SCALES_NAV, test "x${SVG2PNG_SCALES_NAV}" != "xyes" -a "x${SVG2PNG_SCALES_NAV}" != "x")
 536 AM_CONDITIONAL(USE_SVG2PNG, test "x${enable_svg2png}" = "xyes")
 537 AM_CONDITIONAL(USE_SVG, test "x${enable_svg}" = "xyes")
 538
 539 # NLS
 540
 541 AC_ARG_ENABLE(nls,
 542   [  --disable-nls        disable Native Language Support ( gettext/libintl )],
 543    enable_nls=$enableval, enable_nls=yes)
 544
 545
 546 INTLIBS=""
 547 MOFILES=""
 548 POFILES=""
 549 LINGUAS=""
 550
 551 if test "x$enable_nls" = "xyes"; then
 552
 553   AC_CHECK_FUNC(gettext, [HAVEGETTEXT="yes"]
 554              AC_CHECK_LIB(intl, gettext, [INTLIBS="-lintl" HAVEGETTEXT="yes"],
 555                          INTLIBS="" ))
 556
 557   AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
 558   AC_CHECK_PROG(MSGMERGE, msgmerge, msgmerge)
 559   AC_CHECK_PROG(MSGFMT, msgfmt, msgfmt)
 560
 561   if test "$XGETTEXT" != ""; then
 562     if $XGETTEXT --help 2>&1 | grep illegal >/dev/null ; then
 563         echo "xgettext isn't GNU version"
 564         XGETTEXT=""
 565     fi
 566   fi
 567
 568   if test "$XGETTEXT" != "" -a "$HAVEGETTEXT" != ""; then
 569      PO=""
 570      if test "$LINGUAS" = ""; then
 571            ling=` (cd $srcdir/po; /bin/ls *.po.in) `
 572            for l in $ling; do
 573                 lcode=`basename $l .po.in`
 574                 LINGUAS="$LINGUAS$lcode "
 575            done
 576     fi
 577     AC_DEFINE(ENABLE_NLS, [1], [NLS Please])
 578     echo "xgettext and gettext() exist; will build i18n support for $LINGUAS"
 579   else
 580    LINGUAS=""
 581    PO=""
 582    echo "xgettext and libintl.a don't both exist; will not build i18n support"
 583    enable_nls = no
 584  fi
 585  for lang in $LINGUAS; do
 586     MOFILES="$MOFILES $lang.mo"
 587  done
 588  for lang in $LINGUAS; do
 589     POFILES="$POFILES $lang.po"
 590  done
 591
 592 AC_SUBST(INTLIBS)
 593 AC_SUBST(MOFILES)
 594 AC_SUBST(POFILES)
 595 AM_GNU_GETTEXT_VERSION
 596 AM_GNU_GETTEXT(no-libtool, need-ngettext, \$(top_builddir)/intl/)
 597 AC_SUBST(LIBINTL)
 598 AC_SUBST(LTLIBINTL)
 599 if test x"$LIBINTL" != "x" ;then
 600         CFLAGS="$CFLAGS -I\$(top_builddir)/intl/"
 601 fi
 602
 603 fi
 604 AM_CONDITIONAL(ENABLE_NLS, [test "x$enable_nls" = "xyes"])
 605 AC_CHECK_HEADER(
 606         byteswap.h,
 607         AC_DEFINE(
 608                 [HAVE_BYTESWAP_H],
 609                 [1],
 610                 [Define to 1 if you have byteswap.h],
 611                 )
 612                 ,
 613 )
 614
 615 PACKAGE=navit
 616 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
 617 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
 618 AC_SUBST(PACKAGE)
 619 AC_SUBST(VERSION)
 620
 621 AC_CHECK_HEADER(wordexp.h,wordexp_h=yes,wordexp_h=no;NAVIT_CFLAGS="$NAVIT_CFLAGS -I\$(top_srcdir)/navit/support/wordexp";NAVIT_LIBS="$NAVIT_LIBS -L\$(top_builddir)/navit/support/wordexp -lsupport_wordexp")
 622 AM_CONDITIONAL(SUPPORT_WORDEXP, [test "x$wordexp_h" = "xno"])
 623
 624 AC_CANONICAL_HOST
 625 win32=no
 626 case $host_os in
 627 wince)
 628         win32=yes
 629         AC_DEFINE(HAVE_API_WIN32_BASE, 1, [Have Windows Base API])
 630         AC_DEFINE(HAVE_API_WIN32_CE, 1, [Have Windows CE API])
 631         gui_win32=yes; gui_win32_reason="host_os is wince"
 632         graphics_win32=yes; graphics_win32_reason="host_os is wince"
 633         vehicle_wince=yes; vehcile_wince_reason="host_os is wince"
 634         ;;
 635 mingw32)
 636         win32=yes
 637         AC_DEFINE(HAVE_API_WIN32_BASE, 1, [Have Windows Base API])
 638         AC_DEFINE(HAVE_API_WIN32, 1, [Have Windows API])
 639         gui_win32=yes; gui_win32_reason="host_os is mingw32"
 640         graphics_win32=yes; graphics_win32_reason="host_os is mingw32"
 641 esac
 642 if test "x$win32" = "xyes"
 643 then
 644         NAVIT_CFLAGS="$NAVIT_CFLAGS -I\$(top_srcdir)/navit/support/win32"
 645         NAVIT_LIBS="$NAVIT_LIBS -L\$(top_builddir)/navit/support/win32 -lsupport_win32"
 646 fi
 647 AM_CONDITIONAL(SUPPORT_WIN32, [test "x$win32" = "xyes"])
 648
 649 LIBS="$LIBS -lm"
 650 if test "$win32" == "no"; then
 651         LIBS="$LIBS -rdynamic"
 652 fi
 653
 654 support_libc=no
 655 AC_ARG_ENABLE(support_libc, [  --enable-support-libc enable builtin mini libc ], support_libc=$enableval)
 656 AM_CONDITIONAL(SUPPORT_LIBC, [test "x$support_libc" = "xyes"])
 657 if test "x$support_libc" = "xyes"; then
 658         CFLAGS="$CFLAGS -I\$(top_srcdir)/navit/support/libc"
 659 fi
 660
 661 ## graphics
 662 # gd
 663 AC_ARG_ENABLE(graphics-gd, [  --enable-graphics-gd                enable graphics type gd], graphics_gd=$enableval;graphics_gd_reason="configure parameter")
 664 if test "x${graphics_gd}" = "xyes" ; then
 665         if test -z "$GDLIB_CONFIG"; then
 666             AC_PATH_PROG([GDLIB_CONFIG], [gdlib-config], [])
 667         fi
 668         AC_MSG_CHECKING([for gdlib with $GDLIB_CONFIG])
 669         if test ! -x "$GDLIB_CONFIG"; then
 670             if test "x${GDLIB_CONFIG}" = "x" ; then
 671                  graphics_gd_reason="$GDLIB_CONFIG not executable"
 672             else
 673                  graphics_gd_reason="gdlib-config missing"
 674             fi
 675             graphics_gd=no
 676             AC_MSG_RESULT([no])
 677         else
 678             GD_CFLAGS="-I`$GDLIB_CONFIG --includedir`"
 679             GD_LIBS="-L`$GDLIB_CONFIG --libdir` -lgd `$GDLIB_CONFIG --libs`"
 680             AC_SUBST(GD_CFLAGS)
 681             AC_SUBST(GD_LIBS)
 682             AC_MSG_RESULT([yes])
 683         fi
 684 fi
 685 AM_CONDITIONAL(GRAPHICS_GD, test "x${graphics_gd}" = "xyes")
 686 # gtk_drawing_area
 687 AC_ARG_ENABLE(graphics-gtk-drawing-area, [  --disable-graphics-gtk-drawing-area disable graphics type gtk_drawing_area], graphics_gtk_drawing_area=$enableval;graphics_gtk_drawing_area_reason="configure parameter")
 688 AM_CONDITIONAL(GRAPHICS_GTK_DRAWING_AREA, [test "x${graphics_gtk_drawing_area}" = "xyes"])
 689 # win32
 690 AC_ARG_ENABLE(graphics-win32, [  --disable-graphics-win32            disable graphics type win32], graphics_win32=$enableval;graphics_win32_reason="configure parameter")
 691 AM_CONDITIONAL(GRAPHICS_WIN32, test "x${graphics_win32}" = "xyes")
 692 # qt_qpainter
 693 AC_ARG_ENABLE(graphics-qt-qpainter, [  --disable-graphics-qt-qpainter      disable graphics type qt-qpainter], graphics_qt_qpainter=$enableval;graphics_qt_qpainter_reason="configure parameter")
 694 if test "x${graphics_qt_qpainter}" = "xyes" -a "x${QT_GUI_CFLAGS}" = "x" -a "x${QT_GUI_LIBS}" = "x"; then
 695         PKG_CHECK_MODULES(QT_GUI, [QtGui QtCore], ,graphics_qt_qpainter=no,graphics_qt_qpainter_reason="Packages QtGui and/or QtCore missing")
 696 fi
 697 if test "x${graphics_qt_qpainter}" = "xyes" ; then
 698         AC_DEFINE(USE_GRAPICS_QT_QPAINTER, 1, [Build with graphics qt_qpainter])
 699 fi
 700 AC_SUBST(QT_GUI_CFLAGS)
 701 AC_SUBST(QT_GUI_LIBS)
 702 AM_CONDITIONAL(GRAPHICS_QT_QPAINTER, test "x${graphics_qt_qpainter}" = "xyes")
 703
 704 ## gui
 705 # gtk
 706 AC_ARG_ENABLE(gui-gtk, [  --disable-gui-gtk                   disable gui type gtk ], gui_gtk=$enableval)
 707 AM_CONDITIONAL(GUI_GTK, [test "x${gui_gtk}" = "xyes"])
 708 # internal
 709 AC_ARG_ENABLE(gui-internal, [  --disable-gui-internal              disable gui type internal], gui_internal=$enableval;gui_internal_reason="configure parameter")
 710 AM_CONDITIONAL(GUI_INTERNAL, test "x${gui_internal}" = "xyes")
 711 # win32
 712 AC_ARG_ENABLE(gui-win32, [  --disable-gui-win32                 disable gui type win32], gui_win32=$enableval;gui_win32_reason="configure parameter")
 713 AM_CONDITIONAL(GUI_WIN32, test "x${gui_win32}" = "xyes")
 714
 715 ## speech
 716 # cmdline
 717 AC_ARG_ENABLE(speech-cmdline, [  --disable-speech-cmdline            disable speech type cmdline], speech_cmdline=$enableval;speech_cmdline_reason="configure parameter")
 718 AM_CONDITIONAL(SPEECH_CMDLINE, test "x${speech_cmdline}" = "xyes")
 719 # cmdline
 720 AC_ARG_ENABLE(speech-speechd, [  --disable-speech-speech-dispatcher  disable speech type speech-dispatcher], speech_speech_dispatcher=$enableval;speech_speech_dispatcher_reason="configure parameter")
 721 if test "x$speech_speech_dispatcher" = "xyes"; then
 722         AC_CHECK_HEADER(libspeechd.h, AC_DEFINE([HAVE_LIBSPEECHD],[],Define to 1 if you have the <libspeechd.h> header file.) SPEECHD_LIBS="-lspeechd",  speech_speech_dispatcher=no; speech_speech_dispatcher_reason="libspeechd.h missing")
 723 fi
 724 AC_SUBST(SPEECHD_CFLAGS)
 725 AC_SUBST(SPEECHD_LIBS)
 726 AM_CONDITIONAL(SPEECH_SPEECH_DISPATCHER, test "x${speech_speech_dispatcher}" = "xyes")
 727
 728 ## vehicle
 729 # demo
 730 AC_ARG_ENABLE(vehicle-demo, [  --disable-vehicle-demo              disable vehicle type demo], vehicle_demo=$enableval;vehicle_demo_reason="configure parameter")
 731 AM_CONDITIONAL(VEHICLE_DEMO, test "x${vehicle_demo}" = "xyes")
 732 # file
 733 AC_ARG_ENABLE(vehicle-file, [  --disable-vehicle-file              disable vehicle type file], vehicle_file=$enableval;vehicle_file_reason="configure parameter")
 734 AM_CONDITIONAL(VEHICLE_FILE, test "x${vehicle_file}" = "xyes")
 735 # gpsd
 736 if test "x${vehicle_gpsd}" = xyes
 737 then
 738         AC_CHECK_HEADER(gps.h, AC_DEFINE([HAVE_LIBGPS],[],Define to 1 if you have the <gps.h> header file.) GPSD_LIBS="-lgps", vehicle_gpsd=no; vehicle_gpsd_reason="no gps.h" )
 739 fi
 740 AC_SUBST(GPSD_CFLAGS)
 741 AC_SUBST(GPSD_LIBS)
 742 AM_CONDITIONAL(VEHICLE_GPSD, [test "x${vehicle_gpsd}" = "xyes"])
 743 # gypsy
 744 AC_ARG_ENABLE(vehicle-gypsy,[  --disable-vehicle-gypsy             disable vehicle type gypsy], vehicle_gypsy=$enableval;vehicle_gypsy_reason="configure parameter")
 745 if test "x${vehicle_gypsy}" = "xyes"
 746 then
 747         PKG_CHECK_MODULES(GYPSY, gypsy, ,vehicle_gypsy=no;vehicle_gypsy_reason="package gypsy missing")
 748 fi
 749 AC_SUBST(GYPSY_CFLAGS)
 750 AC_SUBST(GYPSY_LIBS)
 751 AM_CONDITIONAL(VEHICLE_GYPSY, test "x${vehicle_gypsy}" = "xyes")
 752 # wince
 753 AC_ARG_ENABLE(vehicle-wince, [  --disable-vehicle-wince             disable vehicle type wince], vehicle_wince=$enableval;vehicle_wince_reason="configure parameter")
 754 AM_CONDITIONAL(VEHICLE_WINCE, test "x${vehicle_wince}" = "xyes")
 755
 756 NAVIT_CFLAGS="$NAVIT_CFLAGS $GLIB_CFLAGS $GMODULE_CFLAGS"
 757 NAVIT_LIBS="$NAVIT_LIBS $GLIB_LIBS $GMODULE_LIBS $LIBINTL"
 758 AC_SUBST(NAVIT_CFLAGS)
 759 AC_SUBST(NAVIT_LIBS)
 760 AC_SUBST(WINDRES)
 761
 762 AC_CONFIG_FILES([
 763 Makefile
 764 navit/Makefile
 765 navit/binding/Makefile
 766 navit/binding/python/Makefile
 767 navit/binding/dbus/Makefile
 768 navit/data/Makefile
 769 navit/data/mg/Makefile
 770 navit/data/textfile/Makefile
 771 navit/data/binfile/Makefile
 772 navit/data/garmin/Makefile
 773 navit/data/poi_geodownload/Makefile
 774 navit/data/poi_geodownload/libmdb/Makefile
 775 navit/data/poi_geodownload/libmdb/include/Makefile
 776 navit/fib-1.1/Makefile
 777 navit/font/Makefile
 778 navit/font/freetype/Makefile
 779 navit/graphics/Makefile
 780 navit/graphics/gd/Makefile
 781 navit/graphics/gtk_drawing_area/Makefile
 782 navit/graphics/directfb/Makefile
 783 navit/graphics/cogl/Makefile
 784 navit/graphics/opengl/Makefile
 785 navit/graphics/null/Makefile
 786 navit/graphics/sdl/Makefile
 787 navit/graphics/qt_qpainter/Makefile
 788 navit/graphics/win32/Makefile
 789 navit/gui/Makefile
 790 navit/gui/gtk/Makefile
 791 navit/gui/internal/Makefile
 792 navit/gui/clutter/Makefile
 793 navit/gui/cegui/Makefile
 794 navit/gui/cegui/datafiles/Makefile
 795 navit/gui/directfb/Makefile
 796 navit/gui/win32/Makefile
 797 navit/osd/Makefile
 798 navit/osd/core/Makefile
 799 navit/speech/Makefile
 800 navit/speech/cmdline/Makefile
 801 navit/speech/speech_dispatcher/Makefile
 802 navit/support/Makefile
 803 navit/support/ezxml/Makefile
 804 navit/support/glib/Makefile
 805 navit/support/libc/Makefile
 806 navit/support/win32/Makefile
 807 navit/support/wordexp/Makefile
 808 navit/support/zlib/Makefile
 809 navit/vehicle/Makefile
 810 navit/vehicle/file/Makefile
 811 navit/vehicle/gpsd/Makefile
 812 navit/vehicle/gypsy/Makefile
 813 navit/vehicle/demo/Makefile
 814 navit/vehicle/wince/Makefile
 815 navit/xpm/Makefile
 816 navit/maps/Makefile
 817 intl/Makefile
 818 po/Makefile
 819 ])
 820 #src/data/garmin_img/Makefile
 821
 822 AC_OUTPUT
 823
 824
 825 echo ""
 826 echo ""
 827 echo "Summary of your installation :"
 828 # FIXME : maybe elaborate missing dependencies
 829 if test x"$sdl" != xyes
 830         then
 831         sdl_failures="(libsdl maybe?) "
 832 fi
 833 if test x"$xmu" != xyes
 834         then
 835         sdl_failures=$sdl_failures"libxmu "
 836 fi
 837 if test x"$glut" != xyes
 838        then
 839         sdl_failures=$sdl_failures"glut "
 840 fi
 841 if test x"$glc" != xyes
 842         then
 843         sdl_failures=$sdl_failures"quesoglc "
 844 fi
 845 if test x"$cegui" != xyes
 846         then
 847         sdl_failures=$sdl_failures"cegui-devel >= 0.5 "
 848 fi
 849 if test -z "$sdl_failures"
 850         then
 851         echo "OpenGL gui  : ENABLED, with $CEGUI_LIBS"
 852         else
 853                  echo "OpenGL gui  : DISABLED : you are missing $sdl_failures"
 854 fi
 855 if test x"$directfb_pkgconfig" = xyes
 856         then
 857         echo "DIRECTFB    : ENABLED"
 858         else
 859         echo "DIRECTFB    : DISABLED"
 860 fi
 861 if test x"$clutter_pkgconfig" = xyes
 862         then
 863         echo "Clutter gui : ENABLED"
 864         else
 865         echo "Clutter gui : DISABLED"
 866 fi
 867 if test x"$enable_hildon" = xyes
 868         then
 869         echo "Maemo/Hildon: ENABLED"
 870         else
 871         echo "Maemo/Hildon: DISABLED"
 872 fi
 873 if test x"${USE_GARMIN}" = xyes
 874         then
 875         if test "x$use_libgarmin" = "xyes"
 876                 then
 877                 echo "Garmin IMG  : ENABLED"
 878                 else
 879                 echo "Garmin IMG  : DISABLED (you don't have libgarmin)"
 880         fi
 881         else
 882                 echo "Garmin IMG  : DISABLED (you requested it)"
 883 fi
 884
 885 if test x"$LIBINTL" = "x" ;then
 886         nls_libs="system gettext support"
 887 else
 888         nls_libs="$LIBINTL"
 889 fi
 890 echo "Plugins:             $plugins ($plugins_reason)"
 891 echo "Postgresql:          $postgresql ($postgresql_reason)"
 892 echo "Samplemap:           $samplemap ($samplemap_reason)"
 893 echo "NLS Support:         $enable_nls($nls_libs)"
 894 echo "Graphics types:"
 895 echo "  gtk_drawing_area:  $graphics_gtk_drawing_area ($graphics_gtk_drawing_area_reason)"
 896 echo "  qt_qpainter:       $graphics_qt_qpainter ($graphics_qt_qpainter_reason)"
 897 echo "  win32:             $graphics_win32 ($graphics_win32_reason)"
 898 echo "  OpenGL:            $graphics_opengl ($graphics_opengl_reason)"
 899 echo "  gd:                $graphics_gd ($graphics_gd_reason)"
 900
 901 echo "GUI types:"
 902 echo "  gtk:               $gui_gtk ($gui_gtk_reason)"
 903 echo "  internal:          $gui_internal ($gui_internal_reason)"
 904 echo "  win32:             $gui_win32 ($gui_win32_reason)"
 905
 906 echo "Speech types:"
 907 echo "  cmdline:           $speech_cmdline ($speech_cmdline_reason)"
 908 echo "  speech_dispatcher: $speech_speech_dispatcher ($speech_speech_dispatcher_reason)"
 909
 910 echo "Vehicle types:"
 911 echo "  demo:              $vehicle_demo ($vehicle_demo_reason)"
 912 echo "  file:              $vehicle_file ($vehicle_file_reason)"
 913 echo "  gpsd:              $vehicle_gpsd ($vehicle_gpsd_reason)"
 914 echo "  gypsy:             $vehicle_gypsy ($vehicle_gypsy_reason)"
 915 echo "  wince:             $vehicle_wince ($vehicle_wince_reason)"
 916
 917 if  test "x${gtk2_pkgconfig}" != "xyes" -a "x${sdl}" != "xyes" -a "x${directfb_pkgconfig}" != "xyes" -a "x${gui_win32}" != "xyes" -a "x${gui_internal}" != "xyes"
 918         then
 919         echo ""
 920         echo ""
 921         echo "*** WARNING! you have no gui that can be built! ***"
 922         echo "Please install the dependency for at least gtk or sdl gui"
 923         echo "For more details, see the wiki at http://wiki.navit-project.org/"
 924         echo ""
 925         exit 1
 926 fi
 927