git.maemo.org Git - navit-package/blob - configure.in

   1 AC_INIT(navit, 0.2.0)
   2 SOURCE_MODE=svn
   3
   4 AM_INIT_AUTOMAKE
   5 AM_CONFIG_HEADER(config.h)
   6
   7 AC_SUBST(SOURCE_MODE)
   8 AM_CONDITIONAL(SOURCE_MODE_SVN, [test "x${SOURCE_MODE}" = "xsvn"])
   9
  10 if test "x${SOURCE_MODE}" = "xsvn" ; then
  11         USE_MAINTAINER_MODE=yes
  12 else
  13         USE_MAINTAINER_MODE=no
  14 fi
  15
  16 AC_DEFUN([AM_MAINTAINER_MODE],
  17 [AC_MSG_CHECKING([whether to enable maintainer-specific portions of Makefiles])
  18   dnl maintainer-mode is enabled by default (reason of inclusion of this function)
  19   AC_ARG_ENABLE(maintainer-mode,
  20 [  --enable-maintainer-mode  enable make rules and dependencies not useful
  21                           (and sometimes confusing) to the casual installer],
  22       USE_MAINTAINER_MODE=$enableval)
  23   AC_MSG_RESULT([$USE_MAINTAINER_MODE])
  24   AM_CONDITIONAL(MAINTAINER_MODE, [test $USE_MAINTAINER_MODE = yes])
  25   MAINT=$MAINTAINER_MODE_TRUE
  26   AC_SUBST(MAINT)dnl
  27 ]
  28 )
  29
  30 AU_DEFUN([jm_MAINTAINER_MODE], [AM_MAINTAINER_MODE])
  31
  32 AM_MAINTAINER_MODE
  33
  34
  35 plugins=yes; plugins_reason=default
  36 postgresql=yes; postgresql_reason=default
  37 samplemap=yes; samplemap_reason=default
  38 binding_dbus=yes; binding_dbus_reason=default
  39 binding_python=yes; binding_python_reason=default
  40 font_freetype=yes; font_freetype_reason=default
  41 fontconfig=yes; fontconfig_reason=default
  42 gui_gtk=no; gui_gtk_reason=default
  43 gui_win32=no; gui_win32_reason=default
  44 gui_internal=yes; gui_internal_reason=default
  45 graphics_gd=no; graphics_gd_reason=default
  46 graphics_gtk_drawing_area=no; graphics_gtk_drawing_area_reason=default
  47 graphics_qt_qpainter=yes; graphics_qt_qpainter_reason=default
  48 graphics_opengl=yes; graphics_opengl_reason=default
  49 graphics_sdl=yes; graphics_sdl_reason=default
  50 graphics_win32=no; graphics_win32_reason=default
  51 speech_cmdline=yes; speech_cmdline_reason=default
  52 speech_speech_dispatcher=yes; speech_speech_dispatcher_reason=default
  53 vehicle_demo=yes; vehicle_demo_reason=default
  54 vehicle_file=yes; vehicle_file_reason=default
  55 vehicle_gpsd=yes; vehicle_gpsd_reason=default
  56 vehicle_gypsy=yes; vehicle_gypsy_reason=default
  57 vehicle_wince=no; vehicle_wince_reason=default
  58
  59 m4_ifndef([AC_USE_SYSTEM_EXTENSIONS],
  60         [AC_DEFUN([AC_USE_SYSTEM_EXTENSIONS], [AC_GNU_SOURCE])])
  61
  62 AC_USE_SYSTEM_EXTENSIONS
  63
  64 AC_PROG_CC
  65 if eval "test x`uname` = xDarwin"; then
  66         CFLAGS="$CFLAGS -I/opt/local/include -L/opt/local/lib"
  67 fi
  68 if eval "test x$GCC = xyes"; then
  69         CFLAGS="$CFLAGS -Wall -Wcast-align -Wmissing-declarations -Wmissing-prototypes -Wstrict-prototypes -Wpointer-arith -Wreturn-type -D_GNU_SOURCE"
  70 fi
  71 AM_PROG_CC_C_O
  72
  73 AC_PROG_CXX
  74 if eval "test x$GXX = xyes"; then
  75         CXXFLAGS="$CXXFLAGS -Wall -Wcast-align -Wpointer-arith -Wreturn-type -D_GNU_SOURCE"
  76 fi
  77
  78 PKG_CHECK_EXISTS
  79 if test "x${cross_compiling}" = "xyes"; then
  80         samplemap="no";samplemap_reason="not supported for cross compiling"
  81         binding_python="no";binding_python_reason="not supported for cross compiling"
  82         postgresql="no";postgresql_reason="not supported for cross compiling"
  83         AC_MSG_CHECKING([for a C compiler for build tools])
  84         AC_CHECK_PROGS(CC_FOR_BUILD, gcc cc)
  85 else
  86         CC_FOR_BUILD=$CC
  87 fi
  88 CCLD_FOR_BUILD="$CC_FOR_BUILD"
  89 AC_SUBST(cross_compiling)
  90 AC_SUBST(CC_FOR_BUILD)
  91 AC_SUBST(CCLD_FOR_BUILD)
  92
  93 AC_ARG_ENABLE(variant, [  --enable-variant=something          set variant], NAVIT_VARIANT=$enableval)
  94 AC_SUBST(NAVIT_VARIANT)
  95
  96 AC_ARG_ENABLE(cache-size, [  --enable-cache-size=size in bytes        set cache size], AC_DEFINE_UNQUOTED(CACHE_SIZE,[${enableval}], [Size of Cache in Bytes]))
  97
  98 AC_ARG_ENABLE(avoid-unaligned, [  --enable-avoid-unaligned          avoid unaligned accesses], AVOID_UNALIGNED=$enableval, AVOID_UNALIGNED=no)
  99 test x"${AVOID_UNALIGNED}" = xyes && AC_DEFINE(AVOID_UNALIGNED,[],Define to avoid unaligned access)
 100
 101 AC_ARG_ENABLE(avoid-float, [  --enable-avoid-float              avoid floating point calculations], AVOID_FLOAT=$enableval, AVOID_FLOAT=no)
 102 test x"${AVOID_FLOAT}" = xyes && AC_DEFINE(AVOID_FLOAT,[],Define to avoid floating point)
 103
 104 AC_ARG_ENABLE(transformation-roll, [  --enable-transformation-roll      add support for specifying roll angle in transformation], ENABLE_ROLL=$enableval, ENABLE_ROLL=no)
 105 test x"${ENABLE_ROLL}" = xyes && AC_DEFINE(ENABLE_ROLL,[],Define to add support for specifying roll angle in transformation)
 106
 107 AC_ARG_ENABLE(hildon, [  --disable-hildon              build without maemo/hildon support], enable_hildon=$enableval, enable_hildon=yes)
 108 if test "x${enable_hildon}" = "xyes" ; then
 109         PKG_CHECK_MODULES(HILDON, hildon-1 >= 0.9.9, , [
 110                 AC_MSG_RESULT(no)
 111                 enable_hildon=no
 112         ])
 113         PKG_CHECK_MODULES(GPSBT, gpsbt, [
 114                 AC_DEFINE(HAVE_GPSBT, 1, [Have the gpsbt library])
 115                 AC_SUBST(GPSBT_CFLAGS)
 116                 AC_SUBST(GPSBT_LIBS)
 117                 ], [
 118                 AC_MSG_RESULT(no)
 119         ])
 120         if test x"${enable_hildon}" = xyes ; then
 121                 AC_DEFINE(USE_HILDON, 1, [Build with maemo/hildon support])
 122                 AC_SUBST(HILDON_CFLAGS)
 123                 AC_SUBST(HILDON_LIBS)
 124         fi
 125 fi
 126 AM_CONDITIONAL(USE_HILDON, test "${enable_hildon}" = "xyes")
 127
 128 AC_ARG_ENABLE(garmin, [  --disable-garmin             disable garmin support], USE_GARMIN=$enableval, USE_GARMIN=yes)
 129
 130 # samplemap
 131 AC_PATH_PROG(_PATH_BZCAT,[bzcat])
 132 if test "x${_PATH_BZCAT}" = "x" ; then
 133         samplemap=no; samplemap_reason="bzcat missing"
 134 fi
 135 AC_ARG_ENABLE(samplemap, [  --disable-samplemap             don't build the samplemap], samplemap=$enableval;samplemap_reason="configure parameter")
 136 AM_CONDITIONAL(BUILD_SAMPLEMAP, [test "x$samplemap" = "xyes"])
 137
 138 AC_ARG_ENABLE(fastmath, [  --disable-fastmath             don't build with fastmath], fastmath=$enableval, fastmath=yes)
 139 AM_CONDITIONAL(FASTMATH, [test "x$fastmath" = "xyes"])
 140
 141 if test x"$fastmath" = xyes; then
 142         if eval "test x$GCC = xyes"; then
 143                 CFLAGS="$CFLAGS -ffast-math"
 144         fi
 145 fi
 146
 147 X_CFLAGS="-I$x_includes"
 148 AS_IF([test -n "$ac_x_libraries"], [X_LIBS="-L$ac_x_libraries"])
 149
 150 # glib
 151 AC_ARG_ENABLE(glib, [  --disable-glib             don't build with external glib], glib=$enableval, glib=yes)
 152 if test x"${glib}" = "xyes"; then
 153         PKG_CHECK_MODULES(GLIB, [glib-2.0 gthread-2.0], [glib=yes],[glib=no])
 154 fi
 155 if test "x${glib}" = "xyes"; then
 156         AC_DEFINE(HAVE_GLIB, 1, [Define to 1 if you have (external) glib library])
 157 else
 158         GLIB_CFLAGS="-I\$(top_srcdir)/navit/support -I\$(top_srcdir)/navit/support/glib -I\$(top_srcdir)/navit/support/ezxml"
 159         GLIB_LIBS="-L\$(top_builddir)/navit/support/glib -lsupport_glib -L\$(top_builddir)/navit/support/ezxml -lsupport_ezxml"
 160 fi
 161
 162 # gmodule
 163 AC_ARG_ENABLE(gmodule, [  --disable-gmodule             don't build with gmodule], gmodule=$enableval, gmodule=yes)
 164 if test x"${gmodule}" = "xyes"; then
 165         PKG_CHECK_MODULES(GMODULE, [gmodule-2.0], [gmodule=yes], [gmodule=no])
 166 fi
 167 if test "x${gmodule}" = "xyes"; then
 168         AC_DEFINE(HAVE_GMODULE, 1, [Define to 1 if you have gmodule])
 169 else
 170         AC_CHECK_LIB(dl, dlopen,
 171                 [plugins_reason="default, via dlopen";GMODULE_LIBS="-ldl";AC_DEFINE(HAVE_DLOPEN, 1, [Define to 1 if you have dlopen])],
 172                 [plugins="no"; plugins_reason="package gmodule and dlopen missing"]
 173         )
 174 fi
 175 # plugins
 176 AC_ARG_ENABLE(plugins,  [  --disable-plugins          disable plugins], [ plugins=$enableval;plugin_reason="configure parameter" ])
 177 if test "x${plugins}" = "xyes"; then
 178         AC_ENABLE_SHARED
 179         AC_DISABLE_STATIC
 180         AC_DEFINE(
 181                 [USE_PLUGINS],
 182                 [],
 183                 Define to 1 if you have plugins.
 184         )
 185 else
 186         AC_DISABLE_SHARED
 187         AC_ENABLE_STATIC
 188 fi
 189 AM_CONDITIONAL(PLUGINS, [test "x$plugins" = "xyes"])
 190 AC_PROG_LIBTOOL
 191
 192 AM_CONDITIONAL(EVENT_GLIB, [test "x$glib" = "xyes"])
 193 AM_CONDITIONAL(SUPPORT_GLIB, [test "x$glib" = "xno"])
 194 AM_CONDITIONAL(SUPPORT_EZXML, [test "x$glib" = "xno"])
 195 AM_CONDITIONAL(MAP_POI_GEODOWNLOAD, [test "x$glib" = "xyes"])
 196
 197 AC_CHECK_HEADER(
 198         zlib.h,
 199         AC_DEFINE(
 200                 [HAVE_ZLIB],
 201                 [],
 202                 Define to 1 if you have the <zlib.h> header file.
 203         )
 204         ZLIB_LIBS="-lz"
 205         zlib=yes,
 206         ZLIB_CFLAGS="-I\$(top_srcdir)/navit/support/zlib"
 207         ZLIB_LIBS="-L\$(top_builddir)/navit/support/zlib -lsupport_zlib"
 208         zlib=no
 209 )
 210 AM_CONDITIONAL(SUPPORT_ZLIB, [test "x$zlib" = "xno"])
 211 AC_SUBST(ZLIB_CFLAGS)
 212 AC_SUBST(ZLIB_LIBS)
 213
 214 # gtk
 215 PKG_CHECK_MODULES(GTK2, [gtk+-2.0], [gtk2_pkgconfig=yes], [gtk2_pkgconfig=no])
 216 if test "x$gtk2_pkgconfig" = "xyes"; then
 217         AC_DEFINE(HAVE_GTK2, 1, [Define to 1 if you have gtk2])
 218         graphics_gtk_drawing_area=yes; graphics_gtk_drawing_area_reason="gtk+-2.0 present"
 219         gui_gtk=yes; gui_gtk_reason="gtk+-2.0 present"
 220 fi
 221
 222 # fsync
 223 AC_MSG_CHECKING(for fsync)
 224 AC_TRY_LINK([#include <unistd.h>], [fsync(0);],AC_MSG_RESULT(yes);AC_DEFINE(HAVE_FSYNC, 1, [Define to 1 if you have the `fsync' function.]),AC_MSG_RESULT(no))
 225
 226 # system
 227 AC_MSG_CHECKING(for system)
 228 AC_TRY_LINK([#include <stdlib.h>], [system("/bin/true");],AC_MSG_RESULT(yes);AC_DEFINE(HAVE_SYSTEM, 1, [Define to 1 if you have the `system' function.]),speech_cmdline=no; speech_cmdline_reason="not supported without system()"; AC_MSG_RESULT(no))
 229
 230 AC_MSG_CHECKING(for CreateProcess)
 231 AC_TRY_LINK([#include <windows.h>], [CreateProcess(NULL,NULL,NULL,NULL,0,0,NULL,NULL,NULL,NULL);],AC_MSG_RESULT(yes);AC_DEFINE(HAVE_CREATEPROCESS, 1, [Define to 1 if you have the `CreateProcess' function.]) speech_cmdline=yes; speech_cmdline_reason="CreateProcess exists", AC_MSG_RESULT(no))
 232
 233 AC_ARG_ENABLE(graphics-sdl, [  --disable-graphics-sdl             don't create graphics sdl], graphics_sdl=$enableval;graphics_sdl_reason="configure parameter")
 234 if test "x${graphics_sdl}" = "xyes" ; then
 235         if test -z "$SDL_CONFIG"; then
 236             AC_PATH_PROG([SDL_CONFIG], [sdl-config], [])
 237         fi
 238 fi
 239 if test "x${graphics_sdl}" = "xyes" ; then
 240         AC_MSG_CHECKING([for SDL libraries with $SDL_CONFIG])
 241         if test ! -x "$SDL_CONFIG"; then
 242             graphics_sdl = "no"
 243             graphics_sdl_reason = "sdl-config not available"
 244             AC_MSG_RESULT([no])
 245         else
 246             SDL_CFLAGS="`$SDL_CONFIG --cflags`"
 247             SDL_LIBS="`$SDL_CONFIG --libs`"
 248             AC_SUBST(SDL_CFLAGS)
 249             AC_SUBST(SDL_LIBS)
 250             AC_MSG_RESULT([yes])
 251         fi
 252 fi
 253 if test "x${graphics_sdl}" = "xyes" ; then
 254         save_CPPFLAGS=$CPPFLAGS
 255         CPPFLAGS="$($SDL_CONFIG --cflags) $CPPFLAGS"
 256         AC_CHECK_HEADER(SDL_image.h,SDL_IMAGE_LIBS=-lSDL_image,graphics_sdl="no";graphics_sdl_reason="SDL_image.h missing")
 257         AC_SUBST(SDL_IMAGE_LIBS)
 258         CPPFLAGS=$save_CPPFLAGS
 259 fi
 260 if test "x${graphics_sdl}" = "xyes" ; then
 261         AC_DEFINE(USE_GRAPHICS_SDL, 1, [Build with graphics sdl])
 262 fi
 263 AM_CONDITIONAL(USE_GRAPHICS_SDL, test "x${graphics_sdl}" = "xyes")
 264
 265 AC_ARG_ENABLE(postgresql, [  --disable-postgresql             don't add postgresql support to osm2navit], postgresql=$enableval;postgresql_reason="configure parameter")
 266 if test "x${postgresql}" = "xyes" ; then
 267         if test -z "$PG_CONFIG"; then
 268             AC_PATH_PROG([PG_CONFIG], [pg_config], [])
 269         fi
 270         AC_MSG_CHECKING([for PostgreSQL libraries with $PG_CONFIG])
 271         if test ! -x "$PG_CONFIG"; then
 272             if test "x${PG_CONFIG}" = "x" ; then
 273                  postgresql_reason="$PG_CONFIG not executable"
 274             else
 275                  postgresql_reason="pg_config missing"
 276             fi
 277             postgresql=no
 278             AC_MSG_RESULT([no])
 279         else
 280             POSTGRESQL_CFLAGS="-I`$PG_CONFIG --includedir`"
 281             POSTGRESQL_LIBS="-L`$PG_CONFIG --libdir` -lpq"
 282             AC_DEFINE(HAVE_POSTGRESQL, 1, [Postgresql libraries available])
 283             AC_SUBST(POSTGRESQL_CFLAGS)
 284             AC_SUBST(POSTGRESQL_LIBS)
 285             AC_MSG_RESULT([yes])
 286         fi
 287 fi
 288 AM_CONDITIONAL(HAVE_POSTGRESQL, test "x${postgresql}" = "xyes")
 289 # font
 290 # freetype
 291 AC_ARG_ENABLE(font-freetype, [  --disable-font-freetype             don't add freetype support], font_freetype=$enableval;font_freetype_reason="configure parameter")
 292 if test "x${font_freetype}" = "xyes" -a "x${FREETYPE2_CFLAGS}" = "x" -a "x${FREETYPE2_LIBS}" = "x"; then
 293         PKG_CHECK_MODULES(FREETYPE2, [freetype2], , [font_freetype=no;font_freetype_reason="Package freetype2 missing"])
 294 fi
 295 AC_SUBST(FREETYPE2_CFLAGS)
 296 AC_SUBST(FREETYPE2_LIBS)
 297 AM_CONDITIONAL(FONT_FREETYPE, test "x${font_freetype}" = "xyes")
 298
 299 AC_ARG_ENABLE(fontconfig, [  --disable-fontconfig             don't add fontconfig support], fontconfig=$enableval;fontconfig_reason="configure parameter")
 300 if test "x${fontconfig}" = "xyes"; then
 301         PKG_CHECK_MODULES(FONTCONFIG, [fontconfig], [fontconfig=yes], [fontconfig=no])
 302 fi
 303 if test "x$fontconfig" = "xyes"; then
 304    AC_DEFINE(HAVE_FONTCONFIG, 1, [Define to 1 if you have fontconfig])
 305 fi
 306 AC_SUBST(FONTCONFIG_CFLAGS)
 307 AC_SUBST(FONTCONFIG_LIBS)
 308
 309 AM_CONDITIONAL(FONTS, test "x${font_freetype}" = "xyes" -a "x$fontconfig" != "xyes")
 310
 311 PKG_CHECK_MODULES(IMLIB2, [imlib2], [imlib2_pkgconfig=yes], [imlib2_pkgconfig=no])
 312 if test "x$imlib2_pkgconfig" = "xyes"; then
 313    AC_DEFINE(HAVE_IMLIB2, 1, [Define to 1 if you have imlib2])
 314 fi
 315 AC_SUBST(IMLIB2_CFLAGS)
 316 AC_SUBST(IMLIB2_LIBS)
 317
 318
 319
 320 AC_ARG_ENABLE(gui-sdl, [  --disable-gui-sdl             don't create gui sdl ], MODULE_GUI_SDL=$enableval, MODULE_GUI_SDL=yes)
 321 if test "x$MODULE_GUI_SDL" = "xyes"; then
 322         AC_CHECK_HEADER(
 323                 SDL/SDL.h,
 324                 AC_DEFINE(
 325                         [HAVE_LIBSDL],
 326                         [],
 327                         Define to 1 if you have the <SDL/SDL.h> header file.
 328                         )
 329                         SDL_LIBS="-lSDL"
 330                         sdl=yes,
 331                 AC_MSG_WARN([*** no SDL/SDL.h -- SDL support disabled])
 332         )
 333 fi
 334
 335 AC_CHECK_HEADER(
 336         X11/Xmu/Xmu.h,
 337         AC_DEFINE(
 338                 [HAVE_XMU],
 339                 [],
 340                 Define to 1 if you have the <X11/Xmu/Xmu.h> header file.
 341                 )
 342                 xmu=yes,
 343         AC_MSG_WARN([*** no X11/Xmu/Xmu.h -- opengl and SDL support disabled])
 344 )
 345
 346 AC_ARG_ENABLE(graphics-opengl, [  --disable-graphics-opengl      disable graphics type OpenGL], graphics_opengl=$enableval;graphics_opengl_reason="configure parameter")
 347 if test "x${graphics_opengl}" = "xyes" ; then
 348
 349 AC_CHECK_HEADER(
 350         GL/gl.h,
 351         AC_DEFINE(
 352                 [HAVE_OPENGL],
 353                 [],
 354                 Define to 1 if you have the <GL/gl.h> header file.
 355                 )
 356                 OPENGL_LIBS="$X_LIBS -lGL -lGLU"
 357                 opengl=yes,
 358         AC_MSG_WARN([*** no GL/gl.h -- opengl and SDL support disabled];graphics_opengl=no;graphics_opengl_reason="Headers missing")
 359 )
 360
 361 AC_CHECK_HEADER(
 362         GL/glut.h,
 363         AC_DEFINE(
 364                 [HAVE_GLUT],
 365                 [],
 366                 Define to 1 if you have the <GL/glut.h> header file.
 367                 )
 368                 glut=yes,
 369         AC_MSG_WARN([*** no GL/glut.h -- opengl and SDL support disabled]);graphics_opengl=no;graphics_opengl_reason="Headers missing"
 370 )
 371
 372 AC_SUBST(OPENGL_CFLAGS)
 373 AC_SUBST(OPENGL_LIBS)
 374
 375 AC_CHECK_HEADER(
 376         GL/glc.h,
 377         AC_DEFINE(
 378                 [HAVE_GLC],
 379                 [],
 380                 Define to 1 if you have the <GL/glc.h> header file.
 381                 )
 382                 GLC_LIBS="-lGLC"
 383                 glc=yes,
 384         AC_MSG_WARN([*** no GL/glc.h -- opengl and SDL support disabled])
 385 )
 386 AC_SUBST(GLC_CFLAGS)
 387 AC_SUBST(GLC_LIBS)
 388 fi
 389
 390 AM_CONDITIONAL(GUI_SDL, [test "x$sdl" = "xyes" -a "x$opengl" = "xyes" -a "x$glc" = "xyes" -a "x$xmu" = "xyes" ])
 391 AM_CONDITIONAL(GRAPHICS_OPENGL, [test "x$glut" = "xyes" -a "x$opengl" = "xyes" -a "x$glc" = "xyes" ])
 392
 393
 394 if test x"${USE_GARMIN}" = xyes
 395 then
 396         # check for libgarmin
 397         PKG_CHECK_MODULES(LIBGARMIN, libgarmin, use_libgarmin=yes, use_libgarmin=no)
 398         AC_SUBST(LIBGARMIN_CFLAGS)
 399         AC_SUBST(LIBGARMIN_LIBS)
 400 fi
 401         AM_CONDITIONAL(HAVELIBGARMIN, [test "x$use_libgarmin" = "xyes"])
 402
 403 ## binding
 404 # python
 405 AC_ARG_ENABLE(binding-python, [  --disable-binding-python             don't create binding python], binding_python=$enableval;binding_python_reason="configure parameter")
 406 if test "x${binding_python}" = "xyes"; then
 407         AC_PATH_PROG(_PATH_PYTHON,[python])
 408         dnl Libraries and flags for embedded Python.
 409         dnl FIXME: I wish there was a less icky way to get this.
 410         if test "x${_PATH_PYTHON}" != "x" ; then
 411                 AC_MSG_CHECKING(for Python linkage)
 412                 AC_PATH_PROG([PYTHONCONFIG], [python-config], [])
 413                 if test "x${PYTHONCONFIG}" = "x" ; then
 414                         py_prefix=`$_PATH_PYTHON -c 'import sys; print sys.prefix'`
 415                         py_ver=`$_PATH_PYTHON -c 'import sys; print sys.version[[:3]]'`
 416                         py_lib=`$_PATH_PYTHON -c 'import sys; print sys.lib'`
 417                         py_libdir="${py_prefix}/${py_lib}/python${py_ver}"
 418                         PYTHON_CFLAGS="-I${py_prefix}/include/python${py_ver}"
 419                         if test -f $py_libdir/config/Makefile -a -f $py_prefix/include/python${py_ver}/Python.h; then
 420                                 py_libs=`grep '^LIBS=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 421                                 py_libc=`grep '^LIBC=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 422                                 py_libm=`grep '^LIBM=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 423                                 py_liblocalmod=`grep '^LOCALMODLIBS=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 424                                 py_libbasemod=`grep '^BASEMODLIBS=' $py_libdir/config/Makefile | sed -e 's/^.*=//'`
 425                                 PYTHON_LIBS="-L$py_libdir/config $py_libs $py_libc $py_libm -lpython$py_ver $py_liblocalmod $py_libbasemod"
 426                                 PYTHON_LIBS=`echo $PYTHON_LIBS | sed -e 's/[ \\t]*/ /g'`
 427                                 AC_MSG_RESULT($py_libdir)
 428                         else
 429                                 binding_python="no"
 430                                 binding_python_reason="$py_libdir/config/Makefile or $py_prefix/include/python${py_ver}/Python.h missing"
 431                         fi
 432
 433                 else
 434                         PYTHON_CFLAGS="`${PYTHONCONFIG} --cflags`"
 435                         PYTHON_LIBS="`${PYTHONCONFIG} --ldflags`"
 436                 fi
 437         else
 438                 binding_python="no"
 439                 binding_python_reason="python executable missing"
 440         fi
 441 fi
 442 if test "x${binding_python}" = xyes ; then
 443         AC_DEFINE(USE_BINDING_PYTHON, 1, [Build with binding python])
 444 fi
 445 AC_SUBST(PYTHON_CFLAGS)
 446 AC_SUBST(PYTHON_LIBS)
 447 AM_CONDITIONAL(BINDING_PYTHON, test "x${binding_python}" = "xyes")
 448
 449 # dbus
 450 AC_ARG_ENABLE(binding-dbus,   [  --disable-binding-dbus               don't create binding dbus], binding_dbus=$enableval;binding_dbus_reason="configure parameter")
 451 if test "x${binding_dbus}" = "xyes" ; then
 452         PKG_CHECK_MODULES(DBUS, [dbus-glib-1], ,binding_dbus=no)
 453 fi
 454 if test "x${binding_dbus}" = "xyes" ; then
 455         AC_DEFINE(USE_BINDING_DBUS, 1, [Build with binding dbus])
 456 fi
 457 AC_SUBST(DBUS_CFLAGS)
 458 AC_SUBST(DBUS_LIBS)
 459 AM_CONDITIONAL(BINDING_DBUS, test "x${binding_dbus}" = "xyes")
 460
 461 # svg
 462 AC_ARG_ENABLE(svg, [  --disable-svg        disable Scalable Vector Graphics], enable_svg=$enableval, enable_svg=yes)
 463 AC_ARG_ENABLE(svg2png, [  --disable-svg2png        disable conversion of svgs to pngs], enable_svg2png=$enableval, enable_svg2png=yes)
 464 AC_ARG_ENABLE(svg2png-scaling, [  --enable-svg2png-scaling   enable conversion of svgs to pngs with specified sizes], SVG2PNG_SCALES=$enableval, SVG2PNG_SCALES="8 16 32 48 96")
 465 AC_ARG_ENABLE(svg2png-scaling-flag, [  --enable-svg2png-scaling-flag   enable conversion of flag svgs to pngs with specified sizes], SVG2PNG_SCALES_FLAG=$enableval, SVG2PNG_SCALES_FLAG="")
 466 AC_ARG_ENABLE(svg2png-scaling-nav, [  --enable-svg2png-scaling-nav   enable conversion of nav svgs to pngs with specified sizes], SVG2PNG_SCALES_NAV=$enableval, SVG2PNG_SCALES_NAV="")
 467 AC_ARG_WITH(svg2png-use-convert, [  --with-svg2png-use-convert   use imagemagick's convert for png creation], SVG2PNG_CONVERTER="convert")
 468 AC_ARG_WITH(svg2png-use-rsvg-convert, [  --with-svg2png-use-rsvg-convert   use librsvg's rsvg-convert for png creation], SVG2PNG_CONVERTER="rsvg-convert")
 469 AC_ARG_WITH(svg2png-use-inkscape, [  --with-svg2png-use-inkscape   use inkscapes internal convert routines for png creation], SVG2PNG_CONVERTER="inkscape")
 470 AC_ARG_WITH(svg2png-use-ksvgtopng4, [  --with-svg2png-use-ksvgtopng4   use kde4's ksvgtopng4 for png creation], SVG2PNG_CONVERTER="ksvgtopng4")
 471 AC_ARG_WITH(svg2png-use-ksvgtopng, [  --with-svg2png-use-ksvgtopng   use kde3's convert for png creation], SVG2PNG_CONVERTER="ksvgtopng")
 472 if test "x${enable_svg2png}" = "xyes" ; then
 473     if test "x${SVG2PNG_CONVERTER}" = "x"; then
 474         SVG2PNG_CONVERTER="ksvgtopng ksvgtopng4 rsvg-convert inkscape convert"
 475     fi
 476     AC_PATH_PROGS([SVG2PNG], ${SVG2PNG_CONVERTER}, [none])
 477     if test "x${SVG2PNG}" = "xnone"; then
 478         enable_svg2png="no"
 479     fi
 480 fi
 481 AC_SUBST(SVG2PNG)
 482 AC_SUBST(SVG2PNG_SCALES)
 483 AC_SUBST(SVG2PNG_SCALES_FLAG)
 484 AC_SUBST(SVG2PNG_SCALES_NAV)
 485 AM_CONDITIONAL(USE_SVG2PNG_SCALES, test "x${SVG2PNG_SCALES}" != "xyes" -a "x${SVG2PNG_SCALES}" != "x")
 486 AM_CONDITIONAL(USE_SVG2PNG_SCALES_FLAG, test "x${SVG2PNG_SCALES_FLAG}" != "xyes" -a "x${SVG2PNG_SCALES_FLAG}" != "x")
 487 AM_CONDITIONAL(USE_SVG2PNG_SCALES_NAV, test "x${SVG2PNG_SCALES_NAV}" != "xyes" -a "x${SVG2PNG_SCALES_NAV}" != "x")
 488 AM_CONDITIONAL(USE_SVG2PNG, test "x${enable_svg2png}" = "xyes")
 489 AM_CONDITIONAL(USE_SVG, test "x${enable_svg}" = "xyes")
 490
 491 # NLS
 492
 493 AC_ARG_ENABLE(nls,
 494   [  --disable-nls        disable Native Language Support ( gettext/libintl )],
 495    enable_nls=$enableval, enable_nls=yes)
 496
 497
 498 INTLIBS=""
 499 MOFILES=""
 500 POFILES=""
 501 POIFILES=""
 502 LINGUAS=""
 503
 504 if test "x$enable_nls" = "xyes"; then
 505
 506   AC_CHECK_FUNC(gettext, [HAVEGETTEXT="yes"]
 507              AC_CHECK_LIB(intl, gettext, [INTLIBS="-lintl" HAVEGETTEXT="yes"],
 508                          INTLIBS="" ))
 509
 510   AC_CHECK_PROG(XGETTEXT, xgettext, xgettext)
 511   AC_CHECK_PROG(MSGMERGE, msgmerge, msgmerge)
 512   AC_CHECK_PROG(MSGFMT, msgfmt, msgfmt)
 513
 514   if test "$XGETTEXT" != ""; then
 515     if $XGETTEXT --help 2>&1 | grep illegal >/dev/null ; then
 516         echo "xgettext isn't GNU version"
 517         XGETTEXT=""
 518     fi
 519   fi
 520
 521   if test "$XGETTEXT" != "" -a "$HAVEGETTEXT" != ""; then
 522      PO=""
 523      if test "$LINGUAS" = ""; then
 524            ling=` (cd $srcdir/po; /bin/ls *.po.in) `
 525            for l in $ling; do
 526                 lcode=`basename $l .po.in`
 527                 LINGUAS="$LINGUAS$lcode "
 528            done
 529     fi
 530     AC_DEFINE(ENABLE_NLS, [1], [NLS Please])
 531     echo "xgettext and gettext() exist; will build i18n support for $LINGUAS"
 532   else
 533    LINGUAS=""
 534    PO=""
 535    echo "xgettext and libintl.a don't both exist; will not build i18n support"
 536    enable_nls = no
 537  fi
 538  for lang in $LINGUAS; do
 539     MOFILES="$MOFILES $lang.mo"
 540  done
 541  for lang in $LINGUAS; do
 542     POFILES="$POFILES $lang.po"
 543  done
 544  for lang in $LINGUAS; do
 545     POIFILES="$POIFILES $lang.po.in"
 546  done
 547
 548 AC_SUBST(INTLIBS)
 549 AC_SUBST(MOFILES)
 550 AC_SUBST(POFILES)
 551 AC_SUBST(POIFILES)
 552 AM_GNU_GETTEXT_VERSION
 553 AM_GNU_GETTEXT(no-libtool, need-ngettext, \$(top_builddir)/intl/)
 554 AC_SUBST(LIBINTL)
 555 AC_SUBST(LTLIBINTL)
 556 if test x"$LIBINTL" != "x" ;then
 557         CFLAGS="$CFLAGS -I\$(top_builddir)/intl/"
 558 fi
 559
 560 fi
 561 AM_CONDITIONAL(ENABLE_NLS, [test "x$enable_nls" = "xyes"])
 562 AC_CHECK_HEADER(
 563         byteswap.h,
 564         AC_DEFINE(
 565                 [HAVE_BYTESWAP_H],
 566                 [1],
 567                 [Define to 1 if you have byteswap.h],
 568                 )
 569                 ,
 570 )
 571
 572 PACKAGE=navit
 573 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE")
 574 AC_DEFINE_UNQUOTED(VERSION, "$VERSION")
 575 AC_SUBST(PACKAGE)
 576 AC_SUBST(VERSION)
 577
 578 AC_CHECK_HEADER(wordexp.h,wordexp_h=yes,wordexp_h=no;NAVIT_CFLAGS="$NAVIT_CFLAGS -I\$(top_srcdir)/navit/support/wordexp";NAVIT_LIBS="$NAVIT_LIBS -L\$(top_builddir)/navit/support/wordexp -lsupport_wordexp")
 579 AM_CONDITIONAL(SUPPORT_WORDEXP, [test "x$wordexp_h" = "xno"])
 580
 581 AC_CANONICAL_HOST
 582 win32=no
 583 win32ce=no
 584 case $host_os in
 585 wince)
 586         win32=yes
 587         win32ce=yes
 588         AC_DEFINE(HAVE_API_WIN32_BASE, 1, [Have Windows Base API])
 589         AC_DEFINE(HAVE_API_WIN32_CE, 1, [Have Windows CE API])
 590         gui_win32=yes; gui_win32_reason="host_os is wince"
 591         graphics_win32=yes; graphics_win32_reason="host_os is wince"
 592         vehicle_wince=yes; vehcile_wince_reason="host_os is wince"
 593         ;;
 594 mingw32)
 595         win32=yes
 596         AC_DEFINE(HAVE_API_WIN32_BASE, 1, [Have Windows Base API])
 597         AC_DEFINE(HAVE_API_WIN32, 1, [Have Windows API])
 598         gui_win32=yes; gui_win32_reason="host_os is mingw32"
 599         graphics_win32=yes; graphics_win32_reason="host_os is mingw32"
 600 esac
 601 if test "x$win32" = "xyes"
 602 then
 603         NAVIT_CFLAGS="$NAVIT_CFLAGS -I\$(top_srcdir)/navit/support/win32"
 604         NAVIT_LIBS="$NAVIT_LIBS -L\$(top_builddir)/navit/support/win32 -lsupport_win32"
 605 fi
 606 AM_CONDITIONAL(SUPPORT_WIN32, [test "x$win32" = "xyes"])
 607 AM_CONDITIONAL(SUPPORT_WIN32CE, [test "x$win32ce" = "xyes"])
 608
 609 LIBS="$LIBS -lm"
 610 if test "$win32" == "no"; then
 611         LIBS="$LIBS -rdynamic"
 612 fi
 613
 614 support_libc=no
 615 AC_ARG_ENABLE(support_libc, [  --enable-support-libc enable builtin mini libc ], support_libc=$enableval)
 616 AM_CONDITIONAL(SUPPORT_LIBC, [test "x$support_libc" = "xyes"])
 617 if test "x$support_libc" = "xyes"; then
 618         CFLAGS="$CFLAGS -I\$(top_srcdir)/navit/support/libc"
 619 fi
 620
 621 ## graphics
 622 # gd
 623 AC_ARG_ENABLE(graphics-gd, [  --enable-graphics-gd                enable graphics type gd], graphics_gd=$enableval;graphics_gd_reason="configure parameter")
 624 if test "x${graphics_gd}" = "xyes" ; then
 625         if test -z "$GDLIB_CONFIG"; then
 626             AC_PATH_PROG([GDLIB_CONFIG], [gdlib-config], [])
 627         fi
 628         AC_MSG_CHECKING([for gdlib with $GDLIB_CONFIG])
 629         if test ! -x "$GDLIB_CONFIG"; then
 630             if test "x${GDLIB_CONFIG}" = "x" ; then
 631                  graphics_gd_reason="$GDLIB_CONFIG not executable"
 632             else
 633                  graphics_gd_reason="gdlib-config missing"
 634             fi
 635             graphics_gd=no
 636             AC_MSG_RESULT([no])
 637         else
 638             GD_CFLAGS="-I`$GDLIB_CONFIG --includedir`"
 639             GD_LIBS="-L`$GDLIB_CONFIG --libdir` -lgd `$GDLIB_CONFIG --libs`"
 640             AC_SUBST(GD_CFLAGS)
 641             AC_SUBST(GD_LIBS)
 642             AC_MSG_RESULT([yes])
 643         fi
 644 fi
 645 AM_CONDITIONAL(GRAPHICS_GD, test "x${graphics_gd}" = "xyes")
 646 # gtk_drawing_area
 647 AC_ARG_ENABLE(graphics-gtk-drawing-area, [  --disable-graphics-gtk-drawing-area disable graphics type gtk_drawing_area], graphics_gtk_drawing_area=$enableval;graphics_gtk_drawing_area_reason="configure parameter")
 648 AM_CONDITIONAL(GRAPHICS_GTK_DRAWING_AREA, [test "x${graphics_gtk_drawing_area}" = "xyes"])
 649 # win32
 650 AC_ARG_ENABLE(graphics-win32, [  --disable-graphics-win32            disable graphics type win32], graphics_win32=$enableval;graphics_win32_reason="configure parameter")
 651 AM_CONDITIONAL(GRAPHICS_WIN32, test "x${graphics_win32}" = "xyes")
 652 # qt_qpainter
 653 AC_ARG_ENABLE(graphics-qt-qpainter, [  --disable-graphics-qt-qpainter      disable graphics type qt-qpainter], graphics_qt_qpainter=$enableval;graphics_qt_qpainter_reason="configure parameter")
 654 if test "x${graphics_qt_qpainter}" = "xyes" -a "x${QT_GUI_CFLAGS}" = "x" -a "x${QT_GUI_LIBS}" = "x"; then
 655         PKG_CHECK_MODULES(QT_GUI, [QtGui QtCore], ,graphics_qt_qpainter=no,graphics_qt_qpainter_reason="Packages QtGui and/or QtCore missing")
 656         if test "x${graphics_qt_qpainter}" = "xno"; then
 657                 PKG_CHECK_MODULES(QT_GUI, [qt-mt],graphics_qt_qpainter=yes,graphics_qt_qpainter_reason="Package qt-mt present")
 658         fi
 659 fi
 660 if test "x${graphics_qt_qpainter}" = "xyes" ; then
 661         AC_DEFINE(USE_GRAPICS_QT_QPAINTER, 1, [Build with graphics qt_qpainter])
 662         MOC=`$PKGCONFIG QtGui --variable=moc_location`
 663         if test "x${MOC}" = "x"; then
 664                 AC_CHECK_PROG(MOC, moc, moc)
 665         fi
 666         AC_SUBST(MOC)
 667 fi
 668 AC_SUBST(QT_GUI_CFLAGS)
 669 AC_SUBST(QT_GUI_LIBS)
 670 AM_CONDITIONAL(GRAPHICS_QT_QPAINTER, test "x${graphics_qt_qpainter}" = "xyes")
 671
 672 ## gui
 673 # gtk
 674 AC_ARG_ENABLE(gui-gtk, [  --disable-gui-gtk                   disable gui type gtk ], gui_gtk=$enableval)
 675 AM_CONDITIONAL(GUI_GTK, [test "x${gui_gtk}" = "xyes"])
 676 # internal
 677 AC_ARG_ENABLE(gui-internal, [  --disable-gui-internal              disable gui type internal], gui_internal=$enableval;gui_internal_reason="configure parameter")
 678 AM_CONDITIONAL(GUI_INTERNAL, test "x${gui_internal}" = "xyes")
 679 # win32
 680 AC_ARG_ENABLE(gui-win32, [  --disable-gui-win32                 disable gui type win32], gui_win32=$enableval;gui_win32_reason="configure parameter")
 681 AM_CONDITIONAL(GUI_WIN32, test "x${gui_win32}" = "xyes")
 682
 683 ## speech
 684 # cmdline
 685 AC_ARG_ENABLE(speech-cmdline, [  --disable-speech-cmdline            disable speech type cmdline], speech_cmdline=$enableval;speech_cmdline_reason="configure parameter")
 686 AM_CONDITIONAL(SPEECH_CMDLINE, test "x${speech_cmdline}" = "xyes")
 687 # cmdline
 688 AC_ARG_ENABLE(speech-speechd, [  --disable-speech-speech-dispatcher  disable speech type speech-dispatcher], speech_speech_dispatcher=$enableval;speech_speech_dispatcher_reason="configure parameter")
 689 if test "x$speech_speech_dispatcher" = "xyes"; then
 690         AC_CHECK_HEADER(libspeechd.h, AC_DEFINE([HAVE_LIBSPEECHD],[],Define to 1 if you have the <libspeechd.h> header file.) SPEECHD_LIBS="-lspeechd",  speech_speech_dispatcher=no; speech_speech_dispatcher_reason="libspeechd.h missing")
 691 fi
 692 AC_SUBST(SPEECHD_CFLAGS)
 693 AC_SUBST(SPEECHD_LIBS)
 694 AM_CONDITIONAL(SPEECH_SPEECH_DISPATCHER, test "x${speech_speech_dispatcher}" = "xyes")
 695
 696 ## vehicle
 697 # demo
 698 AC_ARG_ENABLE(vehicle-demo, [  --disable-vehicle-demo              disable vehicle type demo], vehicle_demo=$enableval;vehicle_demo_reason="configure parameter")
 699 AM_CONDITIONAL(VEHICLE_DEMO, test "x${vehicle_demo}" = "xyes")
 700 # file
 701 AC_ARG_ENABLE(vehicle-file, [  --disable-vehicle-file              disable vehicle type file], vehicle_file=$enableval;vehicle_file_reason="configure parameter")
 702 AM_CONDITIONAL(VEHICLE_FILE, test "x${vehicle_file}" = "xyes")
 703 # gpsd
 704 AC_ARG_ENABLE(vehicle-gpsd, [  --disable-vehicle-gpsd              disable vehicle type gpsd], vehicle_gpsd=$enableval;vehicle_gpsd_reason="configure parameter")
 705 if test "x${vehicle_gpsd}" = xyes
 706 then
 707         AC_CHECK_HEADER(gps.h, AC_DEFINE([HAVE_LIBGPS],[],Define to 1 if you have the <gps.h> header file.) GPSD_LIBS="-lgps", vehicle_gpsd=no; vehicle_gpsd_reason="no gps.h" )
 708 fi
 709 AC_SUBST(GPSD_CFLAGS)
 710 AC_SUBST(GPSD_LIBS)
 711 AM_CONDITIONAL(VEHICLE_GPSD, [test "x${vehicle_gpsd}" = "xyes"])
 712 # gypsy
 713 AC_ARG_ENABLE(vehicle-gypsy,[  --disable-vehicle-gypsy             disable vehicle type gypsy], vehicle_gypsy=$enableval;vehicle_gypsy_reason="configure parameter")
 714 if test "x${vehicle_gypsy}" = "xyes"
 715 then
 716         PKG_CHECK_MODULES(GYPSY, gypsy, ,vehicle_gypsy=no;vehicle_gypsy_reason="package gypsy missing")
 717 fi
 718 AC_SUBST(GYPSY_CFLAGS)
 719 AC_SUBST(GYPSY_LIBS)
 720 AM_CONDITIONAL(VEHICLE_GYPSY, test "x${vehicle_gypsy}" = "xyes")
 721 # wince
 722 AC_ARG_ENABLE(vehicle-wince, [  --disable-vehicle-wince             disable vehicle type wince], vehicle_wince=$enableval;vehicle_wince_reason="configure parameter")
 723 AM_CONDITIONAL(VEHICLE_WINCE, test "x${vehicle_wince}" = "xyes")
 724
 725 NAVIT_CFLAGS="$NAVIT_CFLAGS $GLIB_CFLAGS $GMODULE_CFLAGS"
 726 NAVIT_LIBS="$NAVIT_LIBS $GLIB_LIBS $GMODULE_LIBS $LIBINTL"
 727 AC_SUBST(NAVIT_CFLAGS)
 728 AC_SUBST(NAVIT_LIBS)
 729 AC_SUBST(WINDRES)
 730
 731 AC_CONFIG_FILES([
 732 Makefile
 733 navit/Makefile
 734 navit/binding/Makefile
 735 navit/binding/python/Makefile
 736 navit/binding/dbus/Makefile
 737 navit/map/Makefile
 738 navit/map/mg/Makefile
 739 navit/map/textfile/Makefile
 740 navit/map/shapefile/Makefile
 741 navit/map/binfile/Makefile
 742 navit/map/garmin/Makefile
 743 navit/map/poi_geodownload/Makefile
 744 navit/map/poi_geodownload/libmdb/Makefile
 745 navit/map/poi_geodownload/libmdb/include/Makefile
 746 navit/fib-1.1/Makefile
 747 navit/font/Makefile
 748 navit/font/freetype/Makefile
 749 navit/fonts/Makefile
 750 navit/graphics/Makefile
 751 navit/graphics/gd/Makefile
 752 navit/graphics/gtk_drawing_area/Makefile
 753 navit/graphics/opengl/Makefile
 754 navit/graphics/null/Makefile
 755 navit/graphics/sdl/Makefile
 756 navit/graphics/qt_qpainter/Makefile
 757 navit/graphics/win32/Makefile
 758 navit/gui/Makefile
 759 navit/gui/gtk/Makefile
 760 navit/gui/internal/Makefile
 761 navit/gui/win32/Makefile
 762 navit/osd/Makefile
 763 navit/osd/core/Makefile
 764 navit/speech/Makefile
 765 navit/speech/cmdline/Makefile
 766 navit/speech/speech_dispatcher/Makefile
 767 navit/support/Makefile
 768 navit/support/ezxml/Makefile
 769 navit/support/glib/Makefile
 770 navit/support/libc/Makefile
 771 navit/support/win32/Makefile
 772 navit/support/wordexp/Makefile
 773 navit/support/zlib/Makefile
 774 navit/vehicle/Makefile
 775 navit/vehicle/file/Makefile
 776 navit/vehicle/gpsd/Makefile
 777 navit/vehicle/gypsy/Makefile
 778 navit/vehicle/demo/Makefile
 779 navit/vehicle/wince/Makefile
 780 navit/xpm/Makefile
 781 navit/maps/Makefile
 782 intl/Makefile
 783 po/Makefile
 784 ])
 785 #src/data/garmin_img/Makefile
 786
 787 AC_OUTPUT
 788
 789
 790 echo ""
 791 echo ""
 792 echo "Summary of your installation :"
 793 # FIXME : maybe elaborate missing dependencies
 794 if test x"$sdl" != xyes
 795         then
 796         sdl_failures="(libsdl maybe?) "
 797 fi
 798 if test x"$xmu" != xyes
 799         then
 800         sdl_failures=$sdl_failures"libxmu "
 801 fi
 802 if test x"$glut" != xyes
 803        then
 804         sdl_failures=$sdl_failures"glut "
 805 fi
 806 if test x"$glc" != xyes
 807         then
 808         sdl_failures=$sdl_failures"quesoglc "
 809 fi
 810 if test -z "$sdl_failures"
 811         then
 812         echo "OpenGL gui  : ENABLED, with $CEGUI_LIBS"
 813         else
 814                  echo "OpenGL gui  : DISABLED : you are missing $sdl_failures"
 815 fi
 816 if test x"$enable_hildon" = xyes
 817         then
 818         echo "Maemo/Hildon: ENABLED"
 819         else
 820         echo "Maemo/Hildon: DISABLED"
 821 fi
 822 if test x"${USE_GARMIN}" = xyes
 823         then
 824         if test "x$use_libgarmin" = "xyes"
 825                 then
 826                 echo "Garmin IMG  : ENABLED"
 827                 else
 828                 echo "Garmin IMG  : DISABLED (you don't have libgarmin)"
 829         fi
 830         else
 831                 echo "Garmin IMG  : DISABLED (you requested it)"
 832 fi
 833
 834 if test x"$LIBINTL" = "x" ;then
 835         nls_libs="system gettext support"
 836 else
 837         nls_libs="$LIBINTL"
 838 fi
 839 echo "Plugins:             $plugins ($plugins_reason)"
 840 echo "Postgresql:          $postgresql ($postgresql_reason)"
 841 echo "Samplemap:           $samplemap ($samplemap_reason)"
 842 echo "NLS Support:         $enable_nls ($nls_libs)"
 843 echo "Font renderers:"
 844 echo "  freetype:          $font_freetype ($font_freetype_reason)"
 845 echo "Graphics types:"
 846 echo "  gtk_drawing_area:  $graphics_gtk_drawing_area ($graphics_gtk_drawing_area_reason)"
 847 echo "  qt_qpainter:       $graphics_qt_qpainter ($graphics_qt_qpainter_reason)"
 848 echo "  win32:             $graphics_win32 ($graphics_win32_reason)"
 849 echo "  OpenGL:            $graphics_opengl ($graphics_opengl_reason)"
 850 echo "  gd:                $graphics_gd ($graphics_gd_reason)"
 851 echo "  sdl:               $graphics_sdl ($graphics_sdl_reason)"
 852
 853 echo "GUI types:"
 854 echo "  gtk:               $gui_gtk ($gui_gtk_reason)"
 855 echo "  internal:          $gui_internal ($gui_internal_reason)"
 856 echo "  win32:             $gui_win32 ($gui_win32_reason)"
 857
 858 echo "Bindings:"
 859 echo "  dbus:              $binding_dbus ($binding_dbus_reason)"
 860 echo "  python:            $binding_python ($binding_python_reason)"
 861
 862 echo "Speech types:"
 863 echo "  cmdline:           $speech_cmdline ($speech_cmdline_reason)"
 864 echo "  speech_dispatcher: $speech_speech_dispatcher ($speech_speech_dispatcher_reason)"
 865
 866 echo "Vehicle types:"
 867 echo "  demo:              $vehicle_demo ($vehicle_demo_reason)"
 868 echo "  file:              $vehicle_file ($vehicle_file_reason)"
 869 echo "  gpsd:              $vehicle_gpsd ($vehicle_gpsd_reason)"
 870 echo "  gypsy:             $vehicle_gypsy ($vehicle_gypsy_reason)"
 871 echo "  wince:             $vehicle_wince ($vehicle_wince_reason)"
 872
 873 if  test "x${gtk2_pkgconfig}" != "xyes" -a "x${gui_win32}" != "xyes" -a "x${gui_internal}" != "xyes"
 874 then
 875         echo ""
 876         echo ""
 877         echo "*** WARNING! you have no gui that can be built! ***"
 878         echo "Please install the dependency for at least gtk or sdl gui"
 879         echo "For more details, see the wiki at http://wiki.navit-project.org/"
 880         echo ""
 881         exit 1
 882 fi
 883