git.maemo.org Git - dorian/blob - dorian.pro

   1 QT += webkit xml sql network
   2
   3 INCLUDEPATH += $$PWD \
   4     $$PWD/model \
   5     $$PWD/widgets
   6
   7 SOURCES += \
   8     main.cpp \
   9     mainwindow.cpp \
  10     bookview.cpp \
  11     model/unzip/unzip.c \
  12     model/unzip/ioapi.c \
  13     model/extractzip.cpp \
  14     model/library.cpp \
  15     model/book.cpp \
  16     librarydialog.cpp \
  17     devtools.cpp \
  18     infodialog.cpp \
  19     widgets/translucentbutton.cpp \
  20     settingswindow.cpp \
  21     model/settings.cpp \
  22     bookmarksdialog.cpp \
  23     model/sortedlibrary.cpp \
  24     bookmarkinfodialog.cpp \
  25     widgets/dyalog.cpp \
  26     chaptersdialog.cpp \
  27     widgets/fullscreenwindow.cpp \
  28     trace.cpp \
  29     widgets/toolbuttonbox.cpp \
  30     model/bookfinder.cpp \
  31     widgets/listwindow.cpp \
  32     widgets/progress.cpp \
  33     widgets/adopterwindow.cpp \
  34     platform.cpp \
  35     model/bookdb.cpp \
  36     searchdialog.cpp \
  37     search.cpp \
  38     widgets/flickable.cpp \
  39     widgets/listview.cpp \
  40     searchresultsdialog.cpp
  41
  42 HEADERS += \
  43     mainwindow.h \
  44     bookview.h \
  45     model/opshandler.h \
  46     model/unzip/unzip.h \
  47     model/unzip/ioapi.h \
  48     model/extractzip.h \
  49     model/library.h \
  50     model/book.h \
  51     librarydialog.h \
  52     devtools.h \
  53     infodialog.h \
  54     widgets/translucentbutton.h \
  55     settingswindow.h \
  56     model/settings.h \
  57     bookmarksdialog.h \
  58     model/xmlerrorhandler.h \
  59     model/containerhandler.h \
  60     model/sortedlibrary.h \
  61     model/ncxhandler.h \
  62     bookmarkinfodialog.h \
  63     widgets/dyalog.h \
  64     chaptersdialog.h \
  65     widgets/fullscreenwindow.h \
  66     trace.h \
  67     widgets/toolbuttonbox.h \
  68     model/bookfinder.h \
  69     widgets/listwindow.h \
  70     widgets/progress.h \
  71     widgets/adopterwindow.h \
  72     widgets/listview.h \
  73     model/xmlhandler.h \
  74     platform.h \
  75     model/bookdb.h \
  76     searchdialog.h \
  77     search.h \
  78     widgets/flickable.h \
  79     searchresultsdialog.h
  80
  81 RESOURCES += \
  82     dorian.qrc
  83
  84 OTHER_FILES += \
  85     TODO.txt \
  86     pkg/acknowledgements.txt \
  87     pkg/maemo/postinst \
  88     pkg/maemo/dorian.desktop \
  89     pkg/maemo/control \
  90     pkg/maemo/changelog \
  91     pkg/maemo/build.sh \
  92     styles/night.css \
  93     pkg/changelog \
  94     pkg/maemo/build-scratchbox.sh \
  95     styles/sand.css \
  96     styles/default.css \
  97     pkg/version.txt \
  98     styles/sand.js \
  99     styles/night.js \
 100     styles/default.js \
 101     styles/day.js \
 102     www/index.html \
 103     pkg/maemo/autobuild.sh \
 104     pkg/maemo/autobuild-scratchbox.sh \
 105     LICENSE.txt \
 106     pkg/symbian/book.svg
 107
 108 DEFINES += \
 109     USE_FILE32API
 110
 111 !symbian {
 112     DEFINES += DORIAN_TEST_MODEL
 113     include(model/modeltest/modeltest.pri)
 114 }
 115
 116 unix {
 117     symbian {
 118     } else {
 119         LIBS += -lz
 120     }
 121 }
 122
 123 win32 {
 124     DEFINES += ZLIB_WINAPI
 125     INCLUDEPATH += $$PWD/model/zlib
 126     LIBS += pkg/win32/zlibstat.lib
 127 }
 128
 129 symbian {
 130     ICON = $$PWD/pkg/symbian/book.svgt
 131     TARGET.UID3 = 0xEA633557
 132     TARGET.CAPABILITY = NetworkServices
 133     # FIXME: Include path to OpenC ZLIB?
 134     INCLUDEPATH += c:/Qt/4.7.0/src/3rdparty/zlib
 135     HEADERS += widgets/flickcharm.h
 136     SOURCES += widgets/flickcharm.cpp
 137 }
 138
 139 maemo5 {
 140     QT += maemo5 dbus
 141     isEmpty(PREFIX) {
 142         PREFIX = /usr
 143     }
 144     BINDIR = $$PREFIX/bin
 145     DATADIR =$$PREFIX/share
 146     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
 147
 148     # For "make install"
 149
 150     INSTALLS += target desktop icon48 iconscalable
 151
 152     target.path = $$BINDIR
 153
 154     desktop.path = $$DATADIR/applications/hildon
 155     desktop.files += pkg/maemo/dorian.desktop
 156
 157     icon48.path = $$DATADIR/icons/hicolor/48x48/hildon
 158     icon48.files += pkg/maemo/icon-48/dorian.png
 159
 160     iconscalable.path = $$DATADIR/icons/hicolor/scalable/hildon
 161     iconscalable.files += pkg/maemo/icon-scalable/dorian.png
 162 }