git.maemo.org Git - dorian/blob - dorian.pro

   1 QT += webkit xml
   2
   3 SOURCES += \
   4     main.cpp \
   5     mainwindow.cpp \
   6     bookview.cpp \
   7     unzip/unzip.c \
   8     unzip/ioapi.c \
   9     extractzip.cpp \
  10     library.cpp \
  11     book.cpp \
  12     librarydialog.cpp \
  13     devtools.cpp \
  14     infodialog.cpp \
  15     translucentbutton.cpp \
  16     settingswindow.cpp \
  17     settings.cpp \
  18     bookmarksdialog.cpp \
  19     sortedlibrary.cpp \
  20     bookmarkinfodialog.cpp \
  21     dialog.cpp \
  22     chaptersdialog.cpp
  23
  24 HEADERS += \
  25     mainwindow.h \
  26     bookview.h \
  27     selectionsuppressor.h \
  28     opshandler.h \
  29     unzip/unzip.h \
  30     unzip/ioapi.h \
  31     extractzip.h \
  32     library.h \
  33     book.h \
  34     librarydialog.h \
  35     devtools.h \
  36     infodialog.h \
  37     translucentbutton.h \
  38     settingswindow.h \
  39     settings.h \
  40     bookmarksdialog.h \
  41     xmlerrorhandler.h \
  42     containerhandler.h \
  43     sortedlibrary.h \
  44     ncxhandler.h \
  45     bookmarkinfodialog.h \
  46     dialog.h \
  47     chaptersdialog.h
  48
  49 RESOURCES += \
  50     dorian.qrc
  51
  52 OTHER_FILES += \
  53     TODO.txt \
  54     pkg/acknowledgements.txt \
  55     pkg/maemo/postinst \
  56     pkg/maemo/dorian.desktop \
  57     pkg/maemo/control \
  58     pkg/maemo/changelog \
  59     pkg/maemo/build.sh \
  60     styles/night.css \
  61     pkg/changelog \
  62     pkg/maemo/build-scratchbox.sh \
  63     styles/sand.css \
  64     styles/default.css \
  65     pkg/version.txt \
  66     styles/sand.js \
  67     styles/night.js \
  68     styles/default.js \
  69     styles/day.js \
  70     www/index.html
  71
  72 DEFINES += \
  73     USE_FILE32API \
  74     DORIAN_TEST_MODEL
  75
  76 include(modeltest/modeltest.pri)
  77
  78 unix {
  79     LIBS += -lz
  80 }
  81 windows {
  82     # FIXME: Build zlib, too
  83 }
  84 maemo5 {
  85     QT += maemo5
  86     isEmpty(PREFIX) {
  87         PREFIX = /usr
  88     }
  89     BINDIR = $$PREFIX/bin
  90     DATADIR =$$PREFIX/share
  91     DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
  92
  93     # For "make install"
  94
  95     INSTALLS += target desktop icon48 iconscalable
  96
  97     target.path = $$BINDIR
  98
  99     desktop.path = $$DATADIR/applications/hildon
 100     desktop.files += pkg/maemo/dorian.desktop
 101
 102     icon48.path = $$DATADIR/icons/hicolor/48x48/hildon
 103     icon48.files += pkg/maemo/icon-48/dorian.png
 104
 105     iconscalable.path = $$DATADIR/icons/hicolor/scalable/hildon
 106     iconscalable.files += pkg/maemo/icon-scalable/dorian.png
 107 }