git.maemo.org Git - cinaest/blob - src/imdb/imdb-plaintext-downloader.vala

   1 using GLib;
   2
   3 class IMDbDownloadServer : Object, IMDbDownloader {
   4         MainLoop loop;
   5         Cancellable cancellable;
   6         bool running;
   7         uint source_id;
   8         unowned IMDbSqlite sqlite;
   9         string[] mirrors = {
  10                 "ftp.fu-berlin.de/pub/misc/movies/database/",
  11                 "ftp.funet.fi/pub/mirrors/ftp.imdb.com/pub/",
  12                 "ftp.sunet.se/pub/tv+movies/imdb/"
  13         };
  14         string url;
  15         int flags;
  16         int percent_finished;
  17
  18         delegate void ParseLineFunction (string line);
  19
  20         construct {
  21                 loop = new MainLoop (null, false);
  22                 cancellable = new Cancellable ();
  23         }
  24
  25         // IMDbDownloader implementation
  26
  27         public void download (string mirror, int _flags) throws DBus.Error {
  28                 if (running) {
  29                         stdout.printf ("Download in progress. Abort.\n");
  30                         return;
  31                 }
  32                 running = true;
  33                 if (source_id != 0) {
  34                         Source.remove (source_id);
  35                 }
  36
  37                 stdout.printf ("Download started (%x).", flags);
  38                 progress (0);
  39                 url = "ftp://anonymous@" + mirror;
  40                 flags = _flags;
  41                 try {
  42                         Thread.create(download_thread, false);
  43                 } catch (ThreadError e) {
  44                         critical ("Failed to create download thread\n");
  45                         return;
  46                 }
  47         }
  48
  49         public void cancel () throws DBus.Error {
  50                 cancellable.cancel ();
  51         }
  52
  53         public string[] get_mirrors () throws DBus.Error {
  54                 return mirrors;
  55         }
  56
  57         // Private methods
  58
  59         private void* download_thread () {
  60                 description_changed ("Connecting to FTP ...");
  61                 progress (0);
  62                 percent_finished = 0;
  63
  64                 var cache_dir = Path.build_filename (Environment.get_user_cache_dir (), "cinaest");
  65                 DirUtils.create_with_parents (cache_dir, 0770);
  66
  67                 var _sqlite = new IMDbSqlite (Path.build_filename (cache_dir, "imdb.db"));
  68                 sqlite = _sqlite;
  69                 _sqlite.clear ();
  70
  71                 try {
  72                         var movie_parser = new MovieLineParser (sqlite);
  73                         var genre_parser = new GenreLineParser (sqlite);
  74                         var rating_parser = new RatingLineParser (sqlite);
  75                         var aka_parser = new AkaLineParser (sqlite);
  76                         var plot_parser = new PlotLineParser (sqlite);
  77
  78                         var downloader = new IMDbFtpDownloader (cancellable);
  79                         downloader.progress_changed.connect (on_progress_changed);
  80
  81                         if (MOVIES in flags) {
  82                                 description_changed ("Downloading movie list ...");
  83                                 downloader.download (url + "movies.list.gz", movie_parser);
  84                         }
  85                         percent_finished = 20;
  86                         if (GENRES in flags) {
  87                                 description_changed ("Downloading genre data ...");
  88                                 downloader.download (url + "genres.list.gz", genre_parser);
  89                         }
  90                         percent_finished = 40;
  91                         if (RATINGS in flags) {
  92                                 description_changed ("Downloading rating data ...");
  93                                 downloader.download (url + "ratings.list.gz", rating_parser);
  94                         }
  95                         percent_finished = 60;
  96                         if (AKAS in flags) {
  97                                 description_changed ("Downloading alternative titles ...");
  98                                 downloader.download (url + "aka-titles.list.gz", aka_parser);
  99                         }
 100                         percent_finished = 80;
 101                         if (PLOTS in flags) {
 102                                 description_changed ("Downloading plots ...");
 103                                 print ("Downloading Plots");
 104                                 downloader.download (url + "plot.list.gz", plot_parser);
 105                         }
 106                 } catch (Error e2) {
 107                         if (e2 is IOError.CANCELLED)
 108                                 stdout.printf ("Download cancelled.\n");
 109                         else
 110                                 warning ("Failed to open/read stream: %s\n", e2.message);
 111                 }
 112
 113                 description_changed ("Creating indices ...");
 114                 if (AKAS in flags)
 115                         sqlite.create_aka_index ();
 116                 if (MOVIES in flags)
 117                         sqlite.create_votes_index ();
 118
 119                 if (!cancellable.is_cancelled ()) {
 120                         stdout.printf ("Download complete.\n");
 121                         progress (100);
 122                 }
 123
 124                 sqlite = null;
 125                 running = false;
 126
 127                 timeout_quit ();
 128
 129                 return null;
 130         }
 131
 132         private void on_progress_changed (int percent) {
 133                 progress (percent_finished + percent / 5);
 134         }
 135
 136         private void timeout_quit () {
 137                 source_id = Timeout.add (3000, quit);
 138         }
 139
 140         private bool quit () {
 141                 loop.quit ();
 142
 143                 // One-shot only
 144                 return false;
 145         }
 146
 147         public void run () {
 148                 loop.run ();
 149         }
 150
 151         public static void main () {
 152                 Curl.global_init (Curl.GLOBAL_DEFAULT);
 153
 154                 try {
 155                         var conn = DBus.Bus.get (DBus.BusType.SESSION);
 156                         dynamic DBus.Object bus = conn.get_object ("org.freedesktop.DBus",
 157                                                                    "/org/freedesktop/DBus",
 158                                                                    "org.freedesktop.DBus");
 159
 160                         // Try to register service in session bus
 161                         uint request_name_result = bus.request_name (DBUS_SERVICE, (uint) 0);
 162
 163                         if (request_name_result == DBus.RequestNameReply.PRIMARY_OWNER) {
 164                                 // Start server
 165                                 var server = new IMDbDownloadServer ();
 166                                 conn.register_object (DBUS_OBJECT, server);
 167
 168                                 server.run ();
 169                         } else {
 170                                 critical ("Service \"org.maemo.cinaest.IMDb\" already registered. Abort.\n");
 171                         }
 172                 } catch (Error e) {
 173                         critical ("Oops: %s\n", e.message);
 174                 }
 175
 176                 Curl.global_cleanup ();
 177         }
 178 }