git.maemo.org Git - cinaest/blob - src/imdb/imdb-plaintext-downloader.vala

   1 using GLib;
   2
   3 class IMDbDownloadServer : Object, IMDbDownloader {
   4         MainLoop loop;
   5         Cancellable cancellable;
   6         bool running;
   7         uint source_id;
   8         unowned IMDbSqlite sqlite;
   9         string[] mirrors = {
  10                 "ftp.fu-berlin.de/pub/misc/movies/database/",
  11                 "ftp.funet.fi/pub/mirrors/ftp.imdb.com/pub/",
  12                 "ftp.sunet.se/pub/tv+movies/imdb/"
  13         };
  14         string url;
  15         int flags;
  16         int percent_finished;
  17
  18         delegate void ParseLineFunction (string line);
  19
  20         construct {
  21                 loop = new MainLoop (null, false);
  22                 cancellable = new Cancellable ();
  23         }
  24
  25         // IMDbDownloader implementation
  26
  27         public void download (string mirror, int _flags) throws DBus.Error {
  28                 if (running) {
  29                         stdout.printf ("Download in progress. Abort.\n");
  30                         return;
  31                 }
  32                 running = true;
  33                 if (source_id != 0) {
  34                         Source.remove (source_id);
  35                 }
  36
  37                 stdout.printf ("Download started (%x).", flags);
  38                 progress (0);
  39                 url = "ftp://anonymous@" + mirror;
  40                 flags = _flags;
  41                 try {
  42                         Thread.create(download_thread, false);
  43                 } catch (ThreadError e) {
  44                         critical ("Failed to create download thread\n");
  45                         return;
  46                 }
  47         }
  48
  49         public void cancel () throws DBus.Error {
  50                 cancellable.cancel ();
  51         }
  52
  53         public string[] get_mirrors () throws DBus.Error {
  54                 return mirrors;
  55         }
  56
  57         // Private methods
  58
  59         private void* download_thread () {
  60                 description_changed ("Connecting to FTP ...");
  61                 progress (0);
  62                 percent_finished = 0;
  63
  64                 var cache_dir = Path.build_filename (Environment.get_user_cache_dir (), "cinaest");
  65                 DirUtils.create_with_parents (cache_dir, 0770);
  66
  67                 var _sqlite = new IMDbSqlite (Path.build_filename (cache_dir, "imdb.db"));
  68                 sqlite = _sqlite;
  69                 _sqlite.clear ();
  70
  71                 try {
  72                         var movie_parser = new MovieLineParser (sqlite);
  73                         var genre_parser = new GenreLineParser (sqlite);
  74                         var rating_parser = new RatingLineParser (sqlite);
  75                         var aka_parser = new AkaLineParser (sqlite);
  76
  77                         var downloader = new IMDbFtpDownloader (cancellable);
  78                         downloader.progress_changed.connect (on_progress_changed);
  79
  80                         if (MOVIES in flags) {
  81                                 description_changed ("Downloading movie list ...");
  82                                 downloader.download (url + "movies.list.gz", movie_parser);
  83                         }
  84                         percent_finished = 25;
  85                         if (GENRES in flags) {
  86                                 description_changed ("Downloading genre data ...");
  87                                 downloader.download (url + "genres.list.gz", genre_parser);
  88                         }
  89                         percent_finished = 50;
  90                         if (RATINGS in flags) {
  91                                 description_changed ("Downloading rating data ...");
  92                                 downloader.download (url + "ratings.list.gz", rating_parser);
  93                         }
  94                         percent_finished = 75;
  95                         if (AKAS in flags) {
  96                                 description_changed ("Downloading alternative titles ...");
  97                                 downloader.download (url + "aka-titles.list.gz", aka_parser);
  98                         }
  99                 } catch (Error e2) {
 100                         if (e2 is IOError.CANCELLED)
 101                                 stdout.printf ("Download cancelled.\n");
 102                         else
 103                                 warning ("Failed to open/read stream: %s\n", e2.message);
 104                 }
 105
 106                 description_changed ("Creating indices ...");
 107                 if (AKAS in flags)
 108                         sqlite.create_aka_index ();
 109                 if (MOVIES in flags)
 110                         sqlite.create_votes_index ();
 111
 112                 if (!cancellable.is_cancelled ()) {
 113                         stdout.printf ("Download complete.\n");
 114                         progress (100);
 115                 }
 116
 117                 sqlite = null;
 118                 running = false;
 119
 120                 timeout_quit ();
 121
 122                 return null;
 123         }
 124
 125         private void on_progress_changed (int percent) {
 126                 progress (percent_finished + percent / 4);
 127         }
 128
 129         private void timeout_quit () {
 130                 source_id = Timeout.add (3000, quit);
 131         }
 132
 133         private bool quit () {
 134                 loop.quit ();
 135
 136                 // One-shot only
 137                 return false;
 138         }
 139
 140         public void run () {
 141                 loop.run ();
 142         }
 143
 144         public static void main () {
 145                 Curl.global_init (Curl.GLOBAL_DEFAULT);
 146
 147                 try {
 148                         var conn = DBus.Bus.get (DBus.BusType.SESSION);
 149                         dynamic DBus.Object bus = conn.get_object ("org.freedesktop.DBus",
 150                                                                    "/org/freedesktop/DBus",
 151                                                                    "org.freedesktop.DBus");
 152
 153                         // Try to register service in session bus
 154                         uint request_name_result = bus.request_name (DBUS_SERVICE, (uint) 0);
 155
 156                         if (request_name_result == DBus.RequestNameReply.PRIMARY_OWNER) {
 157                                 // Start server
 158                                 var server = new IMDbDownloadServer ();
 159                                 conn.register_object (DBUS_OBJECT, server);
 160
 161                                 server.run ();
 162                         } else {
 163                                 critical ("Service \"org.maemo.cinaest.IMDb\" already registered. Abort.\n");
 164                         }
 165                 } catch (Error e) {
 166                         critical ("Oops: %s\n", e.message);
 167                 }
 168
 169                 Curl.global_cleanup ();
 170         }
 171 }