git.maemo.org Git - cinaest/blob - src/movie-list-window.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 public class MovieListWindow : StackableWindow {
  23         private MovieListMenu menu;
  24         private Hildon.EditToolbar edit_toolbar;
  25         private Hildon.Entry search_field;
  26         private Toolbar search_bar;
  27         private uint source_id;
  28         private MovieListView movie_list;
  29         private MovieFilter filter;
  30         private MovieListStore store;
  31         private Label no_movies;
  32         private bool search_bar_visible;
  33         private MovieWindow movie_window;
  34
  35         public MovieListWindow (MovieSource source) {
  36                 set_title (source.get_description ());
  37
  38                 // View menu
  39                 menu = new MovieListMenu (this);
  40                 menu.source = source;
  41
  42                 set_main_menu (menu);
  43
  44                 // Search bar
  45                 search_field = new Hildon.Entry (SizeType.FINGER_HEIGHT);
  46
  47                 var search_field_item = new ToolItem ();
  48                 search_field_item.set_expand (true);
  49                 search_field_item.add (search_field);
  50
  51                 var icon_theme = Gtk.IconTheme.get_default ();
  52                 var pixbuf = icon_theme.load_icon ("general_close",
  53                                                    48,
  54                                                    Gtk.IconLookupFlags.NO_SVG);
  55                 var close_image = new Image.from_pixbuf (pixbuf);
  56                 var close_button = new ToolButton (close_image, _("Close"));
  57
  58                 search_bar = new Toolbar ();
  59                 search_bar.insert (search_field_item, 0);
  60                 search_bar.insert (close_button, 1);
  61
  62                 add_toolbar (search_bar);
  63
  64                 // Movie list - connected to menu for sorting
  65                 movie_list = new MovieListView ();
  66                 menu.sortable = movie_list.sorted_store;
  67                 store = movie_list.store;
  68                 store.source = source;
  69
  70                 no_movies = new Label (_("No movies"));
  71                 Hildon.helper_set_logical_font (no_movies, "LargeSystemFont");
  72                 Hildon.helper_set_logical_color (no_movies, RcFlags.FG, StateType.NORMAL, "SecondaryTextColor");
  73                 no_movies.set_size_request (-1, 6 * 70);
  74                 no_movies.set_alignment ((float) 0.5, (float) 0.42);
  75
  76                 var vbox = new VBox (false, 0);
  77                 vbox.pack_start (movie_list, true, true, 0);
  78                 vbox.pack_start (no_movies, false, false, 0);
  79
  80                 add (vbox);
  81
  82                 edit_toolbar = new Hildon.EditToolbar.with_text (_("Select movies"), _("Delete"));
  83                 set_edit_toolbar (edit_toolbar);
  84
  85                 // Connect signals
  86                 menu.filter_changed.connect (() => { start_search (); });
  87                 edit_toolbar.button_clicked.connect (on_delete_button_clicked);
  88                 edit_toolbar.arrow_clicked.connect (leave_edit_mode);
  89                 search_field.changed.connect (on_search_field_changed);
  90                 close_button.clicked.connect (on_close_button_clicked);
  91                 key_press_event.connect (on_key_press_event);
  92                 movie_list.movie_activated.connect (on_movie_activated);
  93                 store.search_finished.connect (on_search_finished);
  94
  95                 store.notify["update-running"].connect (on_update_running_changed);
  96
  97                 search_field.set_flags (WidgetFlags.CAN_DEFAULT);
  98                 search_field.grab_default ();
  99
 100                 show_all ();
 101                 edit_toolbar.hide ();
 102                 search_bar_visible = false;
 103                 search_bar.hide ();
 104
 105                 filter = new MovieFilter ();
 106                 menu.filter = filter;
 107                 filter.title = "";
 108                 if (store.start_search (filter)) {
 109                         no_movies.hide ();
 110                 } else {
 111                         movie_list.hide ();
 112                 }
 113         }
 114
 115         public void on_delete_movies_clicked () {
 116                 fullscreen ();
 117                 edit_toolbar.show ();
 118                 movie_list.set_hildon_ui_mode (UIMode.EDIT);
 119
 120                 var selection = movie_list.get_selection ();
 121                 selection.unselect_all ();
 122         }
 123
 124         private void on_delete_button_clicked () {
 125                 var selection = movie_list.get_selection ();
 126                 int count = selection.count_selected_rows ();
 127                 if (count == 0) {
 128                         Banner.show_information (this, null, _("No movies selected"));
 129                         leave_edit_mode ();
 130                         return;
 131                 }
 132
 133                 var dialog = new Note.confirmation (this, _("Delete %d movies?").printf (count));
 134                 var res = dialog.run ();
 135
 136                 if (res == Gtk.ResponseType.OK) {
 137                         weak TreeModel model;
 138                         var rows = selection.get_selected_rows (out model);
 139
 140                         var movies = new List<Movie> ();
 141
 142                         // get selected movies from the store
 143                         foreach (TreePath path in rows) {
 144                                 TreeIter iter;
 145
 146                                 if (model.get_iter (out iter, path)) {
 147                                         Movie movie;
 148
 149                                         model.get (iter, MovieListStore.Columns.MOVIE, out movie);
 150                                         if (movie != null) {
 151                                                 movies.append (movie);
 152                                         }
 153                                 }
 154                         }
 155                         // and remove them
 156                         foreach (Movie movie in movies) {
 157                                 store.remove (movie);
 158                         }
 159
 160                         // Switch to "No movies" label if the store is emptied
 161                         TreeIter iter;
 162                         if (!store.get_iter_first (out iter)) {
 163                                 movie_list.hide ();
 164                                 no_movies.show ();
 165                         }
 166                 }
 167                 dialog.destroy ();
 168                 leave_edit_mode ();
 169         }
 170
 171         private void leave_edit_mode () {
 172                 movie_list.set_hildon_ui_mode (UIMode.NORMAL);
 173                 edit_toolbar.hide ();
 174                 unfullscreen ();
 175         }
 176
 177         private void on_close_button_clicked () {
 178                 search_field.set_text ("");
 179                 search_bar_visible = false;
 180                 search_bar.hide ();
 181         }
 182
 183         private bool on_key_press_event (Widget widget, Gdk.EventKey event) {
 184                 if (event.str != "") {
 185                         if (!search_bar_visible) {
 186                                 search_bar_visible = true;
 187                                 search_bar.show ();
 188                         }
 189                         search_field.grab_focus ();
 190                 }
 191
 192                 return false;
 193         }
 194
 195         private void on_search_field_changed () {
 196                 // With every change we reset the timer to 500ms
 197                 if (source_id != 0) {
 198                         Source.remove (source_id);
 199                 }
 200                 source_id = Timeout.add (500, start_search);
 201         }
 202
 203         private bool start_search () {
 204                 filter.title = search_field.get_text ();
 205                 if (store.start_search (filter)) {
 206                         movie_list.show ();
 207                         no_movies.hide ();
 208                 }
 209
 210                 // One-shot only
 211                 return false;
 212         }
 213
 214         private void on_search_finished (int movies) {
 215                 if (movies > 100) {
 216                         Banner.show_information (this, null, _("More results available - refine search to reduce the dataset"));
 217                 }
 218         }
 219
 220         private void on_movie_activated (Movie movie) {
 221                 if (movie_window != null)
 222                         return;
 223
 224                 movie_window = new MovieWindow.with_movie (movie, store);
 225                 movie_window.destroy.connect (() => { movie_window = null; });
 226                 movie_window.show ();
 227         }
 228
 229         private void on_update_running_changed (GLib.Object source, ParamSpec spec) {
 230                 TreeIter iter;
 231
 232                 Hildon.gtk_window_set_progress_indicator (this, (int) store.update_running);
 233                 // Update finished, but store still empty?
 234                 if (!store.update_running && !store.get_iter_first (out iter)) {
 235                         movie_list.hide ();
 236                         no_movies.show ();
 237                 }
 238         }
 239 }
 240