git.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     engine/engine.cpp \
  14     facebookservice/facebookauthentication.cpp \
  15     facebookservice/facebookcredentials.cpp \
  16     gps/gpsposition.cpp \
  17     map/baselocationitem.cpp \
  18     map/friendgroupitem.cpp \
  19     map/frienditemshandler.cpp \
  20     map/friendlocationitem.cpp \
  21     map/gpslocationitem.cpp \
  22     map/mapengine.cpp \
  23     map/mapfetcher.cpp \
  24     map/mapscene.cpp \
  25     map/mapscroller.cpp \
  26     map/maptile.cpp \
  27     map/maptilerequest.cpp \
  28     map/mapview.cpp \
  29     map/ownlocationitem.cpp \
  30     network/networkaccessmanager.cpp \
  31     network/networkcookiejar.cpp \
  32     network/networkhandler.cpp \
  33     network/networkreply.cpp \
  34     situareservice/imagefetcher.cpp \
  35     situareservice/situareservice.cpp \
  36     ui/updatelocation/texteditautoresizer.cpp \
  37     ui/updatelocation/updatelocationdialog.cpp \
  38     ui/avatarimage.cpp \
  39     ui/friendlistitem.cpp \
  40     ui/friendlistpanel.cpp \
  41     ui/friendlistview.cpp \
  42     ui/imagebutton.cpp \
  43     ui/logindialog.cpp \
  44     ui/mainwindow.cpp \
  45     ui/mapscale.cpp \
  46     ui/panelsidebar.cpp \
  47     ui/panelsliderbar.cpp \
  48     ui/settingsdialog.cpp \
  49     ui/sidepanel.cpp \
  50     ui/sidepanelbase.cpp \
  51     ui/userinfo.cpp \
  52     ui/userinfopanel.cpp \
  53     ui/zoombutton.cpp \
  54     ui/zoombuttonpanel.cpp \
  55     user/user.cpp \
  56     ui/fullscreenbutton.cpp \
  57     engine/mce.cpp \
  58     routing/routingservice.cpp \
  59     routing/routesegment.cpp \
  60     routing/route.cpp \
  61     map/maprouteitem.cpp
  62 HEADERS += application.h \
  63     common.h \
  64     engine/engine.h \
  65     facebookservice/facebookauthentication.h \
  66     facebookservice/facebookcommon.h \
  67     facebookservice/facebookcredentials.h \
  68     gps/gpscommon.h \
  69     gps/gpsposition.h \
  70     map/baselocationitem.h \
  71     map/friendgroupitem.h \
  72     map/frienditemshandler.h \
  73     map/friendlocationitem.h \
  74     map/gpslocationitem.h \
  75     map/mapcommon.h \
  76     map/mapengine.h \
  77     map/mapfetcher.h \
  78     map/mapscene.h \
  79     map/mapscroller.h \
  80     map/maptile.h \
  81     map/maptilerequest.h \
  82     map/mapview.h \
  83     map/ownlocationitem.h \
  84     network/networkaccessmanager.h \
  85     network/networkcookiejar.h \
  86     network/networkhandler.h \
  87     network/networkreply.h \
  88     situareservice/imagefetcher.h \
  89     situareservice/situarecommon.h \
  90     situareservice/situareservice.h \
  91     ui/updatelocation/texteditautoresizer.h \
  92     ui/updatelocation/updatelocationdialog.h \
  93     ui/avatarimage.h \
  94     ui/friendlistitem.h \
  95     ui/friendlistpanel.h \
  96     ui/friendlistview.h \
  97     ui/imagebutton.h \
  98     ui/logindialog.h \
  99     ui/mainwindow.h \
 100     ui/mapscale.h \
 101     ui/panelcommon.h \
 102     ui/panelsidebar.h \
 103     ui/panelsliderbar.h \
 104     ui/settingsdialog.h \
 105     ui/userinfo.h \
 106     ui/userinfopanel.h \
 107     ui/sidepanel.h \
 108     ui/sidepanelbase.h \
 109     ui/zoombutton.h \
 110     ui/zoombuttonpanel.h \
 111     user/user.h \
 112     ui/fullscreenbutton.h \
 113     engine/mce.h \
 114     routing/routingservice.h \
 115     routing/routingcommon.h \
 116     routing/routesegment.h \
 117     routing/route.h \
 118     map/maprouteitem.h
 119 QT += network \
 120     webkit
 121
 122 DEFINES += QT_NO_DEBUG_OUTPUT
 123
 124 simulator {
 125     SOURCES += network/networkhandlerprivatestub.cpp \
 126                gps/gpspositionprivate.cpp
 127     HEADERS += network/networkhandlerprivatestub.h \
 128                gps/gpspositionprivate.h
 129     QT += maemo5
 130     CONFIG += mobility
 131     MOBILITY += location
 132 } else:maemo5 {
 133     armel {
 134         DEFINES += ARMEL
 135         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 136         SOURCES += network/networkhandlerprivate.cpp \
 137                    engine/mceprivate.cpp
 138         HEADERS += network/networkhandlerprivate.h \
 139                    engine/mceprivate.h
 140         QT += dbus
 141         CONFIG += icd2 qdbus
 142         SOURCES += gps/gpspositionprivateliblocation.cpp \
 143                    gps/liblocationwrapper.cpp \
 144                    gps/geopositioninfo.cpp \
 145                    gps/geocoordinate.cpp
 146         HEADERS += gps/gpspositionprivateliblocation.h \
 147                    gps/liblocationwrapper.h \
 148                    gps/geopositioninfo.h \
 149                    gps/geocoordinate.h
 150         CONFIG += link_pkgconfig
 151         PKGCONFIG += glib-2.0 liblocation mce
 152         LIBS += -llocation
 153     } else {
 154         SOURCES += gps/gpspositionprivatestub.cpp \
 155                    network/networkhandlerprivatestub.cpp \
 156                    engine/mceprivatestub.cpp
 157         HEADERS += gps/gpspositionprivatestub.h \
 158                    network/networkhandlerprivatestub.h \
 159                    engine/mceprivatestub.h
 160     }
 161
 162     QT += maemo5
 163
 164     message([QJson])
 165     message(Make sure you have QJson development headers installed)
 166     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 167     message(to Scratchbox's sources.list in /etc/apt)
 168     message(run: apt-get update)
 169     message(install headers with: apt-get install libqjson-dev)
 170     message([QtMobility])
 171     message(Make sure you have QtMobility development headers installed)
 172     message(install headers with: apt-get install libqtm-dev)
 173 } else {
 174     SOURCES += gps/gpspositionprivatestub.cpp \
 175                network/networkhandlerprivatestub.cpp \
 176                engine/mceprivatestub.cpp
 177     HEADERS += gps/gpspositionprivatestub.h \
 178                network/networkhandlerprivatestub.h \
 179                engine/mceprivatestub.h
 180     message(QJson built in)
 181     message(Make sure you have QJson development headers installed)
 182     message(install headers with: sudo apt-get install libqjson-dev)
 183 }
 184
 185 # -----------------------------------------------------------------
 186 # Debian packetizing additions
 187 # -----------------------------------------------------------------
 188 unix {
 189     # VARIABLES
 190     isEmpty(PREFIX):PREFIX = /usr
 191     BINDIR = $$PREFIX/bin
 192     DATADIR = $$PREFIX/share
 193     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 194         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 195
 196     # MAKE INSTALL
 197     desktop.path = $$DATADIR/applications/hildon
 198     desktop.files += situare.desktop
 199     INSTALLS += desktop
 200     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 201     icon48.files += ../res/icon/48x48/situare.png
 202     INSTALLS += icon48
 203     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 204     icon64.files += ../res/icon/64x64/situare.png
 205     INSTALLS += icon64
 206     target.path = $$BINDIR
 207     INSTALLS += target
 208 }