d6fe6876a62b3d4c8f265996c93ef34952c37abc
[situare] / src / src.pro
1 # -------------------------------------------------
2 # Project created by QtCreator 2010-03-26T07:57:35
3 # -------------------------------------------------
4 TARGET = ../situare
5 TEMPLATE = app
6 INCLUDEPATH += /usr/include/qjson /usr/include/glib-2.0 /usr/lib/glib-2.0/include
7 LIBS += -lqjson
8 CONFIG += icd2
9 QT += dbus
10 RESOURCES += ../images.qrc
11 SOURCES += main.cpp \
12     ui/mainwindow.cpp \
13     situareservice/situareservice.cpp \
14     situareservice/imagefetcher.cpp \
15     facebookservice/facebookcredentials.cpp \
16     facebookservice/facebookauthentication.cpp \
17     map/mapengine.cpp \
18     map/mapview.cpp \
19     map/mapscene.cpp \
20     map/maptile.cpp \
21     map/mapfetcher.cpp \
22     map/ownlocationitem.cpp \
23     map/baselocationitem.cpp \
24     map/friendlocationitem.cpp \
25     ui/updatelocation/updatelocationdialog.cpp \
26     ui/updatelocation/texteditautoresizer.cpp \
27     ui/friendlistview.cpp \
28     ui/friendlistitem.cpp \
29     user/user.cpp \
30     ui/avatarimage.cpp \
31     engine/engine.cpp \
32     ui/settingsdialog.cpp \
33     ui/logindialog.cpp \
34     map/maptilerequest.cpp \
35     ui/imagebutton.cpp \
36     ui/friendlistpanel.cpp \
37     ui/userinfopanel.cpp \
38     ui/panelsidebar.cpp \
39     ui/panelsliderbar.cpp \
40     map/friendgroupitem.cpp \
41     map/frienditemshandler.cpp \
42     gps/gpsposition.cpp \
43     map/gpslocationitem.cpp \
44     ui/zoombuttonpanel.cpp \
45     ui/userinfo.cpp \
46     engine/networkhandler.cpp \
47     ui/sidepanel.cpp \
48     engine/networkaccessmanager.cpp \
49     engine/networkreply.cpp \
50     ui/zoombutton.cpp
51 HEADERS += ui/mainwindow.h \
52     map/mapengine.h \
53     map/mapview.h \
54     map/mapscene.h \
55     map/maptile.h \
56     map/mapfetcher.h \
57     map/mapcommon.h \
58     map/ownlocationitem.h \
59     map/baselocationitem.h \
60     map/friendlocationitem.h \
61     ui/updatelocation/updatelocationdialog.h \
62     ui/updatelocation/texteditautoresizer.h \
63     situareservice/situareservice.h \
64     situareservice/situarecommon.h \
65     situareservice/imagefetcher.h \
66     facebookservice/facebookcredentials.h \
67     facebookservice/facebookauthentication.h \
68     facebookservice/facebookcommon.h \
69     ui/friendlistview.h \
70     ui/friendlistitem.h \
71     user/user.h \
72     ui/avatarimage.h \
73     engine/engine.h \
74     ui/settingsdialog.h \
75     ui/logindialog.h \
76     map/maptilerequest.h \
77     ui/imagebutton.h \
78     ui/friendlistpanel.h \
79     ui/userinfopanel.h \
80     ui/panelcommon.h \
81     ui/panelsidebar.h \
82     ui/panelsliderbar.h \
83     map/friendgroupitem.h \
84     map/frienditemshandler.h \
85     gps/gpsposition.h \
86     map/gpslocationitem.h \
87     gps/gpscommon.h \
88     ui/zoombuttonpanel.h \
89     common.h \
90     ui/userinfo.h \
91     engine/networkhandler.h \
92     ui/sidepanel.h \
93     engine/networkaccessmanager.h \
94     engine/networkreply.h \
95     ui/zoombutton.h
96 QT += network \
97     webkit
98
99 DEFINES += QT_NO_DEBUG_OUTPUT
100
101 maemo5 | simulator {
102     SOURCES += gps/gpspositionprivate.cpp
103     HEADERS += gps/gpspositionprivate.h
104     QT += maemo5
105     CONFIG += mobility
106     MOBILITY = location
107     message([QJson])
108     message(Make sure you have QJson development headers installed)
109     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
110     message(to Scratchbox's sources.list in /etc/apt)
111     message(run: apt-get update)
112     message(install headers with: apt-get install libqjson-dev)
113     message([QtMobility])
114     message(Make sure you have QtMobility development headers installed)
115     message(install headers with: apt-get install libqtm-dev)
116 } else {
117     SOURCES += gps/gpspositionprivatestub.cpp
118     HEADERS += gps/gpspositionprivatestub.h
119     message(QJson built in)
120     message(Make sure you have QJson development headers installed)
121     message(install headers with: sudo apt-get install libqjson-dev)
122 }
123
124 # -----------------------------------------------------------------
125 # Debian packetizing additions
126 # -----------------------------------------------------------------
127 unix {
128     # VARIABLES
129     isEmpty(PREFIX):PREFIX = /usr
130     BINDIR = $$PREFIX/bin
131     DATADIR = $$PREFIX/share
132     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
133         PKGDATADIR=\\\"$$PKGDATADIR\\\"
134     
135     # MAKE INSTALL
136     desktop.path = $$DATADIR/applications/hildon
137     desktop.files += situare.desktop
138     INSTALLS += desktop
139     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
140     icon48.files += ../res/icon/48x48/situare.png
141     INSTALLS += icon48
142     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
143     icon64.files += ../res/icon/64x64/situare.png
144     INSTALLS += icon64
145     target.path = $$BINDIR
146     INSTALLS += target
147 }