git.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     engine/engine.cpp \
  14     facebookservice/facebookauthentication.cpp \
  15     facebookservice/facebookcredentials.cpp \
  16     gps/gpsposition.cpp \
  17     map/baselocationitem.cpp \
  18     map/friendgroupitem.cpp \
  19     map/frienditemshandler.cpp \
  20     map/friendlocationitem.cpp \
  21     map/gpslocationitem.cpp \
  22     map/mapengine.cpp \
  23     map/mapfetcher.cpp \
  24     map/mapscene.cpp \
  25     map/mapscroller.cpp \
  26     map/maptile.cpp \
  27     map/maptilerequest.cpp \
  28     map/mapview.cpp \
  29     map/ownlocationitem.cpp \
  30     network/networkaccessmanager.cpp \
  31     network/networkcookiejar.cpp \
  32     network/networkhandler.cpp \
  33     network/networkreply.cpp \
  34     situareservice/imagefetcher.cpp \
  35     situareservice/situareservice.cpp \
  36     ui/updatelocation/texteditautoresizer.cpp \
  37     ui/updatelocation/updatelocationdialog.cpp \
  38     ui/avatarimage.cpp \
  39     ui/friendlistitem.cpp \
  40     ui/friendlistpanel.cpp \
  41     ui/friendlistview.cpp \
  42     ui/imagebutton.cpp \
  43     ui/logindialog.cpp \
  44     ui/mainwindow.cpp \
  45     ui/mapscale.cpp \
  46     ui/panelsidebar.cpp \
  47     ui/panelsliderbar.cpp \
  48     ui/settingsdialog.cpp \
  49     ui/sidepanel.cpp \
  50     ui/sidepanelbase.cpp \
  51     ui/userinfo.cpp \
  52     ui/userinfopanel.cpp \
  53     ui/zoombutton.cpp \
  54     ui/zoombuttonpanel.cpp \
  55     user/user.cpp \
  56     ui/fullscreenbutton.cpp \
  57     engine/mce.cpp
  58 HEADERS += application.h \
  59     common.h \
  60     engine/engine.h \
  61     facebookservice/facebookauthentication.h \
  62     facebookservice/facebookcommon.h \
  63     facebookservice/facebookcredentials.h \
  64     gps/gpscommon.h \
  65     gps/gpsposition.h \
  66     map/baselocationitem.h \
  67     map/friendgroupitem.h \
  68     map/frienditemshandler.h \
  69     map/friendlocationitem.h \
  70     map/gpslocationitem.h \
  71     map/mapcommon.h \
  72     map/mapengine.h \
  73     map/mapfetcher.h \
  74     map/mapscene.h \
  75     map/mapscroller.h \
  76     map/maptile.h \
  77     map/maptilerequest.h \
  78     map/mapview.h \
  79     map/ownlocationitem.h \
  80     network/networkaccessmanager.h \
  81     network/networkcookiejar.h \
  82     network/networkhandler.h \
  83     network/networkreply.h \
  84     situareservice/imagefetcher.h \
  85     situareservice/situarecommon.h \
  86     situareservice/situareservice.h \
  87     ui/updatelocation/texteditautoresizer.h \
  88     ui/updatelocation/updatelocationdialog.h \
  89     ui/avatarimage.h \
  90     ui/friendlistitem.h \
  91     ui/friendlistpanel.h \
  92     ui/friendlistview.h \
  93     ui/imagebutton.h \
  94     ui/logindialog.h \
  95     ui/mainwindow.h \
  96     ui/mapscale.h \
  97     ui/panelcommon.h \
  98     ui/panelsidebar.h \
  99     ui/panelsliderbar.h \
 100     ui/settingsdialog.h \
 101     ui/userinfo.h \
 102     ui/userinfopanel.h \
 103     ui/sidepanel.h \
 104     ui/sidepanelbase.h \
 105     ui/zoombutton.h \
 106     ui/zoombuttonpanel.h \
 107     user/user.h \
 108     ui/fullscreenbutton.h \
 109     engine/mce.h \
 110     map/osm.h
 111 QT += network \
 112     webkit
 113
 114 DEFINES += QT_NO_DEBUG_OUTPUT
 115
 116 simulator {
 117     SOURCES += network/networkhandlerprivatestub.cpp \
 118                gps/gpspositionprivate.cpp
 119     HEADERS += network/networkhandlerprivatestub.h \
 120                gps/gpspositionprivate.h
 121     QT += maemo5
 122     CONFIG += mobility
 123     MOBILITY += location
 124 } else:maemo5 {
 125     armel {
 126         DEFINES += ARMEL
 127         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 128         SOURCES += network/networkhandlerprivate.cpp \
 129                    engine/mceprivate.cpp
 130         HEADERS += network/networkhandlerprivate.h \
 131                    engine/mceprivate.h
 132         QT += dbus
 133         CONFIG += icd2 qdbus
 134         SOURCES += gps/gpspositionprivateliblocation.cpp \
 135                    gps/liblocationwrapper.cpp \
 136                    gps/geopositioninfo.cpp
 137         HEADERS += gps/gpspositionprivateliblocation.h \
 138                    gps/liblocationwrapper.h \
 139                    gps/geopositioninfo.h
 140         CONFIG += link_pkgconfig
 141         PKGCONFIG += glib-2.0 liblocation mce
 142         LIBS += -llocation
 143     } else {
 144         SOURCES += gps/gpspositionprivatestub.cpp \
 145                    network/networkhandlerprivatestub.cpp \
 146                    engine/mceprivatestub.cpp
 147         HEADERS += gps/gpspositionprivatestub.h \
 148                    network/networkhandlerprivatestub.h \
 149                    engine/mceprivatestub.h
 150     }
 151
 152     QT += maemo5
 153
 154     message([QJson])
 155     message(Make sure you have QJson development headers installed)
 156     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 157     message(to Scratchbox's sources.list in /etc/apt)
 158     message(run: apt-get update)
 159     message(install headers with: apt-get install libqjson-dev)
 160     message([QtMobility])
 161     message(Make sure you have QtMobility development headers installed)
 162     message(install headers with: apt-get install libqtm-dev)
 163 } else {
 164     SOURCES += gps/gpspositionprivatestub.cpp \
 165                network/networkhandlerprivatestub.cpp \
 166                engine/mceprivatestub.cpp
 167     HEADERS += gps/gpspositionprivatestub.h \
 168                network/networkhandlerprivatestub.h \
 169                engine/mceprivatestub.h
 170     message(QJson built in)
 171     message(Make sure you have QJson development headers installed)
 172     message(install headers with: sudo apt-get install libqjson-dev)
 173 }
 174
 175 # -----------------------------------------------------------------
 176 # Debian packetizing additions
 177 # -----------------------------------------------------------------
 178 unix {
 179     # VARIABLES
 180     isEmpty(PREFIX):PREFIX = /usr
 181     BINDIR = $$PREFIX/bin
 182     DATADIR = $$PREFIX/share
 183     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 184         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 185
 186     # MAKE INSTALL
 187     desktop.path = $$DATADIR/applications/hildon
 188     desktop.files += situare.desktop
 189     INSTALLS += desktop
 190     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 191     icon48.files += ../res/icon/48x48/situare.png
 192     INSTALLS += icon48
 193     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 194     icon64.files += ../res/icon/64x64/situare.png
 195     INSTALLS += icon64
 196     target.path = $$BINDIR
 197     INSTALLS += target
 198 }