git.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     coordinates/geocoordinate.cpp \
  14     coordinates/scenecoordinate.cpp \
  15     engine/engine.cpp \
  16     engine/mce.cpp \
  17     facebookservice/facebookauthentication.cpp \
  18     facebookservice/facebookcredentials.cpp \
  19     gps/gpsposition.cpp \
  20     map/baselocationitem.cpp \
  21     map/friendgroupitem.cpp \
  22     map/frienditemshandler.cpp \
  23     map/friendlocationitem.cpp \
  24     map/gpslocationitem.cpp \
  25     map/mapengine.cpp \
  26     map/mapfetcher.cpp \
  27     map/maprouteitem.cpp \
  28     map/mapscene.cpp \
  29     map/mapscroller.cpp \
  30     map/maptile.cpp \
  31     map/maptilerequest.cpp \
  32     map/mapview.cpp \
  33     map/ownlocationitem.cpp \
  34     network/networkaccessmanager.cpp \
  35     network/networkcookiejar.cpp \
  36     network/networkhandler.cpp \
  37     network/networkreply.cpp \
  38     routing/geocodingservice.cpp \
  39     routing/location.cpp \
  40     routing/route.cpp \
  41     routing/routesegment.cpp \
  42     routing/routingservice.cpp \
  43     situareservice/imagefetcher.cpp \
  44     situareservice/situareservice.cpp \
  45     ui/updatelocation/texteditautoresizer.cpp \
  46     ui/updatelocation/updatelocationdialog.cpp \
  47     ui/avatarimage.cpp \
  48     ui/extendedlistitem.cpp \
  49     ui/extendedlistitemdelegate.cpp \
  50     ui/extendedlistitemstore.cpp \
  51     ui/friendlistitem.cpp \
  52     ui/friendlistitemdelegate.cpp \
  53     ui/friendlistpanel.cpp \
  54     ui/friendlistview.cpp \
  55     ui/fullscreenbutton.cpp \
  56     ui/imagebutton.cpp \
  57     ui/indicatorbutton.cpp \
  58     ui/listitem.cpp \
  59     ui/listitemdelegate.cpp \
  60     ui/listview.cpp \
  61     ui/locationlistitem.cpp \
  62     ui/locationlistview.cpp \
  63     ui/indicatorbuttonpanel.cpp \
  64     ui/logindialog.cpp \
  65     ui/mainwindow.cpp \
  66     ui/mapscale.cpp \
  67     ui/settingsdialog.cpp \
  68     ui/userinfo.cpp \
  69     ui/userinfopanel.cpp \
  70     ui/zoombutton.cpp \
  71     ui/zoombuttonpanel.cpp \
  72     ui/searchdialog.cpp \
  73     ui/panelbar.cpp \
  74     ui/panelcontentstack.cpp \
  75     ui/paneltab.cpp \
  76     ui/paneltabbar.cpp \
  77     ui/tabbedpanel.cpp \
  78     ui/routingpanel.cpp \
  79     ui/routewaypointlistitem.cpp \
  80     ui/routewaypointlistview.cpp \
  81     user/user.cpp
  82 HEADERS += application.h \
  83     common.h \
  84     coordinates/geocoordinate.h \
  85     coordinates/scenecoordinate.h \
  86     engine/engine.h \
  87     engine/mce.h \
  88     error.h \
  89     facebookservice/facebookauthentication.h \
  90     facebookservice/facebookcommon.h \
  91     facebookservice/facebookcredentials.h \
  92     gps/gpscommon.h \
  93     gps/gpsposition.h \
  94     map/baselocationitem.h \
  95     map/friendgroupitem.h \
  96     map/frienditemshandler.h \
  97     map/friendlocationitem.h \
  98     map/gpslocationitem.h \
  99     map/mapcommon.h \
 100     map/mapengine.h \
 101     map/mapfetcher.h \
 102     map/maprouteitem.h \
 103     map/mapscene.h \
 104     map/mapscroller.h \
 105     map/maptile.h \
 106     map/maptilerequest.h \
 107     map/mapview.h \
 108     map/osm.h \
 109     map/ownlocationitem.h \
 110     network/networkaccessmanager.h \
 111     network/networkcookiejar.h \
 112     network/networkhandler.h \
 113     network/networkreply.h \
 114     routing/geocodingservice.h \
 115     routing/location.h \
 116     routing/route.h \
 117     routing/routesegment.h \
 118     routing/routingcommon.h \
 119     routing/routingservice.h \
 120     situareservice/imagefetcher.h \
 121     situareservice/situarecommon.h \
 122     situareservice/situareservice.h \
 123     ui/updatelocation/texteditautoresizer.h \
 124     ui/updatelocation/updatelocationdialog.h \
 125     ui/avatarimage.h \
 126     ui/friendlistitem.h \
 127     ui/friendlistitemdelegate.h \
 128     ui/friendlistpanel.h \
 129     ui/friendlistview.h \
 130     ui/fullscreenbutton.h \
 131     ui/imagebutton.h \
 132     ui/indicatorbutton.h \
 133     ui/indicatorbuttonpanel.h \
 134     ui/logindialog.h \
 135     ui/locationlistview.h \
 136     ui/mainwindow.h \
 137     ui/mapscale.h \
 138     ui/settingsdialog.h \
 139     ui/userinfo.h \
 140     ui/userinfopanel.h \
 141     ui/zoombutton.h \
 142     ui/zoombuttonpanel.h \
 143     ui/listcommon.h \
 144     ui/listview.h \
 145     ui/listitem.h \
 146     ui/listitemdelegate.h \
 147     ui/searchdialog.h \
 148     ui/panelbar.h \
 149     ui/panelcommon.h \
 150     ui/panelcontentstack.h \
 151     ui/paneltab.h \
 152     ui/paneltabbar.h \
 153     ui/tabbedpanel.h \
 154     ui/routingpanel.h \
 155     ui/routewaypointlistitem.h \
 156     ui/routewaypointlistview.h \
 157     user/user.h
 158 QT += network \
 159     webkit
 160
 161 DEFINES += QT_NO_DEBUG_OUTPUT
 162
 163 simulator {
 164     SOURCES += network/networkhandlerprivatestub.cpp \
 165                gps/gpspositionprivate.cpp
 166     HEADERS += network/networkhandlerprivatestub.h \
 167                gps/gpspositionprivate.h
 168     QT += maemo5
 169     CONFIG += mobility
 170     MOBILITY += location
 171 } else:maemo5 {
 172     armel {
 173         DEFINES += ARMEL
 174         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 175         SOURCES += network/networkhandlerprivate.cpp \
 176                    engine/mceprivate.cpp
 177         HEADERS += network/networkhandlerprivate.h \
 178                    engine/mceprivate.h
 179         QT += dbus xml
 180         CONFIG += icd2 qdbus
 181         SOURCES += gps/gpspositionprivateliblocation.cpp \
 182                    gps/liblocationwrapper.cpp \
 183                    gps/geopositioninfo.cpp
 184         HEADERS += gps/gpspositionprivateliblocation.h \
 185                    gps/liblocationwrapper.h \
 186                    gps/geopositioninfo.h
 187         CONFIG += link_pkgconfig
 188         PKGCONFIG += glib-2.0 liblocation mce
 189         LIBS += -llocation
 190     } else {
 191         SOURCES += gps/gpspositionprivatestub.cpp \
 192                    network/networkhandlerprivatestub.cpp \
 193                    engine/mceprivatestub.cpp
 194         HEADERS += gps/gpspositionprivatestub.h \
 195                    network/networkhandlerprivatestub.h \
 196                    engine/mceprivatestub.h
 197     }
 198
 199     QT += maemo5
 200
 201     message([QJson])
 202     message(Make sure you have QJson development headers installed)
 203     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 204     message(to Scratchbox's sources.list in /etc/apt)
 205     message(run: apt-get update)
 206     message(install headers with: apt-get install libqjson-dev)
 207     message([QtMobility])
 208     message(Make sure you have QtMobility development headers installed)
 209     message(install headers with: apt-get install libqtm-dev)
 210 } else {
 211     SOURCES += gps/gpspositionprivatestub.cpp \
 212                network/networkhandlerprivatestub.cpp \
 213                engine/mceprivatestub.cpp
 214     HEADERS += gps/gpspositionprivatestub.h \
 215                network/networkhandlerprivatestub.h \
 216                engine/mceprivatestub.h
 217     message(QJson built in)
 218     message(Make sure you have QJson development headers installed)
 219     message(install headers with: sudo apt-get install libqjson-dev)
 220 }
 221
 222 # -----------------------------------------------------------------
 223 # Debian packetizing additions
 224 # -----------------------------------------------------------------
 225 unix {
 226     # VARIABLES
 227     isEmpty(PREFIX):PREFIX = /usr
 228     BINDIR = $$PREFIX/bin
 229     DATADIR = $$PREFIX/share
 230     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 231         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 232
 233     # MAKE INSTALL
 234     desktop.path = $$DATADIR/applications/hildon
 235     desktop.files += situare.desktop
 236     INSTALLS += desktop
 237     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 238     icon48.files += ../res/icon/48x48/situare.png
 239     INSTALLS += icon48
 240     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 241     icon64.files += ../res/icon/64x64/situare.png
 242     INSTALLS += icon64
 243     target.path = $$BINDIR
 244     INSTALLS += target
 245 }