git.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     application.cpp \
  13     engine/engine.cpp \
  14     facebookservice/facebookauthentication.cpp \
  15     facebookservice/facebookcredentials.cpp \
  16     gps/gpsposition.cpp \
  17     map/baselocationitem.cpp \
  18     map/friendgroupitem.cpp \
  19     map/frienditemshandler.cpp \
  20     map/friendlocationitem.cpp \
  21     map/gpslocationitem.cpp \
  22     map/mapengine.cpp \
  23     map/mapfetcher.cpp \
  24     map/mapscene.cpp \
  25     map/mapscroller.cpp \
  26     map/maptile.cpp \
  27     map/maptilerequest.cpp \
  28     map/mapview.cpp \
  29     map/ownlocationitem.cpp \
  30     network/networkaccessmanager.cpp \
  31     network/networkcookiejar.cpp \
  32     network/networkhandler.cpp \
  33     network/networkreply.cpp \
  34     situareservice/imagefetcher.cpp \
  35     situareservice/situareservice.cpp \
  36     ui/updatelocation/texteditautoresizer.cpp \
  37     ui/updatelocation/updatelocationdialog.cpp \
  38     ui/avatarimage.cpp \
  39     ui/friendlistitem.cpp \
  40     ui/friendlistpanel.cpp \
  41     ui/imagebutton.cpp \
  42     ui/logindialog.cpp \
  43     ui/mainwindow.cpp \
  44     ui/mapscale.cpp \
  45     ui/panelsidebar.cpp \
  46     ui/panelsliderbar.cpp \
  47     ui/settingsdialog.cpp \
  48     ui/sidepanel.cpp \
  49     ui/sidepanelbase.cpp \
  50     ui/userinfo.cpp \
  51     ui/userinfopanel.cpp \
  52     ui/zoombutton.cpp \
  53     ui/zoombuttonpanel.cpp \
  54     user/user.cpp \
  55     ui/fullscreenbutton.cpp \
  56     engine/mce.cpp \
  57     ui/indicatorbutton.cpp \
  58     routing/routingservice.cpp \
  59     routing/routesegment.cpp \
  60     routing/route.cpp \
  61     map/maprouteitem.cpp \
  62     coordinates/scenecoordinate.cpp \
  63     coordinates/geocoordinate.cpp \
  64     ui/listview.cpp \
  65     ui/listitem.cpp \
  66     ui/listitemdelegate.cpp \
  67     ui/friendlistitemdelegate.cpp
  68 HEADERS += application.h \
  69     common.h \
  70     engine/engine.h \
  71     facebookservice/facebookauthentication.h \
  72     facebookservice/facebookcommon.h \
  73     facebookservice/facebookcredentials.h \
  74     gps/gpscommon.h \
  75     gps/gpsposition.h \
  76     map/baselocationitem.h \
  77     map/friendgroupitem.h \
  78     map/frienditemshandler.h \
  79     map/friendlocationitem.h \
  80     map/gpslocationitem.h \
  81     map/mapcommon.h \
  82     map/mapengine.h \
  83     map/mapfetcher.h \
  84     map/mapscene.h \
  85     map/mapscroller.h \
  86     map/maptile.h \
  87     map/maptilerequest.h \
  88     map/mapview.h \
  89     map/ownlocationitem.h \
  90     network/networkaccessmanager.h \
  91     network/networkcookiejar.h \
  92     network/networkhandler.h \
  93     network/networkreply.h \
  94     situareservice/imagefetcher.h \
  95     situareservice/situarecommon.h \
  96     situareservice/situareservice.h \
  97     ui/updatelocation/texteditautoresizer.h \
  98     ui/updatelocation/updatelocationdialog.h \
  99     ui/avatarimage.h \
 100     ui/friendlistitem.h \
 101     ui/friendlistpanel.h \
 102     ui/imagebutton.h \
 103     ui/logindialog.h \
 104     ui/mainwindow.h \
 105     ui/mapscale.h \
 106     ui/panelcommon.h \
 107     ui/panelsidebar.h \
 108     ui/panelsliderbar.h \
 109     ui/settingsdialog.h \
 110     ui/userinfo.h \
 111     ui/userinfopanel.h \
 112     ui/sidepanel.h \
 113     ui/sidepanelbase.h \
 114     ui/zoombutton.h \
 115     ui/zoombuttonpanel.h \
 116     user/user.h \
 117     ui/fullscreenbutton.h \
 118     engine/mce.h \
 119     ui/indicatorbutton.h \
 120     routing/routingservice.h \
 121     routing/routingcommon.h \
 122     routing/routesegment.h \
 123     routing/route.h \
 124     map/maprouteitem.h \
 125     map/osm.h \
 126     coordinates/scenecoordinate.h \
 127     coordinates/geocoordinate.h \
 128     ui/listview.h \
 129     ui/listitem.h \
 130     ui/listitemdelegate.h \
 131     ui/friendlistitemdelegate.h \
 132     ui/listcommon.h
 133 QT += network \
 134     webkit
 135
 136 DEFINES += QT_NO_DEBUG_OUTPUT
 137
 138 simulator {
 139     SOURCES += network/networkhandlerprivatestub.cpp \
 140                gps/gpspositionprivate.cpp
 141     HEADERS += network/networkhandlerprivatestub.h \
 142                gps/gpspositionprivate.h
 143     QT += maemo5
 144     CONFIG += mobility
 145     MOBILITY += location
 146 } else:maemo5 {
 147     armel {
 148         DEFINES += ARMEL
 149         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 150         SOURCES += network/networkhandlerprivate.cpp \
 151                    engine/mceprivate.cpp
 152         HEADERS += network/networkhandlerprivate.h \
 153                    engine/mceprivate.h
 154         QT += dbus
 155         CONFIG += icd2 qdbus
 156         SOURCES += gps/gpspositionprivateliblocation.cpp \
 157                    gps/liblocationwrapper.cpp \
 158                    gps/geopositioninfo.cpp
 159         HEADERS += gps/gpspositionprivateliblocation.h \
 160                    gps/liblocationwrapper.h \
 161                    gps/geopositioninfo.h
 162         CONFIG += link_pkgconfig
 163         PKGCONFIG += glib-2.0 liblocation mce
 164         LIBS += -llocation
 165     } else {
 166         SOURCES += gps/gpspositionprivatestub.cpp \
 167                    network/networkhandlerprivatestub.cpp \
 168                    engine/mceprivatestub.cpp
 169         HEADERS += gps/gpspositionprivatestub.h \
 170                    network/networkhandlerprivatestub.h \
 171                    engine/mceprivatestub.h
 172     }
 173
 174     QT += maemo5
 175
 176     message([QJson])
 177     message(Make sure you have QJson development headers installed)
 178     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 179     message(to Scratchbox's sources.list in /etc/apt)
 180     message(run: apt-get update)
 181     message(install headers with: apt-get install libqjson-dev)
 182     message([QtMobility])
 183     message(Make sure you have QtMobility development headers installed)
 184     message(install headers with: apt-get install libqtm-dev)
 185 } else {
 186     SOURCES += gps/gpspositionprivatestub.cpp \
 187                network/networkhandlerprivatestub.cpp \
 188                engine/mceprivatestub.cpp
 189     HEADERS += gps/gpspositionprivatestub.h \
 190                network/networkhandlerprivatestub.h \
 191                engine/mceprivatestub.h
 192     message(QJson built in)
 193     message(Make sure you have QJson development headers installed)
 194     message(install headers with: sudo apt-get install libqjson-dev)
 195 }
 196
 197 # -----------------------------------------------------------------
 198 # Debian packetizing additions
 199 # -----------------------------------------------------------------
 200 unix {
 201     # VARIABLES
 202     isEmpty(PREFIX):PREFIX = /usr
 203     BINDIR = $$PREFIX/bin
 204     DATADIR = $$PREFIX/share
 205     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 206         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 207
 208     # MAKE INSTALL
 209     desktop.path = $$DATADIR/applications/hildon
 210     desktop.files += situare.desktop
 211     INSTALLS += desktop
 212     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 213     icon48.files += ../res/icon/48x48/situare.png
 214     INSTALLS += icon48
 215     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 216     icon64.files += ../res/icon/64x64/situare.png
 217     INSTALLS += icon64
 218     target.path = $$BINDIR
 219     INSTALLS += target
 220 }