git.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc
   9 SOURCES += main.cpp \
  10     ui/mainwindow.cpp \
  11     situareservice/situareservice.cpp \
  12     situareservice/imagefetcher.cpp \
  13     facebookservice/facebookcredentials.cpp \
  14     facebookservice/facebookauthentication.cpp \
  15     map/mapengine.cpp \
  16     map/mapview.cpp \
  17     map/mapscene.cpp \
  18     map/maptile.cpp \
  19     map/mapfetcher.cpp \
  20     map/ownlocationitem.cpp \
  21     map/baselocationitem.cpp \
  22     map/friendlocationitem.cpp \
  23     ui/updatelocation/updatelocationdialog.cpp \
  24     ui/updatelocation/texteditautoresizer.cpp \
  25     ui/friendlistview.cpp \
  26     ui/friendlistitem.cpp \
  27     user/user.cpp \
  28     ui/avatarimage.cpp \
  29     engine/engine.cpp \
  30     ui/settingsdialog.cpp \
  31     ui/logindialog.cpp \
  32     map/maptilerequest.cpp \
  33     ui/imagebutton.cpp \
  34     ui/friendlistpanel.cpp \
  35     ui/userinfopanel.cpp \
  36     ui/panelsidebar.cpp \
  37     ui/panelsliderbar.cpp \
  38     map/friendgroupitem.cpp \
  39     map/frienditemshandler.cpp \
  40     gps/gpsposition.cpp \
  41     map/gpslocationitem.cpp \
  42     ui/zoombuttonpanel.cpp \
  43     ui/userinfo.cpp \
  44     ui/sidepanel.cpp \
  45     ui/zoombutton.cpp \
  46     network/networkaccessmanager.cpp \
  47     network/networkhandler.cpp \
  48     network/networkcookiejar.cpp \
  49     network/networkreply.cpp
  50 HEADERS += ui/mainwindow.h \
  51     map/mapengine.h \
  52     map/mapview.h \
  53     map/mapscene.h \
  54     map/maptile.h \
  55     map/mapfetcher.h \
  56     map/mapcommon.h \
  57     map/ownlocationitem.h \
  58     map/baselocationitem.h \
  59     map/friendlocationitem.h \
  60     ui/updatelocation/updatelocationdialog.h \
  61     ui/updatelocation/texteditautoresizer.h \
  62     situareservice/situareservice.h \
  63     situareservice/situarecommon.h \
  64     situareservice/imagefetcher.h \
  65     facebookservice/facebookcredentials.h \
  66     facebookservice/facebookauthentication.h \
  67     facebookservice/facebookcommon.h \
  68     ui/friendlistview.h \
  69     ui/friendlistitem.h \
  70     user/user.h \
  71     ui/avatarimage.h \
  72     engine/engine.h \
  73     ui/settingsdialog.h \
  74     ui/logindialog.h \
  75     map/maptilerequest.h \
  76     ui/imagebutton.h \
  77     ui/friendlistpanel.h \
  78     ui/userinfopanel.h \
  79     ui/panelcommon.h \
  80     ui/panelsidebar.h \
  81     ui/panelsliderbar.h \
  82     map/friendgroupitem.h \
  83     map/frienditemshandler.h \
  84     gps/gpsposition.h \
  85     map/gpslocationitem.h \
  86     gps/gpscommon.h \
  87     ui/zoombuttonpanel.h \
  88     common.h \
  89     ui/userinfo.h \
  90     ui/sidepanel.h \
  91     ui/zoombutton.h \
  92     network/networkaccessmanager.h \
  93     network/networkhandler.h \
  94     network/networkcookiejar.h \
  95     network/networkreply.h
  96 QT += network \
  97     webkit
  98 DEFINES += QT_NO_DEBUG_OUTPUT
  99
 100 maemo5 | simulator {
 101     armel {
 102         DEFINES += ARMEL
 103         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 104         SOURCES += network/networkhandlerprivate.cpp
 105         HEADERS += network/networkhandlerprivate.h
 106         QT += dbus
 107         CONFIG += icd2
 108     } else {
 109         SOURCES += network/networkhandlerprivatestub.cpp
 110         HEADERS += network/networkhandlerprivatestub.h
 111     }
 112     SOURCES += gps/gpspositionprivate.cpp
 113     HEADERS += gps/gpspositionprivate.h
 114     QT += maemo5
 115     CONFIG += mobility
 116     MOBILITY = location
 117     message([QJson])
 118     message(Make sure you have QJson development headers installed)
 119     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 120     message(to Scratchbox's sources.list in /etc/apt)
 121     message(run: apt-get update)
 122     message(install headers with: apt-get install libqjson-dev)
 123     message([QtMobility])
 124     message(Make sure you have QtMobility development headers installed)
 125     message(install headers with: apt-get install libqtm-dev)
 126 } else {
 127     SOURCES += gps/gpspositionprivatestub.cpp \
 128                network/networkhandlerprivatestub.cpp
 129     HEADERS += gps/gpspositionprivatestub.h \
 130                network/networkhandlerprivatestub.h
 131     message(QJson built in)
 132     message(Make sure you have QJson development headers installed)
 133     message(install headers with: sudo apt-get install libqjson-dev)
 134 }
 135
 136 # -----------------------------------------------------------------
 137 # Debian packetizing additions
 138 # -----------------------------------------------------------------
 139 unix {
 140     # VARIABLES
 141     isEmpty(PREFIX):PREFIX = /usr
 142     BINDIR = $$PREFIX/bin
 143     DATADIR = $$PREFIX/share
 144     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 145         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 146
 147     # MAKE INSTALL
 148     desktop.path = $$DATADIR/applications/hildon
 149     desktop.files += situare.desktop
 150     INSTALLS += desktop
 151     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 152     icon48.files += ../res/icon/48x48/situare.png
 153     INSTALLS += icon48
 154     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 155     icon64.files += ../res/icon/64x64/situare.png
 156     INSTALLS += icon64
 157     target.path = $$BINDIR
 158     INSTALLS += target
 159 }