git.maemo.org Git - situare/blob - src/src.pro

   1 # -------------------------------------------------
   2 # Project created by QtCreator 2010-03-26T07:57:35
   3 # -------------------------------------------------
   4 TARGET = ../situare
   5 TEMPLATE = app
   6 INCLUDEPATH += /usr/include/qjson
   7 LIBS += -lqjson
   8 RESOURCES += ../images.qrc \
   9     ../languages.qrc
  10 TRANSLATIONS += ../res/languages/situare_fi.ts
  11 SOURCES += main.cpp \
  12     ui/mainwindow.cpp \
  13     situareservice/situareservice.cpp \
  14     situareservice/imagefetcher.cpp \
  15     facebookservice/facebookcredentials.cpp \
  16     facebookservice/facebookauthentication.cpp \
  17     map/mapengine.cpp \
  18     map/mapview.cpp \
  19     map/mapscene.cpp \
  20     map/maptile.cpp \
  21     map/mapfetcher.cpp \
  22     map/ownlocationitem.cpp \
  23     map/baselocationitem.cpp \
  24     map/friendlocationitem.cpp \
  25     ui/updatelocation/updatelocationdialog.cpp \
  26     ui/updatelocation/texteditautoresizer.cpp \
  27     ui/friendlistview.cpp \
  28     ui/friendlistitem.cpp \
  29     user/user.cpp \
  30     ui/avatarimage.cpp \
  31     engine/engine.cpp \
  32     ui/settingsdialog.cpp \
  33     ui/logindialog.cpp \
  34     map/maptilerequest.cpp \
  35     ui/imagebutton.cpp \
  36     ui/friendlistpanel.cpp \
  37     ui/userinfopanel.cpp \
  38     ui/panelsidebar.cpp \
  39     ui/panelsliderbar.cpp \
  40     map/friendgroupitem.cpp \
  41     map/frienditemshandler.cpp \
  42     gps/gpsposition.cpp \
  43     map/gpslocationitem.cpp \
  44     ui/zoombuttonpanel.cpp \
  45     ui/userinfo.cpp \
  46     ui/sidepanel.cpp \
  47     ui/zoombutton.cpp \
  48     network/networkaccessmanager.cpp \
  49     network/networkhandler.cpp \
  50     network/networkcookiejar.cpp \
  51     network/networkreply.cpp \
  52     ui/mapscale.cpp
  53 HEADERS += ui/mainwindow.h \
  54     map/mapengine.h \
  55     map/mapview.h \
  56     map/mapscene.h \
  57     map/maptile.h \
  58     map/mapfetcher.h \
  59     map/mapcommon.h \
  60     map/ownlocationitem.h \
  61     map/baselocationitem.h \
  62     map/friendlocationitem.h \
  63     ui/updatelocation/updatelocationdialog.h \
  64     ui/updatelocation/texteditautoresizer.h \
  65     situareservice/situareservice.h \
  66     situareservice/situarecommon.h \
  67     situareservice/imagefetcher.h \
  68     facebookservice/facebookcredentials.h \
  69     facebookservice/facebookauthentication.h \
  70     facebookservice/facebookcommon.h \
  71     ui/friendlistview.h \
  72     ui/friendlistitem.h \
  73     user/user.h \
  74     ui/avatarimage.h \
  75     engine/engine.h \
  76     ui/settingsdialog.h \
  77     ui/logindialog.h \
  78     map/maptilerequest.h \
  79     ui/imagebutton.h \
  80     ui/friendlistpanel.h \
  81     ui/userinfopanel.h \
  82     ui/panelcommon.h \
  83     ui/panelsidebar.h \
  84     ui/panelsliderbar.h \
  85     map/friendgroupitem.h \
  86     map/frienditemshandler.h \
  87     gps/gpsposition.h \
  88     map/gpslocationitem.h \
  89     gps/gpscommon.h \
  90     ui/zoombuttonpanel.h \
  91     common.h \
  92     ui/userinfo.h \
  93     ui/sidepanel.h \
  94     ui/zoombutton.h \
  95     network/networkaccessmanager.h \
  96     network/networkhandler.h \
  97     network/networkcookiejar.h \
  98     network/networkreply.h \
  99     ui/mapscale.h
 100 QT += network \
 101     webkit
 102 DEFINES += QT_NO_DEBUG_OUTPUT
 103
 104 simulator {
 105     SOURCES += network/networkhandlerprivatestub.cpp \
 106                gps/gpspositionprivate.cpp
 107     HEADERS += network/networkhandlerprivatestub.h \
 108                gps/gpspositionprivate.h
 109     QT += maemo5
 110     CONFIG += mobility
 111     MOBILITY += location
 112 } else:maemo5 {
 113     armel {
 114         DEFINES += ARMEL
 115         INCLUDEPATH += /usr/include/glib-2.0 /usr/lib/glib-2.0/include
 116         SOURCES += network/networkhandlerprivate.cpp
 117         HEADERS += network/networkhandlerprivate.h
 118         QT += dbus
 119         CONFIG += icd2
 120         SOURCES += gps/gpspositionprivateliblocation.cpp \
 121                    gps/liblocationwrapper.cpp \
 122                    gps/geopositioninfo.cpp \
 123                    gps/geocoordinate.cpp
 124         HEADERS += gps/gpspositionprivateliblocation.h \
 125                    gps/liblocationwrapper.h \
 126                    gps/geopositioninfo.h \
 127                    gps/geocoordinate.h
 128         CONFIG += link_pkgconfig
 129         PKGCONFIG += glib-2.0 liblocation
 130     } else {
 131         SOURCES += gps/gpspositionprivatestub.cpp \
 132                    network/networkhandlerprivatestub.cpp
 133         HEADERS += gps/gpspositionprivatestub.h \
 134                    network/networkhandlerprivatestub.h
 135     }
 136
 137     QT += maemo5
 138
 139     message([QJson])
 140     message(Make sure you have QJson development headers installed)
 141     message(add: deb http://repository.maemo.org/extras-devel fremantle free non-free)
 142     message(to Scratchbox's sources.list in /etc/apt)
 143     message(run: apt-get update)
 144     message(install headers with: apt-get install libqjson-dev)
 145     message([QtMobility])
 146     message(Make sure you have QtMobility development headers installed)
 147     message(install headers with: apt-get install libqtm-dev)
 148 } else {
 149     SOURCES += gps/gpspositionprivatestub.cpp \
 150                network/networkhandlerprivatestub.cpp
 151     HEADERS += gps/gpspositionprivatestub.h \
 152                network/networkhandlerprivatestub.h
 153     message(QJson built in)
 154     message(Make sure you have QJson development headers installed)
 155     message(install headers with: sudo apt-get install libqjson-dev)
 156 }
 157
 158 # -----------------------------------------------------------------
 159 # Debian packetizing additions
 160 # -----------------------------------------------------------------
 161 unix {
 162     # VARIABLES
 163     isEmpty(PREFIX):PREFIX = /usr
 164     BINDIR = $$PREFIX/bin
 165     DATADIR = $$PREFIX/share
 166     DEFINES += DATADIR=\\\"$$DATADIR\\\" \
 167         PKGDATADIR=\\\"$$PKGDATADIR\\\"
 168
 169     # MAKE INSTALL
 170     desktop.path = $$DATADIR/applications/hildon
 171     desktop.files += situare.desktop
 172     INSTALLS += desktop
 173     icon48.path = $$DATADIR/icons/hicolor/48x48/apps
 174     icon48.files += ../res/icon/48x48/situare.png
 175     INSTALLS += icon48
 176     icon64.path = $$DATADIR/icons/hicolor/64x64/apps
 177     icon64.files += ../res/icon/64x64/situare.png
 178     INSTALLS += icon64
 179     target.path = $$BINDIR
 180     INSTALLS += target
 181 }