#-------------------------------------------------
#
# Project created by QtCreator 2010-08-03T08:54:27
#
#-------------------------------------------------

QT       += core gui sql

maemo5 {
    QT += maemo5
}

TARGET = mdictionary
TEMPLATE = app

MDICT_BINDIR = $$[MDICT_BINDIR]

isEmpty(MDICT_BINDIR) {
  MDICT_BINDIR = .
}

DESTDIR = $${MDICT_BINDIR}

SOURCES += gui/main.cpp\
        gui/MainWindow.cpp \
    gui/SearchBarWidget.cpp \
    gui/WordListWidget.cpp \
    gui/TranslationWidget.cpp \
    backbone/backbone.cpp \
    gui/MenuWidget.cpp \
    gui/MenuTabWidget.cpp \
    gui/DictManagerWidget.cpp \
    gui/DictTypeSelectDialog.cpp \
    backbone/History.cpp \
    gui/HistoryListDialog.cpp \
    gui/WordListProxyStyle.cpp \
    backbone/Bookmarks.cpp \
    gui/SettingsWidget.cpp

HEADERS  += gui/MainWindow.h \
    gui/SearchBarWidget.h \
    gui/WordListWidget.h \
    gui/TranslationWidget.h \
    backbone/backbone.h \
    ../includes/translation.h \
    ../includes/settings.h \
    ../includes/CommonDictInterface.h \
    gui/MenuWidget.h \
    gui/MenuTabWidget.h \
    gui/DictManagerWidget.h \
    gui/DictTypeSelectDialog.h \
    gui/TranslationWidgetAutoResizer.h \
    ../includes/History.h \
    gui/HistoryListDialog.h \
    ../includes/GUIInterface.h \
    gui/WordListProxyStyle.h \
    backbone/Bookmarks.h \
    backbone/BookmarkTranslations.h \
    gui/SettingsWidget.h

FORMS    += gui/MainWindow.ui

unix {
  #VARIABLES
  isEmpty(PREFIX) {
    PREFIX = /usr
  }
  BINDIR = $$PREFIX/bin
  DATADIR =$$PREFIX/share

  DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"

  #MAKE INSTALL

  INSTALLS += target desktop icon64 configs

  configs.path = ~/.mdictionary
  configs.files += ../../../data/mdictionary.defaults

  target.path =$$BINDIR

maemo5 {
  desktop.path = $$DATADIR/applications/hildon
  icon64.path = $$DATADIR/icons/hicolor/64x64/hildon
}

!maemo5 {
  desktop.path = $$DATADIR/applications
  icon64.path = $$DATADIR/icons
}
  desktop.files += ../../../data/other/$${TARGET}.desktop
  icon64.files += ../../../data/icons/64x64/$${TARGET}.png
}

RESOURCES += \
    gui/gui.qrc