git.maemo.org Git - cinaest/blob - src/plugins/imdb-plugin.vala

   1 /* This file is part of Cinaest.
   2  *
   3  * Copyright (C) 2009 Philipp Zabel
   4  *
   5  * Cinaest is free software: you can redistribute it and/or modify
   6  * it under the terms of the GNU General Public License as published by
   7  * the Free Software Foundation, either version 3 of the License, or
   8  * (at your option) any later version.
   9  *
  10  * Cinaest is distributed in the hope that it will be useful,
  11  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  12  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  13  * GNU General Public License for more details.
  14  *
  15  * You should have received a copy of the GNU General Public License
  16  * along with Cinaest. If not, see <http://www.gnu.org/licenses/>.
  17  */
  18
  19 using Gtk;
  20 using Hildon;
  21
  22 class IMDbPlugin : Plugin {
  23         private dynamic DBus.Object server;
  24         List<MovieSource> sources;
  25         private weak Osso.Context osso_context;
  26
  27         public override void hello (Gtk.Window window, Osso.Context context) {
  28                 string filename = Path.build_filename (Environment.get_user_cache_dir(),
  29                                                        "cinaest", "imdb.db", null);
  30                 stdout.printf ("IMDb Plugin Loaded. Cache Db: %s\n", filename);
  31
  32                 if (!FileUtils.test (filename, FileTest.EXISTS)) {
  33                         var note = new Note.confirmation (window, "There is no local copy of the Internet Movie Database (IMDb). Download it now?\n\nThis can be started later from the Settings dialog.");
  34
  35                         var response = note.run ();
  36                         note.destroy ();
  37
  38                         if (response == ResponseType.OK) {
  39                                 download_imdb (window);
  40                         }
  41                 }
  42
  43                 var source = new IMDBSource ();
  44
  45                 sources = new List<MovieSource> ();
  46                 sources.append (source);
  47
  48                 osso_context = context;
  49
  50                 // FIXME - this forces the inclusion of config.h
  51                 (void) Config.GETTEXT_PACKAGE;
  52         }
  53
  54         private void download_imdb (Gtk.Window window) {
  55                 var picker = new PickerDialog (window);
  56                 var selector = new TouchSelector.text ();
  57                 string[] mirrors;
  58
  59                 try {
  60                         var conn = DBus.Bus.get (DBus.BusType.SESSION);
  61                         server = conn.get_object (IMDbDownloader.DBUS_SERVICE,
  62                                                   IMDbDownloader.DBUS_OBJECT,
  63                                                   IMDbDownloader.DBUS_IFACE);
  64
  65                         mirrors = server.get_mirrors ();
  66                 } catch (DBus.Error e) {
  67                         warning ("Failed connect to IMDb downloader: %s", e.message);
  68                         return;
  69                 }
  70
  71                 foreach (string mirror in mirrors) {
  72                         selector.append_text (mirror);
  73                 }
  74
  75                 picker.set_title ("Please select a source mirror");
  76                 picker.set_selector (selector);
  77
  78                 int res = picker.run();
  79                 string mirror = selector.get_current_text ();
  80                 picker.destroy();
  81
  82                 if (res == ResponseType.OK) {
  83                         var download = new IMDbDownloadDialog (window);
  84                         download.run (server, mirror);
  85                         download.destroy ();
  86                 }
  87         }
  88
  89         public override unowned List<MovieSource> get_sources () {
  90                 return sources;
  91         }
  92
  93         public override List<MovieAction> get_actions (Movie movie, Gtk.Window window) {
  94                 List<MovieAction> list = null;
  95
  96                 if (movie.year > 0)
  97                         list.append (new MovieAction (_("IMDb page"), on_visit_imdb, movie, window));
  98                 else
  99                         list.append (new MovieAction (_("Lookup on IMDb"), on_visit_imdb, movie, window));
 100
 101                 return list;
 102         }
 103
 104         private void on_visit_imdb (Movie movie, Gtk.Window window) {
 105                 var url = "http://www.imdb.com/find?s=tt&q=" + movie.title.replace(" ", "+");
 106                 if (movie.year > 0)
 107                         url += "+(%d)".printf (movie.year);
 108
 109                 var status = osso_context.rpc_run_with_defaults ("osso_browser", "open_new_window", null, 's', url, 'b', false);
 110                 if (status != Osso.Status.OK) {
 111                         var banner = (Banner) Hildon.Banner.show_information_with_markup (window, null, "Failed to open browser.");
 112                         banner.set_timeout (1500);
 113                 }
 114         }
 115
 116         public override void settings_dialog (Gtk.Window window) {
 117                 var dialog = new Gtk.Dialog ();
 118                 dialog.set_transient_for (window);
 119                 dialog.set_title (_("IMDb plugin settings"));
 120
 121                 string updated;
 122                 string filename = Path.build_filename (Environment.get_user_cache_dir(),
 123                                                        "cinaest", "imdb.db", null);
 124                 var file = File.new_for_path (filename);
 125                 try {
 126                         var info = file.query_info (FILE_ATTRIBUTE_TIME_MODIFIED, FileQueryInfoFlags.NONE, null);
 127                         TimeVal tv;
 128                         info.get_modification_time (out tv);
 129
 130                         var date = Date ();
 131                         date.set_time_val (tv);
 132                         char[] s = new char[64];
 133                         date.strftime (s, "%x");
 134                         updated = (string) s;
 135                 } catch (Error e) {
 136                         updated = _("unknown");
 137                 }
 138
 139                 var download = new Hildon.Button.with_text (SizeType.FINGER_HEIGHT, ButtonArrangement.VERTICAL, _("Download"), _("Last update: ") + updated);
 140
 141                 VBox content = (VBox) dialog.get_content_area ();
 142                 content.pack_start (download, true, true, 0);
 143
 144                 download.clicked.connect (() => {
 145                         download_imdb (window);
 146                 });
 147
 148                 dialog.show_all ();
 149                 dialog.run ();
 150                 dialog.destroy ();
 151         }
 152
 153         public override unowned string get_name () {
 154                 return "IMDb";
 155         }
 156 }
 157
 158 class IMDBSource : MovieSource {
 159         MovieSource.ReceiveMovieFunction _get_callback;
 160         public override async void get_movies (MovieFilter filter, MovieSource.ReceiveMovieFunction callback, int limit, Cancellable? cancellable) {
 161                 // IMDb has too many movies
 162                 if (filter.title == "")
 163                         return;
 164                 var sqlite = new IMDbSqlite (Path.build_filename (Environment.get_user_cache_dir (),
 165                                              "cinaest", "imdb.db", null));
 166
 167                 _get_callback = callback;
 168                 yield sqlite.query (filter, receive_movie, cancellable);
 169         }
 170
 171         private void receive_movie (string title, int year, int rating, int genres) {
 172                 Movie movie = new Movie ();
 173                 movie.title = title;
 174                 movie.year = year;
 175                 movie.rating = rating;
 176                 movie.genres.field = genres;
 177                 // TODO - depending on settings, this could be something else, like director info or runtime
 178                 movie.secondary = movie.genres.to_string ();
 179                 _get_callback (movie);
 180         }
 181
 182         public override void add_movie (Movie movie) {
 183         }
 184
 185         public override unowned string get_name () {
 186                 return "IMDb";
 187         }
 188
 189         public override unowned string get_description () {
 190                 return "Movies on IMDb";
 191         }
 192
 193         public override bool get_editable () {
 194                 return false;
 195         }
 196 }
 197
 198 [ModuleInit]
 199 public Type register_plugin () {
 200         // types are registered automatically
 201         return typeof (IMDbPlugin);
 202 }