git.maemo.org Git - confmgr/blob - src/src.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-06-23T14:10:47
   4 #
   5 #-------------------------------------------------
   6
   7 QT       += core gui
   8 QT       += xml maemo5 dbus
   9
  10 TARGET = confmgr
  11 TEMPLATE = app
  12 DEPENDPATH += .
  13 DESTDIR = ../
  14
  15 SOURCES += main.cpp\
  16         mainwindow.cpp \
  17     xmlutil.cpp \
  18     profile.cpp \
  19     config.cpp \
  20     addprofile.cpp \
  21     addstep.cpp \
  22     dbusutility.cpp \
  23     confmanager.cpp \
  24     aboutdialog.cpp
  25
  26 HEADERS  += mainwindow.h \
  27     xmlutil.h \
  28     profile.h \
  29     config.h \
  30     addprofile.h \
  31     addstep.h \
  32     dbusutility.h \
  33     confmanager.h \
  34     aboutdialog.h
  35
  36 FORMS    += mainwindow.ui \
  37     addprofile.ui \
  38     addstep.ui \
  39     aboutdialog.ui
  40
  41 CONFIG += mobility
  42 MOBILITY =
  43
  44 symbian {
  45     TARGET.UID3 = 0xea1d6940
  46     # TARGET.CAPABILITY +=
  47     TARGET.EPOCSTACKSIZE = 0x14000
  48     TARGET.EPOCHEAPSIZE = 0x020000 0x800000
  49 }
  50
  51 OTHER_FILES += \
  52     config.xml
  53
  54 unix {
  55   #VARIABLES
  56   isEmpty(PREFIX) {
  57     PREFIX = /usr/local
  58   }
  59   BINDIR = $$PREFIX/bin
  60   DATADIR =$$PREFIX/share
  61
  62   DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"
  63
  64   #MAKE INSTALL
  65
  66   INSTALLS += target desktop service iconxpm icon26 icon48 icon64
  67
  68   target.path =$$BINDIR
  69
  70   desktop.path = $$DATADIR/applications/hildon
  71   desktop.files += $${TARGET}.desktop
  72
  73   service.path = $$DATADIR/dbus-1/services
  74   service.files += $${TARGET}.service
  75
  76   iconxpm.path = $$DATADIR/pixmap
  77   iconxpm.files += ../data/maemo/$${TARGET}.xpm
  78
  79   icon26.path = $$DATADIR/icons/hicolor/26x26/apps
  80   icon26.files += ../data/26x26/$${TARGET}.png
  81
  82   icon48.path = $$DATADIR/icons/hicolor/48x48/apps
  83   icon48.files += ../data/48x48/$${TARGET}.png
  84
  85   icon64.path = $$DATADIR/icons/hicolor/64x64/apps
  86   icon64.files += ../data/64x64/$${TARGET}.png
  87 }