X-Git-Url: http://git.maemo.org/git/?p=dh-make-perl;a=blobdiff_plain;f=dev%2Fi386%2Flibperl-critic-perl%2Flibperl-critic-perl-1.088%2Flib%2FPerl%2FCritic%2FPolicy%2FBuiltinFunctions%2FProhibitSleepViaSelect.pm;fp=dev%2Fi386%2Flibperl-critic-perl%2Flibperl-critic-perl-1.088%2Flib%2FPerl%2FCritic%2FPolicy%2FBuiltinFunctions%2FProhibitSleepViaSelect.pm;h=ca68916560da445f5d2f22d82c161ca7c4a95a12;hp=0000000000000000000000000000000000000000;hb=da95c414033799c3a62606f299c3c00b5c77ca11;hpb=2d38e14bacbb15b98e539843a40b3c52a225f493

diff --git a/dev/i386/libperl-critic-perl/libperl-critic-perl-1.088/lib/Perl/Critic/Policy/BuiltinFunctions/ProhibitSleepViaSelect.pm b/dev/i386/libperl-critic-perl/libperl-critic-perl-1.088/lib/Perl/Critic/Policy/BuiltinFunctions/ProhibitSleepViaSelect.pm
new file mode 100644
index 0000000..ca68916
--- /dev/null
+++ b/dev/i386/libperl-critic-perl/libperl-critic-perl-1.088/lib/Perl/Critic/Policy/BuiltinFunctions/ProhibitSleepViaSelect.pm
@@ -0,0 +1,110 @@
+##############################################################################
+#      $URL: http://perlcritic.tigris.org/svn/perlcritic/trunk/Perl-Critic/lib/Perl/Critic/Policy/BuiltinFunctions/ProhibitSleepViaSelect.pm $
+#     $Date: 2008-07-03 10:19:10 -0500 (Thu, 03 Jul 2008) $
+#   $Author: clonezone $
+# $Revision: 2489 $
+##############################################################################
+
+package Perl::Critic::Policy::BuiltinFunctions::ProhibitSleepViaSelect;
+
+use 5.006001;
+use strict;
+use warnings;
+use Readonly;
+
+use Perl::Critic::Utils qw{ :severities :classification :ppi };
+use base 'Perl::Critic::Policy';
+
+our $VERSION = '1.088';
+
+#-----------------------------------------------------------------------------
+
+Readonly::Scalar my $DESC => q{"select" used to emulate "sleep"};
+Readonly::Scalar my $EXPL => [168];
+Readonly::Scalar my $UNDEFS_IN_SLEEP_SELECT => 3;
+
+#-----------------------------------------------------------------------------
+
+sub supported_parameters { return ()                  }
+sub default_severity     { return $SEVERITY_HIGHEST   }
+sub default_themes       { return qw( core pbp bugs ) }
+sub applies_to           { return 'PPI::Token::Word'  }
+
+#-----------------------------------------------------------------------------
+
+sub violates {
+    my ($self, $elem, undef) = @_;
+
+    return if ($elem ne 'select');
+    return if ! is_function_call($elem);
+
+    if (
+            $UNDEFS_IN_SLEEP_SELECT
+        ==  grep { $_->[0] eq 'undef' } parse_arg_list($elem)
+    ) {
+        return $self->violation( $DESC, $EXPL, $elem );
+    }
+    return; #ok!
+}
+
+1;
+
+__END__
+
+#-----------------------------------------------------------------------------
+
+=pod
+
+=head1 NAME
+
+Perl::Critic::Policy::BuiltinFunctions::ProhibitSleepViaSelect - Use L<Time::HiRes> instead of something like C<select(undef, undef, undef, .05)>.
+
+=head1 AFFILIATION
+
+This Policy is part of the core L<Perl::Critic> distribution.
+
+
+=head1 DESCRIPTION
+
+Conway discourages the use of C<select()> for performing non-integer
+sleeps.  Although documented in L<perlfunc>, it's something that
+generally requires the reader to read C<perldoc -f select> to figure
+out what it should be doing.  Instead, Conway recommends that you use
+the C<Time::HiRes> module when you want to sleep.
+
+  select undef, undef, undef, 0.25;         # not ok
+
+  use Time::HiRes;
+  sleep( 0.25 );                            # ok
+
+
+=head1 CONFIGURATION
+
+This Policy is not configurable except for the standard options.
+
+
+=head1 SEE ALSO
+
+L<Time::HiRes>.
+
+=head1 AUTHOR
+
+Graham TerMarsch <graham@howlingfrog.com>
+
+=head1 COPYRIGHT
+
+Copyright (C) 2005-2007 Graham TerMarsch.  All rights reserved.
+
+This program is free software; you can redistribute it and/or modify
+it under the same terms as Perl itself.
+
+=cut
+
+# Local Variables:
+#   mode: cperl
+#   cperl-indent-level: 4
+#   fill-column: 78
+#   indent-tabs-mode: nil
+#   c-indentation-style: bsd
+# End:
+# ex: set ts=8 sts=4 sw=4 tw=78 ft=perl expandtab shiftround :