git.maemo.org Git - gnuplot/blob - demo/fillbetween.dem

   1 #
   2 # Demonstrate filling the area between two curves
   3 # and also the application of fillstyle to filled curves.
   4 # Ethan Merritt  <merritt@u.washington.edu>
   5 # June 2004
   6 #
   7 set title "Fill area between two curves"
   8 set style data lines
   9 set xrange [10:*]
  10 set yrange [0:175]
  11 plot 'silver.dat' u 1:2:3 w filledcu, \
  12       '' u 1:2 lt -1 notitle, '' u 1:3 lt -1 notitle
  13 pause -1 "Hit return to continue"
  14 set style fill pattern 2
  15 set title "Fill area between two curves (pattern fill)"
  16 replot
  17 pause -1 "Hit return to continue"
  18 set title "Fill area between two curves (above/below)"
  19 set style fill solid 1.0 noborder
  20 set xrange [250:500]
  21 set auto y
  22 plot 'silver.dat' u 1:2:($3+$1/50.) w filledcurves above title 'Above', \
  23                '' u 1:2:($3+$1/50.) w filledcurves below title 'Below', \
  24                '' u 1:2 lt -1 lw 2 title 'curve 1', \
  25                '' u 1:($3+$1/50.) lt 3 lw 2 title 'curve 2'
  26 pause -1 "Hit return to continue"
  27 reset