git.maemo.org Git - gnuplot/blob - demo/fillcrvs.dem

   1 #
   2 # $Id: fillcrvs.dem,v 1.5 2004/09/28 06:06:10 sfeam Exp $
   3 #
   4 ### Demo for 'with filledcurves'
   5
   6 reset
   7
   8 set title
   9 set key outside
  10 set title "plot with filledcurve [options]"
  11 plot [-10:10] [-5:3] \
  12         1.5+sin(x)/x with filledcurve x2, \
  13         sin(x)/x with filledcurve, \
  14         1+sin(x)/x with lines, \
  15         -1+sin(x)/x with filledcurve y1=-2, \
  16         -2.5+sin(x)/x with filledcurve xy=-5,-4., \
  17         -4.3+sin(x)/x with filledcurve x1, \
  18         (x>3.5 ? x/3-3 : 1/0) with filledcurve y2
  19 pause -1 'Press Return to continue'
  20
  21 set key on
  22 set title "Intersection of two parabolas"
  23 plot x*x with filledcurves, 50-x*x with filledcurves, x*x with line lt 1
  24 pause -1 'Press Return to continue'
  25
  26 set grid front
  27 set title "Filled sinus and cosinus curves"
  28 plot 2+sin(x)**2 with filledcurve x1, cos(x)**2 with filledcurve x1
  29 pause -1 'Press Return to continue'
  30
  31 set title "The red bat: abs(x) with filledcurve xy=2,5"
  32 plot abs(x) with filledcurve xy=2,5
  33 pause -1 'Press Return to continue'
  34
  35 set title "Some sqrt stripes on filled graph background"
  36 plot [0:10] [-8:6] \
  37         -8 with filledcurve x2 lt 15, \
  38         sqrt(x) with filledcurves y1=-0.5, \
  39         sqrt(10-x)-4.5 with filledcurves y1=-5.5
  40 pause -1 'Press Return to continue'
  41
  42 reset
  43 set title "Let's smile with parametric filled curves"
  44 set size square
  45 set key off
  46 unset border
  47 unset xtics
  48 unset ytics
  49 set grid
  50 set arrow 1 from -0.1,0.26 to 0.18,-0.17 front size 0.1,40 lt 5 lw 4
  51 set label 1 "gnuplot" at 0,1.2 center front
  52 set label 2 "gnuplot" at 0.02,-0.6 center front
  53 set parametric
  54 set xrange [-1:1]
  55 set yrange [-1:1.6]
  56 plot [t=-pi:pi] \
  57         sin(t),cos(t) with filledcurve xy=0,0 lt 15,    \
  58         sin(t)/8-0.5,cos(t)/8+0.4 with filledcurve lt 3,        \
  59         sin(t)/8+0.5,cos(t)/8+0.4 with filledcurve lt 3,        \
  60         t/5,abs(t/5)-0.8 with filledcurve xy=0.1,-0.5 lt 1, \
  61         t/3,1.52-abs(t/pi) with filledcurve xy=0,1.8 lt -1
  62 pause -1 'Press Return to continue'
  63
  64 reset