# -------------------------------------------------
# Project created by QtCreator 2010-01-15T21:14:13
# -------------------------------------------------
TARGET = hikingdiary
TEMPLATE = app
QT += xml
SOURCES += main.cpp \
    mainwindow.cpp \
    maemo5location.cpp \
    maemo5locationprivate.cpp \
    xmlparser.cpp \
    diarydata.cpp \
    diarydatamanager.cpp
HEADERS += mainwindow.h \
    maemo5location.h \
    maemo5locationprivate.h \
    xmlparser.h \
    diarydata.h \
    diarydatamanager.h
OTHER_FILES += 
LIBS += 
CONFIG += link_pkgconfig
INCLUDEPATH += /usr/include/location \
    /usr/include/glib-2.0 \
    /usr/lib/glib-2.0/include
PKGCONFIG += glib-2.0 \
    liblocation
exists(/usr/lib/liblocation.so) { 
    DEFINES += LIBLOCATION
    message(liblocation found)
}

# -----------------------------------------------------------------
# Debian packetizing additions
# -----------------------------------------------------------------
unix { 
    # VARIABLES
    isEmpty(PREFIX):PREFIX = /usr
    BINDIR = $$PREFIX/bin
    DATADIR = $$PREFIX/share
    DEFINES += DATADIR=\\\"$$DATADIR\\\" \
        PKGDATADIR=\\\"$$PKGDATADIR\\\"
    
    # MAKE INSTALL
    desktop.path = $$DATADIR/applications/hildon
    desktop.files += hikingdiary.desktop
    INSTALLS += desktop
    icon26.path = $$DATADIR/icons/hicolor/26x26/apps
    icon26.files += ../res/icon/26x26/hikingdiary.png
    INSTALLS += icon26
    icon48.path = $$DATADIR/icons/hicolor/48x48/apps
    icon48.files += ../res/icon/48x48/hikingdiary.png
    INSTALLS += icon48
    icon64.path = $$DATADIR/icons/hicolor/64x64/apps
    icon64.files += ../res/icon/64x64/hikingdiary.png
    INSTALLS += icon64
    target.path = $$BINDIR
    INSTALLS += target
}