TEMPLATE = app
TARGET = irwi

# DEFINES += LIRC_USEQTSOCKET

SOURCES += rating.cpp
SOURCES += settingsdlg.cpp
SOURCES += main.cpp
SOURCES += mainwidget.cpp
SOURCES += irctrl.cpp
SOURCES += remote.cpp
SOURCES += remotedbmgr.cpp
SOURCES += selectremotedlg.cpp
SOURCES += advsettingsdlg.cpp
SOURCES += settingstable.cpp
SOURCES += aboutdlg.cpp
SOURCES += remotelistwidgetitem.cpp
SOURCES += onlinepollerthread.cpp

HEADERS += rating.h
HEADERS += settingsdlg.h
HEADERS += mainwidget.h
HEADERS += irctrl.h
HEADERS += remote.h
HEADERS += remotedbmgr.h
HEADERS += selectremotedlg.h
HEADERS += advsettingsdlg.h
HEADERS += settingstable.h
HEADERS += aboutdlg.h
HEADERS += remotelistwidgetitem.h
HEADERS += onlinepollerthread.h

include(qmaemo5homescreenadaptor/qmaemo5homescreenadaptor.pri)

OBJECTS_DIR = obj
MOC_DIR = moc

QT += network
QT += xml
QT += dbus

CONFIG += mobility
MOBILITY += bearer

unix {
#VARIABLES
isEmpty(PREFIX) {
    PREFIX = /usr
}

BINDIR = $$PREFIX/bin
DATADIR =$$PREFIX/share

DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"

#MAKE INSTALL

INSTALLS += target desktop iconxpm icon26 icon48 icon64

  target.path = $$PREFIX/lib/hildon-desktop

  desktop.path = $$PREFIX/share/applications/hildon-home
  desktop.files += $${TARGET}.desktop

  iconxpm.path = $$DATADIR/pixmap
  iconxpm.files += ../data/maemo/$${TARGET}.xpm

  icon26.path = $$DATADIR/icons/hicolor/26x26/apps
  icon26.files += ../data/26x26/$${TARGET}.png

  icon48.path = $$DATADIR/icons/hicolor/48x48/apps
  icon48.files += ../data/48x48/$${TARGET}.png

  icon64.path = $$DATADIR/icons/hicolor/64x64/apps
  icon64.files += ../data/64x64/$${TARGET}.png
}