QT += network sql maemo5
TARGET = jenirokd
CONFIG += qdbus
TEMPLATE = app
SOURCES += main.cpp \
    calllistener.cpp \
    informationbox.cpp \
    ../common/source.cpp \
    ../common/eniro.cpp \
    ../common/mobil1881.cpp \
    ../common/sourcecoreconfig.cpp \
    ../common/enirocoreconfig.cpp \
    ../common/emptycoreconfig.cpp \
    ../common/contactmanager.cpp \
    ../common/db.cpp \
    ../common/settings.cpp \
    ../common/connectionmanager.cpp \
    ../common/cache.cpp \
    ../common/dastelefonbuch.cpp
HEADERS += calllistener.h \
    informationbox.h \
    ../common/source.h \
    ../common/eniro.h \
    ../common/mobil1881.h \
    ../common/enirocoreconfig.h \
    ../common/sourcecoreconfig.h \
    ../common/emptycoreconfig.h \
    ../common/contactmanager.h \
    ../common/db.h \
    ../common/settings.h \
    ../common/connectionmanager.h \
    ../common/cache.h \
    ../common/dastelefonbuch.h
RESOURCES = ../common/translations.qrc
INCLUDEPATH += ../common
CONFIG += link_pkgconfig
PKGCONFIG += libebook-1.2 gconf-2.0

unix {
  #VARIABLES
  isEmpty(PREFIX) {
    PREFIX = /usr
  }

  BINDIR = $$PREFIX/bin
  DATADIR =$$PREFIX/share

  DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"

  #MAKE INSTALL

  INSTALLS += target init event

  target.path =$$BINDIR

  init.path = /etc/init.d
  init.files += data/init.d/jenirokd

  event.path = /etc/event.d
  event.files += data/event.d/jenirokd
}