QT += network sql maemo5
TARGET = jenirok
TEMPLATE = app
SOURCES += main.cpp \
    mainwindow.cpp \
    searchdialog.cpp \
    resultwindow.cpp \
    detailwindow.cpp \
    settingsdialog.cpp \
    aboutdialog.cpp \
    buttonselector.cpp \
    connectionselector.cpp \
    daemon.cpp \
    ../common/source.cpp \
    ../common/eniro.cpp \
    ../common/mobil1881.cpp \
    ../common/sourcecoreconfig.cpp \
    ../common/emptycoreconfig.cpp \
    sourceguiconfig.cpp \
    ../common/enirocoreconfig.cpp \
    eniroguiconfig.cpp \
    emptyguiconfig.cpp \
    ../common/contactmanager.cpp \
    ../common/db.cpp \
    ../common/settings.cpp \
    ../common/connectionmanager.cpp \ 
    ../common/cache.cpp \
    ../common/dastelefonbuch.cpp \
    logwindow.cpp \
    listwidget.cpp \
    ovimaps.cpp
HEADERS += mainwindow.h \
    searchdialog.h \
    resultwindow.h \
    detailwindow.h \
    settingsdialog.h \
    aboutdialog.h \
    buttonselector.h \
    connectionselector.h \
    daemon.h \
    ../common/source.h \
    ../common/eniro.h \
    ../common/mobil1881.h \
    ../common/sourcecoreconfig.h \
    ../common/emptycoreconfig.h \
    sourceguiconfig.h \
    ../common/enirocoreconfig.h \
    eniroguiconfig.h \
    emptyguiconfig.h \
    ../common/contactmanager.h \
    ../common/db.h \
    ../common/settings.h \
    ../common/connectionmanager.h \
    ../common/cache.h \
    ../common/dastelefonbuch.h \
    logwindow.h \
    listwidget.h \
    ovimaps.h
RESOURCES = icons.qrc ../common/translations.qrc
TRANSLATIONS = ../common/translations/fi_FI.ts
INCLUDEPATH += ../common
CONFIG += link_pkgconfig
PKGCONFIG += libebook-1.2 gconf-2.0

unix {
  #VARIABLES
  isEmpty(PREFIX) {
    PREFIX = /usr
  }

  BINDIR = $$PREFIX/bin
  DATADIR =$$PREFIX/share

  DEFINES += DATADIR=\\\"$$DATADIR\\\" PKGDATADIR=\\\"$$PKGDATADIR\\\"

  #MAKE INSTALL

  INSTALLS += target desktop iconxpm icon26 icon48 icon64

  target.path =$$BINDIR

  desktop.path = $$DATADIR/applications/hildon
  desktop.files += data/$${TARGET}.desktop

  iconxpm.path = $$DATADIR/pixmap
  iconxpm.files += data/maemo/$${TARGET}.xpm

  icon26.path = $$DATADIR/icons/hicolor/26x26/apps
  icon26.files += data/26x26/$${TARGET}.png

  icon48.path = $$DATADIR/icons/hicolor/48x48/apps
  icon48.files += data/48x48/$${TARGET}.png

  icon64.path = $$DATADIR/icons/hicolor/64x64/apps
  icon64.files += data/64x64/$${TARGET}.png
}