git.maemo.org Git - mafwsubrenderer/blob - gst-plugins-base-subtitles0.10/configure.ac

   1 AC_PREREQ(2.60)
   2
   3 dnl please read gstreamer/docs/random/autotools before changing this file
   4
   5 dnl initialize autoconf
   6 dnl releases only do -Wall, git and prerelease does -Werror too
   7 dnl use a three digit version number for releases, and four for git/prerelease
   8 AC_INIT(GStreamer Base Plug-ins, 0.10.34,
   9     http://bugzilla.gnome.org/enter_bug.cgi?product=GStreamer,
  10     gst-plugins-base)
  11
  12 AG_GST_INIT
  13
  14 dnl initialize automake
  15 AM_INIT_AUTOMAKE([-Wno-portability 1.10])
  16
  17 dnl define PACKAGE_VERSION_* variables
  18 AS_VERSION
  19
  20 dnl check if this is a release version
  21 AS_NANO(GST_GIT="no", GST_GIT="yes")
  22
  23 dnl can autoconf find the source ?
  24 AC_CONFIG_SRCDIR([gst/audiotestsrc/gstaudiotestsrc.c])
  25
  26 dnl define the output header for config
  27 AM_CONFIG_HEADER([config.h])
  28
  29 dnl AM_MAINTAINER_MODE only provides the option to configure to enable it
  30 AM_MAINTAINER_MODE
  31
  32 dnl sets host_* variables
  33 AC_CANONICAL_HOST
  34
  35 dnl use pretty build output with automake >= 1.11
  36 m4_ifdef([AM_SILENT_RULES],[AM_SILENT_RULES([yes])],
  37   [AM_DEFAULT_VERBOSITY=1
  38    AC_SUBST(AM_DEFAULT_VERBOSITY)])
  39
  40 dnl our libraries and install dirs use major.minor as a version
  41 GST_MAJORMINOR=$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR
  42 dnl we override it here if we need to for the release candidate of new series
  43 GST_MAJORMINOR=0.10
  44 AC_SUBST(GST_MAJORMINOR)
  45
  46 dnl CURRENT, REVISION, AGE
  47 dnl - library source changed -> increment REVISION
  48 dnl - interfaces added/removed/changed -> increment CURRENT, REVISION = 0
  49 dnl - interfaces added -> increment AGE
  50 dnl - interfaces removed -> AGE = 0
  51 dnl sets GST_LT_LDFLAGS
  52 AS_LIBTOOL(GST, 24, 0, 24)
  53
  54 dnl FIXME: this macro doesn't actually work;
  55 dnl the generated libtool script has no support for the listed tags.
  56 dnl So this needs to be fixed first if we want to use this
  57 dnl AS_LIBTOOL_TAGS
  58
  59 AC_LIBTOOL_WIN32_DLL
  60 AM_PROG_LIBTOOL
  61
  62 dnl *** required versions of GStreamer stuff ***
  63 GST_REQ=0.10.34
  64
  65 dnl *** autotools stuff ****
  66
  67 dnl allow for different autotools
  68 AS_AUTOTOOLS_ALTERNATE
  69
  70 dnl Add parameters for aclocal
  71 AC_SUBST(ACLOCAL_AMFLAGS, "-I m4 -I common/m4")
  72
  73 dnl set up gettext
  74 dnl the version check needs to stay here because autopoint greps for it
  75 AM_GNU_GETTEXT_VERSION([0.14])
  76 AM_GNU_GETTEXT([external])
  77 AG_GST_GETTEXT([gst-plugins-base-$GST_MAJORMINOR])
  78
  79 dnl *** check for arguments to configure ***
  80
  81 AG_GST_ARG_DEBUG
  82 AG_GST_ARG_PROFILING
  83 AG_GST_ARG_VALGRIND
  84 AG_GST_ARG_GCOV
  85
  86 AG_GST_ARG_EXAMPLES
  87
  88 AG_GST_ARG_WITH_PKG_CONFIG_PATH
  89 AG_GST_ARG_WITH_PACKAGE_NAME
  90 AG_GST_ARG_WITH_PACKAGE_ORIGIN
  91
  92 AG_GST_PKG_CONFIG_PATH
  93
  94 dnl let distro override plugin install helper path
  95 AC_ARG_WITH(install-plugins-helper,
  96   AC_HELP_STRING([--with-install-plugins-helper],
  97     [specify path of helper script to call to install plugins]),
  98   [
  99     case "${withval}" in
 100       yes) AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 101       no)  AC_MSG_ERROR(bad value ${withval} for --with-install-plugins-helper) ;;
 102       *)   GST_INSTALL_PLUGINS_HELPER="${withval}" ;;
 103     esac
 104   ],
 105   [
 106     dnl Default value
 107     AS_AC_EXPAND(GST_INSTALL_PLUGINS_HELPER,${libexecdir}/gst-install-plugins-helper)
 108   ]
 109 )
 110 AC_MSG_NOTICE(Using $GST_INSTALL_PLUGINS_HELPER as plugin install helper)
 111 AC_DEFINE_UNQUOTED(GST_INSTALL_PLUGINS_HELPER, "$GST_INSTALL_PLUGINS_HELPER",
 112     [plugin install helper script])
 113 AC_SUBST(GST_INSTALL_PLUGINS_HELPER)
 114
 115 AG_GST_ARG_WITH_PLUGINS
 116
 117 AG_GST_ARG_ENABLE_EXTERNAL
 118
 119 AG_GST_ARG_ENABLE_EXPERIMENTAL
 120
 121 dnl *** checks for platform ***
 122
 123 dnl * hardware/architecture *
 124
 125 dnl common/m4/gst-arch.m4
 126 dnl check CPU type
 127 AG_GST_ARCH
 128
 129 dnl check for large file support
 130 dnl affected plugins must include config.h
 131 AC_SYS_LARGEFILE
 132
 133 dnl *** checks for programs ***
 134
 135 dnl find a compiler
 136 AC_PROG_CC
 137 AC_PROG_CC_STDC
 138
 139 dnl check if the compiler supports '-c' and '-o' options
 140 AM_PROG_CC_C_O
 141
 142 dnl determine if c++ is available on this system
 143 AC_PROG_CXX
 144 dnl CXX may be set to some default even if no c++ compiler is available
 145 dnl (thanks autotools!), so just try to compile some c++ code to make sure
 146 AC_LANG_PUSH([C++])
 147 AC_TRY_COMPILE([ class Foo { int bar; };], , working_cxx=yes, working_cxx=no)
 148 AC_LANG_POP([C++])
 149 AC_MSG_NOTICE([working c++ compiler found: $working_cxx])
 150 AM_CONDITIONAL(HAVE_CXX, test "x$working_cxx" = "xyes")
 151
 152 AC_PATH_PROG(VALGRIND_PATH, valgrind, no)
 153 AM_CONDITIONAL(HAVE_VALGRIND, test ! "x$VALGRIND_PATH" = "xno")
 154
 155 dnl check for gobject-introspection
 156 GOBJECT_INTROSPECTION_CHECK([0.9.12])
 157
 158 dnl check for documentation tools
 159 GTK_DOC_CHECK([1.3])
 160 AS_PATH_PYTHON([2.1])
 161 AG_GST_PLUGIN_DOCS([1.3],[2.1])
 162
 163 dnl *** checks for libraries ***
 164
 165 dnl libm, for sin() etc.
 166 AC_CHECK_LIBM
 167 AC_SUBST(LIBM)
 168
 169 dnl *** checks for header files ***
 170
 171 dnl check if we have ANSI C header files
 172 AC_HEADER_STDC
 173
 174 dnl used in gst/ffmpegcolorspace/mem.c
 175 dnl FIXME: could be fixed by redefining av_malloc and av_free to GLib's
 176 AC_CHECK_HEADERS([malloc.h])
 177
 178 ac_cppflags_save="$CPPFLAGS"
 179 CPPFLAGS="`$PKG_CONFIG --cflags libxml-2.0`"
 180 AC_COMPILE_IFELSE(
 181   AC_LANG_PROGRAM([
 182 #include <libxml/HTMLparser.h>
 183                      ],[
 184 #ifndef LIBXML_HTML_ENABLED
 185 #error libxml2 has no HTML support
 186 #endif /* LIBXML_HTML_ENABLED */
 187                    ]), HAVE_LIBXML_HTML="yes", HAVE_LIBXML_HTML="no")
 188 CPPFLAGS="$ac_cppflags_save"
 189 AM_CONDITIONAL(HAVE_LIBXML_HTML, test "x$HAVE_LIBXML_HTML" = "xyes")
 190
 191 dnl used in gst/tcp
 192 AC_CHECK_HEADERS([sys/socket.h],
 193   HAVE_SYS_SOCKET_H="yes", HAVE_SYS_SOCKET_H="no")
 194 AM_CONDITIONAL(HAVE_SYS_SOCKET_H, test "x$HAVE_SYS_SOCKET_H" = "xyes")
 195
 196 dnl used in gst-libs/gst/rtsp
 197 AC_CHECK_HEADERS([winsock2.h], HAVE_WINSOCK2_H=yes)
 198 if test "x$HAVE_WINSOCK2_H" = "xyes"; then
 199   WIN32_LIBS="-lws2_32"
 200   AC_SUBST(WIN32_LIBS)
 201 fi
 202
 203 dnl check for hstrerror, for gst-libs/gst/rtsp
 204 save_libs="$LIBS"
 205 AC_CHECK_FUNC(hstrerror, ,
 206     AC_CHECK_LIB(resolv, hstrerror, ,
 207         [AC_DEFINE(NO_HSTRERROR, 1,
 208              [Define if you have no native hstrerror() function.])]))
 209 HSTRERROR_LIBS=$LIBS
 210 AC_SUBST(HSTRERROR_LIBS)
 211 LIBS="$save_libs"
 212
 213 dnl used in gst-libs/gst/pbutils and associated unit test
 214 AC_CHECK_HEADERS([process.h sys/types.h sys/wait.h sys/stat.h])
 215
 216 dnl ffmpegcolorspace includes _stdint.h
 217 dnl also, Windows does not have long long
 218 AX_CREATE_STDINT_H
 219
 220 dnl *** checks for functions ***
 221 AC_CHECK_FUNCS([localtime_r gmtime_r])
 222
 223 dnl *** checks for math functions ***
 224 LIBS_SAVE=$LIBS
 225 LIBS="$LIBS $LIBM"
 226 AC_CHECK_FUNCS(log2)
 227 LIBS=$LIBS_SAVE
 228
 229 dnl *** checks for types/defines ***
 230
 231 dnl Check for FIONREAD ioctl declaration
 232 dnl used in gst/tcp
 233 GST_CHECK_FIONREAD
 234
 235 dnl *** checks for structures ***
 236
 237 dnl *** checks for compiler characteristics ***
 238
 239 dnl *** checks for library functions ***
 240
 241 dnl check for fseeko()
 242 AC_FUNC_FSEEKO
 243
 244 dnl Check for fast float to int casting as defined in C99
 245 dnl used in gst-libs/gst/floatcast/floatcast.h
 246 save_libs=$LIBS
 247 LIBS="$LIBS $LIBM"
 248 AC_C99_FUNC_LRINT
 249 AC_C99_FUNC_LRINTF
 250 LIBS=$save_libs
 251
 252 dnl Check for a way to display the function name in debug output
 253 AG_GST_CHECK_FUNCTION
 254
 255 dnl *** checks for socket and nsl libraries ***
 256 AC_CHECK_FUNC(socket,,[AC_CHECK_LIB(socket,socket)])
 257 AC_CHECK_FUNC(gethostbyname,,[AC_CHECK_LIB(nsl,gethostbyname)])
 258
 259 dnl *** checks for dependency libraries ***
 260
 261 dnl GLib is required
 262 AG_GST_GLIB_CHECK([2.22])
 263
 264 ORC_CHECK([0.4.11])
 265
 266 dnl checks for gstreamer
 267 dnl uninstalled is selected preferentially -- see pkg-config(1)
 268 AG_GST_CHECK_GST($GST_MAJORMINOR, [$GST_REQ], yes)
 269 AG_GST_CHECK_GST_BASE($GST_MAJORMINOR, [$GST_REQ], yes)
 270 AG_GST_CHECK_GST_GDP($GST_MAJORMINOR, [$GST_REQ], yes)
 271 AG_GST_CHECK_GST_CONTROLLER($GST_MAJORMINOR, [$GST_REQ], yes)
 272 AG_GST_CHECK_GST_CHECK($GST_MAJORMINOR, [$GST_REQ], no)
 273 AM_CONDITIONAL(HAVE_GST_CHECK, test "x$HAVE_GST_CHECK" = "xyes")
 274
 275 dnl Check for documentation xrefs
 276 GLIB_PREFIX="`$PKG_CONFIG --variable=prefix glib-2.0`"
 277 GST_PREFIX="`$PKG_CONFIG --variable=prefix gstreamer-$GST_MAJORMINOR`"
 278 AC_SUBST(GLIB_PREFIX)
 279 AC_SUBST(GST_PREFIX)
 280
 281 dnl GTK is optional and only used in examples
 282 HAVE_GTK=no
 283 HAVE_GTK_X11=no
 284 GTK2_REQ=2.14.0
 285 GTK3_REQ=2.91.3
 286 if test "x$BUILD_EXAMPLES" = "xyes"; then
 287   AC_MSG_CHECKING([which gtk+ version to compile examples against (optional)])
 288   AC_ARG_WITH([gtk],
 289     AC_HELP_STRING([--with-gtk=3.0|2.0],
 290                    [which gtk+ version to compile against (default: 2.0)]),
 291     [case "$with_gtk" in
 292         2.0) GTK_REQ=$GTK2_REQ ;;
 293         3.0) GTK_REQ=$GTK3_REQ ;;
 294         *) AC_MSG_ERROR([invalid gtk+ version specified]);;
 295     esac],
 296     [with_gtk=2.0
 297      GTK_REQ=$GTK2_REQ])
 298   AC_MSG_RESULT([$with_gtk (>= $GTK_REQ)])
 299   PKG_CHECK_MODULES(GTK, gtk+-$with_gtk >= $GTK_REQ, HAVE_GTK=yes, HAVE_GTK=no)
 300   dnl some examples need gtk+-x11
 301   PKG_CHECK_MODULES(GTK_X11, gtk+-x11-$with_gtk >= $GTK_REQ, HAVE_GTK_X11=yes, HAVE_GTK_X11=no)
 302   AC_SUBST(GTK_LIBS)
 303   AC_SUBST(GTK_CFLAGS)
 304 fi
 305 AM_CONDITIONAL(HAVE_GTK, test "x$HAVE_GTK" = "xyes")
 306 AM_CONDITIONAL(HAVE_GTK_X11, test "x$HAVE_GTK_X11" = "xyes")
 307
 308 dnl QT is optional and only used in examples
 309 PKG_CHECK_MODULES(QT, QtGui >= 4.6, [
 310   HAVE_QT_GV=yes
 311   HAVE_QT=yes
 312 ], [
 313   HAVE_QT_GV=no
 314   PKG_CHECK_MODULES(QT, QtGui >= 4.0, HAVE_QT=yes, HAVE_QT=no)
 315 ])
 316 if test "x$HAVE_QT" = "xyes"; then
 317   AC_MSG_CHECKING([Qt moc])
 318   QT4_MOC=`$PKG_CONFIG --variable=moc_location QtGui`
 319   AC_MSG_RESULT($QT4_MOC)
 320   AC_SUBST(QT4_MOC)
 321 fi
 322 AM_CONDITIONAL(HAVE_QT, test "x$HAVE_QT" = "xyes")
 323 AM_CONDITIONAL(HAVE_QT_GV, test "x$HAVE_QT_GV" = "xyes")
 324
 325 dnl chck for linux headers needed by the joystick seek example
 326 AC_COMPILE_IFELSE(
 327 [
 328   AC_LANG_PROGRAM([
 329     #include <linux/input.h>
 330     #include <linux/joystick.h>
 331   ],[
 332     struct js_event js;
 333     js.type = JS_EVENT_AXIS;
 334   ])
 335 ], [
 336   HAVE_LINUX_JOYSTICK_HEADERS="yes"
 337 ], [
 338   HAVE_LINUX_JOYSTICK_HEADERS="no"
 339 ])
 340 AM_CONDITIONAL(HAVE_LINUX_JOYSTICK_HEADERS, test "x$HAVE_LINUX_JOYSTICK_HEADERS" = "xyes")
 341
 342 dnl Check for -Bsymbolic-functions linker flag used to avoid
 343 dnl intra-library PLT jumps, if available.
 344 AC_ARG_ENABLE(Bsymbolic,
 345               [AC_HELP_STRING([--disable-Bsymbolic],
 346                               [avoid linking with -Bsymbolic])],,
 347               [SAVED_LDFLAGS="${LDFLAGS}"
 348                AC_MSG_CHECKING([for -Bsymbolic-functions linker flag])
 349                LDFLAGS=-Wl,-Bsymbolic-functions
 350                AC_TRY_LINK([], [int main (void) { return 0; }],
 351                            AC_MSG_RESULT(yes)
 352                            enable_Bsymbolic=yes,
 353                            AC_MSG_RESULT(no)
 354                            enable_Bsymbolic=no)
 355                LDFLAGS="${SAVED_LDFLAGS}"])
 356
 357
 358 dnl *** set variables based on configure arguments ***
 359
 360 dnl set license and copyright notice
 361 GST_LICENSE="LGPL"
 362 AC_DEFINE_UNQUOTED(GST_LICENSE, "$GST_LICENSE", [GStreamer license])
 363 AC_SUBST(GST_LICENSE)
 364
 365 dnl set location of plugin directory
 366 AG_GST_SET_PLUGINDIR
 367
 368 dnl set release date/time
 369 AG_GST_SET_PACKAGE_RELEASE_DATETIME_WITH_NANO([$PACKAGE_VERSION_NANO],
 370   ["${srcdir}/gst-plugins-base.doap"],
 371   [$PACKAGE_VERSION_MAJOR.$PACKAGE_VERSION_MINOR.$PACKAGE_VERSION_MICRO])
 372
 373 dnl define an ERROR_CFLAGS Makefile variable
 374 dnl -Wformat-nonliteral - see ext/pango/gstclockoverlay.c and http://gcc.gnu.org/bugzilla/show_bug.cgi?id=39438
 375 AG_GST_SET_ERROR_CFLAGS($GST_GIT, [
 376     -Wmissing-declarations -Wmissing-prototypes -Wredundant-decls -Wundef
 377     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 378     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 379     -Wno-multichar -Wnested-externs ])
 380
 381 dnl define an ERROR_CXXFLAGS Makefile variable
 382 AG_GST_SET_ERROR_CXXFLAGS($GST_GIT, [
 383     -Wmissing-declarations -Wredundant-decls -Wundef
 384     -Wwrite-strings -Wformat-nonliteral -Wformat-security
 385     -Winit-self -Wmissing-include-dirs -Waddress -Waggregate-return
 386     -Wno-multichar])
 387
 388 dnl define correct level for debugging messages
 389 AG_GST_SET_LEVEL_DEFAULT($GST_GIT)
 390
 391 dnl used in examples
 392 AG_GST_DEFAULT_ELEMENTS
 393
 394 dnl needed for encoding-target
 395 GST_DATADIR="$GST_PREFIX/share"
 396 AC_DEFINE_UNQUOTED(GST_DATADIR, "$GST_DATADIR", [system wide data directory])
 397 AC_DEFINE_UNQUOTED(GST_MAJORMINOR, "$GST_MAJORMINOR", [major/minor version])
 398
 399 dnl behaviour of speex based audio resampler
 400 AC_MSG_CHECKING(which audio resample format to use for integer)
 401 AC_ARG_WITH([audioresample_format],
 402         AS_HELP_STRING([--with-audioresample-format],[Which implementation should be used for integer audio resampling, int/float/auto, (default is auto)]),
 403         [ac_cv_audioresample_format=$withval], [ac_cv_audioresample_format=auto])dnl
 404 AC_MSG_RESULT($ac_cv_audioresample_format)
 405 case $ac_cv_audioresample_format in
 406   int)
 407     AC_DEFINE(AUDIORESAMPLE_FORMAT_INT,1,[The int implementation should be used for integer audio resampling])
 408     AC_SUBST(AUDIORESAMPLE_FORMAT_INT)
 409   ;;
 410   float)
 411     AC_DEFINE(AUDIORESAMPLE_FORMAT_FLOAT,1,[The float implementation should be used for integer audio resampling])
 412     AC_SUBST(AUDIORESAMPLE_FORMAT_FLOAT)
 413   ;;
 414   auto)
 415     AC_DEFINE(AUDIORESAMPLE_FORMAT_AUTO,1,[The implementation that should be used for integer audio resampling witll be benchmarked at runtime])
 416     AC_SUBST(AUDIORESAMPLE_FORMAT_AUTO)
 417 esac
 418
 419 dnl *** plug-ins to include ***
 420
 421 dnl these are all the gst plug-ins, compilable without additional libs
 422 AG_GST_CHECK_PLUGIN(adder)
 423 AG_GST_CHECK_PLUGIN(app)
 424 AG_GST_CHECK_PLUGIN(audioconvert)
 425 AG_GST_CHECK_PLUGIN(audiorate)
 426 AG_GST_CHECK_PLUGIN(audiotestsrc)
 427 AG_GST_CHECK_PLUGIN(encoding)
 428 AG_GST_CHECK_PLUGIN(ffmpegcolorspace)
 429 AG_GST_CHECK_PLUGIN(gdp)
 430 AG_GST_CHECK_PLUGIN(playback)
 431 AG_GST_CHECK_PLUGIN(audioresample)
 432 AG_GST_CHECK_PLUGIN(subparse)
 433 AG_GST_CHECK_PLUGIN(tcp)
 434 AG_GST_CHECK_PLUGIN(typefind)
 435 AG_GST_CHECK_PLUGIN(videotestsrc)
 436 AG_GST_CHECK_PLUGIN(videorate)
 437 AG_GST_CHECK_PLUGIN(videoscale)
 438 AG_GST_CHECK_PLUGIN(volume)
 439
 440 dnl check for gstreamer core features (subsystems)
 441 dnl FIXME: this assumes srcdir == builddir for uninstalled setups
 442 GST_CONFIGPATH=`$PKG_CONFIG --variable=includedir gstreamer-0.10`"/gst/gstconfig.h"
 443 AG_GST_PARSE_SUBSYSTEM_DISABLES($GST_CONFIGPATH)
 444 AM_CONDITIONAL(USE_XML, test $GST_DISABLE_XML != "1")
 445
 446 dnl disable plug-ins that require libxml2's HTML support if it is not available
 447 if test "x$HAVE_LIBXML_HTML" != "xyes"; then
 448   AG_GST_DISABLE_PLUGIN(subparse)
 449 fi
 450
 451 dnl disable plug-ins that require sys/socket.h if it is not available
 452 if test "x$HAVE_SYS_SOCKET_H" != "xyes"; then
 453   AG_GST_DISABLE_PLUGIN(tcp)
 454 fi
 455
 456 dnl iso-codes is optional, used by libgsttag
 457 AC_ARG_ENABLE(iso-codes,
 458 AC_HELP_STRING([--enable-iso-codes],[use iso-codes if installed]),
 459 [case "${enableval}" in
 460   yes) enable_iso_codes=yes ;;
 461   no)  enable_iso_codes=no ;;
 462   *) AC_MSG_ERROR(bad value ${enableval} for --enable-iso-codes) ;;
 463 esac
 464 ],
 465 [enable_iso_codes=yes]) dnl Default value
 466
 467 AC_MSG_CHECKING([whether to use iso-codes if they are available])
 468 if test "x$enable_iso_codes" = "xyes"; then
 469   AC_MSG_RESULT([yes])
 470   have_iso_codes=no
 471   AC_MSG_CHECKING([whether iso-codes are available on this system])
 472   if $PKG_CONFIG iso-codes; then
 473     AC_MSG_RESULT([yes])
 474     AC_MSG_CHECKING([whether iso-codes has iso-639 domain])
 475     if $PKG_CONFIG --variable=domains iso-codes | $GREP -q 639 ; then
 476       AC_MSG_RESULT([yes])
 477       AC_MSG_CHECKING([for iso-codes prefix])
 478       ISO_CODES_PREFIX=`$PKG_CONFIG --variable=prefix iso-codes`
 479       if test -d "$ISO_CODES_PREFIX"; then
 480         AC_MSG_RESULT([yes])
 481         AC_MSG_CHECKING([ISO_CODES_PREFIX])
 482         AC_MSG_RESULT([$ISO_CODES_PREFIX])
 483         ISO_639_DOMAIN="iso_639"
 484         AC_MSG_CHECKING([ISO_639_DOMAIN])
 485         AC_MSG_RESULT([$ISO_639_DOMAIN])
 486         have_iso_codes=yes
 487         AC_DEFINE([HAVE_ISO_CODES], [1], [make use of iso-codes for ISO-639])
 488         AC_DEFINE_UNQUOTED([ISO_CODES_PREFIX], ["$ISO_CODES_PREFIX"], [prefix])
 489         ISO_CODES_VERSION=`$PKG_CONFIG --modversion iso-codes`
 490         AC_DEFINE_UNQUOTED([ISO_CODES_VERSION], ["$ISO_CODES_VERSION"], [ ])
 491       else
 492         AC_MSG_RESULT([no])
 493       fi
 494     else
 495       AC_MSG_RESULT([no])
 496     fi
 497   else
 498     AC_MSG_RESULT([no])
 499   fi
 500   AM_CONDITIONAL(USE_ISO_CODES, test "x$have_iso_codes" = "xyes")
 501 else
 502   AC_MSG_RESULT([no (disabled via --disable-iso-codes)])
 503   AM_CONDITIONAL(USE_ISO_CODES, false)
 504 fi
 505
 506 dnl *** sys plug-ins ***
 507
 508 echo
 509 AC_MSG_NOTICE([Checking libraries for plugins in sys/])
 510 echo
 511
 512 dnl *** X11 ***
 513 translit(dnm, m, l) AM_CONDITIONAL(USE_X, true)
 514 AG_GST_CHECK_FEATURE(X, [X libraries and plugins],
 515                   [ximagesink], [
 516   AC_PATH_XTRA
 517   ac_cflags_save="$CFLAGS"
 518   ac_cppflags_save="$CPPFLAGS"
 519   CFLAGS="$CFLAGS $X_CFLAGS"
 520   CPPFLAGS="$CPPFLAGS $X_CFLAGS"
 521
 522   dnl now try to find the HEADER
 523   AC_CHECK_HEADER(X11/Xlib.h, HAVE_X="yes", HAVE_X="no")
 524
 525   if test "x$HAVE_X" = "xno"
 526   then
 527     AC_MSG_NOTICE([cannot find X11 development files])
 528   else
 529     dnl this is much more than we want
 530     X_LIBS="$X_LIBS $X_PRE_LIBS $X_EXTRA_LIBS"
 531     dnl AC_PATH_XTRA only defines the path needed to find the X libs,
 532     dnl it does not add the libs; therefore we add them here
 533     X_LIBS="$X_LIBS -lX11"
 534     AC_SUBST(X_CFLAGS)
 535     AC_SUBST(X_LIBS)
 536   fi
 537   AC_SUBST(HAVE_X)
 538   CFLAGS="$ac_cflags_save"
 539   CPPFLAGS="$ac_cppflags_save"
 540 ])
 541
 542 dnl Check for Xv extension
 543 translit(dnm, m, l) AM_CONDITIONAL(USE_XVIDEO, true)
 544 AG_GST_CHECK_FEATURE(XVIDEO, [X11 XVideo extensions],
 545                   [xvimagesink], [
 546   AG_GST_CHECK_XV
 547 ])
 548
 549 dnl check for X Shm
 550 translit(dnm, m, l) AM_CONDITIONAL(USE_XSHM, true)
 551 AG_GST_CHECK_FEATURE(XSHM, [X Shared Memory extension], , [
 552   if test x$HAVE_X = xyes; then
 553     AC_CHECK_LIB(Xext, XShmAttach,
 554                  HAVE_XSHM="yes", HAVE_XSHM="no",
 555                  $X_LIBS)
 556     if test "x$HAVE_XSHM" = "xyes"; then
 557       XSHM_LIBS="-lXext"
 558     else
 559       dnl On AIX, it is in XextSam instead, but we still need -lXext
 560       AC_CHECK_LIB(XextSam, XShmAttach,
 561                    HAVE_XSHM="yes", HAVE_XSHM="no",
 562                    $X_LIBS)
 563       if test "x$HAVE_XSHM" = "xyes"; then
 564         XSHM_LIBS="-lXext -lXextSam"
 565       fi
 566     fi
 567   fi
 568 ], , [
 569   AC_SUBST(HAVE_XSHM)
 570   AC_SUBST(XSHM_LIBS)
 571 ])
 572
 573 dnl v4l/v4l2 checks have been moved down because they require X
 574
 575 dnl *** Video 4 Linux ***
 576 dnl for information about the header/define, see sys/v4l/gstv4lelement.h
 577 dnl renamed to GST_V4L in accordance with V4L2 below
 578 translit(dnm, m, l) AM_CONDITIONAL(USE_GST_V4L, true)
 579 AG_GST_CHECK_FEATURE(GST_V4L, [Video 4 Linux], video4linux, [
 580   AC_CHECK_DECL(VID_TYPE_MPEG_ENCODER, HAVE_GST_V4L="yes", HAVE_GST_V4L="no", [
 581 #include <sys/types.h>
 582 #define _LINUX_TIME_H
 583 #define __user
 584 #include <linux/videodev.h>
 585   ])
 586
 587   dnl we can build v4l without Xv, but then we won't have XOverlay support
 588   if test "x$HAVE_GST_V4L" = "xyes" -a "x$HAVE_XVIDEO" != "xyes"
 589   then
 590     AC_MSG_NOTICE([NO XVIDEO FOUND, VIDEO4LINUX WILL BE BUILT])
 591     AC_MSG_NOTICE([WITHOUT XOVERLAY SUPPORT])
 592   fi
 593 ])
 594
 595 # Optional gudev for device probing
 596 AC_ARG_WITH([gudev],
 597   AC_HELP_STRING([--with-gudev],
 598     [device detection with gudev]),
 599   [],
 600   [with_gudev=check])
 601 if test x$HAVE_GST_V4L = xyes; then
 602   if test x$with_gudev != xno; then
 603       PKG_CHECK_MODULES(GUDEV, [ gudev-1.0 >= 143 ],
 604           [ have_gudev=yes
 605             AC_DEFINE(HAVE_GUDEV, 1,
 606                [Whether gudev is available for device detection])
 607             AC_DEFINE([G_UDEV_API_IS_SUBJECT_TO_CHANGE], 1, [I know the API is subject to change.])
 608           ], [
 609           have_gudev=no
 610           ])
 611   else
 612     have_gudev=no
 613   fi
 614 fi
 615 AC_SUBST(GUDEV_CFLAGS)
 616 AC_SUBST(GUDEV_LIBS)
 617
 618 dnl *** ext plug-ins ***
 619 dnl keep this list sorted alphabetically !
 620
 621 if test "x$BUILD_EXTERNAL" = "xyes"; then
 622
 623 echo
 624 AC_MSG_NOTICE([Checking libraries for plugins in ext/])
 625 echo
 626
 627 dnl *** alsa ***
 628 translit(dnm, m, l) AM_CONDITIONAL(USE_ALSA, true)
 629 AG_GST_CHECK_FEATURE(ALSA, [ALSA], alsa, [
 630   PKG_CHECK_MODULES(ALSA, alsa >= 0.9.1, [
 631     HAVE_ALSA="yes"
 632     AC_SUBST(ALSA_CFLAGS)
 633     AC_SUBST(ALSA_LIBS)
 634   ], [
 635     AM_PATH_ALSA(0.9.1, HAVE_ALSA="yes", HAVE_ALSA="no")
 636   ])
 637 ])
 638
 639 dnl *** CDParanoia ***
 640 dnl Note: upstream has a pkg-config file only in post-10.2 SVN so far
 641 translit(dnm, m, l) AM_CONDITIONAL(USE_CDPARANOIA, true)
 642 AG_GST_CHECK_FEATURE(CDPARANOIA, [CDParanoia], cdparanoia, [
 643   PKG_CHECK_MODULES(CDPARANOIA, cdparanoia-3 >= 10.2, [
 644     HAVE_CDPARANOIA="yes"
 645   ], [
 646     AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 647                         cdda_open, -lm,
 648                         cdda_interface.h,
 649                         CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 650                         HEADER_DIR="no"
 651                         FOUND_CDPARANOIA="yes")
 652     if test "x$FOUND_CDPARANOIA" != "xyes";
 653     then
 654       AG_GST_CHECK_LIBHEADER(CDPARANOIA, cdda_interface,
 655                           cdda_open, -lm,
 656                           cdda/cdda_interface.h,
 657                           CDPARANOIA_LIBS="-lcdda_interface -lcdda_paranoia"
 658                           HEADER_DIR="yes"
 659                           FOUND_CDPARANOIA="yes")
 660     fi
 661     if test "x$HEADER_DIR" = "xyes";
 662     then
 663       AC_DEFINE_UNQUOTED(CDPARANOIA_HEADERS_IN_DIR, ,
 664                          defined if cdda headers are in a cdda/ directory)
 665     fi
 666     if test "x$FOUND_CDPARANOIA" = "xyes";
 667     then
 668       AC_CHECK_LIB(cdda_paranoia,
 669                    paranoia_cachemodel_size,
 670                    : ,
 671                    HAVE_CDPARANOIA=no,
 672                  [-lcdda_interface])
 673     fi
 674
 675     AC_SUBST(CDPARANOIA_LIBS)
 676   ])
 677 ])
 678 dnl FIXME : add second check somehow if that is necessary
 679 dnl AC_CHECK_LIB(cdda_paranoia, paranoia_init, : , HAVE_CDPARANOIA=no, -lcdda_interface )
 680 dnl AC_CHECK_HEADER(cdda_paranoia.h, :, HAVE_CDPARANOIA=no)
 681
 682 dnl *** GNOME VFS ***
 683 translit(dnm, m, l) AM_CONDITIONAL(USE_GNOME_VFS, true)
 684 AG_GST_CHECK_FEATURE(GNOME_VFS, [GNOME VFS], gnomevfs, [
 685   PKG_CHECK_MODULES(GNOME_VFS, gnome-vfs-2.0, [
 686       HAVE_GNOME_VFS="yes"
 687       AC_SUBST(GNOME_VFS_CFLAGS)
 688       AC_SUBST(GNOME_VFS_LIBS)
 689       GNOME_VFS_MODULES_DIR="`$PKG_CONFIG --variable=modulesdir gnome-vfs-2.0`"
 690       AC_DEFINE_UNQUOTED(GNOME_VFS_MODULES_DIR, "$GNOME_VFS_MODULES_DIR",
 691              [The GnomeVFS modules directory.])
 692     ],[
 693       HAVE_GNOME_VFS="no"
 694     ]
 695     )
 696 ])
 697
 698 dnl *** ivorbis ***
 699 dnl AM_PATH_IVORBIS only takes two options
 700 translit(dnm, m, l) AM_CONDITIONAL(USE_IVORBIS, true)
 701 AG_GST_CHECK_FEATURE(IVORBIS, [integer vorbis plug-in], ivorbisdec, [
 702   AG_GST_PKG_CHECK_MODULES(IVORBIS, vorbisidec)
 703   if test $HAVE_IVORBIS = no
 704   then
 705     IVORBIS_LIBS=
 706     IVORBIS_CFLAGS=
 707     AC_CHECK_LIB(vorbisidec, vorbis_block_init,
 708       [IVORBIS_LIBS=-lvorbisidec
 709       HAVE_IVORBIS=yes
 710       case $host in
 711       arm-*-*)
 712         IVORBIS_CFLAGS="-D_ARM_ASSEM_ $IVORBIS_CFLAGS"
 713       esac
 714       ],
 715       HAVE_IVORBIS=no)
 716     AC_SUBST(IVORBIS_LIBS)
 717     AC_SUBST(IVORBIS_CFLAGS)
 718   else
 719     AC_CHECK_LIB(vorbisidec, vorbis_dsp_pcmout,
 720       AC_DEFINE([USE_TREMOLO],1, "Define if building for android"),
 721       USE_TREMOLO=no)
 722   fi
 723 ])
 724
 725 dnl *** libgio ***
 726 translit(dnm, m, l) AM_CONDITIONAL(USE_GIO, true)
 727 AG_GST_CHECK_FEATURE(GIO, [GIO library], gio, [
 728   PKG_CHECK_MODULES(GIO, gio-2.0 >= 2.16, [
 729     HAVE_GIO="yes"
 730     GIO_MODULE_DIR="`$PKG_CONFIG --variable=giomoduledir gio-2.0`"
 731     AC_DEFINE_UNQUOTED(GIO_MODULE_DIR, "$GIO_MODULE_DIR",
 732            [The GIO modules directory.])
 733     GIO_LIBDIR="`$PKG_CONFIG --variable=libdir gio-2.0`"
 734     AC_DEFINE_UNQUOTED(GIO_LIBDIR, "$GIO_LIBDIR",
 735            [The GIO library directory.])
 736   ], [
 737     HAVE_GIO="no"
 738   ])
 739   AC_SUBST(GIO_CFLAGS)
 740   AC_SUBST(GIO_LIBS)
 741   AC_SUBST(GIO_LDFLAGS)
 742 ])
 743
 744 dnl *** libvisual ***
 745 translit(dnm, m, l) AM_CONDITIONAL(USE_LIBVISUAL, true)
 746 AG_GST_CHECK_FEATURE(LIBVISUAL, [libvisual visualization library], libvisual, [
 747   AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual-0.4 >= 0.4.0)
 748   if test $HAVE_LIBVISUAL = no
 749   then
 750     AG_GST_PKG_CHECK_MODULES(LIBVISUAL, libvisual = 0.2.0)
 751     if test x$HAVE_LIBVISUAL = xyes; then
 752       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.2`"
 753     fi
 754   else
 755     if test x$HAVE_LIBVISUAL = xyes; then
 756       LIBVIS_PLUGINSDIR="`$PKG_CONFIG --variable=pluginsbasedir libvisual-0.4`"
 757     fi
 758   fi
 759   AC_MSG_NOTICE([libvisual pluginsdir: $LIBVIS_PLUGINSDIR])
 760   if test x$LIBVIS_PLUGINSDIR != x; then
 761     AC_DEFINE_UNQUOTED(LIBVISUAL_PLUGINSBASEDIR,
 762         "$LIBVIS_PLUGINSDIR",
 763         [directory in which the detected libvisual's plugins are located])
 764   fi
 765 ])
 766
 767 dnl *** ogg ***
 768 translit(dnm, m, l) AM_CONDITIONAL(USE_OGG, true)
 769 AG_GST_CHECK_FEATURE(OGG, [Xiph Ogg library], ogg, [
 770   AG_GST_PKG_CHECK_MODULES(OGG, ogg >= 1.0)
 771   if test $HAVE_OGG = no
 772   then
 773     XIPH_PATH_OGG(HAVE_OGG="yes", HAVE_OGG="no")
 774     AS_SCRUB_INCLUDE(OGG_CFLAGS)
 775   fi
 776 ])
 777
 778 dnl *** pango ***
 779 translit(dnm, m, l) AM_CONDITIONAL(USE_PANGO, true)
 780 AG_GST_CHECK_FEATURE(PANGO, [Pango font rendering], pango, [
 781   AG_GST_PKG_CHECK_MODULES(PANGO, pango >= 1.16.0  pangocairo >= 1.16.0)
 782 ])
 783
 784 dnl *** theora ***
 785 translit(dnm, m, l) AM_CONDITIONAL(USE_THEORA, true)
 786 AG_GST_CHECK_FEATURE(THEORA, [Xiph Theora video codec], theora, [
 787   AG_GST_PKG_CHECK_MODULES(THEORA, theoradec >= 1.1 theoraenc >= 1.1)
 788 ])
 789
 790 dnl *** vorbis ***
 791 dnl AM_PATH_VORBIS only takes two options
 792 translit(dnm, m, l) AM_CONDITIONAL(USE_VORBIS, true)
 793 AG_GST_CHECK_FEATURE(VORBIS, [Xiph Vorbis audio codec], vorbis, [
 794   AG_GST_PKG_CHECK_MODULES(VORBIS, vorbis >= 1.0 vorbisenc >= 1.0)
 795   if test $HAVE_VORBIS = no
 796   then
 797     XIPH_PATH_VORBIS(HAVE_VORBIS="yes", HAVE_VORBIS="no")
 798     AS_SCRUB_INCLUDE(VORBIS_CFLAGS)
 799   fi
 800 ])
 801
 802 if test "x$HAVE_VORBIS" = "xyes"; then
 803   ac_cflags_save="$CFLAGS"
 804   AC_COMPILE_IFELSE(
 805     AC_LANG_PROGRAM([
 806 #include <vorbis/codec.h>
 807                      ],[
 808 vorbis_dsp_state *v;
 809
 810 vorbis_synthesis_restart (v);
 811                      ]), HAVE_VSR=yes, HAVE_VSR=no)
 812   if test "x$HAVE_VSR" = "xyes"; then
 813     AC_DEFINE_UNQUOTED(HAVE_VORBIS_SYNTHESIS_RESTART, 1,
 814                        [defined if vorbis_synthesis_restart is present])
 815   fi
 816   CFLAGS="$ac_cflags_save"
 817 fi
 818
 819 else
 820
 821 dnl not building plugins with external dependencies,
 822 dnl but we still need to set the conditionals
 823 AM_CONDITIONAL(USE_ALSA, false)
 824 AM_CONDITIONAL(USE_CDPARANOIA, false)
 825 AM_CONDITIONAL(USE_GIO, false)
 826 AM_CONDITIONAL(USE_GNOME_VFS, false)
 827 AM_CONDITIONAL(USE_IVORBIS, false)
 828 AM_CONDITIONAL(USE_LIBVISUAL, false)
 829 AM_CONDITIONAL(USE_OGG, false)
 830 AM_CONDITIONAL(USE_PANGO, false)
 831 AM_CONDITIONAL(USE_THEORA, false)
 832 AM_CONDITIONAL(USE_VORBIS, false)
 833
 834 fi dnl of EXT plugins
 835
 836 dnl seeking needs freetype, so check for it here
 837 PKG_CHECK_MODULES(FT2, freetype2 >= 2.0.9, HAVE_FT2="yes", [
 838   AC_CHECK_FT2(2.0.9, HAVE_FT2="yes", HAVE_FT2="no")
 839 ])
 840 dnl make the HAVE_FT2 variable available to automake and Makefile.am
 841 AM_CONDITIONAL(HAVE_FT2, test "x$HAVE_FT2" = "xyes")
 842 AC_SUBST(FT2_CFLAGS)
 843 AC_SUBST(FT2_LIBS)
 844
 845 dnl *** finalize CFLAGS, LDFLAGS, LIBS
 846
 847 dnl Overview:
 848 dnl GST_OPTION_CFLAGS:  common flags for profiling, debugging, errors, ...
 849 dnl GST_*:              flags shared by built objects to link against GStreamer
 850 dnl GST_PLUGINS_BASE_CFLAGS: to link internally against the plugins base libs
 851 dnl                          (compare to other modules) or for i18n
 852 dnl GST_ALL_LDFLAGS:    linker flags shared by all
 853 dnl GST_LIB_LDFLAGS:    additional linker flags for all libaries
 854 dnl GST_LT_LDFLAGS:     library versioning of our libraries
 855 dnl GST_PLUGIN_LDFLAGS: flags to be used for all plugins
 856
 857 dnl GST_OPTION_CFLAGS
 858 if test "x$USE_DEBUG" = xyes; then
 859    PROFILE_CFLAGS="-g"
 860 fi
 861 AC_SUBST(PROFILE_CFLAGS)
 862
 863 if test "x$PACKAGE_VERSION_NANO" = "x1"; then
 864   dnl Define _only_ when compiling a git version (not pre-releases or releases)
 865   DEPRECATED_CFLAGS="-DGST_DISABLE_DEPRECATED"
 866 else
 867   DEPRECATED_CFLAGS=""
 868 fi
 869 AC_SUBST(DEPRECATED_CFLAGS)
 870
 871 dnl every flag in GST_OPTION_CFLAGS and GST_OPTION_CXXFLAGS can be overridden
 872 dnl at make time with e.g. make ERROR_CFLAGS=""
 873 GST_OPTION_CFLAGS="\$(WARNING_CFLAGS) \$(ERROR_CFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 874 GST_OPTION_CXXFLAGS="\$(WARNING_CXXFLAGS) \$(ERROR_CXXFLAGS) \$(DEBUG_CFLAGS) \$(PROFILE_CFLAGS) \$(GCOV_CFLAGS) \$(OPT_CFLAGS) \$(DEPRECATED_CFLAGS)"
 875 AC_SUBST(GST_OPTION_CFLAGS)
 876 AC_SUBST(GST_OPTION_CXXFLAGS)
 877
 878 dnl our libraries need to be versioned correctly
 879 AC_SUBST(GST_LT_LDFLAGS)
 880
 881 dnl GST_PLUGINS_BASE_CFLAGS
 882 dnl prefer internal headers to already installed ones
 883 dnl also add builddir include for enumtypes and marshal
 884 GST_PLUGINS_BASE_CFLAGS="-I\$(top_srcdir)/gst-libs -I\$(top_builddir)/gst-libs"
 885 AC_SUBST(GST_PLUGINS_BASE_CFLAGS)
 886
 887 dnl FIXME: do we want to rename to GST_ALL_* ?
 888 dnl add GST_OPTION_CFLAGS, but overridable
 889 GST_CXXFLAGS="$GLIB_CFLAGS $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CXXFLAGS)"
 890 GST_CFLAGS="$GLIB_CFLAGS $GST_CFLAGS $GLIB_EXTRA_CFLAGS \$(GST_OPTION_CFLAGS)"
 891 AC_SUBST(GST_CFLAGS)
 892 AC_SUBST(GST_CXXFLAGS)
 893 dnl add GCOV libs because libtool strips -fprofile-arcs -ftest-coverage
 894 GST_LIBS="$GST_LIBS \$(GCOV_LIBS)"
 895 AC_SUBST(GST_LIBS)
 896
 897 dnl LDFLAGS really should only contain flags, not libs - they get added before
 898 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 899 GST_ALL_LDFLAGS="-no-undefined"
 900 if test "x${enable_Bsymbolic}" = "xyes"; then
 901   GST_ALL_LDFLAGS="$GST_ALL_LDFLAGS -Wl,-Bsymbolic-functions"
 902 fi
 903 AC_SUBST(GST_ALL_LDFLAGS)
 904
 905 dnl GST_LIB_LDFLAGS
 906 dnl linker flags shared by all libraries
 907 dnl LDFLAGS modifier defining exported symbols from built libraries
 908 dnl (export _gst_foo but not __gst_foo)
 909 GST_LIB_LDFLAGS="-export-symbols-regex ^_?\(gst_\|Gst\|GST_\).*"
 910 AC_SUBST(GST_LIB_LDFLAGS)
 911
 912 dnl this really should only contain flags, not libs - they get added before
 913 dnl whatevertarget_LIBS and -L flags here affect the rest of the linking
 914 GST_PLUGIN_LDFLAGS="-module -avoid-version -export-symbols-regex '^[_]*gst_plugin_desc.*' $GST_ALL_LDFLAGS"
 915 AC_SUBST(GST_PLUGIN_LDFLAGS)
 916
 917 dnl *** output files ***
 918
 919 AC_CONFIG_FILES(
 920 Makefile
 921 gst-plugins-base.spec
 922 gst/Makefile
 923 gst/adder/Makefile
 924 gst/app/Makefile
 925 gst/audioconvert/Makefile
 926 gst/audiorate/Makefile
 927 gst/audiotestsrc/Makefile
 928 gst/encoding/Makefile
 929 gst/ffmpegcolorspace/Makefile
 930 gst/gdp/Makefile
 931 gst/playback/Makefile
 932 gst/audioresample/Makefile
 933 gst/subparse/Makefile
 934 gst/tcp/Makefile
 935 gst/typefind/Makefile
 936 gst/videotestsrc/Makefile
 937 gst/videorate/Makefile
 938 gst/videoscale/Makefile
 939 gst/volume/Makefile
 940 sys/Makefile
 941 sys/ximage/Makefile
 942 sys/xvimage/Makefile
 943 sys/v4l/Makefile
 944 ext/Makefile
 945 ext/alsa/Makefile
 946 ext/cdparanoia/Makefile
 947 ext/gnomevfs/Makefile
 948 ext/gio/Makefile
 949 ext/libvisual/Makefile
 950 ext/ogg/Makefile
 951 ext/pango/Makefile
 952 ext/theora/Makefile
 953 ext/vorbis/Makefile
 954 gst-libs/Makefile
 955 gst-libs/gst/Makefile
 956 gst-libs/gst/audio/Makefile
 957 gst-libs/gst/app/Makefile
 958 gst-libs/gst/cdda/Makefile
 959 gst-libs/gst/fft/Makefile
 960 gst-libs/gst/floatcast/Makefile
 961 gst-libs/gst/interfaces/Makefile
 962 gst-libs/gst/netbuffer/Makefile
 963 gst-libs/gst/riff/Makefile
 964 gst-libs/gst/rtp/Makefile
 965 gst-libs/gst/rtsp/Makefile
 966 gst-libs/gst/sdp/Makefile
 967 gst-libs/gst/tag/Makefile
 968 gst-libs/gst/pbutils/Makefile
 969 gst-libs/gst/pbutils/gstpluginsbaseversion.h
 970 gst-libs/gst/video/Makefile
 971 tools/Makefile
 972 pkgconfig/Makefile
 973 pkgconfig/gstreamer-audio.pc
 974 pkgconfig/gstreamer-audio-uninstalled.pc
 975 pkgconfig/gstreamer-app.pc
 976 pkgconfig/gstreamer-app-uninstalled.pc
 977 pkgconfig/gstreamer-cdda.pc
 978 pkgconfig/gstreamer-cdda-uninstalled.pc
 979 pkgconfig/gstreamer-fft.pc
 980 pkgconfig/gstreamer-fft-uninstalled.pc
 981 pkgconfig/gstreamer-floatcast.pc
 982 pkgconfig/gstreamer-floatcast-uninstalled.pc
 983 pkgconfig/gstreamer-interfaces.pc
 984 pkgconfig/gstreamer-interfaces-uninstalled.pc
 985 pkgconfig/gstreamer-netbuffer.pc
 986 pkgconfig/gstreamer-netbuffer-uninstalled.pc
 987 pkgconfig/gstreamer-pbutils.pc
 988 pkgconfig/gstreamer-pbutils-uninstalled.pc
 989 pkgconfig/gstreamer-riff.pc
 990 pkgconfig/gstreamer-riff-uninstalled.pc
 991 pkgconfig/gstreamer-rtp.pc
 992 pkgconfig/gstreamer-rtp-uninstalled.pc
 993 pkgconfig/gstreamer-rtsp.pc
 994 pkgconfig/gstreamer-rtsp-uninstalled.pc
 995 pkgconfig/gstreamer-sdp.pc
 996 pkgconfig/gstreamer-sdp-uninstalled.pc
 997 pkgconfig/gstreamer-tag.pc
 998 pkgconfig/gstreamer-tag-uninstalled.pc
 999 pkgconfig/gstreamer-video.pc
1000 pkgconfig/gstreamer-video-uninstalled.pc
1001 pkgconfig/gstreamer-plugins-base.pc
1002 pkgconfig/gstreamer-plugins-base-uninstalled.pc
1003 tests/Makefile
1004 tests/check/Makefile
1005 tests/examples/Makefile
1006 tests/examples/app/Makefile
1007 tests/examples/dynamic/Makefile
1008 tests/examples/encoding/Makefile
1009 tests/examples/gio/Makefile
1010 tests/examples/overlay/Makefile
1011 tests/examples/seek/Makefile
1012 tests/examples/snapshot/Makefile
1013 tests/examples/playrec/Makefile
1014 tests/examples/volume/Makefile
1015 tests/examples/v4l/Makefile
1016 tests/files/Makefile
1017 tests/icles/Makefile
1018 tests/icles/playback/Makefile
1019 docs/Makefile
1020 docs/design/Makefile
1021 docs/libs/Makefile
1022 docs/plugins/Makefile
1023 docs/version.entities
1024 po/Makefile.in
1025 common/Makefile
1026 common/m4/Makefile
1027 m4/Makefile
1028 )
1029
1030 dnl Create the config.h file for Visual Studio builds
1031 dnl Beware of spaces and /'s in some of the shell variable contents.
1032 sed \
1033     -e 's/.*config.h.in.*autoheader.*/\/* Autogenerated config.h created for win32 Visual Studio builds *\/\n\n\/* PREFIX -- specifically added for Windows for easier moving *\/\n#define PREFIX "C:\\\\gstreamer"/' \
1034     -e 's/.* GST_INSTALL_PLUGINS_HELPER/#define GST_INSTALL_PLUGINS_HELPER PREFIX "\\\\libexec\\\\gst-install-plugins-helper.exe"/' \
1035     -e 's/.* GETTEXT_PACKAGE$/#define GETTEXT_PACKAGE "'$GETTEXT_PACKAGE'"/' \
1036     -e 's/.* GST_DATADIR$/#define GST_DATADIR PREFIX "\\\\share"/' \
1037     -e 's/.* GST_LEVEL_DEFAULT$/#define GST_LEVEL_DEFAULT GST_LEVEL_ERROR/' \
1038     -e 's/.* GST_LICENSE$/#define GST_LICENSE "'$GST_LICENSE'"/' \
1039     -e 's/.* GST_MAJORMINOR$/#define GST_MAJORMINOR "'$GST_MAJORMINOR'"/' \
1040     -e "s,.* GST_PACKAGE_NAME$,#define GST_PACKAGE_NAME \"${GST_PACKAGE_NAME}\"," \
1041     -e 's/.* GST_PACKAGE_ORIGIN$/#define GST_PACKAGE_ORIGIN "Unknown package origin"/' \
1042     -e "s,.* GST_PACKAGE_RELEASE_DATETIME$,#define GST_PACKAGE_RELEASE_DATETIME \"${GST_PACKAGE_RELEASE_DATETIME}\"," \
1043     -e 's/.* HAVE_CPU_I386$/#define HAVE_CPU_I386 1/' \
1044     -e 's/.* HAVE_FGETPOS$/#define HAVE_FGETPOS 1/' \
1045     -e 's/.* HAVE_FSETPOS$/#define HAVE_FSETPOS 1/' \
1046     -e 's/.* HAVE_ISO_CODES$/#undef HAVE_ISO_CODES/' \
1047     -e 's/.* HAVE_LIBXML2$/#define HAVE_LIBXML2 1/' \
1048     -e 's/.* HAVE_PROCESS_H$/#define HAVE_PROCESS_H 1/' \
1049     -e 's/.* HAVE_STDLIB_H$/#define HAVE_STDLIB_H 1/' \
1050     -e 's/.* HAVE_STRING_H$/#define HAVE_STRING_H 1/' \
1051     -e 's/.* HAVE_SYS_STAT_H$/#define HAVE_SYS_STAT_H 1/' \
1052     -e 's/.* HAVE_SYS_TYPES_H$/#define HAVE_SYS_TYPES_H 1/' \
1053     -e 's/.* HAVE_WIN32$/#define HAVE_WIN32 1/' \
1054     -e 's/.* HAVE_WINSOCK2_H$/#define HAVE_WINSOCK2_H 1/' \
1055     -e 's/.* HOST_CPU$/#define HOST_CPU "i686"/' \
1056     -e 's/.* ISO_CODES_PREFIX$/#undef ISO_CODES_PREFIX/' \
1057     -e 's/.* ISO_CODES_VERSION$/#undef ISO_CODES_VERSION/' \
1058     -e 's/.* LIBDIR$/#ifdef _DEBUG\n#  define LIBDIR PREFIX "\\\\debug\\\\lib"\n#else\n#  define LIBDIR PREFIX "\\\\lib"\n#endif/' \
1059     -e 's/.* LOCALEDIR$/#define LOCALEDIR PREFIX "\\\\share\\\\locale"/' \
1060     -e "s/.* PACKAGE$/#define PACKAGE \"$PACKAGE\"/" \
1061     -e 's/.* PACKAGE_BUGREPORT$/#define PACKAGE_BUGREPORT "http:\/\/bugzilla.gnome.org\/enter_bug.cgi?product=GStreamer"/' \
1062     -e "s/.* PACKAGE_NAME$/#define PACKAGE_NAME \"$PACKAGE_NAME\"/" \
1063     -e "s/.* PACKAGE_STRING$/#define PACKAGE_STRING \"$PACKAGE_STRING\"/" \
1064     -e 's/.* PACKAGE_TARNAME$/#define PACKAGE_TARNAME "'$PACKAGE_TARNAME'"/' \
1065     -e 's/.* PACKAGE_VERSION$/#define PACKAGE_VERSION "'$PACKAGE_VERSION'"/' \
1066     -e 's/.* PLUGINDIR$/#ifdef _DEBUG\n#  define PLUGINDIR PREFIX "\\\\debug\\\\lib\\\\gstreamer-0.10"\n#else\n#  define PLUGINDIR PREFIX "\\\\lib\\\\gstreamer-0.10"\n#endif/' \
1067     -e 's/.* USE_BINARY_REGISTRY$/#define USE_BINARY_REGISTRY/' \
1068     -e 's/.* VERSION$/#define VERSION "'$VERSION'"/' \
1069     -e "s/.* DEFAULT_AUDIOSINK$/#define DEFAULT_AUDIOSINK \"directsoundsink\"/" \
1070     -e "s/.* DEFAULT_VIDEOSINK$/#define DEFAULT_VIDEOSINK \"directdrawsink\"/" \
1071     -e "s/.* DEFAULT_VISUALIZER$/#define DEFAULT_VISUALIZER \"goom\"/" \
1072     config.h.in >win32/common/config.h-new
1073
1074
1075
1076 AC_OUTPUT
1077
1078 AG_GST_OUTPUT_PLUGINS
1079 ORC_OUTPUT
1080