git.maemo.org Git - mafwsubrenderer/blob - qmafw-gst-subtitles-renderer/applet/subtitlesapplet.pro

   1 TEMPLATE      = lib
   2 TARGET        = subtitlesapplet
   3
   4 isEmpty(PREFIX) {
   5     PREFIX=/usr
   6 }
   7
   8 isEmpty(MODE) {
   9     CONFIG += release
  10     QMAKE_CXXFLAGS += -g
  11     QMAKE_CFLAGS   += -g
  12 }
  13
  14 contains(MODE, release) {
  15     CONFIG += release
  16     DEFINES        += G_DISABLE_ASSERT
  17     QMAKE_CXXFLAGS += -g
  18     QMAKE_CFLAGS   += -g
  19 }
  20
  21 contains(MODE, debug) {
  22     CONFIG += debug
  23 }
  24
  25 CONFIG       += plugin gui meegotouch duicontrolpanel link_pkgconfig
  26 PKGCONFIG    += pango
  27
  28 QMAKE_CXXFLAGS  += -Wall -Werror
  29 QMAKE_CFLAGS    += -Wall -Werror
  30
  31 QMAKE_CLEAN     += build-stamp \
  32                    configure-stamp
  33
  34 # Input
  35 HEADERS += subtitlesapplet.h \
  36     subtitleswidget.h \
  37     subtitlesbrief.h
  38
  39 SOURCES += subtitlesapplet.cpp \
  40     subtitleswidget.cpp \
  41     subtitlesbrief.cpp
  42
  43 TRANSLATIONS += translations/subtitlesapplet_en.ts
  44
  45 target.path  += $$PREFIX/lib/duicontrolpanel/applets
  46
  47 desktop.files += subtitles.desktop
  48 desktop.path  = $$PREFIX/share/duicontrolpanel/desktops
  49
  50 translations.files += translations/*.qm
  51 translations.path = $$PREFIX/share/l10n/meegotouch
  52
  53 INSTALLS     += target desktop translations