git.maemo.org Git - mafwsubrenderer/blob - qmafw-gst-subtitles-renderer/qmafw-gst-subtitles-renderer.pro

   1 TEMPLATE        = lib
   2 TARGET          = qmafw-gst-renderer-plugin
   3 VERSION         = 0.0.55-1
   4
   5 QT = core network
   6
   7 isEmpty(PREFIX) {
   8     PREFIX=/usr
   9 }
  10
  11 isEmpty(MODE) {
  12     CONFIG += release
  13     QMAKE_CXXFLAGS += -g
  14     QMAKE_CFLAGS   += -g
  15 }
  16
  17 contains(MODE, release) {
  18     CONFIG += release
  19     DEFINES        += G_DISABLE_ASSERT
  20     QMAKE_CXXFLAGS += -g
  21     QMAKE_CFLAGS   += -g
  22 }
  23
  24 contains(MODE, debug) {
  25     CONFIG += debug
  26 }
  27
  28 CONFIG          += no_keywords qt qdbus link_pkgconfig plugin
  29 PKGCONFIG       += qmafw glib-2.0 gobject-2.0 gq-gconf gstreamer-0.10 gstreamer-plugins-base-0.10 QtSparql
  30 PKGCONFIG       += contextprovider-1.0 contextsubscriber-1.0 qmsystem2 usb_moded
  31
  32 LIBS +=  -lgstinterfaces-0.10 -lgstpbutils-0.10 -ldbus-qeventloop -ltotem-plparser
  33
  34 DEPENDPATH      += . inc src
  35 INCLUDEPATH     += . inc $$system(pkg-config --variable=includedir qmafw)
  36
  37 #DEFINES += QT_NO_DEBUG_OUTPUT
  38
  39 QMAKE_CXXFLAGS  += -Wall -Werror
  40 QMAKE_CFLAGS    += -Wall -Werror
  41
  42 QMAKE_CLEAN     += build-stamp \
  43                    configure-stamp
  44
  45 # Version info
  46 DEFINES             += _VERSION_INFO
  47 QMAKE_EXTRA_TARGETS += revtarget
  48 revtarget.target     = inc/version.h
  49 revtarget.commands  += @echo update version info
  50 revtarget.commands  += $$escape_expand( \\n\\t )@echo \"namespace \{\" > $$revtarget.target
  51 revtarget.commands  += $$escape_expand( \\n\\t )@echo \"const char *revision = \\\"$(shell svnversion -n . || echo N/A )\\\";\" >> $$revtarget.target
  52 revtarget.commands  += $$escape_expand( \\n\\t )@echo \"const char *build_time = \\\"$(shell date )\\\";\" >> $$revtarget.target
  53 revtarget.commands  += $$escape_expand( \\n\\t )@echo \"\};\" >> $$revtarget.target
  54 # update revision/buildtime every time when linking is required
  55 QMAKE_POST_LINK     += @rm -f $$revtarget.target
  56
  57 # Input
  58 HEADERS += MafwGstRenderer.h \
  59     MafwGstRendererPlugin.h \
  60     MafwBlankingPreventer.h \
  61     mafw-gst-renderer-utils.h \
  62     mafw-gst-renderer-worker.h \
  63     MafwGstRendererVolume.h \
  64     MafwGstRendererPlaylistFileUtility.h \
  65     MafwGstRendererNetworkMonitor.h \
  66     MafwGstRendererDolby.h \
  67     MafwGstScreenshot.h \
  68     MafwMmcMonitor.h \
  69     mafw-gst-renderer-seeker.h \
  70     MafwGstRendererHaltState.h
  71
  72 SOURCES += MafwGstRenderer.cpp \
  73     MafwGstRendererPlugin.cpp \
  74     MafwBlankingPreventer.cpp \
  75     mafw-gst-renderer-utils.c \
  76     mafw-gst-renderer-worker.c \
  77     MafwGstRendererVolume.cpp \
  78     MafwGstRendererPlaylistFileUtility.cpp \
  79     MafwGstRendererNetworkMonitor.cpp \
  80     MafwGstRendererDolby.cpp \
  81     MafwGstScreenshot.cpp \
  82     MafwMmcMonitor.cpp \
  83     mafw-gst-renderer-seeker.c \
  84     MafwGstRendererHaltState.cpp
  85
  86 DISTFILES += qmafw-gst-renderer.service
  87
  88 # Installation
  89 service.files     = com.nokia.mafw.plugin.libqmafw_gst_renderer_plugin.service
  90 service.path      = $$PREFIX/share/dbus-1/services
  91 target.path       = $$PREFIX/lib/qmafw-plugin
  92
  93 context.files     = com.nokia.mafw.context_provider.libqmafw_gst_renderer.context
  94 context.path      = $$PREFIX/share/contextkit/providers
  95
  96 settings.files    = mafw-gst-renderer-plugin.conf
  97 settings.path     = /usr/share/qmafw
  98
  99 INSTALLS         += target service context settings