git.maemo.org Git - mafwsubrenderer/blob - qmafw-gst-subtitles-renderer/qmafw-gst-subtitles-renderer.pro

   1 TEMPLATE        = lib
   2 TARGET          = qmafw-gst-renderer-plugin
   3 VERSION         = 0.0.55-1
   4
   5 QT = core network
   6
   7 isEmpty(PREFIX) {
   8     PREFIX=/usr
   9 }
  10
  11 isEmpty(MODE) {
  12     CONFIG += release
  13     QMAKE_CXXFLAGS += -g
  14     QMAKE_CFLAGS   += -g
  15 }
  16
  17 contains(MODE, release) {
  18     CONFIG += release
  19     DEFINES        += G_DISABLE_ASSERT
  20     QMAKE_CXXFLAGS += -g
  21     QMAKE_CFLAGS   += -g
  22 }
  23
  24 contains(MODE, debug) {
  25     CONFIG += debug
  26 }
  27
  28 CONFIG          += no_keywords qt qdbus link_pkgconfig plugin
  29 PKGCONFIG       += qmafw glib-2.0 gobject-2.0 gq-gconf gstreamer-0.10 gstreamer-plugins-base-0.10 QtSparql
  30 PKGCONFIG       += contextprovider-1.0 contextsubscriber-1.0 qmsystem2 usb_moded
  31
  32 LIBS +=  -lgstinterfaces-0.10 -lgstpbutils-0.10 -ldbus-qeventloop -ltotem-plparser
  33
  34 DEPENDPATH      += . inc src
  35 INCLUDEPATH     += . inc $$system(pkg-config --variable=includedir qmafw)
  36
  37 SUBDIRS         += applet
  38
  39 #DEFINES += QT_NO_DEBUG_OUTPUT
  40
  41 QMAKE_CXXFLAGS  += -Wall -Werror
  42 QMAKE_CFLAGS    += -Wall -Werror
  43
  44 QMAKE_CLEAN     += build-stamp \
  45                    configure-stamp
  46
  47 # Version info
  48 DEFINES             += _VERSION_INFO
  49 QMAKE_EXTRA_TARGETS += revtarget
  50 revtarget.target     = inc/version.h
  51 revtarget.commands  += @echo update version info
  52 revtarget.commands  += $$escape_expand( \\n\\t )@echo \"namespace \{\" > $$revtarget.target
  53 revtarget.commands  += $$escape_expand( \\n\\t )@echo \"const char *revision = \\\"$(shell svnversion -n . || echo N/A )\\\";\" >> $$revtarget.target
  54 revtarget.commands  += $$escape_expand( \\n\\t )@echo \"const char *build_time = \\\"$(shell date )\\\";\" >> $$revtarget.target
  55 revtarget.commands  += $$escape_expand( \\n\\t )@echo \"\};\" >> $$revtarget.target
  56 # update revision/buildtime every time when linking is required
  57 QMAKE_POST_LINK     += @rm -f $$revtarget.target
  58
  59 # Input
  60 HEADERS += MafwGstRenderer.h \
  61     MafwGstRendererPlugin.h \
  62     MafwBlankingPreventer.h \
  63     mafw-gst-renderer-utils.h \
  64     mafw-gst-renderer-worker.h \
  65     MafwGstRendererVolume.h \
  66     MafwGstRendererPlaylistFileUtility.h \
  67     MafwGstRendererNetworkMonitor.h \
  68     MafwGstRendererDolby.h \
  69     MafwGstScreenshot.h \
  70     MafwMmcMonitor.h \
  71     mafw-gst-renderer-seeker.h \
  72     MafwGstRendererHaltState.h
  73
  74 SOURCES += MafwGstRenderer.cpp \
  75     MafwGstRendererPlugin.cpp \
  76     MafwBlankingPreventer.cpp \
  77     mafw-gst-renderer-utils.c \
  78     mafw-gst-renderer-worker.c \
  79     MafwGstRendererVolume.cpp \
  80     MafwGstRendererPlaylistFileUtility.cpp \
  81     MafwGstRendererNetworkMonitor.cpp \
  82     MafwGstRendererDolby.cpp \
  83     MafwGstScreenshot.cpp \
  84     MafwMmcMonitor.cpp \
  85     mafw-gst-renderer-seeker.c \
  86     MafwGstRendererHaltState.cpp
  87
  88 DISTFILES += qmafw-gst-renderer.service
  89
  90 # Installation
  91 service.files     = com.nokia.mafw.plugin.libqmafw_gst_renderer_plugin.service
  92 service.path      = $$PREFIX/share/dbus-1/services
  93 target.path       = $$PREFIX/lib/qmafw-plugin
  94
  95 context.files     = com.nokia.mafw.context_provider.libqmafw_gst_renderer.context
  96 context.path      = $$PREFIX/share/contextkit/providers
  97
  98 settings.files    = mafw-gst-renderer-plugin.conf
  99 settings.path     = /usr/share/qmafw
 100
 101 INSTALLS         += target service context settings