TEMPLATE        = lib
TARGET          = qmafw-gst-renderer-plugin
VERSION         = 0.0.55-1

QT = core network

isEmpty(PREFIX) {
    PREFIX=/usr
}

isEmpty(MODE) {
    CONFIG += release
    QMAKE_CXXFLAGS += -g
    QMAKE_CFLAGS   += -g
}

contains(MODE, release) {
    CONFIG += release
    DEFINES        += G_DISABLE_ASSERT
    QMAKE_CXXFLAGS += -g
    QMAKE_CFLAGS   += -g
}

contains(MODE, debug) {
    CONFIG += debug
}

CONFIG          += no_keywords qt qdbus link_pkgconfig plugin
PKGCONFIG       += qmafw glib-2.0 gobject-2.0 gq-gconf gstreamer-0.10 gstreamer-plugins-base-0.10 QtSparql
PKGCONFIG       += contextprovider-1.0 contextsubscriber-1.0 qmsystem2 usb_moded

LIBS +=  -lgstinterfaces-0.10 -lgstpbutils-0.10 -ldbus-qeventloop -ltotem-plparser

DEPENDPATH      += . inc src
INCLUDEPATH     += . inc $$system(pkg-config --variable=includedir qmafw) 

#DEFINES += QT_NO_DEBUG_OUTPUT

QMAKE_CXXFLAGS  += -Wall -Werror
QMAKE_CFLAGS    += -Wall -Werror

QMAKE_CLEAN     += build-stamp \
                   configure-stamp

# Version info
DEFINES             += _VERSION_INFO
QMAKE_EXTRA_TARGETS += revtarget
revtarget.target     = inc/version.h
revtarget.commands  += @echo update version info
revtarget.commands  += $$escape_expand( \\n\\t )@echo \"namespace \{\" > $$revtarget.target
revtarget.commands  += $$escape_expand( \\n\\t )@echo \"const char *revision = \\\"$(shell svnversion -n . || echo N/A )\\\";\" >> $$revtarget.target
revtarget.commands  += $$escape_expand( \\n\\t )@echo \"const char *build_time = \\\"$(shell date )\\\";\" >> $$revtarget.target
revtarget.commands  += $$escape_expand( \\n\\t )@echo \"\};\" >> $$revtarget.target
# update revision/buildtime every time when linking is required
QMAKE_POST_LINK     += @rm -f $$revtarget.target

# Input
HEADERS += MafwGstRenderer.h \
    MafwGstRendererPlugin.h \
    MafwBlankingPreventer.h \
    mafw-gst-renderer-utils.h \
    mafw-gst-renderer-worker.h \
    MafwGstRendererVolume.h \
    MafwGstRendererPlaylistFileUtility.h \
    MafwGstRendererNetworkMonitor.h \
    MafwGstRendererDolby.h \
    MafwGstScreenshot.h \
    MafwMmcMonitor.h \
    mafw-gst-renderer-seeker.h \
    MafwGstRendererHaltState.h

SOURCES += MafwGstRenderer.cpp \
    MafwGstRendererPlugin.cpp \
    MafwBlankingPreventer.cpp \
    mafw-gst-renderer-utils.c \
    mafw-gst-renderer-worker.c \
    MafwGstRendererVolume.cpp \
    MafwGstRendererPlaylistFileUtility.cpp \
    MafwGstRendererNetworkMonitor.cpp \
    MafwGstRendererDolby.cpp \
    MafwGstScreenshot.cpp \
    MafwMmcMonitor.cpp \
    mafw-gst-renderer-seeker.c \
    MafwGstRendererHaltState.cpp

DISTFILES += qmafw-gst-renderer.service

# Installation
service.files     = com.nokia.mafw.plugin.libqmafw_gst_renderer_plugin.service
service.path      = $$PREFIX/share/dbus-1/services
target.path       = $$PREFIX/lib/qmafw-plugin

context.files     = com.nokia.mafw.context_provider.libqmafw_gst_renderer.context
context.path      = $$PREFIX/share/contextkit/providers

settings.files    = mafw-gst-renderer-plugin.conf
settings.path     = /usr/share/qmafw

INSTALLS         += target service context settings