git.maemo.org Git - mardrone/blob - mardrone/imports/com/meego/extras/ListButton.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the Qt Components project.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.1
  42 import Qt.labs.components 1.1
  43 import "." 1.0
  44 import "../meego/UIConstants.js" as UI
  45 import com.nokia.meego 1.0
  46
  47 Item {
  48     id: button
  49
  50     // Common public API
  51     property bool checked: false
  52     property bool checkable: false
  53     property alias pressed: mouseArea.pressed
  54     property alias text: label.text
  55     property url iconSource
  56
  57     signal clicked
  58
  59     // Used in ButtonGroup.js to set the segmented look on the buttons.
  60     property string __buttonType
  61
  62     // Styling for the Button
  63     property Style platformStyle: ButtonStyle {}
  64
  65     // Deprecated, TODO remove
  66     property alias style: button.platformStyle
  67
  68     implicitWidth: iconAndLabel.prefferedWidth
  69     implicitHeight: platformStyle.buttonHeight
  70
  71     property alias font: label.font
  72
  73     BorderImage {
  74         id: background
  75         anchors.fill: parent
  76
  77         border { left: button.platformStyle.backgroundMarginLeft; top: button.platformStyle.backgroundMarginTop;
  78                  right: button.platformStyle.backgroundMarginRight; bottom: button.platformStyle.backgroundMarginBottom }
  79         source: !enabled ?
  80                   (checked ? button.platformStyle.checkedDisabledBackground : button.platformStyle.disabledBackground) :
  81                   pressed ?
  82                       button.platformStyle.pressedBackground :
  83                   checked ?
  84                       button.platformStyle.checkedBackground :
  85                       button.platformStyle.background;
  86     }
  87
  88     Item {
  89         id: iconAndLabel
  90         property real xMargins: icon.visible ? (UI.PADDING_XLARGE * (label.visible ? 3 : 2)) : (UI.BUTTON_LABEL_MARGIN * 2)
  91         property real prefferedWidth: xMargins + (icon.visible ? icon.width : 0) + (label.visible ? label.prefferedSize.width : 0)
  92
  93         width: xMargins + (icon.visible ? icon.width : 0) + (label.visible? label.width : 0)
  94         height: platformStyle.buttonHeight
  95
  96         anchors.verticalCenter: button.verticalCenter
  97         anchors.horizontalCenter: button.horizontalCenter
  98         anchors.verticalCenterOffset: -1
  99
 100         Image {
 101             id: icon
 102             source: button.iconSource
 103             x: UI.PADDING_XLARGE
 104             anchors.verticalCenter: iconAndLabel.verticalCenter
 105             width: UI.SIZE_ICON_DEFAULT
 106             height: UI.SIZE_ICON_DEFAULT
 107             visible: source != ""
 108         }
 109
 110         Label {
 111             id: label
 112             x: icon.visible ? (icon.x + icon.width + UI.PADDING_XLARGE) : UI.BUTTON_LABEL_MARGIN
 113             anchors.verticalCenter: iconAndLabel.verticalCenter
 114             anchors.verticalCenterOffset: 1
 115
 116             property real availableWidth: button.width - iconAndLabel.xMargins - (icon.visible ? icon.width : 0)
 117             width: Math.min(prefferedSize.width, availableWidth)
 118
 119             elide: Text.ElideRight
 120             font.family: button.platformStyle.fontFamily
 121             font.weight: button.platformStyle.fontWeight
 122             font.pixelSize: button.platformStyle.fontPixelSize
 123             font.capitalization: button.platformStyle.fontCapitalization
 124             color: !enabled ? button.platformStyle.disabledTextColor :
 125                    pressed ? button.platformStyle.pressedTextColor :
 126                    checked ? button.platformStyle.checkedTextColor :
 127                              button.platformStyle.textColor;
 128             text: ""
 129             visible: text != ""
 130
 131             Label {
 132                 id: prefferedSize
 133                 font: parent.font
 134                 text: parent.text
 135                 visible: false
 136             }
 137             property alias prefferedSize: prefferedSize
 138         }
 139     }
 140
 141     MouseArea {
 142         id: mouseArea
 143         anchors.fill: parent
 144
 145         onClicked: {
 146             if (button.checkable)
 147                 button.checked = !button.checked;
 148             button.clicked();
 149         }
 150     }
 151 }