git.maemo.org Git - mardrone/blob - mardrone/imports/com/nokia/android.1.1/ApplicationWindow.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the Qt Components project.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.1
  42 import "." 1.1
  43
  44 Window {
  45     id: root
  46
  47     property bool fullScreen: false
  48     default property alias content: contentItem.data
  49     property alias pageStack: stack
  50     property variant initialPage
  51     property bool softwareInputPanelEnabled: false
  52
  53     onInitialPageChanged: {
  54         if (initialPage && contentArea.initialized) {
  55             if (stack.depth == 0)
  56                 stack.push(initialPage, null, true)
  57             else if (stack.depth == 1)
  58                 stack.replace(initialPage, null, true)
  59             else
  60                 console.log("Cannot update ApplicationWindow.initialPage")
  61         }
  62     }
  63
  64     Component.onCompleted: {
  65         console.log("warning: ApplicationWindow is an experimental component. Use Window instead.")
  66         contentArea.initialized = true
  67         if (initialPage && stack.depth == 0)
  68             stack.push(initialPage, null, true)
  69     }
  70
  71     Item {
  72         id: contentArea
  73
  74         property bool initialized: false
  75
  76         anchors.top: sbar.bottom
  77         anchors.bottom: sip.top
  78         anchors.left: parent.left
  79         anchors.right: parent.right
  80         Item {
  81             id: contentItem
  82             anchors.fill: parent
  83             PageStack {
  84                 id: stack
  85                 anchors.fill: parent
  86                 toolBar: tbar
  87             }
  88         }
  89     }
  90
  91     StatusBar {
  92         id: sbar
  93
  94         width: parent.width
  95         state: root.fullScreen ? "Hidden" : "Visible"
  96         platformInverted: root.platformInverted
  97
  98         states: [
  99             State {
 100                 name: "Visible"
 101                 PropertyChanges { target: sbar; y: 0; opacity: 1 }
 102             },
 103             State {
 104                 name: "Hidden"
 105                 PropertyChanges { target: sbar; y: -height; opacity: 0 }
 106             }
 107         ]
 108
 109         transitions: [
 110             Transition {
 111                 from: "Hidden"; to: "Visible"
 112                 ParallelAnimation {
 113                     NumberAnimation { target: sbar; properties: "y"; duration: 200; easing.type: Easing.OutQuad }
 114                     NumberAnimation { target: sbar; properties: "opacity"; duration: 200; easing.type: Easing.Linear }
 115                 }
 116             },
 117             Transition {
 118                 from: "Visible"; to: "Hidden"
 119                 ParallelAnimation {
 120                     NumberAnimation { target: sbar; properties: "y"; duration: 200; easing.type: Easing.Linear }
 121                     NumberAnimation { target: sbar; properties: "opacity"; duration: 200; easing.type: Easing.Linear }
 122                 }
 123             }
 124         ]
 125     }
 126
 127     Item {
 128         id: sip
 129
 130         anchors { bottom: parent.bottom; left: parent.left; right: parent.right }
 131
 132         Behavior on height { PropertyAnimation { duration: 200 } }
 133
 134         states: [
 135             State {
 136                 name: "Visible"; when: inputContext.visible && softwareInputPanelEnabled
 137                 PropertyChanges { target: sip; height: inputContext.height }
 138             },
 139
 140             State {
 141                 name: "Hidden"; when: !root.fullScreen
 142                 PropertyChanges { target: sip; height: tbar.height }
 143             },
 144
 145             State {
 146                 name: "HiddenInFullScreen"; when: root.fullScreen
 147                 PropertyChanges { target: sip; height: 0 }
 148             }
 149         ]
 150     }
 151
 152     ToolBar {
 153         id: tbar
 154
 155         width: parent.width
 156         state: root.fullScreen ? "Hidden" : "Visible"
 157         platformInverted: root.platformInverted
 158
 159         states: [
 160             State {
 161                 name: "Visible"
 162                 PropertyChanges { target: tbar; y: parent.height - height; opacity: 1 }
 163             },
 164             State {
 165                 name: "Hidden"
 166                 PropertyChanges { target: tbar; y: parent.height; opacity: 0 }
 167             }
 168         ]
 169
 170         transitions: [
 171             Transition {
 172                 from: "Hidden"; to: "Visible"
 173                 ParallelAnimation {
 174                     NumberAnimation { target: tbar; properties: "y"; duration: 200; easing.type: Easing.OutQuad }
 175                     NumberAnimation { target: tbar; properties: "opacity"; duration: 200; easing.type: Easing.Linear }
 176                 }
 177             },
 178             Transition {
 179                 from: "Visible"; to: "Hidden"
 180                 ParallelAnimation {
 181                     NumberAnimation { target: tbar; properties: "y"; duration: 200; easing.type: Easing.Linear }
 182                     NumberAnimation { target: tbar; properties: "opacity"; duration: 200; easing.type: Easing.Linear }
 183                 }
 184             }
 185         ]
 186     }
 187
 188     // event preventer when page transition is active
 189     MouseArea {
 190         anchors.fill: parent
 191         enabled: pageStack.busy
 192     }
 193 }