git.maemo.org Git - mardrone/blob - mardrone/imports/com/nokia/android.1.1/ContextMenu.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the Qt Components project.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.1
  42 import "." 1.1
  43
  44 Item {
  45     id: root
  46
  47     default property alias content: menu.content
  48     property Item visualParent: null
  49     property alias status: popup.status
  50
  51     // Symbian specific API
  52     property bool platformInverted: false
  53
  54     function open() {
  55         popup.open()
  56     }
  57
  58     function close() {
  59         popup.close()
  60     }
  61
  62     visible: false
  63     implicitWidth: {
  64         if (screen.width < screen.height)
  65             screen.width - 2 * platformStyle.paddingLarge
  66         else
  67             privateStyle.dialogMaxSize
  68     }
  69
  70     Popup {
  71         id: popup
  72
  73         animationDuration: 250
  74         state: "Hidden"
  75         anchors.centerIn: parent
  76         visible: status != DialogStatus.Closed
  77         enabled: status == DialogStatus.Open
  78         width: root.width
  79         height: menu.height
  80         platformInverted: root.platformInverted
  81
  82         onFaderClicked: {
  83             privateStyle.play(Android.PopupClose)
  84             close()
  85         }
  86
  87         MenuContent {
  88             id: menu
  89             containingPopup: popup
  90             width: parent.width
  91             platformInverted: root.platformInverted
  92             onItemClicked: popup.close()
  93         }
  94
  95         states: [
  96             State {
  97                 name: "Hidden"
  98                 when: status == DialogStatus.Closing || status == DialogStatus.Closed
  99                 PropertyChanges { target: popup; opacity: 0 }
 100             },
 101             State {
 102                 name: "Visible"
 103                 when: status == DialogStatus.Opening || status == DialogStatus.Open
 104                 PropertyChanges { target: popup; opacity: 1 }
 105             }
 106         ]
 107
 108         transitions: [
 109             Transition {
 110                 from: "Visible"; to: "Hidden"
 111                 SequentialAnimation {
 112                     NumberAnimation { properties: "opacity"; duration: popup.animationDuration; easing.type: Easing.Linear }
 113                     PropertyAction { target: popup; property: "status"; value: DialogStatus.Closed }
 114                 }
 115             },
 116             Transition {
 117                 from: "Hidden"; to: "Visible"
 118                 SequentialAnimation {
 119                     NumberAnimation { properties: "opacity"; duration: popup.animationDuration; easing.type: Easing.Linear }
 120                     PropertyAction { target: popup; property: "status"; value: DialogStatus.Open }
 121                 }
 122             }
 123         ]
 124     }
 125 }