git.maemo.org Git - mardrone/blob - mardrone/imports/com/nokia/android.1.1/RadioButton.qml

   1 /****************************************************************************
   2 **
   3 ** Copyright (C) 2011 Nokia Corporation and/or its subsidiary(-ies).
   4 ** All rights reserved.
   5 ** Contact: Nokia Corporation (qt-info@nokia.com)
   6 **
   7 ** This file is part of the Qt Components project.
   8 **
   9 ** $QT_BEGIN_LICENSE:BSD$
  10 ** You may use this file under the terms of the BSD license as follows:
  11 **
  12 ** "Redistribution and use in source and binary forms, with or without
  13 ** modification, are permitted provided that the following conditions are
  14 ** met:
  15 **   * Redistributions of source code must retain the above copyright
  16 **     notice, this list of conditions and the following disclaimer.
  17 **   * Redistributions in binary form must reproduce the above copyright
  18 **     notice, this list of conditions and the following disclaimer in
  19 **     the documentation and/or other materials provided with the
  20 **     distribution.
  21 **   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
  22 **     the names of its contributors may be used to endorse or promote
  23 **     products derived from this software without specific prior written
  24 **     permission.
  25 **
  26 ** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
  27 ** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
  28 ** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
  29 ** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
  30 ** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
  31 ** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
  32 ** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
  33 ** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
  34 ** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
  35 ** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
  36 ** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
  37 ** $QT_END_LICENSE$
  38 **
  39 ****************************************************************************/
  40
  41 import QtQuick 1.1
  42 import Qt.labs.components 1.1
  43 import "." 1.1
  44
  45 Item {
  46     id: root
  47
  48     // Common Public API
  49     property alias checked: checkable.checked
  50     property bool pressed: stateGroup.state == "Pressed" || stateGroup.state == "KeyPressed"
  51     signal clicked
  52     property alias text: label.text
  53
  54     // Symbian specific API
  55     property alias platformExclusiveGroup: checkable.exclusiveGroup
  56     property bool platformInverted: false
  57
  58     QtObject {
  59         id: internal
  60         objectName: "internal"
  61         property color disabledColor: root.platformInverted ? platformStyle.colorDisabledLightInverted
  62                                                             : platformStyle.colorDisabledLight
  63         property color pressedColor: root.platformInverted ? platformStyle.colorPressedInverted
  64                                                            : platformStyle.colorPressed
  65         property color normalColor: root.platformInverted ? platformStyle.colorNormalLightInverted
  66                                                           : platformStyle.colorNormalLight
  67
  68         function toggle() {
  69             clickedEffect.restart()
  70             checkable.toggle()
  71             root.clicked()
  72         }
  73
  74         function icon_postfix() {
  75             if (pressed)
  76                 return "pressed"
  77             else if (root.checked) {
  78                 if (!root.enabled)
  79                     return "disabled_selected"
  80                 else
  81                     return "normal_selected"
  82             } else {
  83                 if (!root.enabled)
  84                     return "disabled_unselected"
  85                 else
  86                     return "normal_unselected"
  87             }
  88         }
  89     }
  90
  91     StateGroup {
  92         id: stateGroup
  93
  94         states: [
  95             State { name: "Pressed" },
  96             State { name: "KeyPressed" },
  97             State { name: "Canceled" }
  98         ]
  99
 100         transitions: [
 101             Transition {
 102                 to: "Pressed"
 103                 ScriptAction { script:  privateStyle.play(Android.BasicItem) }
 104             },
 105             Transition {
 106                 from: "Pressed"
 107                 to: ""
 108                 ScriptAction { script: privateStyle.play(Android.CheckBox) }
 109                 ScriptAction { script: internal.toggle() }
 110             },
 111             Transition {
 112                 from: "KeyPressed"
 113                 to: ""
 114                 ScriptAction { script: internal.toggle() }
 115             }
 116         ]
 117     }
 118
 119     implicitWidth: privateStyle.textWidth(label.text, label.font) + platformStyle.paddingMedium + privateStyle.buttonSize
 120     implicitHeight: privateStyle.buttonSize
 121
 122     Image {
 123         id: image
 124         source: privateStyle.imagePath("qtg_graf_radiobutton_" + internal.icon_postfix(),
 125                                        root.platformInverted)
 126         anchors.left: parent.left
 127         anchors.verticalCenter: parent.verticalCenter
 128         sourceSize.width: privateStyle.buttonSize
 129         sourceSize.height: privateStyle.buttonSize
 130
 131         MouseArea {
 132             id: mouseArea
 133             anchors.fill: parent
 134
 135             onPressed: stateGroup.state = "Pressed"
 136             onReleased: stateGroup.state = ""
 137             onClicked: stateGroup.state = ""
 138             onExited: stateGroup.state = "Canceled"
 139             onCanceled: {
 140                 // Mark as canceled
 141                 stateGroup.state = "Canceled"
 142                 // Reset state. Can't expect a release since mouse was ungrabbed
 143                 stateGroup.state = ""
 144             }
 145         }
 146     }
 147
 148     Text {
 149         id: label
 150         elide: Text.ElideRight
 151         anchors.left: image.right
 152         anchors.leftMargin: platformStyle.paddingMedium
 153         anchors.verticalCenter: parent.verticalCenter
 154         anchors.right: parent.right
 155         horizontalAlignment: Text.AlignLeft
 156
 157         font { family: platformStyle.fontFamilyRegular; pixelSize: platformStyle.fontSizeMedium }
 158         color: root.enabled ? (root.pressed ? internal.pressedColor : internal.normalColor)
 159                             : internal.disabledColor
 160     }
 161
 162     ParallelAnimation {
 163         id: clickedEffect
 164         SequentialAnimation {
 165             PropertyAnimation {
 166                 target: image
 167                 property: "scale"
 168                 from: 1.0
 169                 to: 0.8
 170                 easing.type: Easing.Linear
 171                 duration: 50
 172             }
 173             PropertyAnimation {
 174                 target: image
 175                 property: "scale"
 176                 from: 0.8
 177                 to: 1.0
 178                 easing.type: Easing.OutQuad
 179                 duration: 170
 180             }
 181         }
 182     }
 183
 184     Keys.onPressed: {
 185         if (!event.isAutoRepeat && (event.key == Qt.Key_Select
 186                                     || event.key == Qt.Key_Return
 187                                     || event.key == Qt.Key_Enter)) {
 188             stateGroup.state = "KeyPressed"
 189             event.accepted = true
 190         }
 191     }
 192
 193     Keys.onReleased: {
 194         if (!event.isAutoRepeat && (event.key == Qt.Key_Select
 195                                     || event.key == Qt.Key_Return
 196                                     || event.key == Qt.Key_Enter)) {
 197             stateGroup.state = ""
 198             event.accepted = true
 199         }
 200     }
 201
 202     Checkable {
 203         id: checkable
 204         value: root.text
 205         enabled: true
 206     }
 207 }