TARGET = mdictionary
TEMPLATE = app

include(../../mdictionary.pri)

QT = core \
    gui \
    xml \
    xmlpatterns \
    sql \
    dbus \
    webkit \
    declarative

maemo5:QT += maemo5

message($$CONFIG)

SOURCES += gui/main.cpp \
    backbone/ConfigGenerator.cpp \
    gui/MainWindow.cpp \
    gui/SearchBarWidget.cpp \
    gui/WordListWidget.cpp \
    gui/TranslationWidget.cpp \
    backbone/backbone.cpp \
    gui/MenuWidget.cpp \
    gui/MenuTabWidget.cpp \
    gui/DictManagerWidget.cpp \
    gui/DictTypeSelectDialog.cpp \
    backbone/History.cpp \
    gui/HistoryListDialog.cpp \
    gui/WordListProxyStyle.cpp \
    backbone/Bookmarks.cpp \
    gui/SettingsWidget.cpp \
    gui/BookmarksWidget.cpp \
    gui/WelcomeScreenWidget.cpp \
    gui/AboutWidget.cpp \
    gui/TranslationView.cpp \
    gui/DBusAdapter.cpp \
    gui/NotifyManager.cpp \
    gui/SpinBox.cpp \
    gui/DictTypeModel.cpp \
    gui/DictManagerModel.cpp

HEADERS += gui/MainWindow.h \
    backbone/ConfigGenerator.h \
    gui/AboutWidget.h \
    gui/SearchBarWidget.h \
    gui/WordListWidget.h \
    gui/TranslationWidget.h \
    backbone/backbone.h \
    ../include/translation.h \
    ../include/settings.h \
    ../include/CommonDictInterface.h \
    gui/MenuWidget.h \
    gui/MenuTabWidget.h \
    gui/DictManagerWidget.h \
    gui/DictTypeSelectDialog.h \
    ../include/History.h \
    gui/HistoryListDialog.h \
    ../include/GUIInterface.h \
    gui/WordListProxyStyle.h \
    backbone/Bookmarks.h \
    backbone/BookmarkTranslations.h \
    gui/SettingsWidget.h \
    gui/BookmarksWidget.h \
    gui/WelcomeScreenWidget.h \
    ../include/Notify.h \
    gui/TranslationView.h \
    ../include/AccentsNormalizer.h \
    ../include/DictDialog.h \
    gui/DBusAdapter.h \
    gui/NotifyManager.h \
    gui/SpinBox.h \
    gui/DictTypeModel.h \
    gui/DictManagerModel.h

RESOURCES += ../../data/gui.qrc

TRANSLATIONS += pl_PL.ts \
                en_US.ts

OTHER_FILES += \
    qml/WelcomeScreenWidget.qml \
    qml/Button.qml \
    qml/AboutWidget.qml \
    qml/SearchBarWidget.qml \
    qml/IconButton.qml \
    qml/MyTextLineEdit.qml \
    qml/ProgressBar.qml \
    qml/ElementsListView.qml \
    qml/DictTypeSelectDialog.qml \
    qml/DictManagerWidget.qml \
    qml/WordListWidget.qml \
    qml/TranslationView.qml \
    qml/FlickableWebView.qml \
    qml/ScrollBar.qml \
    qml/SpinBox.qml

target.path = $$BIN_DIR
INSTALLS += target

unix { 
        #icons and misc
	maemo5 {
		desktop.path = $$SHARE_DIR/applications/hildon
		icon64.path = $$SHARE_DIR/icons/hicolor/64x64/hildon
	}    
	!maemo5 {
		desktop.path = $$SHARE_DIR/applications
		icon64.path = $$SHARE_DIR/icons
	}

	desktop.files += ../../data/other/$${TARGET}.desktop
	icon64.files += ../../data/icons/64x64/$${TARGET}.png

    shared.path = $$DATA_DIR
    shared.files += ../../data/icons/16x16/staron.png
    shared.files += ../../data/xsl/mask.png

    #css
    meego {
        css.path = $$DATA_DIR/css
        css.files += ../../data/css_meego/style.css
    }
    else:maemo5 {
        css.path = $$DATA_DIR/css
        css.files += ../../data/css_maemo/style.css
    }
    else {
        css.path = $$DATA_DIR/css
        css.files += ../../data/css_desktop/style.css
    }

    #css images
    meego {
	css_images.path = $$DATA_DIR/css/images
        css_images.files += ../../data/css_meego/images/header-background.png
        css_images.files += ../../data/css_meego/images/header-border.png
        css_images.files += ../../data/css_meego/images/shadow-grey-bg.png
        css_images.files += ../../data/css_meego/images/shadow-white-bg.png
        css_images.files += ../../data/css_meego/images/tab-background.png
        css_images.files += ../../data/css_meego/images/key-background.png
        css_images.files += ../../data/css_meego/images/shadow-transparent-bg. png
        css_images.files += ../../data/css_meego/images/splash2.png
    }
    else:maemo5 {
        css.path = $$DATA_DIR/css
        css.files += ../../data/css_maemo/style.css

        css_images.path = $$DATA_DIR/css/images
        css_images.files += ../../data/css_maemo/images/header-background.png
        css_images.files += ../../data/css_maemo/images/header-border.png
        css_images.files += ../../data/css_maemo/images/shadow-grey-bg.png
        css_images.files += ../../data/css_maemo/images/shadow-white-bg.png
        css_images.files += ../../data/css_maemo/images/tab-background.png
        css_images.files += ../../data/css_maemo/images/key-background.png
    }
    else {
        css.path = $$DATA_DIR/css
        css.files += ../../data/css_desktop/style.css

        css_images.path = $$DATA_DIR/css/images
        css_images.files += ../../data/css_desktop/images/header-background.png
        css_images.files += ../../data/css_desktop/images/header-border.png
        css_images.files += ../../data/css_desktop/images/shadow-grey-bg.png
        css_images.files += ../../data/css_desktop/images/shadow-white-bg.png
        css_images.files += ../../data/css_desktop/images/tab-background.png
        css_images.files += ../../data/css_desktop/images/key-background.png
    }

    #services
    service.path = $$SHARE_DIR/dbus-1/services
    service.files += ../../data/other/com.comarch.mdictionary.service

    #qmls (stub)
    meego {
        qmls.path = $$DATA_DIR/qml
        qmls.files += ./qml/WelcomeScreenWidget.qml
    }
    else:maemo5 {
        qmls.path = $$DATA_DIR/qml
        qmls.files += ./qml/WelcomeScreenWidget.qml
    }
    else {
        qmls.path = $$DATA_DIR/qml
        qmls.files += ./qml/WelcomeScreenWidget.qml
     	qmls.files += ./qml/Button.qml 
     	qmls.files += ./qml/AboutWidget.qml
     	qmls.files += ./qml/SearchBarWidget.qml
    	qmls.files += ./qml/IconButton.qml
     	qmls.files += ./qml/MyTextLineEdit.qml
        qmls.files += ./qml/ProgressBar.qml
        qmls.files += ./qml/ElementsListView.qml
        qmls.files += ./qml/DictTypeSelectDialog.qml
        qmls.files += ./qml/DictManagerWidget.qml
        qmls.files += ./qml/WordListWidget.qml
        qmls.files += ./qml/TranslationView.qml
        qmls.files += ./qml/FlickableWebView.qml
        qmls.files += ./qml/ScrollBar.qml
    }
	
    INSTALLS += desktop icon64 shared service css css_images qmls
}


check.commands = echo 'No check here'
QMAKE_EXTRA_TARGETS += check