git.maemo.org Git - modest/blob - configure.ac

   1 # Copyright (c) 2006,2007 Nokia Corporation
   2 # All rights reserved.
   3 #
   4 # Redistribution and use in source and binary forms, with or without
   5 # modification, are permitted provided that the following conditions are
   6 # met:
   7 #
   8 # * Redistributions of source code must retain the above copyright
   9 #   notice, this list of conditions and the following disclaimer.
  10 # * Redistributions in binary form must reproduce the above copyright
  11 #   notice, this list of conditions and the following disclaimer in the
  12 #   documentation and/or other materials provided with the distribution.
  13 # * Neither the name of the Nokia Corporation nor the names of its
  14 #   contributors may be used to endorse or promote products derived from
  15 #   this software without specific prior written permission.
  16 #
  17 # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
  18 # IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  19 # TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
  20 # PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER
  21 # OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  22 # EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  23 # PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  24 # PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  25 # LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  26 # NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  27 # SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  28
  29 AC_INIT([modest],[3.0],[http://maemo.org])
  30 AC_CONFIG_HEADERS([config.h])
  31
  32 m4_define([modest_api_major_version], [1])
  33 m4_define([modest_api_minor_version], [99])
  34 m4_define([modest_api_micro_version], [0])
  35 m4_define([modest_api_version], [modest_api_major_version.modest_api_minor_version.modest_api_micro_version])
  36
  37
  38 AC_CONFIG_SRCDIR(src/modest-main.c)
  39 AM_INIT_AUTOMAKE([dist-bzip2])
  40
  41 MODEST_API_MAJOR_VERSION=modest_api_major_version
  42 MODEST_API_MINOR_VERSION=modest_api_minor_version
  43 MODEST_API_MICRO_VERSION=modest_api_micro_version
  44 MODEST_API_VERSION=modest_api_version
  45 AC_SUBST(MODEST_API_MAJOR_VERSION)
  46 AC_SUBST(MODEST_API_MINOR_VERSION)
  47 AC_SUBST(MODEST_API_MICRO_VERSION)
  48 AC_SUBST(MODEST_API_VERSION)
  49
  50 ALL_LINGUAS="en_GB"
  51
  52 MODEST_LOCALE_DIR='$prefix/${DATADIRNAME}/locale'
  53 AM_GLIB_DEFINE_LOCALEDIR([MODEST_LOCALE_DIR])
  54 AM_GLIB_GNU_GETTEXT
  55
  56 if test x$prefix = xNONE; then
  57    prefix=/usr/local
  58 fi
  59 AC_SUBST(prefix)
  60
  61 AC_PROG_CC
  62 AC_PROG_CXX
  63 AM_PROG_CC_STDC
  64 AC_HEADER_STDC
  65 AC_PROG_LIBTOOL
  66
  67
  68 # Option to enable debugging
  69 AC_ARG_ENABLE(debug,
  70               [AC_HELP_STRING([--enable-debug],[Debugging (default=no)])],
  71               [with_debug=yes], [with_debug=no])
  72
  73 if test "x$with_debug" == "xyes" ; then
  74         CFLAGS="$CFLAGS -ggdb -O0 -DDEBUG -Wall"
  75 else
  76         CFLAGS="$CFLAGS -O2 -Wall"
  77 fi
  78
  79 # Option to enable debugging
  80 AC_ARG_ENABLE(gcov,
  81               [AC_HELP_STRING([--enable-gcov],[Coverage reporting (default=no)])],
  82               [with_gcov=yes], [with_gcov=no])
  83
  84 if test "x$with_gcov" == "xyes" ; then
  85         CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
  86         LDFLAGS="$LDFLAGS -lgcov"
  87 fi
  88
  89
  90
  91 dnl -------
  92 dnl GtkHTML
  93 dnl -------
  94
  95 AC_MSG_CHECKING(for installed version of libgtkhtml3)
  96 pkg-config --exists libgtkhtml-3.14
  97 retval=$?
  98 gtk_html_found=false
  99 if test $retval -eq 0 ; then
 100     gtk_html_found=true
 101     gtk_html_version=3.14
 102 else
 103     pkg-config --exists libgtkhtml-3.8
 104     retval=$?
 105     if test $retval -eq 0 ; then
 106       gtk_html_found=true
 107       gtk_html_version=3.8
 108     else
 109           if [ $gui = "true" ]; then
 110             AC_MSG_RESULT(libgtkhtml 3.4 or higher is not found!)
 111           fi
 112     fi
 113 fi
 114
 115 if [ $gtk_html_found = "true" ]; then
 116    version=`pkg-config --modversion libgtkhtml-${gtk_html_version}`
 117    AC_MSG_RESULT(found version $version)
 118 else
 119    AC_MSG_ERROR([install gtkhtml 3.8 or newer])
 120 fi
 121
 122
 123 dnl # GLib/Gobject/Gtk/Gconf => mandatory
 124
 125 PKG_CHECK_MODULES(MODEST_GSTUFF,glib-2.0 >= 2.6 gobject-2.0 gtk+-2.0 >= 2.6 gconf-2.0 gnome-vfs-2.0 libgtkhtml-${gtk_html_version} libtinymail-1.0 libtinymail-camel-1.0 libtinymail-gnomevfs-1.0 libtinymailui-1.0 libtinymailui-gtk-1.0)
 126 AC_SUBST(MODEST_GSTUFF_CFLAGS)
 127 AC_SUBST(MODEST_GSTUFF_LIBS)
 128
 129 modest_save_cflags="$CFLAGS"
 130 modest_save_libs="$LIBS"
 131 PKG_CHECK_MODULES(MODEST_GTKHTML,libgtkhtml-${gtk_html_version})
 132 AC_SUBST(MODEST_GTKHTML_CFLAGS)
 133 AC_SUBST(MODEST_GTKHTML_LIBS)
 134 CFLAGS="$MODEST_GTKHTML_CFLAGS"
 135 LIBS="$MODEST_GTKHTML_LIBS"
 136 AC_CHECK_DECLS([gtk_widget_tap_and_hold_setup],[],[], [#include <gtk/gtk.h>])
 137 AC_CHECK_FUNCS(gtk_html_set_max_image_size)
 138 AC_SUBST(HAVE_GTK_HTML_SET_MAX_IMAGE_SIZE)
 139 AC_CHECK_FUNCS(gtk_html_get_selection_area)
 140 AC_SUBST(HAVE_GTK_HTML_GET_SELECTION_AREA)
 141 AC_CHECK_FUNCS(gtk_tree_view_column_get_cell_data_hint)
 142 AC_SUBST(HAVE_GTK_TREE_VIEW_COLUMN_GET_CELL_DATA_HINT)
 143 CFLAGS="$modest_save_cflags"
 144 LIBS="$modest_save_libs"
 145
 146
 147 dnl dnl now, determine what to build
 148 dnl AC_MSG_NOTICE([Determining what platform to build])
 149 PKG_CHECK_MODULES(MODEST_MAEMO_LIBS,conic,[detected_platform=maemo],[detected_platform=gnome])
 150
 151 AC_ARG_WITH(platform, [
 152 Target platform:
 153   --with-platform=detect  detect target platform (default)
 154   --with-platform=gnome   build for Gnome
 155   --with-platform=maemo   build for Maemo
 156 ],
 157 [case "${with_platform}" in
 158        gnome|maemo|detect)    MODEST_PLATFORM=${with_platform};;
 159        *)        AC_MSG_ERROR([Unknown platform selected]);;
 160 esac], [MODEST_PLATFORM=detect])
 161
 162 if test "$MODEST_PLATFORM" = "detect"; then
 163         MODEST_PLATFORM="$detected_platform"
 164         with_platform=$detected_platform
 165 fi
 166
 167 if test "$with_platform" = "maemo"; then
 168         MODEST_PLUGIN_DEFINES=" -DMODEST_PLATFORM_MAEMO -DMODEST_API_VERSION=${MODEST_API_VERSION}"
 169 elif test "$with_platform" = "gnome"; then
 170         MODEST_PLUGIN_DEFINES=" -DMODEST_PLATFORM_GNOME -DMODEST_API_VERSION=${MODEST_API_VERSION}"
 171 fi
 172 AC_SUBST(MODEST_PLUGIN_DEFINES)
 173
 174 #
 175 # check the widgets library
 176 #
 177 have_hildon2=false
 178 have_hildon1=false
 179 have_hildon0=false
 180 have_gtk=false
 181 PKG_CHECK_EXISTS(hildon-1, have_hildon1=true,have_hildon1=false)
 182 if test "$have_hildon1" = "true"; then
 183    PKG_CHECK_EXISTS(hildon-1 >= 2.1.0 hildon-fm-2, have_hildon2=true, have_hildon2=false)
 184    PKG_CHECK_MODULES(MODEST_HILDON_WIDGETS,hildon-1 hildon-fm-2)
 185    hildonpkgs="hildon-1 hildon-fm-2"
 186    detected_toolkit=hildon1
 187    echo "DETECTED HILDON 1 $have_hildon2."
 188 else
 189    hildonpkgs="hildon-libs hildon-fm"
 190    detected_toolkit=hildon1
 191    PKG_CHECK_EXISTS(hildon-libs >= 0.12.0, have_hildon1=true, have_hildon1=false)
 192    if test "$have_hildon1" = "false"; then
 193       PKG_CHECK_EXISTS(hildon-libs, have_hildon0=true, have_hildon0=false)
 194       if test "$have_hildon0" = "false"; then
 195          have_gtk=true
 196          detected_toolkit=gtk
 197          hildonpkgs=
 198       fi
 199    fi
 200    if test "$have_gtk" = "false"; then
 201       PKG_CHECK_MODULES(MODEST_HILDON_WIDGETS,hildon-libs hildon-fm)
 202    fi
 203 fi
 204
 205 dnl --------------- HILDON & PLUGIN PKGS -----------
 206 pluginpkgs=$hildonpkgs
 207 echo "Plugin Packages $pluginpkgs"
 208 AC_SUBST(pluginpkgs)
 209
 210 use_profile_data=false
 211 # Plugin packages must not include libcanberra and libprofile
 212 if test "$have_hildon2" = "true"; then
 213    echo "DETECTED HILDON 2 $have_hildon2."
 214    detected_toolkit=hildon2
 215    hildonpkgs="$hildonpkgs libcanberra"
 216    AC_CHECK_HEADER([profiled/keys_nokia.h], use_profile_data=true, use_profile_data=false)
 217    if test "$use_profile_data" = "true"; then
 218       hildonpkgs="$hildonpkgs profile"
 219       AC_DEFINE_UNQUOTED(MODEST_USE_PROFILE, 1, ["Use the Profile data include"])
 220    fi
 221    echo "HILDON 2 PACKAGES $hildonpkgs"
 222 fi
 223 AC_SUBST(hildonpkgs)
 224
 225 dnl --------------- HILDON API ------------
 226 hildon_api=
 227 if test "$have_hildon0" = "true"; then
 228    hildon_api=0
 229 elif test "$have_hildon1" = "true"; then
 230    hildon_api=1
 231 elif test "$have_gtk" = "false"; then
 232    hildon_api=`$PKG_CONFIG --modversion hildon-1 | cut -d. -f1`
 233 fi
 234
 235 AC_DEFINE_UNQUOTED(MODEST_HILDON_API, $hildon_api, ["the API version of hildon"])
 236 MODEST_PLUGIN_DEFINES="$MODEST_PLUGIN_DEFINES -DMODEST_HILDON_API=$hildon_api"
 237
 238 AC_ARG_WITH(toolkit, [
 239 Target toolkit:
 240   --with-toolkit=detect  detect target toolkit (default)
 241   --with-toolkit=gtk   build for Gnome
 242   --with-toolkit=hildon1   build for Hildon 1.x
 243   --with-toolkit=hildon2   build for Hildon 2.x
 244 ],
 245 [case "${with_toolkit}" in
 246        gtk|hildon1|hildon2|detect)    MODEST_TOOLKIT=${with_toolkit};;
 247        *)        AC_MSG_ERROR([Unknown platform selected]);;
 248 esac], [MODEST_TOOLKIT=detect])
 249
 250 if test "$MODEST_TOOLKIT" = "detect"; then
 251         MODEST_TOOLKIT="$detected_toolkit"
 252         with_toolkit=$detected_toolkit
 253 fi
 254
 255 if test "$with_toolkit" = "hildon1"; then
 256         MODEST_PLUGIN_DEFINES="$MODEST_PLUGIN_DEFINES -DMODEST_TOOLKIT_HILDON1"
 257 elif test "$with_toolkit" = "hildon2"; then
 258         MODEST_PLUGIN_DEFINES="$MODEST_PLUGIN_DEFINES -DMODEST_TOOLKIT_HILDON2"
 259 elif test "$with_toolkit" = "gtk"; then
 260         MODEST_PLUGIN_DEFINES="$MODEST_PLUGIN_DEFINES -DMODEST_TOOLKIT_GNOME"
 261 fi
 262
 263 dnl Whether to use maemo-launcher or not
 264 AC_ARG_ENABLE([maemo-launcher],
 265               [AS_HELP_STRING([--enable-maemo-launcher],
 266                               [build with maemo-launcher support])],
 267                               [case "${enableval}" in
 268                                yes) maemo_launcher=true ;;
 269                                no)  maemo_launcher=false ;;
 270                                *) AC_MSG_ERROR([bad value ${enableval} for --enable-maemo-launcher]) ;;
 271                                esac], [maemo_launcher=false])
 272 if test x$maemo_launcher = xtrue
 273 then
 274         PKG_CHECK_MODULES(MAEMO_LAUNCHER, [maemo-launcher-app])
 275         AC_SUBST(MAEMO_LAUNCHER_CFLAGS)
 276         AC_SUBST(MAEMO_LAUNCHER_LIBS)
 277 fi
 278
 279 have_easysetup=false
 280 if test "x$with_toolkit" == "xgtk"; then
 281    PKG_CHECK_MODULES(MODEST_TOOLKIT,glib-2.0 >= 2.8 gtk+-2.0 >= 2.10 libnotify)
 282    AC_DEFINE_UNQUOTED(MODEST_TOOLKIT_GTK, 1, ["Whether modest is being build for the gtk toolkit."])
 283    MODEST_TOOLKIT_DIR=gnome
 284 else
 285    have_easysetup=true
 286    PKG_CHECK_MODULES(MODEST_TOOLKIT,$hildonpkgs)
 287    if test "$with_toolkit" = "hildon2"; then
 288       AC_DEFINE_UNQUOTED(MODEST_TOOLKIT_HILDON2, 1, ["Whether modest is being build for the hildon2 toolkit."])
 289       MODEST_TOOLKIT_DIR=hildon2
 290    else
 291       AC_DEFINE_UNQUOTED(MODEST_TOOLKIT_HILDON1, 1, ["Whether modest is being build for the hildon2 toolkit."])
 292       MODEST_TOOLKIT_DIR=maemo
 293    fi
 294     AC_DEFINE_UNQUOTED(MODEST_HAVE_EASYSETUP, 1, ["Whether we have the easysetup feature"])
 295 fi
 296 AM_CONDITIONAL(MODEST_HAVE_EASYSETUP,test "x$have_easysetup" == "xtrue")
 297 AC_SUBST(MODEST_TOOLKIT)
 298 AC_SUBST(MODEST_TOOLKIT_DIR)
 299
 300 if test "x$with_platform" == "xgnome"; then
 301       PKG_CHECK_MODULES(MODEST_PLATFORM,libtinymail-gnome-desktop-1.0 glib-2.0 >= 2.8 libnotify)
 302     AC_DEFINE_UNQUOTED(MODEST_PLATFORM_GNOME, 1, ["Whether modest is being built for the GNOME platform."])
 303 dnl     AC_MSG_ERROR([The GNOME Build is currently broken; please try the Maemo build instead])
 304 else
 305     have_dbusapi=true
 306     PKG_CHECK_MODULES(MODEST_PLATFORM,libosso dbus-1 libtinymail-maemo-1.0 libebook-1.2 )
 307     AC_DEFINE_UNQUOTED(MODEST_PLATFORM_MAEMO, 1, ["Whether modest is being built for the MAEMO platform."])
 308 fi
 309 AM_CONDITIONAL(MODEST_HAVE_DBUS_API,test "x$have_dbusapi" == "xtrue")
 310 AC_SUBST(MODEST_PLATFORM)
 311
 312
 313
 314 #
 315 # check for wpeditor or libwpeditor-plus (on maemo)
 316 #
 317 if test "x$with_toolkit" != "xgtk"; then
 318 PKG_CHECK_MODULES(MODEST_WPEDITOR,wpeditor,have_wpeditor=true,have_wpeditor=false)
 319 if test "x$have_wpeditor" == "xfalse"; then
 320    PKG_CHECK_MODULES(MODEST_WPEDITOR,libwpeditor-plus,have_libwpeditorplus=true,have_libwpeditorplus=false)
 321    if test "x$have_libwpeditorplus" == "xtrue"; then
 322         wpeditor="libwpeditor-plus"
 323         AC_DEFINE_UNQUOTED(MODEST_HAVE_LIBWPEDITOR_PLUS, 1, ["Whether libwpeditor-plus is used."])
 324    else
 325         AC_MSG_ERROR([you need to have either wpeditor or libwpeditor-plus installed])
 326    fi
 327 else
 328    wpeditor="wpeditor"
 329    AC_DEFINE_UNQUOTED(MODEST_HAVE_WPEDITOR, 1, ["Whether wpeditor is used."])
 330 fi
 331 fi
 332
 333
 334 #
 335 # check libalarm
 336 #
 337 if test "x$with_platform" == "xmaemo"; then
 338    PKG_CHECK_MODULES(MODEST_LIBALARM,libalarm,have_libalarm=true,have_libalarm=false)
 339    if test "x$have_libalarm" == "xfalse"; then
 340       PKG_CHECK_MODULES(MODEST_LIBALARM, alarm, have_libalarm=true,have_libalarm=false)
 341    fi
 342    if test "x$have_libalarm" == "xtrue"; then
 343       AC_DEFINE_UNQUOTED(MODEST_HAVE_LIBALARM, 1, ["Whether libalarm is used."])
 344       AC_SUBST(MODEST_LIBALARM_CFLAGS)
 345       AC_SUBST(MODEST_LIBALARM_LIBS)
 346    fi
 347 fi
 348
 349 #
 350 # check for MCE
 351 #
 352 if test "x$with_platform" == "xmaemo"; then
 353 PKG_CHECK_MODULES(MODEST_MCE,mce,have_mce=true,have_mce=false)
 354 if test "x$have_mce" == "xtrue"; then
 355    mce="mce"
 356    AC_DEFINE_UNQUOTED(MODEST_HAVE_MCE, 1, ["Whether mce is used."])
 357    AC_SUBST(MODEST_MCE_CFLAGS)
 358    AC_SUBST(MODEST_MCE_LIBS)
 359 else
 360    mce=""
 361 fi
 362 fi
 363
 364 #
 365 # check for libconic; this is a trick to check whether we run
 366 # on a 'real' maemo platform, or on, say, ubuntu embedded
 367 # this determines whether we build with the non-hildon GTK+
 368 #
 369 if test "x$with_platform" == "xmaemo"; then
 370 PKG_CHECK_MODULES(MODEST_LIBCONIC,conic,have_libconic=true,have_libconic=false)
 371 if test "x$have_libconic" == "xtrue"; then
 372    AC_DEFINE_UNQUOTED(MODEST_HAVE_HILDON_GTK,1,["Whether modest is being built with Hildon/Gtk"])
 373    AC_DEFINE_UNQUOTED(MODEST_HAVE_CONIC,1,["Whether modest has conic available"])
 374    AC_SUBST(MODEST_LIBCONIC_CLAGS)
 375    AC_SUBST(MODEST_LIBCONIC_LIBS)
 376 else
 377 # if we define this, tinymail will not try to #include conic headers
 378    CFLAGS="$CFLAGS -DLIBTINYMAIL_MAEMO_WITHOUT_CONIC"
 379 fi
 380 fi
 381
 382 #
 383 # check hildon-help (only for maemo AND NOT fremantle)
 384 #
 385 if test "x$with_toolkit" == "xhildon1"; then
 386    PKG_CHECK_MODULES(MODEST_HILDON_HELP,hildon-help,have_hildon_help=true,have_hildon_help=false)
 387    if test "x$have_hildon_help" == "xfalse"; then
 388       PKG_CHECK_MODULES(MODEST_HILDON_HELP,libossohelp,have_osso_help=true,have_osso_help=false)
 389       if test "x$have_osso_help" == "xtrue"; then
 390         helplib="osso-help"
 391         AC_DEFINE_UNQUOTED(MODEST_HAVE_OSSO_HELP, 1, ["Whether osso-help is used."])
 392       else
 393         AC_MSG_ERROR([you need to have either osso-help or hildon-help installed])
 394       fi
 395    else
 396      helplib="hildon-help"
 397      AC_DEFINE_UNQUOTED(MODEST_HAVE_HILDON_HELP, 1, ["Whether hildon-help is used."])
 398    fi
 399 fi
 400
 401
 402
 403 #
 404 # check for the notification stuff (only maemo)
 405 #
 406 if test "x$with_toolkit" != "xgtk"; then
 407    PKG_CHECK_MODULES(MODEST_HILDON_NOTIFY,hildon-notify libnotify,have_hildon_notify=true,have_hildon_notify=false)
 408    if test "x$have_hildon_notify" == "xtrue"; then
 409       AC_DEFINE_UNQUOTED(MODEST_HAVE_HILDON_NOTIFY, 1, ["Whether hildon-notify is available"])
 410    fi
 411 fi
 412
 413
 414 #
 415 # check for the uri/mime stuff
 416 #
 417 if test "x$with_toolkit" != "xgtk"; then
 418    PKG_CHECK_MODULES(MODEST_HILDON_MIME,libhildonmime,have_hildonmime=true,have_hildonmime=false)
 419    if test "x$have_hildonmime" == "xfalse"; then
 420       PKG_CHECK_MODULES(MODEST_HILDON_MIME,libossomime,have_ossomime=true,have_ossomime=false)
 421       if test "x$have_ossomime" == "xtrue"; then
 422         mimelib="osso-mime"
 423         AC_DEFINE_UNQUOTED(MODEST_HAVE_OSSO_MIME, 1, ["Whether osso-mime is used."])
 424       else
 425         AC_MSG_ERROR([you need to have either osso-mime or hildon-mime installed])
 426       fi
 427    else
 428      mimelib="hildon-mime"
 429      AC_DEFINE_UNQUOTED(MODEST_HAVE_HILDON_MIME, 1, ["Whether hildon-mime is used."])
 430    fi
 431 fi
 432
 433 PKG_CHECK_MODULES(MODEST_MOZEMBED, libtinymailui-mozembed-1.0, have_mozembed=true, have_mozembed=false)
 434 AC_ARG_ENABLE(mozembed,
 435 AC_HELP_STRING([--enable-mozembed],
 436         [Build with GtkMozEmbed (yes, no)]),
 437 [case "${enableval}" in
 438       yes)
 439         if test x$have_mozembed = xfalse; then
 440            AC_MSG_ERROR([building of GtkMozEmbed support requested and gtkmozembed not found])
 441         fi
 442         use_mozembed=true
 443         ;;
 444       *)
 445         use_mozembed=false
 446         ;;
 447 esac],[use_mozembed=false])
 448
 449 AM_CONDITIONAL(BUILD_MOZEMBED, test x$use_mozembed = xtrue)
 450
 451 if test x$use_mozembed = xtrue; then
 452         AC_DEFINE_UNQUOTED(MODEST_USE_MOZEMBED, 1, ["Whether we use GtkMozEmbed."])
 453 fi
 454
 455 #dnl wether we can and should build the
 456 #dnl search plugin (on maemo)
 457 if test "x$with_platform" == "xmaemo"; then
 458 PKG_CHECK_MODULES(MODEST_OGS, libosso >= 0.8.5 libogs-1.2, have_ogs=true, have_ogs=false)
 459 have_ogs_support=false
 460 AC_ARG_ENABLE(ogs_support,
 461 AC_HELP_STRING([--enable-ogs-support],
 462         [Build with osso global search support (yes, no)]),
 463 [case "${enableval}" in
 464       yes)
 465         if test x$have_ogs = xfalse; then
 466            AC_MSG_ERROR([building of ogs support requested and libogs-1.2 not found])
 467         fi
 468         ;;
 469       *)
 470         have_ogs_support=false
 471         ;;
 472 esac],[have_ogs_support=$have_ogs])
 473
 474 if test x$have_ogs_support = xtrue; then
 475         AC_DEFINE_UNQUOTED(MODEST_HAVE_OGS, 1, ["Whether ogs is available."])
 476 fi
 477 fi
 478
 479
 480
 481
 482 #
 483 # check the version of the addressbook on maemo
 484 #
 485 if test "x$with_platform" == "xmaemo"; then
 486    PKG_CHECK_MODULES(MODEST_ABOOK,osso-addressbook-1.0,have_abook=true,have_abook=false)
 487    abook_api=`$PKG_CONFIG --modversion osso-addressbook-1.0 | cut -d. -f1`
 488    AC_SUBST(MODEST_ABOOK_CFLAGS)
 489    AC_SUBST(MODEST_ABOOK_LIBS)
 490
 491    if test "x$have_abook" == "xfalse"; then
 492      PKG_CHECK_MODULES(MODEST_ABOOK, libosso-abook-1.0,have_abook=true,have_abook=false)
 493      abook_api=`$PKG_CONFIG --modversion libosso-abook-1.0 | cut -d. -f1`
 494      AC_SUBST(MODEST_ABOOK_CFLAGS)
 495      AC_SUBST(MODEST_ABOOK_LIBE)
 496    fi
 497
 498    if test "x$have_abook" == "xtrue"; then
 499       AC_DEFINE_UNQUOTED(OSSO_ABOOK_ENABLE_DEPRECATED, 1, ["use deprecated addressbook API"])
 500       AC_DEFINE_UNQUOTED(MODEST_ABOOK_API, $abook_api, ["the API version of osso-addressbook"])
 501       AC_DEFINE_UNQUOTED(MODEST_HAVE_ABOOK, 1, ["whether we have osso-addressbook"])
 502       addressbook="osso-addressbook"
 503    fi
 504 fi
 505
 506
 507 #
 508 # if we don't have an addressbook, use the dummy one
 509 #
 510 AM_CONDITIONAL(MODEST_USE_DUMMY_ADDRESS_BOOK,test "x$have_abook" != "xtrue")
 511
 512
 513 AM_GLIB_GNU_GETTEXT
 514 IT_PROG_INTLTOOL([0.35.0])
 515
 516 # gettext support
 517 GETTEXT_PACKAGE=modest
 518 AC_SUBST(GETTEXT_PACKAGE)
 519 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", ["gettext package"])
 520
 521
 522 #
 523 # settings for maemo platform
 524 #
 525 if test "x$with_platform" == "xmaemo"; then
 526
 527   # warnings are errors, but don't check format errors, because
 528   # it breaks with logical ids
 529   CFLAGS="$CFLAGS -Wno-format-extra-args -Werror"
 530
 531    desktopentrydir=`$PKG_CONFIG osso-af-settings --variable=desktopentrydir`
 532    serviceentrydir=`$PKG_CONFIG dbus-glib-1 --variable=prefix`/share/dbus-1/services
 533    localedir=`$PKG_CONFIG osso-af-settings --variable=localedir`
 534    backupsettingsdir=/etc/osso-backup/applications
 535    ossocudscriptsdir=/etc/osso-cud-scripts
 536    pixmapdir=`$PKG_CONFIG osso-af-settings --variable=hildonpixmapdir`
 537    icon_26x26dir=$datadir/icons/hicolor/26x26/hildon
 538    icon_34x34dir=$datadir/icons/hicolor/34x34/hildon
 539    icon_40x40dir=$datadir/icons/hicolor/40x40/hildon
 540    icon_50x50dir=$datadir/icons/hicolor/50x50/hildon
 541    icon_scalabledir=$datadir/icons/hicolor/scalable/hildon
 542    pluginlibdir=`$PKG_CONFIG hildon-control-panel --variable=plugindir`
 543    plugindesktopentrydir=`$PKG_CONFIG hildon-control-panel --variable=plugindesktopentrydir`
 544
 545    dbus_api="dbus_api"
 546    AC_SUBST(dbus_api)
 547
 548    # Define as variables in Makefiles
 549    AC_SUBST(desktopentrydir)
 550    AC_SUBST(serviceentrydir)
 551    AC_SUBST(backupsettingsdir)
 552    AC_SUBST(ossocudscriptsdir)
 553    AC_SUBST(localedir)
 554    AC_SUBST(pixmapdir)
 555    AC_SUBST(icon_26x26dir)
 556    AC_SUBST(icon_34x34dir)
 557    AC_SUBST(icon_40x40dir)
 558    AC_SUBST(icon_50x50dir)
 559    AC_SUBST(icon_scalabledir)
 560    AC_SUBST(pluginlibdir)
 561    AC_SUBST(plugindesktopentrydir)
 562
 563 fi
 564
 565 dnl ## setup the testing framework (ie., make check)
 566 build_tests=false
 567 AC_ARG_ENABLE(tests,
 568 AC_HELP_STRING([--enable-tests],
 569         [Build tests (no, yes)]),
 570 [case "${enableval}" in
 571       yes)
 572         build_tests=true ;;
 573       *) build_tests=false ;;
 574 esac],[build_tests=false])
 575 AM_CONDITIONAL(BUILD_TESTS, test x$build_tests = xtrue)
 576
 577
 578
 579 dnl ## is the check package installed?
 580 if test x$build_tests = xtrue; then
 581    PKG_CHECK_MODULES(CHECK, check >= 0.9.4 glib-2.0)
 582 fi
 583
 584
 585
 586 dnl ## do we want documentation (gtk-doc)
 587 build_docs=false
 588 AC_ARG_ENABLE(docs,
 589 AC_HELP_STRING([--enable-docs],
 590         [Build documentation (yes, no)]),
 591 [case "${enableval}" in
 592       yes)
 593         build_docs=true ;;
 594       *) build_docs=false ;;
 595 esac],[build_docs=false])
 596 AM_CONDITIONAL(BUILD_DOCS, test x$build_docs = xtrue)
 597
 598 dnl ## gtk-doc
 599 GTK_DOC_CHECK([1.0])
 600
 601 AC_OUTPUT([
 602 po/Makefile.in
 603 Makefile
 604 man/Makefile
 605 src/Makefile
 606 src/modest-plugin-1.0.pc
 607 src/dbus_api/Makefile
 608 src/gnome/Makefile
 609 src/maemo/Makefile
 610 src/maemo/easysetup/Makefile
 611 src/hildon2/Makefile
 612 src/widgets/Makefile
 613 docs/Makefile
 614 docs/reference/Makefile
 615 tests/Makefile
 616 tests/dbus_api/Makefile
 617 src/maemo/modest.desktop
 618 src/maemo/com.nokia.modest.service
 619 src/hildon2/modest.desktop
 620 src/hildon2/com.nokia.modest.service
 621 libmodest-dbus-client/Makefile
 622 libmodest-dbus-client/libmodest-dbus-client-1.0.pc
 623 ])
 624
 625
 626 echo
 627 echo "modest configure results"
 628 echo "-----------------------------------"
 629 echo "Platform         : $with_platform"
 630 echo "Toolkit          : $with_toolkit"
 631 echo "Prefix           : ${prefix}"
 632 echo "Build tests      : $build_tests"
 633 echo "Build docs       : $build_docs"
 634 echo "Gettext Package  : $GETTEXT_PACKAGE"
 635
 636 if test "x$with_platform" == "xmaemo"; then
 637    echo "Maemo Launcher   : $maemo_launcher"
 638    echo "Editor lib       : $wpeditor"
 639    echo "Addressbook      : $have_abook"
 640    if test "x$with_toolkit" == "xhildon1"; then
 641       echo "Help lib         : $helplib"
 642    fi
 643    echo "libconic support : $have_libconic"
 644    echo "Alarm            : $have_libalarm"
 645    echo "MCE              : $have_mce"
 646    echo "Hildon-Notify    : $have_hildon_notify"
 647    echo "LibOGS support   : $have_ogs_support"
 648 fi
 649
 650 echo "MozEmbed support : $use_mozembed"
 651 if [ $gtk_html_found = "true" ]; then
 652    echo "GtkHTML version  : $gtk_html_version"
 653 fi
 654
 655 echo "CFLAGS           : $CFLAGS"
 656 echo "Debug version    : $with_debug"
 657 echo ""
 658 echo "NOTE: you should do a 'make clean' after changing architecture or platform (--with-platform=)"
 659 echo ""