git.maemo.org Git - modest/blob - configure.ac

   1 # Copyright (c) 2006,2007 Nokia Corporation
   2 # All rights reserved.
   3 #
   4 # Redistribution and use in source and binary forms, with or without
   5 # modification, are permitted provided that the following conditions are
   6 # met:
   7 #
   8 # * Redistributions of source code must retain the above copyright
   9 #   notice, this list of conditions and the following disclaimer.
  10 # * Redistributions in binary form must reproduce the above copyright
  11 #   notice, this list of conditions and the following disclaimer in the
  12 #   documentation and/or other materials provided with the distribution.
  13 # * Neither the name of the Nokia Corporation nor the names of its
  14 #   contributors may be used to endorse or promote products derived from
  15 #   this software without specific prior written permission.
  16 #
  17 # THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS "AS
  18 # IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT LIMITED
  19 # TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR A
  20 # PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT OWNER
  21 # OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL, SPECIAL,
  22 # EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT LIMITED TO,
  23 # PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE, DATA, OR
  24 # PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY THEORY OF
  25 # LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT (INCLUDING
  26 # NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE OF THIS
  27 # SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE.
  28
  29 AC_INIT([modest],[3.2],[http://maemo.org])
  30 AC_CONFIG_HEADERS([config.h])
  31
  32 m4_define([modest_api_major_version], [1])
  33 m4_define([modest_api_minor_version], [99])
  34 m4_define([modest_api_micro_version], [0])
  35 m4_define([modest_api_version], [modest_api_major_version.modest_api_minor_version.modest_api_micro_version])
  36
  37
  38 AC_CONFIG_SRCDIR(src/modest-main.c)
  39 AM_INIT_AUTOMAKE([dist-bzip2])
  40
  41 MODEST_API_MAJOR_VERSION=modest_api_major_version
  42 MODEST_API_MINOR_VERSION=modest_api_minor_version
  43 MODEST_API_MICRO_VERSION=modest_api_micro_version
  44 MODEST_API_VERSION=modest_api_version
  45 AC_SUBST(MODEST_API_MAJOR_VERSION)
  46 AC_SUBST(MODEST_API_MINOR_VERSION)
  47 AC_SUBST(MODEST_API_MICRO_VERSION)
  48 AC_SUBST(MODEST_API_VERSION)
  49
  50 ALL_LINGUAS="en_GB"
  51
  52 MODEST_LOCALE_DIR='$prefix/${DATADIRNAME}/locale'
  53 AM_GLIB_DEFINE_LOCALEDIR([MODEST_LOCALE_DIR])
  54 AM_GLIB_GNU_GETTEXT
  55
  56 if test x$prefix = xNONE; then
  57    prefix=/usr/local
  58 fi
  59 AC_SUBST(prefix)
  60
  61 AC_PROG_CC
  62 AC_PROG_CXX
  63 AM_PROG_CC_STDC
  64 AM_PROG_CC_C_O
  65 AC_HEADER_STDC
  66 AC_PROG_LIBTOOL
  67
  68
  69 # Option to enable debugging
  70 AC_ARG_ENABLE(debug,
  71               [AC_HELP_STRING([--enable-debug],[Debugging (default=no)])],
  72               [with_debug=yes], [with_debug=no])
  73
  74 if test "x$with_debug" == "xyes" ; then
  75         CFLAGS="$CFLAGS -ggdb -O0 -DDEBUG -Wall"
  76 else
  77         CFLAGS="$CFLAGS -O2 -Wall"
  78 fi
  79
  80 # Option to enable debugging
  81 AC_ARG_ENABLE(gcov,
  82               [AC_HELP_STRING([--enable-gcov],[Coverage reporting (default=no)])],
  83               [with_gcov=yes], [with_gcov=no])
  84
  85 if test "x$with_gcov" == "xyes" ; then
  86         CFLAGS="$CFLAGS -fprofile-arcs -ftest-coverage"
  87         LDFLAGS="$LDFLAGS -lgcov"
  88 fi
  89
  90
  91
  92 dnl -------
  93 dnl GtkHTML
  94 dnl -------
  95
  96 AC_MSG_CHECKING(for installed version of libgtkhtml3)
  97 pkg-config --exists libgtkhtml-3.14
  98 retval=$?
  99 gtk_html_found=false
 100 if test $retval -eq 0 ; then
 101     gtk_html_found=true
 102     gtk_html_version=3.14
 103 else
 104     pkg-config --exists libgtkhtml-3.8
 105     retval=$?
 106     if test $retval -eq 0 ; then
 107       gtk_html_found=true
 108       gtk_html_version=3.8
 109     else
 110           if [ $gui = "true" ]; then
 111             AC_MSG_RESULT(libgtkhtml 3.4 or higher is not found!)
 112           fi
 113     fi
 114 fi
 115
 116 if [ $gtk_html_found = "true" ]; then
 117    version=`pkg-config --modversion libgtkhtml-${gtk_html_version}`
 118    AC_MSG_RESULT(found version $version)
 119 else
 120    AC_MSG_ERROR([install gtkhtml 3.8 or newer])
 121 fi
 122
 123
 124 PKG_CHECK_MODULES(LIBMODEST_DBUS_CLIENT,libmodest-dbus-client-1.0 >= 3.2.0)
 125
 126
 127 dnl # GLib/Gobject/Gtk/Gconf => mandatory
 128
 129 PKG_CHECK_MODULES(MODEST_GSTUFF,glib-2.0 >= 2.6 gobject-2.0 gtk+-2.0 >= 2.6 gconf-2.0 gnome-vfs-2.0 libgtkhtml-${gtk_html_version} libtinymail-1.0 >= 1.1.90 libtinymail-camel-1.0 >= 1.1.90 libtinymail-gnomevfs-1.0 >= 1.1.90 libtinymailui-1.0 >= 1.1.90 libtinymailui-gtk-1.0 >= 1.1.90)
 130 AC_SUBST(MODEST_GSTUFF_CFLAGS)
 131 AC_SUBST(MODEST_GSTUFF_LIBS)
 132
 133 modest_save_cflags="$CFLAGS"
 134 modest_save_libs="$LIBS"
 135 PKG_CHECK_MODULES(MODEST_GTKHTML,libgtkhtml-${gtk_html_version})
 136 AC_SUBST(MODEST_GTKHTML_CFLAGS)
 137 AC_SUBST(MODEST_GTKHTML_LIBS)
 138 CFLAGS="$MODEST_GTKHTML_CFLAGS"
 139 LIBS="$MODEST_GTKHTML_LIBS"
 140 AC_CHECK_DECLS([gtk_widget_tap_and_hold_setup],[],[], [#include <gtk/gtk.h>])
 141 AC_CHECK_FUNCS(gtk_html_set_max_image_size)
 142 AC_SUBST(HAVE_GTK_HTML_SET_MAX_IMAGE_SIZE)
 143 AC_CHECK_FUNCS(gtk_html_get_selection_area)
 144 AC_SUBST(HAVE_GTK_HTML_GET_SELECTION_AREA)
 145 AC_CHECK_FUNCS(gtk_html_set_allow_dnd)
 146 AC_SUBST(HAVE_GTK_HTML_SET_ALLOW_DND)
 147 AC_CHECK_FUNCS(gtk_html_set_default_engine)
 148 AC_SUBST(HAVE_GTK_HTML_SET_DEFAULT_ENGINE)
 149 AC_CHECK_FUNCS(gtk_html_set_word_char_wrapping)
 150 AC_SUBST(HAVE_GTK_HTML_SET_WORD_CHAR_WRAPPING)
 151 AC_CHECK_FUNCS(gtk_tree_view_column_get_cell_data_hint)
 152 AC_SUBST(HAVE_GTK_TREE_VIEW_COLUMN_GET_CELL_DATA_HINT)
 153 CFLAGS="$modest_save_cflags"
 154 LIBS="$modest_save_libs"
 155
 156
 157 dnl dnl now, determine what to build
 158 dnl AC_MSG_NOTICE([Determining what platform to build])
 159 PKG_CHECK_MODULES(MODEST_MAEMO_LIBS,conic,[detected_platform=maemo],[detected_platform=gnome])
 160
 161 AC_ARG_WITH(platform, [
 162 Target platform:
 163   --with-platform=detect  detect target platform (default)
 164   --with-platform=gnome   build for Gnome
 165   --with-platform=maemo   build for Maemo
 166 ],
 167 [case "${with_platform}" in
 168        gnome|maemo|detect)    MODEST_PLATFORM=${with_platform};;
 169        *)        AC_MSG_ERROR([Unknown platform selected]);;
 170 esac], [MODEST_PLATFORM=detect])
 171
 172 if test "$MODEST_PLATFORM" = "detect"; then
 173         MODEST_PLATFORM="$detected_platform"
 174         with_platform=$detected_platform
 175 fi
 176
 177 if test "$with_platform" = "maemo"; then
 178         MODEST_PLUGIN_DEFINES=" -DMODEST_PLATFORM_MAEMO -DMODEST_API_VERSION=${MODEST_API_VERSION}"
 179 elif test "$with_platform" = "gnome"; then
 180         MODEST_PLUGIN_DEFINES=" -DMODEST_PLATFORM_GNOME -DMODEST_API_VERSION=${MODEST_API_VERSION}"
 181 fi
 182 AC_SUBST(MODEST_PLUGIN_DEFINES)
 183 AM_CONDITIONAL(MODEST_BUILD_ASDBUS,test "x$with_platform" == "xmaemo")
 184
 185
 186 #
 187 # check the widgets library
 188 #
 189 have_hildon2=false
 190 have_hildon1=false
 191 have_hildon0=false
 192 have_gtk=false
 193 PKG_CHECK_EXISTS(hildon-1, have_hildon1=true,have_hildon1=false)
 194 if test "$have_hildon1" = "true"; then
 195    PKG_CHECK_EXISTS(hildon-1 >= 2.1.0 hildon-fm-2, have_hildon2=true, have_hildon2=false)
 196    PKG_CHECK_MODULES(MODEST_HILDON_WIDGETS,hildon-1 hildon-fm-2)
 197    hildonpkgs="hildon-1 hildon-fm-2"
 198    detected_toolkit=hildon1
 199    echo "DETECTED HILDON 1 $have_hildon2."
 200 else
 201    hildonpkgs="hildon-libs hildon-fm"
 202    detected_toolkit=hildon1
 203    PKG_CHECK_EXISTS(hildon-libs >= 0.12.0, have_hildon1=true, have_hildon1=false)
 204    if test "$have_hildon1" = "false"; then
 205       PKG_CHECK_EXISTS(hildon-libs, have_hildon0=true, have_hildon0=false)
 206       if test "$have_hildon0" = "false"; then
 207          have_gtk=true
 208          detected_toolkit=gtk
 209          hildonpkgs=
 210       fi
 211    fi
 212    if test "$have_gtk" = "false"; then
 213       PKG_CHECK_MODULES(MODEST_HILDON_WIDGETS,hildon-libs hildon-fm)
 214    fi
 215 fi
 216
 217 dnl --------------- HILDON & PLUGIN PKGS -----------
 218 pluginpkgs=$hildonpkgs
 219 echo "Plugin Packages $pluginpkgs"
 220 AC_SUBST(pluginpkgs)
 221
 222 use_profile_data=false
 223 # Plugin packages must not include libcanberra and libprofile
 224 if test "$have_hildon2" = "true"; then
 225    echo "DETECTED HILDON 2 $have_hildon2."
 226    detected_toolkit=hildon2
 227    hildonpkgs="$hildonpkgs libcanberra"
 228    AC_CHECK_HEADER([profiled/keys_nokia.h], use_profile_data=true, use_profile_data=false)
 229    if test "$use_profile_data" = "true"; then
 230       hildonpkgs="$hildonpkgs profile"
 231       AC_DEFINE_UNQUOTED(MODEST_USE_PROFILE, 1, ["Use the Profile data include"])
 232    fi
 233    echo "HILDON 2 PACKAGES $hildonpkgs"
 234 fi
 235 AC_SUBST(hildonpkgs)
 236
 237 dnl --------------- HILDON API ------------
 238 hildon_api=
 239 if test "$have_hildon0" = "true"; then
 240    hildon_api=0
 241 elif test "$have_hildon1" = "true"; then
 242    hildon_api=1
 243 elif test "$have_gtk" = "false"; then
 244    hildon_api=`$PKG_CONFIG --modversion hildon-1 | cut -d. -f1`
 245 fi
 246
 247 AC_DEFINE_UNQUOTED(MODEST_HILDON_API, $hildon_api, ["the API version of hildon"])
 248 MODEST_PLUGIN_DEFINES="$MODEST_PLUGIN_DEFINES -DMODEST_HILDON_API=$hildon_api"
 249
 250 AC_ARG_WITH(toolkit, [
 251 Target toolkit:
 252   --with-toolkit=detect  detect target toolkit (default)
 253   --with-toolkit=gtk   build for Gnome
 254   --with-toolkit=hildon1   build for Hildon 1.x
 255   --with-toolkit=hildon2   build for Hildon 2.x
 256 ],
 257 [case "${with_toolkit}" in
 258        gtk|hildon1|hildon2|detect)    MODEST_TOOLKIT=${with_toolkit};;
 259        *)        AC_MSG_ERROR([Unknown platform selected]);;
 260 esac], [MODEST_TOOLKIT=detect])
 261
 262 if test "$MODEST_TOOLKIT" = "detect"; then
 263         MODEST_TOOLKIT="$detected_toolkit"
 264         with_toolkit=$detected_toolkit
 265 fi
 266
 267 if test "$with_toolkit" = "hildon1"; then
 268         MODEST_PLUGIN_DEFINES="$MODEST_PLUGIN_DEFINES -DMODEST_TOOLKIT_HILDON1"
 269 elif test "$with_toolkit" = "hildon2"; then
 270         MODEST_PLUGIN_DEFINES="$MODEST_PLUGIN_DEFINES -DMODEST_TOOLKIT_HILDON2"
 271 elif test "$with_toolkit" = "gtk"; then
 272         MODEST_PLUGIN_DEFINES="$MODEST_PLUGIN_DEFINES -DMODEST_TOOLKIT_GNOME"
 273 fi
 274
 275 dnl Whether to use maemo-launcher or not
 276 AC_ARG_ENABLE([maemo-launcher],
 277               [AS_HELP_STRING([--enable-maemo-launcher],
 278                               [build with maemo-launcher support])],
 279                               [case "${enableval}" in
 280                                yes) maemo_launcher=true ;;
 281                                no)  maemo_launcher=false ;;
 282                                *) AC_MSG_ERROR([bad value ${enableval} for --enable-maemo-launcher]) ;;
 283                                esac], [maemo_launcher=false])
 284 if test x$maemo_launcher = xtrue
 285 then
 286         PKG_CHECK_MODULES(MAEMO_LAUNCHER, [maemo-launcher-app])
 287         AC_SUBST(MAEMO_LAUNCHER_CFLAGS)
 288         AC_SUBST(MAEMO_LAUNCHER_LIBS)
 289         MAEMO_LAUNCHER_MODEST_LDFLAGS="-shared "
 290 else
 291         MAEMO_LAUNCHER_MODEST_LDFLAGS="-export-dynamic "
 292 fi
 293 AC_SUBST(MAEMO_LAUNCHER_MODEST_LDFLAGS)
 294
 295 have_easysetup=false
 296 if test "x$with_toolkit" == "xgtk"; then
 297    PKG_CHECK_MODULES(MODEST_TOOLKIT,glib-2.0 >= 2.8 gtk+-2.0 >= 2.10 libnotify gtksourceview-2.0)
 298    AC_DEFINE_UNQUOTED(MODEST_TOOLKIT_GTK, 1, ["Whether modest is being build for the gtk toolkit."])
 299    MODEST_TOOLKIT_DIR=gnome
 300 else
 301    have_easysetup=true
 302    PKG_CHECK_MODULES(MODEST_TOOLKIT,$hildonpkgs)
 303    if test "$with_toolkit" = "hildon2"; then
 304       AC_DEFINE_UNQUOTED(MODEST_TOOLKIT_HILDON2, 1, ["Whether modest is being build for the hildon2 toolkit."])
 305       MODEST_TOOLKIT_DIR=hildon2
 306    else
 307       AC_DEFINE_UNQUOTED(MODEST_TOOLKIT_HILDON1, 1, ["Whether modest is being build for the hildon2 toolkit."])
 308       MODEST_TOOLKIT_DIR=maemo
 309    fi
 310     AC_DEFINE_UNQUOTED(MODEST_HAVE_EASYSETUP, 1, ["Whether we have the easysetup feature"])
 311 fi
 312 AM_CONDITIONAL(MODEST_HAVE_EASYSETUP,test "x$have_easysetup" == "xtrue")
 313 AC_SUBST(MODEST_TOOLKIT)
 314 AC_SUBST(MODEST_TOOLKIT_DIR)
 315
 316 if test "x$with_platform" == "xgnome"; then
 317       PKG_CHECK_MODULES(MODEST_PLATFORM,libtinymail-gnome-desktop-1.0 >= 1.1.90 glib-2.0 >= 2.8 libnotify)
 318     AC_DEFINE_UNQUOTED(MODEST_PLATFORM_GNOME, 1, ["Whether modest is being built for the GNOME platform."])
 319 dnl     AC_MSG_ERROR([The GNOME Build is currently broken; please try the Maemo build instead])
 320 else
 321     have_dbusapi=true
 322     PKG_CHECK_MODULES(MODEST_PLATFORM,libosso dbus-1 libtinymail-maemo-1.0 >= 1.1.90 libebook-1.2 )
 323     AC_DEFINE_UNQUOTED(MODEST_PLATFORM_MAEMO, 1, ["Whether modest is being built for the MAEMO platform."])
 324 fi
 325 AM_CONDITIONAL(MODEST_HAVE_DBUS_API,test "x$have_dbusapi" == "xtrue")
 326 AC_SUBST(MODEST_PLATFORM)
 327
 328
 329
 330 #
 331 # check for wpeditor or libwpeditor-plus (on maemo)
 332 #
 333 if test "x$with_toolkit" != "xgtk"; then
 334 PKG_CHECK_MODULES(MODEST_WPEDITOR,wpeditor,have_wpeditor=true,have_wpeditor=false)
 335 if test "x$have_wpeditor" == "xfalse"; then
 336    PKG_CHECK_MODULES(MODEST_WPEDITOR,libwpeditor-plus,have_libwpeditorplus=true,have_libwpeditorplus=false)
 337    if test "x$have_libwpeditorplus" == "xtrue"; then
 338         wpeditor="libwpeditor-plus"
 339         AC_DEFINE_UNQUOTED(MODEST_HAVE_LIBWPEDITOR_PLUS, 1, ["Whether libwpeditor-plus is used."])
 340    else
 341         AC_MSG_ERROR([you need to have either wpeditor or libwpeditor-plus installed])
 342    fi
 343 else
 344    wpeditor="wpeditor"
 345    AC_DEFINE_UNQUOTED(MODEST_HAVE_WPEDITOR, 1, ["Whether wpeditor is used."])
 346 fi
 347 fi
 348
 349
 350 #
 351 # check libalarm
 352 #
 353 if test "x$with_platform" == "xmaemo"; then
 354    PKG_CHECK_MODULES(MODEST_LIBALARM,libalarm,have_libalarm=true,have_libalarm=false)
 355    if test "x$have_libalarm" == "xfalse"; then
 356       PKG_CHECK_MODULES(MODEST_LIBALARM, alarm, have_libalarm=true,have_libalarm=false)
 357    fi
 358    if test "x$have_libalarm" == "xtrue"; then
 359       AC_DEFINE_UNQUOTED(MODEST_HAVE_LIBALARM, 1, ["Whether libalarm is used."])
 360       AC_SUBST(MODEST_LIBALARM_CFLAGS)
 361       AC_SUBST(MODEST_LIBALARM_LIBS)
 362    fi
 363 fi
 364
 365 #
 366 # check for MCE
 367 #
 368 if test "x$with_platform" == "xmaemo"; then
 369 PKG_CHECK_MODULES(MODEST_MCE,mce,have_mce=true,have_mce=false)
 370 if test "x$have_mce" == "xtrue"; then
 371    mce="mce"
 372    AC_DEFINE_UNQUOTED(MODEST_HAVE_MCE, 1, ["Whether mce is used."])
 373    AC_SUBST(MODEST_MCE_CFLAGS)
 374    AC_SUBST(MODEST_MCE_LIBS)
 375 else
 376    mce=""
 377 fi
 378 fi
 379
 380 #
 381 # check for libconic; this is a trick to check whether we run
 382 # on a 'real' maemo platform, or on, say, ubuntu embedded
 383 # this determines whether we build with the non-hildon GTK+
 384 #
 385 if test "x$with_platform" == "xmaemo"; then
 386 PKG_CHECK_MODULES(MODEST_LIBCONIC,conic,have_libconic=true,have_libconic=false)
 387 if test "x$have_libconic" == "xtrue"; then
 388    AC_DEFINE_UNQUOTED(MODEST_HAVE_HILDON_GTK,1,["Whether modest is being built with Hildon/Gtk"])
 389    AC_DEFINE_UNQUOTED(MODEST_HAVE_CONIC,1,["Whether modest has conic available"])
 390    AC_SUBST(MODEST_LIBCONIC_CLAGS)
 391    AC_SUBST(MODEST_LIBCONIC_LIBS)
 392 else
 393 # if we define this, tinymail will not try to #include conic headers
 394    CFLAGS="$CFLAGS -DLIBTINYMAIL_MAEMO_WITHOUT_CONIC"
 395 fi
 396 fi
 397
 398 #
 399 # check hildon-help (only for maemo AND NOT fremantle)
 400 #
 401 if test "x$with_toolkit" == "xhildon1"; then
 402    PKG_CHECK_MODULES(MODEST_HILDON_HELP,hildon-help,have_hildon_help=true,have_hildon_help=false)
 403    if test "x$have_hildon_help" == "xfalse"; then
 404       PKG_CHECK_MODULES(MODEST_HILDON_HELP,libossohelp,have_osso_help=true,have_osso_help=false)
 405       if test "x$have_osso_help" == "xtrue"; then
 406         helplib="osso-help"
 407         AC_DEFINE_UNQUOTED(MODEST_HAVE_OSSO_HELP, 1, ["Whether osso-help is used."])
 408       else
 409         AC_MSG_ERROR([you need to have either osso-help or hildon-help installed])
 410       fi
 411    else
 412      helplib="hildon-help"
 413      AC_DEFINE_UNQUOTED(MODEST_HAVE_HILDON_HELP, 1, ["Whether hildon-help is used."])
 414    fi
 415 fi
 416
 417
 418
 419 #
 420 # check for the notification stuff (only maemo)
 421 #
 422 if test "x$with_toolkit" != "xgtk"; then
 423    PKG_CHECK_MODULES(MODEST_HILDON_NOTIFY,hildon-notify libnotify,have_hildon_notify=true,have_hildon_notify=false)
 424    if test "x$have_hildon_notify" == "xtrue"; then
 425       AC_DEFINE_UNQUOTED(MODEST_HAVE_HILDON_NOTIFY, 1, ["Whether hildon-notify is available"])
 426    fi
 427 fi
 428
 429
 430 #
 431 # check for the uri/mime stuff
 432 #
 433 if test "x$with_toolkit" != "xgtk"; then
 434    PKG_CHECK_MODULES(MODEST_HILDON_MIME,libhildonmime,have_hildonmime=true,have_hildonmime=false)
 435    if test "x$have_hildonmime" == "xfalse"; then
 436       PKG_CHECK_MODULES(MODEST_HILDON_MIME,libossomime,have_ossomime=true,have_ossomime=false)
 437       if test "x$have_ossomime" == "xtrue"; then
 438         mimelib="osso-mime"
 439         AC_DEFINE_UNQUOTED(MODEST_HAVE_OSSO_MIME, 1, ["Whether osso-mime is used."])
 440       else
 441         AC_MSG_ERROR([you need to have either osso-mime or hildon-mime installed])
 442       fi
 443    else
 444      mimelib="hildon-mime"
 445      AC_DEFINE_UNQUOTED(MODEST_HAVE_HILDON_MIME, 1, ["Whether hildon-mime is used."])
 446    fi
 447 fi
 448
 449 PKG_CHECK_MODULES(MODEST_MOZEMBED, libtinymailui-mozembed-1.0 >= 1.1.90, have_mozembed=true, have_mozembed=false)
 450 AC_ARG_ENABLE(mozembed,
 451 AC_HELP_STRING([--enable-mozembed],
 452         [Build with GtkMozEmbed (yes, no)]),
 453 [case "${enableval}" in
 454       yes)
 455         if test x$have_mozembed = xfalse; then
 456            AC_MSG_ERROR([building of GtkMozEmbed support requested and gtkmozembed not found])
 457         fi
 458         use_mozembed=true
 459         ;;
 460       *)
 461         use_mozembed=false
 462         ;;
 463 esac],[use_mozembed=false])
 464
 465 AM_CONDITIONAL(BUILD_MOZEMBED, test x$use_mozembed = xtrue)
 466
 467 if test x$use_mozembed = xtrue; then
 468         AC_DEFINE_UNQUOTED(MODEST_USE_MOZEMBED, 1, ["Whether we use GtkMozEmbed."])
 469 fi
 470
 471 #dnl wether we can and should build the
 472 #dnl search plugin (on maemo)
 473 if test "x$with_platform" == "xmaemo"; then
 474 PKG_CHECK_MODULES(MODEST_OGS, libosso >= 0.8.5 libogs-1.2, have_ogs=true, have_ogs=false)
 475 have_ogs_support=false
 476 AC_ARG_ENABLE(ogs_support,
 477 AC_HELP_STRING([--enable-ogs-support],
 478         [Build with osso global search support (yes, no)]),
 479 [case "${enableval}" in
 480       yes)
 481         if test x$have_ogs = xfalse; then
 482            AC_MSG_ERROR([building of ogs support requested and libogs-1.2 not found])
 483         fi
 484         ;;
 485       *)
 486         have_ogs_support=false
 487         ;;
 488 esac],[have_ogs_support=$have_ogs])
 489
 490 if test x$have_ogs_support = xtrue; then
 491         AC_DEFINE_UNQUOTED(MODEST_HAVE_OGS, 1, ["Whether ogs is available."])
 492 fi
 493 fi
 494
 495
 496
 497
 498 #
 499 # check the version of the addressbook on maemo
 500 #
 501 if test "x$with_platform" == "xmaemo"; then
 502    PKG_CHECK_MODULES(MODEST_ABOOK,osso-addressbook-1.0,have_abook=true,have_abook=false)
 503    abook_api=`$PKG_CONFIG --modversion osso-addressbook-1.0 | cut -d. -f1`
 504    AC_SUBST(MODEST_ABOOK_CFLAGS)
 505    AC_SUBST(MODEST_ABOOK_LIBS)
 506
 507    if test "x$have_abook" == "xfalse"; then
 508      PKG_CHECK_MODULES(MODEST_ABOOK, libosso-abook-1.0,have_abook=true,have_abook=false)
 509      abook_api=`$PKG_CONFIG --modversion libosso-abook-1.0 | cut -d. -f1`
 510      AC_SUBST(MODEST_ABOOK_CFLAGS)
 511      AC_SUBST(MODEST_ABOOK_LIBS)
 512
 513      modest_save_cflags="$CFLAGS"
 514      modest_save_libs="$LIBS"
 515      CFLAGS="$MODEST_ABOOK_CFLAGS"
 516      LIBS="$MODEST_ABOOK_LIBS"
 517      AC_CHECK_FUNCS(osso_abook_contact_chooser_set_visible_func)
 518      AC_SUBST(HAVE_OSSO_ABOOK_CONTACT_CHOOSER_SET_VISIBLE_FUNC)
 519      CFLAGS="$modest_save_cflags"
 520      LIBS="$modest_save_libs"
 521    fi
 522
 523    if test "x$have_abook" == "xtrue"; then
 524       AC_DEFINE_UNQUOTED(OSSO_ABOOK_ENABLE_DEPRECATED, 1, ["use deprecated addressbook API"])
 525       AC_DEFINE_UNQUOTED(MODEST_ABOOK_API, $abook_api, ["the API version of osso-addressbook"])
 526       AC_DEFINE_UNQUOTED(MODEST_HAVE_ABOOK, 1, ["whether we have osso-addressbook"])
 527       addressbook="osso-addressbook"
 528    fi
 529
 530    # Check the presence of the calendar widgets
 531    PKG_CHECK_MODULES(MODEST_CALENDAR_WIDGETS,calendar-ui-widgets,have_calendar_widgets=true,have_calendar_widgets=false)
 532    AC_SUBST(MODEST_CALENDAR_WIDGETS_CFLAGS)
 533    AC_SUBST(MODEST_CALENDAR_WIDGETS_LIBS)
 534    if test "x$have_calendar_widgets" == "xtrue"; then
 535       AC_DEFINE_UNQUOTED(MODEST_USE_CALENDAR_WIDGETS, 1, ["Use the Calendar color widgets"])
 536    fi
 537 fi
 538
 539 AC_CHECK_HEADERS([clockd/libtime.h], have_libtime=true, have_libtime=false)
 540
 541 if test "x$have_libtime" == "xtrue"; then
 542    AC_DEFINE_UNQUOTED(MODEST_USE_LIBTIME, 1, ["use libtime API"])
 543    MODEST_LIBTIME_LIBS=-ltime
 544 else
 545    MODEST_LIBTIME_LIBS=
 546 fi
 547 AC_SUBST(MODEST_LIBTIME_LIBS)
 548
 549 AC_CHECK_HEADERS([iphbd/libiphb.h], have_libiphb=true, have_libiphb=false)
 550
 551 if test "x$have_libiphb" == "xtrue"; then
 552    AC_DEFINE_UNQUOTED(MODEST_USE_IPHB, 1, ["use IP Heartbeat API"])
 553    MODEST_LIBIPHB_LIBS=-liphb
 554 else
 555    MODEST_LIBIPHB_LIBS=
 556 fi
 557 AC_SUBST(MODEST_LIBIPHB_LIBS)
 558
 559 #
 560 # if we don't have an addressbook, use the dummy one
 561 #
 562 AM_CONDITIONAL(MODEST_USE_DUMMY_ADDRESS_BOOK,test "x$have_abook" != "xtrue")
 563
 564
 565 AM_GLIB_GNU_GETTEXT
 566 IT_PROG_INTLTOOL([0.35.0])
 567
 568 # gettext support
 569 GETTEXT_PACKAGE=modest
 570 AC_SUBST(GETTEXT_PACKAGE)
 571 AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", ["gettext package"])
 572
 573
 574 #
 575 # settings for maemo platform
 576 #
 577 if test "x$with_platform" == "xmaemo"; then
 578
 579   # warnings are errors, but don't check format errors, because
 580   # it breaks with logical ids
 581   CFLAGS="$CFLAGS -Wno-format-extra-args -Werror"
 582
 583    desktopentrydir=`$PKG_CONFIG osso-af-settings --variable=desktopentrydir`
 584    serviceentrydir=`$PKG_CONFIG dbus-glib-1 --variable=prefix`/share/dbus-1/services
 585    localedir=`$PKG_CONFIG osso-af-settings --variable=localedir`
 586    backupsettingsdir=/etc/osso-backup/applications
 587    prebackupdir=/etc/osso-backup/pre-backup.d/
 588    restoredir=/etc/osso-backup/restore.d/always/
 589    ossocudscriptsdir=/etc/osso-cud-scripts
 590    pixmapdir=`$PKG_CONFIG osso-af-settings --variable=hildonpixmapdir`
 591    icon_26x26dir=$datadir/icons/hicolor/26x26/hildon
 592    icon_34x34dir=$datadir/icons/hicolor/34x34/hildon
 593    icon_40x40dir=$datadir/icons/hicolor/40x40/hildon
 594    icon_50x50dir=$datadir/icons/hicolor/50x50/hildon
 595    icon_scalabledir=$datadir/icons/hicolor/scalable/hildon
 596    pluginlibdir=`$PKG_CONFIG hildon-control-panel --variable=plugindir`
 597    plugindesktopentrydir=`$PKG_CONFIG hildon-control-panel --variable=plugindesktopentrydir`
 598
 599    dbus_api="dbus_api"
 600    AC_SUBST(dbus_api)
 601
 602    # Define as variables in Makefiles
 603    AC_SUBST(desktopentrydir)
 604    AC_SUBST(serviceentrydir)
 605    AC_SUBST(backupsettingsdir)
 606    AC_SUBST(prebackupdir)
 607    AC_SUBST(restoredir)
 608    AC_SUBST(ossocudscriptsdir)
 609    AC_SUBST(localedir)
 610    AC_SUBST(pixmapdir)
 611    AC_SUBST(icon_26x26dir)
 612    AC_SUBST(icon_34x34dir)
 613    AC_SUBST(icon_40x40dir)
 614    AC_SUBST(icon_50x50dir)
 615    AC_SUBST(icon_scalabledir)
 616    AC_SUBST(pluginlibdir)
 617    AC_SUBST(plugindesktopentrydir)
 618
 619 fi
 620
 621 dnl ## setup the testing framework (ie., make check)
 622 build_tests=false
 623 AC_ARG_ENABLE(tests,
 624 AC_HELP_STRING([--enable-tests],
 625         [Build tests (no, yes)]),
 626 [case "${enableval}" in
 627       yes)
 628         build_tests=true ;;
 629       *) build_tests=false ;;
 630 esac],[build_tests=false])
 631 AM_CONDITIONAL(BUILD_TESTS, test x$build_tests = xtrue)
 632
 633
 634
 635 dnl ## is the check package installed?
 636 if test x$build_tests = xtrue; then
 637    PKG_CHECK_MODULES(CHECK, check >= 0.9.4 glib-2.0)
 638 fi
 639
 640
 641
 642 dnl ## do we want documentation (gtk-doc)
 643 build_docs=false
 644 AC_ARG_ENABLE(docs,
 645 AC_HELP_STRING([--enable-docs],
 646         [Build documentation (yes, no)]),
 647 [case "${enableval}" in
 648       yes)
 649         build_docs=true ;;
 650       *) build_docs=false ;;
 651 esac],[build_docs=false])
 652 AM_CONDITIONAL(BUILD_DOCS, test x$build_docs = xtrue)
 653
 654 dnl ## gtk-doc
 655 GTK_DOC_CHECK([1.0])
 656
 657 AC_OUTPUT([
 658 po/Makefile.in
 659 Makefile
 660 man/Makefile
 661 src/Makefile
 662 src/modest-plugin-1.0.pc
 663 src/dbus_api/Makefile
 664 src/gnome/Makefile
 665 src/maemo/Makefile
 666 src/maemo/easysetup/Makefile
 667 src/hildon2/Makefile
 668 src/widgets/Makefile
 669 docs/Makefile
 670 docs/reference/Makefile
 671 tests/Makefile
 672 tests/dbus_api/Makefile
 673 src/maemo/modest.desktop
 674 src/maemo/com.nokia.modest.service
 675 src/hildon2/modest.desktop
 676 src/hildon2/com.nokia.modest.service
 677 ])
 678
 679
 680 echo
 681 echo "modest configure results"
 682 echo "-----------------------------------"
 683 echo "Platform         : $with_platform"
 684 echo "Toolkit          : $with_toolkit"
 685 echo "Prefix           : ${prefix}"
 686 echo "Build tests      : $build_tests"
 687 echo "Build docs       : $build_docs"
 688 echo "Gettext Package  : $GETTEXT_PACKAGE"
 689
 690 if test "x$with_platform" == "xmaemo"; then
 691    echo "Maemo Launcher   : $maemo_launcher"
 692    echo "Editor lib       : $wpeditor"
 693    echo "Addressbook      : $have_abook"
 694    if test "x$with_toolkit" == "xhildon1"; then
 695       echo "Help lib         : $helplib"
 696    fi
 697    echo "libconic support : $have_libconic"
 698    echo "Alarm            : $have_libalarm"
 699    echo "MCE              : $have_mce"
 700    echo "Hildon-Notify    : $have_hildon_notify"
 701    echo "LibOGS support   : $have_ogs_support"
 702    echo "Calendar widgets : $have_calendar_widgets"
 703 fi
 704
 705 echo "MozEmbed support : $use_mozembed"
 706 if [ $gtk_html_found = "true" ]; then
 707    echo "GtkHTML version  : $gtk_html_version"
 708 fi
 709 echo "Libtime          : $have_libtime"
 710
 711 echo "CFLAGS           : $CFLAGS"
 712 echo "Debug version    : $with_debug"
 713 echo ""
 714 echo "NOTE: you should do a 'make clean' after changing architecture or platform (--with-platform=)"
 715 echo ""