dnl configure.ac for modest 
dnl Time-stamp: <2006-12-10 12:52:34 (djcb)> 
dnl written by Dirk-Jan C. Binnema <dirk-jan.binnema@nokia.com>


AC_INIT([modest],[0.0.1],[http://maemo.org])
AC_CONFIG_HEADERS([config.h])

AC_CONFIG_SRCDIR(src/modest-main.c)
AM_INIT_AUTOMAKE(AC_PACKAGE_NAME,AC_PACKAGE_VERSION)

# Check for gettext support
GETTEXT_PACKAGE=modest
AC_SUBST(GETTEXT_PACKAGE)
AC_DEFINE_UNQUOTED(GETTEXT_PACKAGE, "$GETTEXT_PACKAGE", ["Description"])

ALL_LINGUAS="en_GB gl nl"
#AM_GLIB_DEFINE_LOCALEDIR([MODEST_LOCALE_DIR])
AM_GLIB_GNU_GETTEXT

modestlocaledir='$prefix/${DATADIRNAME}/locale'
AC_SUBST(modestlocaledir)

if test x$prefix = xNONE; then
   prefix=/usr/local
fi
AC_SUBST(prefix)

AC_PROG_CC
AM_PROG_CC_STDC
AC_HEADER_STDC
AC_PROG_LIBTOOL




dnl # GLib/Gobject/Gtk/Gconf => mandatory
PKG_CHECK_MODULES(MODEST_GSTUFF,glib-2.0 >= 2.6 gobject-2.0 gtk+-2.0 >= 2.6 gconf-2.0 libgtkhtml-3.8 libglade-2.0 libtinymail-1.0 libtinymail-camel-1.0 libtinymailui-1.0 libtinymailui-gtk-1.0) 
AC_SUBST(MODEST_GSTUFF_CFLAGS)
AC_SUBST(MODEST_GSTUFF_LIBS)





dnl dnl now, determine what to build
AC_MSG_NOTICE([Determining what platform to build])
PKG_CHECK_MODULES(MODEST_LIBTINYMAIL_MAEMO,libosso,[with_platform=maemo],true)


AC_ARG_WITH(platform,
[--with-platform=gtk		platform to build for [gtk]],
[case "${with_platform}" in
       gtk)    MODEST_PLATFORM=gtk;;
       maemo) MODEST_PLATFORM=maemo;;
       *)      MODEST_PLATFORM=${with_platform}
esac], [MODEST_PLATFORM=gtk
               with_platform=gtk])
AC_SUBST(MODEST_PLATFORM)


if test "x$with_platform" = "xmaemo"; then
   PKG_CHECK_MODULES(MODEST_LIBTINYMAIL_MAEMO,libtinymail-maemo-1.0 hildon-libs libosso)
   AC_SUBST(MODEST_LIBTINYMAIL_MAEMO_CFLAGS)
   AC_SUBST(MODEST_LIBTINYMAIL_MAEMO_LIBS) 
   MODEST_PLATFORM_ID=2
else
   PKG_CHECK_MODULES(MODEST_LIBTINYMAIL_GNOME_DESKTOP,libtinymail-gnome-desktop-1.0 libnm_glib glib-2.0 >= 2.8)
   AC_SUBST(MODEST_LIBTINYMAIL_GNOME_DESKTOP_CFLAGS)
   AC_SUBST(MODEST_LIBTINYMAIL_GNOME_DESKTOP_LIBS)
   MODEST_PLATFORM_ID=1
fi

dnl 1==>gtk, 2==>maemo
AC_SUBST(MODEST_PLATFORM_ID)





dnl ## setup the testing framework (ie., make check)
build_tests=false
AC_ARG_ENABLE(tests,
AC_HELP_STRING([--enable-tests],
	[Build tests (no, yes)]),
[case "${enableval}" in
      yes)
	build_tests=true ;;
      *) build_tests=false ;;
esac],[build_tests=false])
AM_CONDITIONAL(BUILD_TESTS, test x$build_tests = xtrue)

dnl ## is the check package installed?
if test x$build_tests = xtrue; then
   PKG_CHECK_MODULES(CHECK, check >= 0.9.4 glib-2.0)
fi





dnl ## do we want documentation (gtk-doc)
build_docs=false
AC_ARG_ENABLE(docs,
AC_HELP_STRING([--enable-docs],
	[Build documentation (yes, no)]),
[case "${enableval}" in
      yes)
	build_docs=true ;;
      *) build_docs=false ;;
esac],[build_docs=false])
AM_CONDITIONAL(BUILD_DOCS, test x$build_docs = xtrue)

dnl ## is the check package installed?
GTK_DOC_CHECK([1.0])




AC_OUTPUT([
po/Makefile.in
Makefile
src/Makefile
src/gtk/Makefile
src/maemo/Makefile
src/widgets/Makefile
docs/Makefile
docs/reference/Makefile
tests/Makefile
])





echo
echo "modest configure results"
echo "-----------------------------------"
echo "Platform       : $with_platform"
echo "Build tests    : $build_tests"
echo "Build docs     : $build_docs"
echo ""
echo "NOTE: you should do a 'make clean' after changing platform (--with-platform=)"
echo ""