git.maemo.org Git - movie-schedule/blob - src/src.pro

   1 #-------------------------------------------------
   2 #
   3 # Project created by QtCreator 2010-03-01T19:21:07
   4 #
   5 #-------------------------------------------------
   6
   7 QT       += core gui network dbus
   8
   9 CONFIG += link_pkgconfig
  10
  11 maemo5 {
  12     QT += maemo5
  13     DEFINES += Q_WS_MAEMO_5
  14     maemo_sdk {
  15         CONFIG += icd2
  16         PKGCONFIG += calendar-backend liblocation
  17         DEFINES += MAEMO_SDK LIBLOCATION
  18     }
  19 }
  20
  21 mobility {
  22     MOBILITY += location
  23     DEFINES += QT_MOBILITY
  24     !contains(DEFINES, LIBLOCATION) {
  25         DEFINES += QT_MOBILITY_LOCATION
  26     }
  27 }
  28
  29 TARGET = movie-schedule
  30 TEMPLATE = app
  31
  32 INCLUDEPATH += .
  33
  34 SOURCES += \
  35     main.cpp \
  36     control/actioncontroller.cpp \
  37     control/maincontroller.cpp \
  38     control/moviecontroller.cpp \
  39     control/settingscontroller.cpp \
  40     control/theatercontroller.cpp \
  41     data/cinema.cpp \
  42     data/cinemakey.cpp \
  43     data/cinemaschedule.cpp \
  44     data/location.cpp \
  45     data/movie.cpp \
  46     data/moviekey.cpp \
  47     data/scheduleentry.cpp \
  48     data/scheduleentrykey.cpp \
  49     data/settings.cpp \
  50     searchclients/abstractsearchclient.cpp \
  51     searchclients/movieschedulesearchclient.cpp \
  52     searchclients/moviesearchclient.cpp \
  53     searchclients/theaterschedulesearchclient.cpp \
  54     searchclients/theatersearchclient.cpp \
  55     ui/abstractmainwindow.cpp \
  56     ui/backgroundlabel.cpp \
  57     ui/cinemapainter.cpp \
  58     ui/contextdialog.cpp \
  59     ui/daypainter.cpp \
  60     ui/locationdialog.cpp \
  61     ui/mainwindow.cpp \
  62     ui/moviedelegate.cpp \
  63     ui/moviemodel.cpp \
  64     ui/moviepainter.cpp \
  65     ui/moviescheduledelegate.cpp \
  66     ui/movieschedulemodel.cpp \
  67     ui/moviewindow.cpp \
  68     ui/ratingprovider.cpp \
  69     ui/theaterdelegate.cpp \
  70     ui/theatermodel.cpp \
  71     ui/theaterscheduledelegate.cpp \
  72     ui/theaterschedulemodel.cpp \
  73     ui/theaterwindow.cpp \
  74     ui/uiutils.cpp \
  75     utils/assertedlock.cpp \
  76     utils/assertedlocker.cpp \
  77     utils/calendar.cpp \
  78     utils/timeutils.cpp \
  79     movieschedule.cpp \
  80     ui/scheduleentryitem.cpp \
  81     control/itemmodelsortcontroller.cpp \
  82     control/itemmodelsortclient.cpp \
  83     control/itemmodelsortproxy.cpp \
  84     utils/asynccallclient.cpp \
  85     utils/asynccallproxy.cpp \
  86     utils/asynccall.cpp \
  87     ui/styleutils.cpp \
  88     searchclients/gpsclient.cpp \
  89     ui/aboutdialog.cpp \
  90     searchclients/searchclientsemaphore.cpp \
  91     control/locationcontroller.cpp \
  92     utils/connectivitymanager.cpp
  93
  94 HEADERS  += \
  95     control/actioncontroller.h \
  96     control/maincontroller.h \
  97     control/moviecontroller.h \
  98     control/settingscontroller.h \
  99     control/theatercontroller.h \
 100     data/cinema.h \
 101     data/cinemakey.h \
 102     data/cinemaschedule.h \
 103     data/location.h \
 104     data/movie.h \
 105     data/moviekey.h \
 106     data/scheduleentry.h \
 107     data/scheduleentrykey.h \
 108     data/settings.h \
 109     searchclients/abstractsearchclient.h \
 110     searchclients/movieschedulesearchclient.h \
 111     searchclients/moviesearchclient.h \
 112     searchclients/theaterschedulesearchclient.h \
 113     searchclients/theatersearchclient.h \
 114     ui/abstractmainwindow.h \
 115     ui/backgroundlabel.h \
 116     ui/cinemapainter.h \
 117     ui/contextdialog.h \
 118     ui/daypainter.h \
 119     ui/locationdialog.h \
 120     ui/mainwindow.h \
 121     ui/moviedelegate.h \
 122     ui/moviemodel.h \
 123     ui/moviepainter.h \
 124     ui/moviescheduledelegate.h \
 125     ui/movieschedulemodel.h \
 126     ui/moviewindow.h \
 127     ui/ratingprovider.h \
 128     ui/theaterdelegate.h \
 129     ui/theatermodel.h \
 130     ui/theaterscheduledelegate.h \
 131     ui/theaterschedulemodel.h \
 132     ui/theaterwindow.h \
 133     ui/uiutils.h \
 134     utils/assertedlock.h \
 135     utils/assertedlocker.h \
 136     utils/calendar.h \
 137     utils/timeutils.h \
 138     utils/connect.h \
 139     movieschedule.h \
 140     ui/scheduleentryitem.h \
 141     control/itemmodelsortcontroller.h \
 142     control/itemmodelsortclient.h \
 143     control/itemmodelsortproxy.h \
 144     utils/asynccallclient.h \
 145     utils/asynccallproxy.h \
 146     utils/asynccall.h \
 147     ui/styleutils.h \
 148     searchclients/gpsclient.h \
 149     ui/aboutdialog.h \
 150     searchclients/searchclientsemaphore.h \
 151     control/locationcontroller.h \
 152     utils/connectivitymanager.h
 153
 154 FORMS    += \
 155     ui/theaterwindow.ui \
 156     ui/mainwindow.ui \
 157     ui/locationdialog.ui \
 158     ui/moviewindow.ui \
 159     ui/contextdialog.ui \
 160     ui/aboutdialog.ui \
 161
 162 RESOURCES += \
 163     resources.qrc
 164
 165 TRANSLATIONS += \
 166     translations/movie-schedule_de.ts
 167
 168 OTHER_FILES += \
 169     translations/movie-schedule_de.ts \
 170     ../data/movie-schedule.desktop \
 171     ../debian/copyright \
 172     ../debian/control \
 173     ../debian/changelog \
 174     ../debian/rules \
 175     ../data/clap.xcf \
 176     ../README \
 177     (Example) \
 178     ../COPYING \
 179     ../debian/postinst \
 180     ../debian/optify \
 181     ../debian/compat
 182
 183 maemo5 {
 184     SOURCES += ui/optionsdialog.cpp
 185     HEADERS += ui/optionsdialog.h
 186     FORMS += ui/optionsdialog.ui
 187 }
 188
 189 !isEmpty(TRANSLATIONS) {
 190     isEmpty(QMAKE_LRELEASE) {
 191         win32:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]\lrelease.exe
 192         else:QMAKE_LRELEASE = $$[QT_INSTALL_BINS]/lrelease
 193     }
 194
 195     isEmpty(TS_DIR):TS_DIR = translations
 196
 197     TSQM.name = lrelease ${QMAKE_FILE_IN}
 198     TSQM.input = TRANSLATIONS
 199     TSQM.output = $$TS_DIR/${QMAKE_FILE_BASE}.qm
 200     TSQM.commands = $$QMAKE_LRELEASE ${QMAKE_FILE_IN} -qm $$TS_DIR/${QMAKE_FILE_BASE}.qm
 201     TSQM.CONFIG = no_link
 202     QMAKE_EXTRA_COMPILERS += TSQM
 203
 204     PRE_TARGETDEPS += compiler_TSQM_make_all
 205 }
 206
 207 unix {
 208     #VARIABLES
 209     isEmpty(PREFIX) {
 210         PREFIX = /usr/local
 211         DEFINES += DEFAULT_PREFIX
 212     }
 213
 214     BINDIR = $$PREFIX/bin
 215     DATADIR =$$PREFIX/share
 216
 217     DEFINES += DATADIR=\"$$DATADIR\" PKGDATADIR=\"$$PKGDATADIR\"
 218
 219     #MAKE INSTALL
 220
 221     INSTALLS += target desktop scalable i18n
 222
 223     target.path = $$BINDIR
 224
 225     desktop.path = $$DATADIR/applications/hildon
 226     desktop.files += ../data/$${TARGET}.desktop
 227
 228     scalable.path = $$DATADIR/icons/hicolor/scalable/hildon
 229     scalable.files += ../data/scalable/$${TARGET}.png
 230
 231     i18n.path = $$DATADIR/$${TARGET}
 232     i18n.files += ../builddir/src/translations
 233
 234 }