git.maemo.org Git - pkg-perl/blob - deb-src/libdevel-symdump-perl/libdevel-symdump-perl-2.08/Makefile.PL

   1 use lib "./lib";
   2 use Devel::Symdump ();
   3 use ExtUtils::MakeMaker qw(:DEFAULT);
   4
   5 eval { require File::Spec; };
   6 my $HAVE_FILE_SPEC = !$@;
   7 use strict;
   8 use vars qw($VERSION);
   9
  10 my $Id = q$Id: Makefile.PL 146 2005-08-09 04:25:21Z k $;
  11 $VERSION = sprintf "%.3f", 1 + substr(q$Rev: 146 $,4)/1000;
  12
  13 my $version_diff = 0; # we'll have to die if this becomes true
  14 {
  15   local $^W;
  16   $ExtUtils::MakeMaker::VERSION = eval $ExtUtils::MakeMaker::VERSION;
  17 }
  18 if ($HAVE_FILE_SPEC) {
  19   my $version_from = File::Spec->catfile(qw(lib Devel Symdump.pm));
  20   my $version_set_manually = 1; # not by SVN
  21
  22   if ($ARGV[0] && $ARGV[0] eq "--setversion") {
  23     die "Your perl is a bit dated[$]].\nDo not make a release with it\n" if $] < 5.008;
  24     die "Your MakeMaker is a bit dated[$]].\nDo not make a release with it\n"
  25         if $ExtUtils::MakeMaker::VERSION < 6.3004;
  26     die "Your MakeMaker doesn't do the sign woodoo" unless
  27         MM->can("signature_target");
  28     shift @ARGV;
  29     my $st;
  30     local $ENV{LANG} = "C";
  31     open $st, "svn st -u|" or die;
  32     my $dirty = 0;
  33     while (<$st>) {
  34       next if /^\?/;
  35       next if /^Head revision:/;
  36       next if /^Status against revision:/;
  37       print;
  38       $dirty++;
  39     }
  40     close $st;
  41     die "Not everything checked in?" if $dirty;
  42
  43     # $re parses the upper boundary of the output of svnversion
  44     my $re;
  45     eval q{ $re = qr/(?:\d+:)?(\d+)[SM]*$/; };
  46     die $@ if $@; # old perl
  47     my($sv_dot)  = `svnversion .`             =~ $re;
  48     my($sv_from) = `svn st -u -v $version_from`  =~ /^.{8}\s*(?:\d+)\s*(\d+)/;
  49     die "Could not determine sv_from or sv_dot"
  50         unless $sv_from > 0 && $sv_dot > 0;
  51     if ($version_set_manually) {
  52       unshift @INC, "lib";
  53       require $version_from;
  54       open my $fh, "make the-release-name|" or die;
  55       my $have_version;
  56       while (<$fh>) {
  57         next unless /^version\s+([\d\._]+)/;
  58         $have_version = eval $1;
  59       }
  60       die "could not determine current version from Makefile" unless $have_version;
  61       eval q{
  62       no warnings "numeric";
  63       if ($Devel::Symdump::VERSION != $have_version) {
  64         warn "Not equal: D:S:VERSION[$Devel::Symdump::VERSION] Makefile version[$have_version]";
  65         $version_diff = 1;
  66       }
  67 };
  68       die $@ if $@;
  69     } else {
  70       if ($sv_dot > $sv_from) {
  71         warn "setting some property to make a checkin of this file possible";
  72         0==system(svn => "propset",
  73                   "cpan:release",
  74                   "after_$sv_dot",
  75                   $version_from) or die;
  76         warn "checking in to get the version up to the bleading edge";
  77         0==system(svn => "ci",
  78                   "-m",
  79                   "Property set for release after_$sv_dot",
  80                   $version_from) or die;
  81         # will have to die after Makefile is rewritten:
  82         $version_diff = 1;
  83       }
  84     }
  85     exit unless $version_diff;
  86   }
  87 }
  88
  89 my @sign = (MM->can("signature_target") ? (SIGN => 1) : ());
  90 WriteMakefile(
  91               NAME => "Devel::Symdump",
  92               DISTNAME => "Devel-Symdump",
  93               VERSION_FROM => "lib/Devel/Symdump.pm",
  94               ($ExtUtils::MakeMaker::VERSION >= 6.3001 ?
  95                (LICENSE      => "perl") : (),
  96               ),
  97               PREREQ_PM => {
  98                             'Test::More' => 0,
  99                            },
 100               'clean' => {FILES => '*/*/*~'},
 101               'dist' => {
 102                          DIST_DEFAULT => 'Makefile setversion README all chlog tardist',
 103                          COMPRESS => 'gzip -9f'
 104                         },
 105               @sign,
 106              );
 107
 108 if ($version_diff){
 109   die "
 110 ==> I had to update some \$VERSIONs <==
 111 ==> Your Makefile has been rebuilt. <==
 112 ==> Please rerun the make command.  <==
 113 ";
 114 }
 115
 116 # Exclude .svn directories.
 117 sub MY::libscan {
 118   my($self,$path) = @_;
 119   return '' if $path =~ m:(\b(RCS|CVS|SCCS)|\.svn)\b: ;
 120   $path;
 121 }
 122
 123 sub MY::postamble {
 124   q{
 125 setversion:
 126         $(PERL) Makefile.PL --setversion
 127
 128 README: lib/Devel/Symdump.pm Makefile
 129         chmod +w $@
 130         /usr/bin/pod2text lib/Devel/Symdump.pm > $@
 131
 132 chlog ::
 133         LC_ALL=en_GB.utf8 svn log -v -r `svnversion . | perl -ne '/(?:\d+:)?(\d+)[SM]*$$/&&print $$1'`:1 > ChangeLog.svn
 134         cat ChangeLog.local >> ChangeLog.svn
 135
 136 the-release-name :
 137         $(NOECHO) $(ECHO) 'version ' $(VERSION)
 138         $(NOECHO) $(ECHO) 'release-name ' $(DISTVNAME).tar$(SUFFIX)
 139
 140 release ::
 141         /usr/bin/perl -I../../CPAN/SVN/release-lib -S release $(DISTVNAME).tar$(SUFFIX)
 142
 143 sign:
 144         cpansign -s
 145
 146 howto-release:
 147         @$(ECHO) manually set version in Symdump.pm, edit ChangeLog
 148         @$(ECHO) make ci dist \&\& make release
 149 }
 150 }
 151
 152 sub MY::dist_ci {
 153   return qq{ci :
 154         svn ci
 155 };
 156 }
 157
 158 sub MY::dist_test {
 159   return q{
 160 # if we depend on $(DISTVNAME).tar$(SUFFIX), then the rest of the
 161 # Makefile breaks our intent to NOT remake dist
 162 disttest :
 163         rm -rf $(DISTVNAME)
 164         tar xvzf $(DISTVNAME).tar$(SUFFIX)
 165         cd $(DISTVNAME) && $(ABSPERLRUN) Makefile.PL
 166         cd $(DISTVNAME) && $(MAKE) $(PASTHRU)
 167         cd $(DISTVNAME) && $(MAKE) test $(PASTHRU)
 168 }
 169 }